Koha/Objects.pm

   1 package Koha::Objects;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23 use List::MoreUtils qw( none );
  24
  25 use Koha::Database;
  26
  27 =head1 NAME
  28
  29 Koha::Objects - Koha Object set base class
  30
  31 =head1 SYNOPSIS
  32
  33     use Koha::Objects;
  34     my @objects = Koha::Objects->search({ borrowernumber => $borrowernumber});
  35
  36 =head1 DESCRIPTION
  37
  38 This class must be subclassed.
  39
  40 =head1 API
  41
  42 =head2 Class Methods
  43
  44 =cut
  45
  46 =head3 Koha::Objects->new();
  47
  48 my $object = Koha::Objects->new();
  49
  50 =cut
  51
  52 sub new {
  53     my ($class) = @_;
  54     my $self = {};
  55
  56     bless( $self, $class );
  57 }
  58
  59 =head3 Koha::Objects->_new_from_dbic();
  60
  61 my $object = Koha::Objects->_new_from_dbic( $resultset );
  62
  63 =cut
  64
  65 sub _new_from_dbic {
  66     my ( $class, $resultset ) = @_;
  67     my $self = { _resultset => $resultset };
  68
  69     bless( $self, $class );
  70 }
  71
  72 =head3 Koha::Objects->find();
  73
  74 Similar to DBIx::Class::ResultSet->find this method accepts:
  75     \%columns_values | @pk_values, { key => $unique_constraint, %attrs }?
  76 Strictly speaking, columns_values should only refer to columns under an
  77 unique constraint.
  78
  79 It returns undef if no results were found
  80
  81 my $object = Koha::Objects->find( { col1 => $val1, col2 => $val2 } );
  82 my $object = Koha::Objects->find( $id );
  83 my $object = Koha::Objects->find( $idpart1, $idpart2, $attrs ); # composite PK
  84
  85 =cut
  86
  87 sub find {
  88     my ( $self, @pars ) = @_;
  89
  90     my $object;
  91
  92     unless (!@pars || none { defined($_) } @pars) {
  93         my $result = $self->_resultset()->find(@pars);
  94         if ($result) {
  95             $object = $self->object_class()->_new_from_dbic($result);
  96         }
  97     }
  98
  99     return $object;
 100 }
 101
 102 =head3 Koha::Objects->find_or_create();
 103
 104 my $object = Koha::Objects->find_or_create( $attrs );
 105
 106 =cut
 107
 108 sub find_or_create {
 109     my ( $self, $params ) = @_;
 110
 111     my $result = $self->_resultset->find_or_create($params);
 112
 113     return unless $result;
 114
 115     my $object = $self->object_class->_new_from_dbic($result);
 116
 117     return $object;
 118 }
 119
 120 =head3 Koha::Objects->search();
 121
 122 my @objects = Koha::Objects->search($params);
 123
 124 =cut
 125
 126 sub search {
 127     my ( $self, $params, $attributes ) = @_;
 128
 129     if (wantarray) {
 130         my @dbic_rows = $self->_resultset()->search($params, $attributes);
 131
 132         return $self->_wrap(@dbic_rows);
 133
 134     }
 135     else {
 136         my $class = ref($self) ? ref($self) : $self;
 137         my $rs = $self->_resultset()->search($params, $attributes);
 138
 139         return $class->_new_from_dbic($rs);
 140     }
 141 }
 142
 143 =head3 search_related
 144
 145     my @objects = Koha::Objects->search_related( $rel_name, $cond?, \%attrs? );
 146     my $objects = Koha::Objects->search_related( $rel_name, $cond?, \%attrs? );
 147
 148 Searches the specified relationship, optionally specifying a condition and attributes for matching records.
 149
 150 =cut
 151
 152 sub search_related {
 153     my ( $self, $rel_name, @params ) = @_;
 154
 155     return if !$rel_name;
 156     if (wantarray) {
 157         my @dbic_rows = $self->_resultset()->search_related($rel_name, @params);
 158         return if !@dbic_rows;
 159         my $object_class = _get_objects_class( $dbic_rows[0]->result_class );
 160
 161         eval "require $object_class";
 162         return _wrap( $object_class, @dbic_rows );
 163
 164     } else {
 165         my $rs = $self->_resultset()->search_related($rel_name, @params);
 166         return if !$rs;
 167         my $object_class = _get_objects_class( $rs->result_class );
 168
 169         eval "require $object_class";
 170         return _new_from_dbic( $object_class, $rs );
 171     }
 172 }
 173
 174 =head3 single
 175
 176 my $object = Koha::Objects->search({}, { rows => 1 })->single
 177
 178 Returns one and only one object that is part of this set.
 179 Returns undef if there are no objects found.
 180
 181 This is optimal as it will grab the first returned result without instantiating
 182 a cursor.
 183
 184 See:
 185 http://search.cpan.org/dist/DBIx-Class/lib/DBIx/Class/Manual/Cookbook.pod#Retrieve_one_and_only_one_row_from_a_resultset
 186
 187 =cut
 188
 189 sub single {
 190     my ($self) = @_;
 191
 192     my $single = $self->_resultset()->single;
 193     return unless $single;
 194
 195     return $self->object_class()->_new_from_dbic($single);
 196 }
 197
 198 =head3 Koha::Objects->next();
 199
 200 my $object = Koha::Objects->next();
 201
 202 Returns the next object that is part of this set.
 203 Returns undef if there are no more objects to return.
 204
 205 =cut
 206
 207 sub next {
 208     my ( $self ) = @_;
 209
 210     my $result = $self->_resultset()->next();
 211     return unless $result;
 212
 213     my $object = $self->object_class()->_new_from_dbic( $result );
 214
 215     return $object;
 216 }
 217
 218 =head3 Koha::Objects->last;
 219
 220 my $object = Koha::Objects->last;
 221
 222 Returns the last object that is part of this set.
 223 Returns undef if there are no object to return.
 224
 225 =cut
 226
 227 sub last {
 228     my ( $self ) = @_;
 229
 230     my $count = $self->_resultset->count;
 231     return unless $count;
 232
 233     my ( $result ) = $self->_resultset->slice($count - 1, $count - 1);
 234
 235     my $object = $self->object_class()->_new_from_dbic( $result );
 236
 237     return $object;
 238 }
 239
 240 =head3 empty
 241
 242     my $empty_rs = Koha::Objects->new->empty;
 243
 244 Sets the resultset empty. This is handy for consistency on method returns
 245 (e.g. if we know in advance we won't have results but want to keep returning
 246 an iterator).
 247
 248 =cut
 249
 250 sub empty {
 251     my ($self) = @_;
 252
 253     $self->_resultset()->set_cache([]);
 254
 255     return $self;
 256 }
 257
 258 =head3 Koha::Objects->reset();
 259
 260 Koha::Objects->reset();
 261
 262 resets iteration so the next call to next() will start agein
 263 with the first object in a set.
 264
 265 =cut
 266
 267 sub reset {
 268     my ( $self ) = @_;
 269
 270     $self->_resultset()->reset();
 271
 272     return $self;
 273 }
 274
 275 =head3 Koha::Objects->as_list();
 276
 277 Koha::Objects->as_list();
 278
 279 Returns an arrayref of the objects in this set.
 280
 281 =cut
 282
 283 sub as_list {
 284     my ( $self ) = @_;
 285
 286     my @dbic_rows = $self->_resultset()->all();
 287
 288     my @objects = $self->_wrap(@dbic_rows);
 289
 290     return wantarray ? @objects : \@objects;
 291 }
 292
 293 =head3 Koha::Objects->unblessed
 294
 295 Returns an unblessed representation of objects.
 296
 297 =cut
 298
 299 sub unblessed {
 300     my ($self) = @_;
 301
 302     return [ map { $_->unblessed } $self->as_list ];
 303 }
 304
 305 =head3 Koha::Objects->get_column
 306
 307 Return all the values of this set for a given column
 308
 309 =cut
 310
 311 sub get_column {
 312     my ($self, $column_name) = @_;
 313     return $self->_resultset->get_column( $column_name )->all;
 314 }
 315
 316 =head3 Koha::Objects->TO_JSON
 317
 318 Returns an unblessed representation of objects, suitable for JSON output.
 319
 320 =cut
 321
 322 sub TO_JSON {
 323     my ($self) = @_;
 324
 325     return [ map { $_->TO_JSON } $self->as_list ];
 326 }
 327
 328 =head3 Koha::Objects->to_api
 329
 330 Returns a representation of the objects, suitable for API output .
 331
 332 =cut
 333
 334 sub to_api {
 335     my ($self, $params) = @_;
 336
 337     return [ map { $_->to_api($params) } $self->as_list ];
 338 }
 339
 340 =head3 attributes_from_api
 341
 342     my $attributes = $objects->attributes_from_api( $api_attributes );
 343
 344 Translates attributes from the API to DBIC
 345
 346 =cut
 347
 348 sub attributes_from_api {
 349     my ( $self, $attributes ) = @_;
 350
 351     $self->{_singular_object} ||= $self->object_class->new();
 352     return $self->{_singular_object}->attributes_from_api( $attributes );
 353 }
 354
 355 =head3 from_api_mapping
 356
 357     my $mapped_attributes_hash = $objects->from_api_mapping;
 358
 359 Attributes map from the API to DBIC
 360
 361 =cut
 362
 363 sub from_api_mapping {
 364     my ( $self ) = @_;
 365
 366     $self->{_singular_object} ||= $self->object_class->new();
 367     return $self->{_singular_object}->from_api_mapping;
 368 }
 369
 370 =head3 prefetch_whitelist
 371
 372     my $whitelist = $object->prefetch_whitelist()
 373
 374 Returns a hash of prefetchable subs and the type it returns
 375
 376 =cut
 377
 378 sub prefetch_whitelist {
 379     my ( $self ) = @_;
 380
 381     $self->{_singular_object} ||= $self->object_class->new();
 382
 383     $self->{_singular_object}->prefetch_whitelist;
 384 }
 385
 386 =head3 Koha::Objects->_wrap
 387
 388 wraps the DBIC object in a corresponding Koha object
 389
 390 =cut
 391
 392 sub _wrap {
 393     my ( $self, @dbic_rows ) = @_;
 394
 395     my @objects = map { $self->object_class->_new_from_dbic( $_ ) } @dbic_rows;
 396
 397     return @objects;
 398 }
 399
 400 =head3 Koha::Objects->_resultset
 401
 402 Returns the internal resultset or creates it if undefined
 403
 404 =cut
 405
 406 sub _resultset {
 407     my ($self) = @_;
 408
 409     if ( ref($self) ) {
 410         $self->{_resultset} ||=
 411           Koha::Database->new()->schema()->resultset( $self->_type() );
 412
 413         return $self->{_resultset};
 414     }
 415     else {
 416         return Koha::Database->new()->schema()->resultset( $self->_type() );
 417     }
 418 }
 419
 420 sub _get_objects_class {
 421     my ( $type ) = @_;
 422     return unless $type;
 423
 424     if( $type->can('koha_objects_class') ) {
 425         return $type->koha_objects_class;
 426     }
 427     $type =~ s|Schema::Result::||;
 428     return "${type}s";
 429 }
 430
 431 =head3 columns
 432
 433 my @columns = Koha::Objects->columns
 434
 435 Return the table columns
 436
 437 =cut
 438
 439 sub columns {
 440     my ( $class ) = @_;
 441     return Koha::Database->new->schema->resultset( $class->_type )->result_source->columns;
 442 }
 443
 444 =head3 AUTOLOAD
 445
 446 The autoload method is used call DBIx::Class method on a resultset.
 447
 448 Important: If you plan to use one of the DBIx::Class methods you must provide
 449 relevant tests in t/db_dependent/Koha/Objects.t
 450 Currently count, pager, update and delete are covered.
 451
 452 =cut
 453
 454 sub AUTOLOAD {
 455     my ( $self, @params ) = @_;
 456
 457     my @known_methods = qw( count is_paged pager update delete result_class single slice );
 458     my $method = our $AUTOLOAD;
 459     $method =~ s/.*:://;
 460
 461
 462     unless ( grep { $_ eq $method } @known_methods ) {
 463         my $class = ref($self) ? ref($self) : $self;
 464         Koha::Exceptions::Object::MethodNotCoveredByTests->throw(
 465             error      => sprintf("The method %s->%s is not covered by tests!", $class, $method),
 466             show_trace => 1
 467         );
 468     }
 469
 470     my $r = eval { $self->_resultset->$method(@params) };
 471     if ( $@ ) {
 472         carp "No method $method found for " . ref($self) . " " . $@;
 473         return
 474     }
 475     return $r;
 476 }
 477
 478 =head3 _type
 479
 480 The _type method must be set for all child classes.
 481 The value returned by it should be the DBIC resultset name.
 482 For example, for holds, _type should return 'Reserve'.
 483
 484 =cut
 485
 486 sub _type { }
 487
 488 =head3 object_class
 489
 490 This method must be set for all child classes.
 491 The value returned by it should be the name of the Koha
 492 object class that is returned by this class.
 493 For example, for holds, object_class should return 'Koha::Hold'.
 494
 495 =cut
 496
 497 sub object_class { }
 498
 499 sub DESTROY { }
 500
 501 =head1 AUTHOR
 502
 503 Kyle M Hall <kyle@bywatersolutions.com>
 504
 505 =cut
 506
 507 1;