Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28 use Koha::SMTP::Servers;
  29
  30 use base qw(Koha::Object);
  31
  32 =head1 NAME
  33
  34 Koha::Library - Koha Library Object class
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =head3 stockrotationstages
  41
  42   my $stages = Koha::Library->stockrotationstages;
  43
  44 Returns the stockrotation stages associated with this Library.
  45
  46 =cut
  47
  48 sub stockrotationstages {
  49     my ( $self ) = @_;
  50     my $rs = $self->_result->stockrotationstages;
  51     return Koha::StockRotationStages->_new_from_dbic( $rs );
  52 }
  53
  54 =head3 get_effective_marcorgcode
  55
  56     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  57
  58 Returns the effective MARC organization code of the library. It falls back to the value
  59 from the I<MARCOrgCode> syspref if undefined for the library.
  60
  61 =cut
  62
  63 sub get_effective_marcorgcode {
  64     my ( $self )  = @_;
  65
  66     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  67 }
  68
  69 =head3 smtp_server
  70
  71     my $smtp_server = $library->smtp_server;
  72     $library->smtp_server({ smtp_server => $smtp_server });
  73     $library->smtp_server({ smtp_server => undef });
  74
  75 Accessor for getting and setting the library's SMTP server.
  76
  77 Returns the effective SMTP server configuration to be used on the library. The returned
  78 value is always a I<Koha::SMTP::Server> object.
  79
  80 Setting it to undef will remove the link to a specific SMTP server and effectively
  81 make the library use the default setting
  82
  83 =cut
  84
  85 sub smtp_server {
  86     my ( $self, $params ) = @_;
  87
  88     my $library_smtp_server_rs = $self->_result->library_smtp_server;
  89
  90     if ( exists $params->{smtp_server} ) {
  91
  92         $self->_result->result_source->schema->txn_do( sub {
  93             $library_smtp_server_rs->delete
  94                 if $library_smtp_server_rs;
  95
  96             if ( defined $params->{smtp_server} ) {
  97                 # Set the new server
  98                 # Remove any already set SMTP server
  99
 100                 my $smtp_server = $params->{smtp_server};
 101                 $smtp_server->_result->add_to_library_smtp_servers({ library_id => $self->id });
 102             }
 103         });
 104     } # else => reset to default
 105     else {
 106         # Getter
 107         if ( $library_smtp_server_rs ) {
 108             # use Data::Printer colored => 1;
 109             # p($library_smtp_server_rs);
 110             return Koha::SMTP::Servers->find(
 111                 $library_smtp_server_rs->smtp_server_id );
 112         }
 113
 114         return Koha::SMTP::Servers->get_default;
 115     }
 116
 117     return $self;
 118 }
 119
 120 =head3 inbound_email_address
 121
 122   my $to_email = Koha::Library->inbound_email_address;
 123
 124 Returns an effective email address which should be accessible to librarians at the branch.
 125
 126 =cut
 127
 128 sub inbound_email_address {
 129     my ($self) = @_;
 130
 131     return
 132          $self->branchreplyto
 133       || $self->branchemail
 134       || C4::Context->preference('ReplytoDefault')
 135       || C4::Context->preference('KohaAdminEmailAddress')
 136       || undef;
 137 }
 138
 139 =head3 library_groups
 140
 141 Return the Library groups of this library
 142
 143 =cut
 144
 145 sub library_groups {
 146     my ( $self ) = @_;
 147     my $rs = $self->_result->library_groups;
 148     return Koha::Library::Groups->_new_from_dbic( $rs );
 149 }
 150
 151 =head3 cash_registers
 152
 153 Return Cash::Registers associated with this Library
 154
 155 =cut
 156
 157 sub cash_registers {
 158     my ( $self ) = @_;
 159     my $rs = $self->_result->cash_registers;
 160     return Koha::Cash::Registers->_new_from_dbic( $rs );
 161 }
 162
 163 =head3 to_api_mapping
 164
 165 This method returns the mapping for representing a Koha::Library object
 166 on the API.
 167
 168 =cut
 169
 170 sub to_api_mapping {
 171     return {
 172         branchcode       => 'library_id',
 173         branchname       => 'name',
 174         branchaddress1   => 'address1',
 175         branchaddress2   => 'address2',
 176         branchaddress3   => 'address3',
 177         branchzip        => 'postal_code',
 178         branchcity       => 'city',
 179         branchstate      => 'state',
 180         branchcountry    => 'country',
 181         branchphone      => 'phone',
 182         branchfax        => 'fax',
 183         branchemail      => 'email',
 184         branchreplyto    => 'reply_to_email',
 185         branchreturnpath => 'return_path_email',
 186         branchurl        => 'url',
 187         issuing          => undef,
 188         branchip         => 'ip',
 189         branchnotes      => 'notes',
 190         marcorgcode      => 'marc_org_code',
 191     };
 192 }
 193
 194 =head3 get_hold_libraries
 195
 196 Return all libraries (including self) that belong to the same hold groups
 197
 198 =cut
 199
 200 sub get_hold_libraries {
 201     my ( $self ) = @_;
 202     my $library_groups = $self->library_groups;
 203     my @hold_libraries;
 204     while ( my $library_group = $library_groups->next ) {
 205         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 206         if($root->ft_local_hold_group) {
 207             push @hold_libraries, $root->all_libraries;
 208         }
 209     }
 210
 211     my %seen;
 212     @hold_libraries =
 213       grep { !$seen{ $_->id }++ } @hold_libraries;
 214
 215     return @hold_libraries;
 216 }
 217
 218 =head3 validate_hold_sibling
 219
 220 Return if given library is a valid hold group member
 221
 222 =cut
 223
 224 sub validate_hold_sibling {
 225     my ( $self, $params ) = @_;
 226     my @hold_libraries = $self->get_hold_libraries;
 227
 228     foreach (@hold_libraries) {
 229         my $hold_library = $_;
 230         my $is_valid = 1;
 231         foreach my $key (keys %$params) {
 232             unless($hold_library->$key eq $params->{$key}) {
 233                 $is_valid=0;
 234                 last;
 235             }
 236         }
 237         if($is_valid) {
 238             #Found one library that meets all search parameters
 239             return 1;
 240         }
 241     }
 242     return 0;
 243 }
 244
 245 =head2 Internal methods
 246
 247 =head3 _type
 248
 249 =cut
 250
 251 sub _type {
 252     return 'Branch';
 253 }
 254
 255 1;