Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28 use Koha::SMTP::Servers;
  29
  30 use base qw(Koha::Object);
  31
  32 =head1 NAME
  33
  34 Koha::Library - Koha Library Object class
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =head3 stockrotationstages
  41
  42   my $stages = Koha::Library->stockrotationstages;
  43
  44 Returns the stockrotation stages associated with this Library.
  45
  46 =cut
  47
  48 sub stockrotationstages {
  49     my ( $self ) = @_;
  50     my $rs = $self->_result->stockrotationstages;
  51     return Koha::StockRotationStages->_new_from_dbic( $rs );
  52 }
  53
  54 =head3 get_effective_marcorgcode
  55
  56     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  57
  58 Returns the effective MARC organization code of the library. It falls back to the value
  59 from the I<MARCOrgCode> syspref if undefined for the library.
  60
  61 =cut
  62
  63 sub get_effective_marcorgcode {
  64     my ( $self )  = @_;
  65
  66     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  67 }
  68
  69 =head3 smtp_server
  70
  71     my $smtp_server = $library->smtp_server;
  72     $library->smtp_server({ smtp_server => $smtp_server });
  73     $library->smtp_server({ smtp_server => undef });
  74
  75 Accessor for getting and setting the library's SMTP server.
  76
  77 Returns the effective SMTP server configuration to be used on the library. The returned
  78 value is always a I<Koha::SMTP::Server> object.
  79
  80 Setting it to undef will remove the link to a specific SMTP server and effectively
  81 make the library use the default setting
  82
  83 =cut
  84
  85 sub smtp_server {
  86     my ( $self, $params ) = @_;
  87
  88     my $library_smtp_server_rs = $self->_result->library_smtp_server;
  89
  90     if ( exists $params->{smtp_server} ) {
  91
  92         $self->_result->result_source->schema->txn_do( sub {
  93             $library_smtp_server_rs->delete
  94                 if $library_smtp_server_rs;
  95
  96             if ( defined $params->{smtp_server} ) {
  97                 # Set the new server
  98                 # Remove any already set SMTP server
  99
 100                 my $smtp_server = $params->{smtp_server};
 101                 $smtp_server->_result->add_to_library_smtp_servers({ library_id => $self->id });
 102             }
 103         });
 104     } # else => reset to default
 105     else {
 106         # Getter
 107         if ( $library_smtp_server_rs ) {
 108             return Koha::SMTP::Servers->find(
 109                 $library_smtp_server_rs->smtp_server_id );
 110         }
 111
 112         return Koha::SMTP::Servers->get_default;
 113     }
 114
 115     return $self;
 116 }
 117
 118 =head3 inbound_email_address
 119
 120   my $to_email = Koha::Library->inbound_email_address;
 121
 122 Returns an effective email address which should be accessible to librarians at the branch.
 123
 124 =cut
 125
 126 sub inbound_email_address {
 127     my ($self) = @_;
 128
 129     return
 130          $self->branchreplyto
 131       || $self->branchemail
 132       || C4::Context->preference('ReplytoDefault')
 133       || C4::Context->preference('KohaAdminEmailAddress')
 134       || undef;
 135 }
 136
 137 =head3 inbound_ill_address
 138
 139   my $to_email = Koha::Library->inbound_ill_address;
 140
 141 Returns an effective email address which should be accessible to librarians at the branch
 142 for inter library loans communication.
 143
 144 =cut
 145
 146 sub inbound_ill_address {
 147     my ($self) = @_;
 148
 149     return
 150          $self->branchillemail
 151       || C4::Context->preference('ILLDefaultStaffEmail')
 152       || $self->inbound_email_address;
 153 }
 154
 155 =head3 library_groups
 156
 157 Return the Library groups of this library
 158
 159 =cut
 160
 161 sub library_groups {
 162     my ( $self ) = @_;
 163     my $rs = $self->_result->library_groups;
 164     return Koha::Library::Groups->_new_from_dbic( $rs );
 165 }
 166
 167 =head3 cash_registers
 168
 169 Return Cash::Registers associated with this Library
 170
 171 =cut
 172
 173 sub cash_registers {
 174     my ( $self ) = @_;
 175     my $rs = $self->_result->cash_registers;
 176     return Koha::Cash::Registers->_new_from_dbic( $rs );
 177 }
 178
 179 =head3 to_api_mapping
 180
 181 This method returns the mapping for representing a Koha::Library object
 182 on the API.
 183
 184 =cut
 185
 186 sub to_api_mapping {
 187     return {
 188         branchcode       => 'library_id',
 189         branchname       => 'name',
 190         branchaddress1   => 'address1',
 191         branchaddress2   => 'address2',
 192         branchaddress3   => 'address3',
 193         branchzip        => 'postal_code',
 194         branchcity       => 'city',
 195         branchstate      => 'state',
 196         branchcountry    => 'country',
 197         branchphone      => 'phone',
 198         branchfax        => 'fax',
 199         branchemail      => 'email',
 200         branchillemail   => 'illemail',
 201         branchreplyto    => 'reply_to_email',
 202         branchreturnpath => 'return_path_email',
 203         branchurl        => 'url',
 204         issuing          => undef,
 205         branchip         => 'ip',
 206         branchnotes      => 'notes',
 207         marcorgcode      => 'marc_org_code',
 208     };
 209 }
 210
 211 =head3 get_hold_libraries
 212
 213 Return all libraries (including self) that belong to the same hold groups
 214
 215 =cut
 216
 217 sub get_hold_libraries {
 218     my ( $self ) = @_;
 219     my $library_groups = $self->library_groups;
 220     my @hold_libraries;
 221     while ( my $library_group = $library_groups->next ) {
 222         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 223         if($root->ft_local_hold_group) {
 224             push @hold_libraries, $root->all_libraries;
 225         }
 226     }
 227
 228     my %seen;
 229     @hold_libraries =
 230       grep { !$seen{ $_->id }++ } @hold_libraries;
 231
 232     return Koha::Libraries->search({ branchcode => { '-in' => [ keys %seen ] } });
 233 }
 234
 235 =head3 validate_hold_sibling
 236
 237 Return if given library is a valid hold group member
 238
 239 =cut
 240
 241 sub validate_hold_sibling {
 242     my ( $self, $params ) = @_;
 243
 244     return 1 if $params->{branchcode} eq $self->id;
 245
 246     my @hold_libraries = $self->get_hold_libraries;
 247
 248     foreach (@hold_libraries) {
 249         my $hold_library = $_;
 250         my $is_valid = 1;
 251         foreach my $key (keys %$params) {
 252             unless($hold_library->$key eq $params->{$key}) {
 253                 $is_valid=0;
 254                 last;
 255             }
 256         }
 257         if($is_valid) {
 258             #Found one library that meets all search parameters
 259             return 1;
 260         }
 261     }
 262     return 0;
 263 }
 264
 265 =head2 Internal methods
 266
 267 =head3 _type
 268
 269 =cut
 270
 271 sub _type {
 272     return 'Branch';
 273 }
 274
 275 1;