Koha/Patron/Attribute.pm

   1 package Koha::Patron::Attribute;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Koha::Database;
  21 use Koha::Exceptions::Patron::Attribute;
  22 use Koha::Patron::Attribute::Types;
  23 use Koha::AuthorisedValues;
  24
  25 use base qw(Koha::Object);
  26
  27 =head1 NAME
  28
  29 Koha::Patron::Attribute - Koha Patron Attribute Object class
  30
  31 =head1 API
  32
  33 =head2 Class Methods
  34
  35 =cut
  36
  37 =head3 store
  38
  39     my $attribute = Koha::Patron::Attribute->new({ code => 'a_code', ... });
  40     try { $attribute->store }
  41     catch { handle_exception };
  42
  43 =cut
  44
  45 sub store {
  46
  47     my $self = shift;
  48
  49     $self->_check_repeatable;
  50     $self->check_unique_id;
  51
  52     return $self->SUPER::store();
  53 }
  54
  55 =head3 type
  56
  57     my $attribute_type = $attribute->type;
  58
  59 Returns a C<Koha::Patron::Attribute::Type> object corresponding to the current patron attribute
  60
  61 =cut
  62
  63 sub type {
  64
  65     my $self = shift;
  66
  67     return scalar Koha::Patron::Attribute::Types->find( $self->code );
  68 }
  69
  70 =head3 authorised_value
  71
  72 my $authorised_value = $attribute->authorised_value;
  73
  74 Return the Koha::AuthorisedValue object of this attribute when one is attached.
  75
  76 Return undef if this attribute is not attached to an authorised value
  77
  78 =cut
  79
  80 sub authorised_value {
  81     my ($self) = @_;
  82
  83     return unless $self->type->authorised_value_category;
  84
  85     my $av = Koha::AuthorisedValues->search(
  86         {
  87             category         => $self->type->authorised_value_category,
  88             authorised_value => $self->attribute,
  89         }
  90     );
  91     return unless $av->count; # Data inconsistency
  92     return $av->next;
  93 }
  94
  95 =head3 description
  96
  97 my $description = $patron_attribute->description;
  98
  99 Return the value of this attribute or the description of the authorised value (when attached).
 100
 101 This method must be called when the authorised value's description must be
 102 displayed instead of the code.
 103
 104 =cut
 105
 106 sub description {
 107     my ( $self) = @_;
 108     if ( $self->type->authorised_value_category ) {
 109         my $av = $self->authorised_value;
 110         return $av ? $av->lib : "";
 111     }
 112     return $self->attribute;
 113 }
 114
 115
 116 =head2 Internal methods
 117
 118 =head3 _check_repeatable
 119
 120 _check_repeatable checks if the attribute type is repeatable and throws and exception
 121 if the attribute type isn't repeatable and there's already an attribute with the same
 122 code for the given patron.
 123
 124 =cut
 125
 126 sub _check_repeatable {
 127
 128     my $self = shift;
 129
 130     if ( !$self->type->repeatable ) {
 131         my $attr_count = Koha::Patron::Attributes->search(
 132             {   borrowernumber => $self->borrowernumber,
 133                 code           => $self->code
 134             }
 135             )->count;
 136         Koha::Exceptions::Patron::Attribute::NonRepeatable->throw()
 137             if $attr_count > 0;
 138     }
 139
 140     return $self;
 141 }
 142
 143 =head3 check_unique_id
 144
 145 check_unique_id checks if the attribute type is marked as unique id and throws and exception
 146 if the attribute type is a unique id and there's already an attribute with the same
 147 code and value on the database.
 148
 149 =cut
 150
 151 sub check_unique_id {
 152
 153     my $self = shift;
 154
 155     if ( $self->type->unique_id ) {
 156         my $params = { code => $self->code, attribute => $self->attribute };
 157
 158         $params->{borrowernumber} = { '!=' => $self->borrowernumber } if $self->borrowernumber;
 159         $params->{id}             = { '!=' => $self->id }             if $self->in_storage;
 160
 161         my $unique_count = Koha::Patron::Attributes
 162             ->search( $params )
 163             ->count;
 164         Koha::Exceptions::Patron::Attribute::UniqueIDConstraint->throw()
 165             if $unique_count > 0;
 166     }
 167
 168     return $self;
 169 }
 170
 171 =head3 _type
 172
 173 =cut
 174
 175 sub _type {
 176     return 'BorrowerAttribute';
 177 }
 178
 179 1;