Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::Debarments;
  43 use Koha::Patron::HouseboundProfile;
  44 use Koha::Patron::HouseboundRole;
  45 use Koha::Patron::Images;
  46 use Koha::Patron::Modifications;
  47 use Koha::Patron::Relationships;
  48 use Koha::Patrons;
  49 use Koha::Plugins;
  50 use Koha::Subscription::Routinglists;
  51 use Koha::Token;
  52 use Koha::Virtualshelves;
  53
  54 use base qw(Koha::Object);
  55
  56 use constant ADMINISTRATIVE_LOCKOUT => -1;
  57
  58 our $RESULTSET_PATRON_ID_MAPPING = {
  59     Accountline          => 'borrowernumber',
  60     Aqbasketuser         => 'borrowernumber',
  61     Aqbudget             => 'budget_owner_id',
  62     Aqbudgetborrower     => 'borrowernumber',
  63     ArticleRequest       => 'borrowernumber',
  64     BorrowerAttribute    => 'borrowernumber',
  65     BorrowerDebarment    => 'borrowernumber',
  66     BorrowerFile         => 'borrowernumber',
  67     BorrowerModification => 'borrowernumber',
  68     ClubEnrollment       => 'borrowernumber',
  69     Issue                => 'borrowernumber',
  70     ItemsLastBorrower    => 'borrowernumber',
  71     Linktracker          => 'borrowernumber',
  72     Message              => 'borrowernumber',
  73     MessageQueue         => 'borrowernumber',
  74     OldIssue             => 'borrowernumber',
  75     OldReserve           => 'borrowernumber',
  76     Rating               => 'borrowernumber',
  77     Reserve              => 'borrowernumber',
  78     Review               => 'borrowernumber',
  79     SearchHistory        => 'userid',
  80     Statistic            => 'borrowernumber',
  81     Suggestion           => 'suggestedby',
  82     TagAll               => 'borrowernumber',
  83     Virtualshelfcontent  => 'borrowernumber',
  84     Virtualshelfshare    => 'borrowernumber',
  85     Virtualshelve        => 'owner',
  86 };
  87
  88 =head1 NAME
  89
  90 Koha::Patron - Koha Patron Object class
  91
  92 =head1 API
  93
  94 =head2 Class Methods
  95
  96 =head3 new
  97
  98 =cut
  99
 100 sub new {
 101     my ( $class, $params ) = @_;
 102
 103     return $class->SUPER::new($params);
 104 }
 105
 106 =head3 fixup_cardnumber
 107
 108 Autogenerate next cardnumber from highest value found in database
 109
 110 =cut
 111
 112 sub fixup_cardnumber {
 113     my ( $self ) = @_;
 114     my $max = Koha::Patrons->search({
 115         cardnumber => {-regexp => '^-?[0-9]+$'}
 116     }, {
 117         select => \'CAST(cardnumber AS SIGNED)',
 118         as => ['cast_cardnumber']
 119     })->_resultset->get_column('cast_cardnumber')->max;
 120     $self->cardnumber(($max || 0) +1);
 121 }
 122
 123 =head3 trim_whitespace
 124
 125 trim whitespace from data which has some non-whitespace in it.
 126 Could be moved to Koha::Object if need to be reused
 127
 128 =cut
 129
 130 sub trim_whitespaces {
 131     my( $self ) = @_;
 132
 133     my $schema  = Koha::Database->new->schema;
 134     my @columns = $schema->source($self->_type)->columns;
 135
 136     for my $column( @columns ) {
 137         my $value = $self->$column;
 138         if ( defined $value ) {
 139             $value =~ s/^\s*|\s*$//g;
 140             $self->$column($value);
 141         }
 142     }
 143     return $self;
 144 }
 145
 146 =head3 plain_text_password
 147
 148 $patron->plain_text_password( $password );
 149
 150 stores a copy of the unencrypted password in the object
 151 for use in code before encrypting for db
 152
 153 =cut
 154
 155 sub plain_text_password {
 156     my ( $self, $password ) = @_;
 157     if ( $password ) {
 158         $self->{_plain_text_password} = $password;
 159         return $self;
 160     }
 161     return $self->{_plain_text_password}
 162         if $self->{_plain_text_password};
 163
 164     return;
 165 }
 166
 167 =head3 store
 168
 169 Patron specific store method to cleanup record
 170 and do other necessary things before saving
 171 to db
 172
 173 =cut
 174
 175 sub store {
 176     my ($self) = @_;
 177
 178     $self->_result->result_source->schema->txn_do(
 179         sub {
 180             if (
 181                 C4::Context->preference("autoMemberNum")
 182                 and ( not defined $self->cardnumber
 183                     or $self->cardnumber eq '' )
 184               )
 185             {
 186                 # Warning: The caller is responsible for locking the members table in write
 187                 # mode, to avoid database corruption.
 188                 # We are in a transaction but the table is not locked
 189                 $self->fixup_cardnumber;
 190             }
 191
 192             unless( $self->category->in_storage ) {
 193                 Koha::Exceptions::Object::FKConstraint->throw(
 194                     broken_fk => 'categorycode',
 195                     value     => $self->categorycode,
 196                 );
 197             }
 198
 199             $self->trim_whitespaces;
 200
 201             # Set surname to uppercase if uppercasesurname is true
 202             $self->surname( uc($self->surname) )
 203                 if C4::Context->preference("uppercasesurnames");
 204
 205             $self->relationship(undef) # We do not want to store an empty string in this field
 206               if defined $self->relationship
 207                      and $self->relationship eq "";
 208
 209             unless ( $self->in_storage ) {    #AddMember
 210
 211                 # Generate a valid userid/login if needed
 212                 $self->generate_userid
 213                   if not $self->userid or not $self->has_valid_userid;
 214
 215                 # Add expiration date if it isn't already there
 216                 unless ( $self->dateexpiry ) {
 217                     $self->dateexpiry( $self->category->get_expiry_date );
 218                 }
 219
 220                 # Add enrollment date if it isn't already there
 221                 unless ( $self->dateenrolled ) {
 222                     $self->dateenrolled(dt_from_string);
 223                 }
 224
 225                 # Set the privacy depending on the patron's category
 226                 my $default_privacy = $self->category->default_privacy || q{};
 227                 $default_privacy =
 228                     $default_privacy eq 'default' ? 1
 229                   : $default_privacy eq 'never'   ? 2
 230                   : $default_privacy eq 'forever' ? 0
 231                   :                                                   undef;
 232                 $self->privacy($default_privacy);
 233
 234                 # Call any check_password plugins if password is passed
 235                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 236                     my @plugins = Koha::Plugins->new()->GetPlugins({
 237                         method => 'check_password',
 238                     });
 239                     foreach my $plugin ( @plugins ) {
 240                         # This plugin hook will also be used by a plugin for the Norwegian national
 241                         # patron database. This is why we need to pass both the password and the
 242                         # borrowernumber to the plugin.
 243                         my $ret = $plugin->check_password(
 244                             {
 245                                 password       => $self->password,
 246                                 borrowernumber => $self->borrowernumber
 247                             }
 248                         );
 249                         if ( $ret->{'error'} == 1 ) {
 250                             Koha::Exceptions::Password::Plugin->throw();
 251                         }
 252                     }
 253                 }
 254
 255                 # Make a copy of the plain text password for later use
 256                 $self->plain_text_password( $self->password );
 257
 258                 # Create a disabled account if no password provided
 259                 $self->password( $self->password
 260                     ? Koha::AuthUtils::hash_password( $self->password )
 261                     : '!' );
 262
 263                 $self->borrowernumber(undef);
 264
 265                 $self = $self->SUPER::store;
 266
 267                 $self->add_enrolment_fee_if_needed(0);
 268
 269                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 270                   if C4::Context->preference("BorrowersLog");
 271             }
 272             else {    #ModMember
 273
 274                 my $self_from_storage = $self->get_from_storage;
 275                 # FIXME We should not deal with that here, callers have to do this job
 276                 # Moved from ModMember to prevent regressions
 277                 unless ( $self->userid ) {
 278                     my $stored_userid = $self_from_storage->userid;
 279                     $self->userid($stored_userid);
 280                 }
 281
 282                 # Password must be updated using $self->set_password
 283                 $self->password($self_from_storage->password);
 284
 285                 if ( $self->category->categorycode ne
 286                     $self_from_storage->category->categorycode )
 287                 {
 288                     # Add enrolement fee on category change if required
 289                     $self->add_enrolment_fee_if_needed(1)
 290                       if C4::Context->preference('FeeOnChangePatronCategory');
 291
 292                     # Clean up guarantors on category change if required
 293                     $self->guarantor_relationships->delete
 294                       if ( $self->category->category_type ne 'C'
 295                         && $self->category->category_type ne 'P' );
 296
 297                 }
 298
 299                 # Actionlogs
 300                 if ( C4::Context->preference("BorrowersLog") ) {
 301                     my $info;
 302                     my $from_storage = $self_from_storage->unblessed;
 303                     my $from_object  = $self->unblessed;
 304                     my @skip_fields  = (qw/lastseen updated_on/);
 305                     for my $key ( keys %{$from_storage} ) {
 306                         next if any { /$key/ } @skip_fields;
 307                         if (
 308                             (
 309                                   !defined( $from_storage->{$key} )
 310                                 && defined( $from_object->{$key} )
 311                             )
 312                             || ( defined( $from_storage->{$key} )
 313                                 && !defined( $from_object->{$key} ) )
 314                             || (
 315                                    defined( $from_storage->{$key} )
 316                                 && defined( $from_object->{$key} )
 317                                 && ( $from_storage->{$key} ne
 318                                     $from_object->{$key} )
 319                             )
 320                           )
 321                         {
 322                             $info->{$key} = {
 323                                 before => $from_storage->{$key},
 324                                 after  => $from_object->{$key}
 325                             };
 326                         }
 327                     }
 328
 329                     if ( defined($info) ) {
 330                         logaction(
 331                             "MEMBERS",
 332                             "MODIFY",
 333                             $self->borrowernumber,
 334                             to_json(
 335                                 $info,
 336                                 { utf8 => 1, pretty => 1, canonical => 1 }
 337                             )
 338                         );
 339                     }
 340                 }
 341
 342                 # Final store
 343                 $self = $self->SUPER::store;
 344             }
 345         }
 346     );
 347     return $self;
 348 }
 349
 350 =head3 delete
 351
 352 $patron->delete
 353
 354 Delete patron's holds, lists and finally the patron.
 355
 356 Lists owned by the borrower are deleted, but entries from the borrower to
 357 other lists are kept.
 358
 359 =cut
 360
 361 sub delete {
 362     my ($self) = @_;
 363
 364     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 365     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 366
 367     $self->_result->result_source->schema->txn_do(
 368         sub {
 369             # Cancel Patron's holds
 370             my $holds = $self->holds;
 371             while( my $hold = $holds->next ){
 372                 $hold->cancel;
 373             }
 374
 375             # Delete all lists and all shares of this borrower
 376             # Consistent with the approach Koha uses on deleting individual lists
 377             # Note that entries in virtualshelfcontents added by this borrower to
 378             # lists of others will be handled by a table constraint: the borrower
 379             # is set to NULL in those entries.
 380             # NOTE:
 381             # We could handle the above deletes via a constraint too.
 382             # But a new BZ report 11889 has been opened to discuss another approach.
 383             # Instead of deleting we could also disown lists (based on a pref).
 384             # In that way we could save shared and public lists.
 385             # The current table constraints support that idea now.
 386             # This pref should then govern the results of other routines/methods such as
 387             # Koha::Virtualshelf->new->delete too.
 388             # FIXME Could be $patron->get_lists
 389             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 390
 391             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 392             # for patron selfreg
 393             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 394
 395             $self->SUPER::delete;
 396
 397             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 398         }
 399     );
 400     return $self;
 401 }
 402
 403
 404 =head3 category
 405
 406 my $patron_category = $patron->category
 407
 408 Return the patron category for this patron
 409
 410 =cut
 411
 412 sub category {
 413     my ( $self ) = @_;
 414     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 415 }
 416
 417 =head3 image
 418
 419 =cut
 420
 421 sub image {
 422     my ( $self ) = @_;
 423
 424     return Koha::Patron::Images->find( $self->borrowernumber );
 425 }
 426
 427 =head3 library
 428
 429 Returns a Koha::Library object representing the patron's home library.
 430
 431 =cut
 432
 433 sub library {
 434     my ( $self ) = @_;
 435     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 436 }
 437
 438 =head3 sms_provider
 439
 440 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 441
 442 =cut
 443
 444 sub sms_provider {
 445     my ( $self ) = @_;
 446     my $sms_provider_rs = $self->_result->sms_provider;
 447     return unless $sms_provider_rs;
 448     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 449 }
 450
 451 =head3 guarantor_relationships
 452
 453 Returns Koha::Patron::Relationships object for this patron's guarantors
 454
 455 Returns the set of relationships for the patrons that are guarantors for this patron.
 456
 457 This is returned instead of a Koha::Patron object because the guarantor
 458 may not exist as a patron in Koha. If this is true, the guarantors name
 459 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 460
 461 =cut
 462
 463 sub guarantor_relationships {
 464     my ($self) = @_;
 465
 466     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 467 }
 468
 469 =head3 guarantee_relationships
 470
 471 Returns Koha::Patron::Relationships object for this patron's guarantors
 472
 473 Returns the set of relationships for the patrons that are guarantees for this patron.
 474
 475 The method returns Koha::Patron::Relationship objects for the sake
 476 of consistency with the guantors method.
 477 A guarantee by definition must exist as a patron in Koha.
 478
 479 =cut
 480
 481 sub guarantee_relationships {
 482     my ($self) = @_;
 483
 484     return Koha::Patron::Relationships->search(
 485         { guarantor_id => $self->id },
 486         {
 487             prefetch => 'guarantee',
 488             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 489         }
 490     );
 491 }
 492
 493 =head3 relationships_debt
 494
 495 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 496
 497 =cut
 498
 499 sub relationships_debt {
 500     my ($self, $params) = @_;
 501
 502     my $include_guarantors  = $params->{include_guarantors};
 503     my $only_this_guarantor = $params->{only_this_guarantor};
 504     my $include_this_patron = $params->{include_this_patron};
 505
 506     my @guarantors;
 507     if ( $only_this_guarantor ) {
 508         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 509         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 510     } elsif ( $self->guarantor_relationships->count ) {
 511         # I am a guarantee, just get all my guarantors
 512         @guarantors = $self->guarantor_relationships->guarantors;
 513     } else {
 514         # I am a guarantor, I need to get all the guarantors of all my guarantees
 515         @guarantors = map { $_->guarantor_relationships->guarantors } $self->guarantee_relationships->guarantees;
 516     }
 517
 518     my $non_issues_charges = 0;
 519     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 520     foreach my $guarantor (@guarantors) {
 521         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 522
 523         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 524         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships();
 525         my $guarantees_non_issues_charges = 0;
 526         foreach my $guarantee (@guarantees) {
 527             next if $seen->{ $guarantee->id };
 528             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 529             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 530             $seen->{ $guarantee->id } = 1;
 531         }
 532
 533         $non_issues_charges += $guarantees_non_issues_charges;
 534         $seen->{ $guarantor->id } = 1;
 535     }
 536
 537     return $non_issues_charges;
 538 }
 539
 540 =head3 housebound_profile
 541
 542 Returns the HouseboundProfile associated with this patron.
 543
 544 =cut
 545
 546 sub housebound_profile {
 547     my ( $self ) = @_;
 548     my $profile = $self->_result->housebound_profile;
 549     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 550         if ( $profile );
 551     return;
 552 }
 553
 554 =head3 housebound_role
 555
 556 Returns the HouseboundRole associated with this patron.
 557
 558 =cut
 559
 560 sub housebound_role {
 561     my ( $self ) = @_;
 562
 563     my $role = $self->_result->housebound_role;
 564     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 565     return;
 566 }
 567
 568 =head3 siblings
 569
 570 Returns the siblings of this patron.
 571
 572 =cut
 573
 574 sub siblings {
 575     my ($self) = @_;
 576
 577     my @guarantors = $self->guarantor_relationships()->guarantors();
 578
 579     return unless @guarantors;
 580
 581     my @siblings =
 582       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 583
 584     return unless @siblings;
 585
 586     my %seen;
 587     @siblings =
 588       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 589
 590     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 591 }
 592
 593 =head3 merge_with
 594
 595     my $patron = Koha::Patrons->find($id);
 596     $patron->merge_with( \@patron_ids );
 597
 598     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 599     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 600     of the keeper patron.
 601
 602 =cut
 603
 604 sub merge_with {
 605     my ( $self, $patron_ids ) = @_;
 606
 607     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 608     return if $anonymous_patron && $self->id eq $anonymous_patron;
 609
 610     my @patron_ids = @{ $patron_ids };
 611
 612     # Ensure the keeper isn't in the list of patrons to merge
 613     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 614
 615     my $schema = Koha::Database->new()->schema();
 616
 617     my $results;
 618
 619     $self->_result->result_source->schema->txn_do( sub {
 620         foreach my $patron_id (@patron_ids) {
 621
 622             next if $patron_id eq $anonymous_patron;
 623
 624             my $patron = Koha::Patrons->find( $patron_id );
 625
 626             next unless $patron;
 627
 628             # Unbless for safety, the patron will end up being deleted
 629             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 630
 631             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 632                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 633                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 634                 $rs->update({ $field => $self->id });
 635                 if ( $r eq 'BorrowerDebarment' ) {
 636                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 637                 }
 638             }
 639
 640             $patron->move_to_deleted();
 641             $patron->delete();
 642         }
 643     });
 644
 645     return $results;
 646 }
 647
 648
 649
 650 =head3 wants_check_for_previous_checkout
 651
 652     $wants_check = $patron->wants_check_for_previous_checkout;
 653
 654 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 655
 656 =cut
 657
 658 sub wants_check_for_previous_checkout {
 659     my ( $self ) = @_;
 660     my $syspref = C4::Context->preference("checkPrevCheckout");
 661
 662     # Simple cases
 663     ## Hard syspref trumps all
 664     return 1 if ($syspref eq 'hardyes');
 665     return 0 if ($syspref eq 'hardno');
 666     ## Now, patron pref trumps all
 667     return 1 if ($self->checkprevcheckout eq 'yes');
 668     return 0 if ($self->checkprevcheckout eq 'no');
 669
 670     # More complex: patron inherits -> determine category preference
 671     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 672     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 673     return 0 if ($checkPrevCheckoutByCat eq 'no');
 674
 675     # Finally: category preference is inherit, default to 0
 676     if ($syspref eq 'softyes') {
 677         return 1;
 678     } else {
 679         return 0;
 680     }
 681 }
 682
 683 =head3 do_check_for_previous_checkout
 684
 685     $do_check = $patron->do_check_for_previous_checkout($item);
 686
 687 Return 1 if the bib associated with $ITEM has previously been checked out to
 688 $PATRON, 0 otherwise.
 689
 690 =cut
 691
 692 sub do_check_for_previous_checkout {
 693     my ( $self, $item ) = @_;
 694
 695     my @item_nos;
 696     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 697     if ( $biblio->is_serial ) {
 698         push @item_nos, $item->{itemnumber};
 699     } else {
 700         # Get all itemnumbers for given bibliographic record.
 701         @item_nos = $biblio->items->get_column( 'itemnumber' );
 702     }
 703
 704     # Create (old)issues search criteria
 705     my $criteria = {
 706         borrowernumber => $self->borrowernumber,
 707         itemnumber => \@item_nos,
 708     };
 709
 710     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 711     if ($delay) {
 712         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 713         my $newer_than = dt_from_string()->subtract( days => $delay );
 714         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 715     }
 716
 717     # Check current issues table
 718     my $issues = Koha::Checkouts->search($criteria);
 719     return 1 if $issues->count; # 0 || N
 720
 721     # Check old issues table
 722     my $old_issues = Koha::Old::Checkouts->search($criteria);
 723     return $old_issues->count;  # 0 || N
 724 }
 725
 726 =head3 is_debarred
 727
 728 my $debarment_expiration = $patron->is_debarred;
 729
 730 Returns the date a patron debarment will expire, or undef if the patron is not
 731 debarred
 732
 733 =cut
 734
 735 sub is_debarred {
 736     my ($self) = @_;
 737
 738     return unless $self->debarred;
 739     return $self->debarred
 740       if $self->debarred =~ '^9999'
 741       or dt_from_string( $self->debarred ) > dt_from_string;
 742     return;
 743 }
 744
 745 =head3 is_expired
 746
 747 my $is_expired = $patron->is_expired;
 748
 749 Returns 1 if the patron is expired or 0;
 750
 751 =cut
 752
 753 sub is_expired {
 754     my ($self) = @_;
 755     return 0 unless $self->dateexpiry;
 756     return 0 if $self->dateexpiry =~ '^9999';
 757     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 758     return 0;
 759 }
 760
 761 =head3 is_going_to_expire
 762
 763 my $is_going_to_expire = $patron->is_going_to_expire;
 764
 765 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 766
 767 =cut
 768
 769 sub is_going_to_expire {
 770     my ($self) = @_;
 771
 772     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 773
 774     return 0 unless $delay;
 775     return 0 unless $self->dateexpiry;
 776     return 0 if $self->dateexpiry =~ '^9999';
 777     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 778     return 0;
 779 }
 780
 781 =head3 set_password
 782
 783     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 784
 785 Set the patron's password.
 786
 787 =head4 Exceptions
 788
 789 The passed string is validated against the current password enforcement policy.
 790 Validation can be skipped by passing the I<skip_validation> parameter.
 791
 792 Exceptions are thrown if the password is not good enough.
 793
 794 =over 4
 795
 796 =item Koha::Exceptions::Password::TooShort
 797
 798 =item Koha::Exceptions::Password::WhitespaceCharacters
 799
 800 =item Koha::Exceptions::Password::TooWeak
 801
 802 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 803
 804 =back
 805
 806 =cut
 807
 808 sub set_password {
 809     my ( $self, $args ) = @_;
 810
 811     my $password = $args->{password};
 812
 813     unless ( $args->{skip_validation} ) {
 814         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 815
 816         if ( !$is_valid ) {
 817             if ( $error eq 'too_short' ) {
 818                 my $min_length = $self->category->effective_min_password_length;
 819                 $min_length = 3 if not $min_length or $min_length < 3;
 820
 821                 my $password_length = length($password);
 822                 Koha::Exceptions::Password::TooShort->throw(
 823                     length => $password_length, min_length => $min_length );
 824             }
 825             elsif ( $error eq 'has_whitespaces' ) {
 826                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 827             }
 828             elsif ( $error eq 'too_weak' ) {
 829                 Koha::Exceptions::Password::TooWeak->throw();
 830             }
 831         }
 832     }
 833
 834     if ( C4::Context->config("enable_plugins") ) {
 835         # Call any check_password plugins
 836         my @plugins = Koha::Plugins->new()->GetPlugins({
 837             method => 'check_password',
 838         });
 839         foreach my $plugin ( @plugins ) {
 840             # This plugin hook will also be used by a plugin for the Norwegian national
 841             # patron database. This is why we need to pass both the password and the
 842             # borrowernumber to the plugin.
 843             my $ret = $plugin->check_password(
 844                 {
 845                     password       => $password,
 846                     borrowernumber => $self->borrowernumber
 847                 }
 848             );
 849             # This plugin hook will also be used by a plugin for the Norwegian national
 850             # patron database. This is why we need to call the actual plugins and then
 851             # check skip_validation afterwards.
 852             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 853                 Koha::Exceptions::Password::Plugin->throw();
 854             }
 855         }
 856     }
 857
 858     my $digest = Koha::AuthUtils::hash_password($password);
 859
 860     # We do not want to call $self->store and retrieve password from DB
 861     $self->password($digest);
 862     $self->login_attempts(0);
 863     $self->SUPER::store;
 864
 865     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 866         if C4::Context->preference("BorrowersLog");
 867
 868     return $self;
 869 }
 870
 871
 872 =head3 renew_account
 873
 874 my $new_expiry_date = $patron->renew_account
 875
 876 Extending the subscription to the expiry date.
 877
 878 =cut
 879
 880 sub renew_account {
 881     my ($self) = @_;
 882     my $date;
 883     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 884         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 885     } else {
 886         $date =
 887             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 888             ? dt_from_string( $self->dateexpiry )
 889             : dt_from_string;
 890     }
 891     my $expiry_date = $self->category->get_expiry_date($date);
 892
 893     $self->dateexpiry($expiry_date);
 894     $self->date_renewed( dt_from_string() );
 895     $self->store();
 896
 897     $self->add_enrolment_fee_if_needed(1);
 898
 899     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 900     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 901 }
 902
 903 =head3 has_overdues
 904
 905 my $has_overdues = $patron->has_overdues;
 906
 907 Returns the number of patron's overdues
 908
 909 =cut
 910
 911 sub has_overdues {
 912     my ($self) = @_;
 913     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 914     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 915 }
 916
 917 =head3 track_login
 918
 919     $patron->track_login;
 920     $patron->track_login({ force => 1 });
 921
 922     Tracks a (successful) login attempt.
 923     The preference TrackLastPatronActivity must be enabled. Or you
 924     should pass the force parameter.
 925
 926 =cut
 927
 928 sub track_login {
 929     my ( $self, $params ) = @_;
 930     return if
 931         !$params->{force} &&
 932         !C4::Context->preference('TrackLastPatronActivity');
 933     $self->lastseen( dt_from_string() )->store;
 934 }
 935
 936 =head3 move_to_deleted
 937
 938 my $is_moved = $patron->move_to_deleted;
 939
 940 Move a patron to the deletedborrowers table.
 941 This can be done before deleting a patron, to make sure the data are not completely deleted.
 942
 943 =cut
 944
 945 sub move_to_deleted {
 946     my ($self) = @_;
 947     my $patron_infos = $self->unblessed;
 948     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 949     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 950 }
 951
 952 =head3 article_requests
 953
 954 my @requests = $borrower->article_requests();
 955 my $requests = $borrower->article_requests();
 956
 957 Returns either a list of ArticleRequests objects,
 958 or an ArtitleRequests object, depending on the
 959 calling context.
 960
 961 =cut
 962
 963 sub article_requests {
 964     my ( $self ) = @_;
 965
 966     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 967
 968     return $self->{_article_requests};
 969 }
 970
 971 =head3 article_requests_current
 972
 973 my @requests = $patron->article_requests_current
 974
 975 Returns the article requests associated with this patron that are incomplete
 976
 977 =cut
 978
 979 sub article_requests_current {
 980     my ( $self ) = @_;
 981
 982     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 983         {
 984             borrowernumber => $self->id(),
 985             -or          => [
 986                 { status => Koha::ArticleRequest::Status::Pending },
 987                 { status => Koha::ArticleRequest::Status::Processing }
 988             ]
 989         }
 990     );
 991
 992     return $self->{_article_requests_current};
 993 }
 994
 995 =head3 article_requests_finished
 996
 997 my @requests = $biblio->article_requests_finished
 998
 999 Returns the article requests associated with this patron that are completed
1000
1001 =cut
1002
1003 sub article_requests_finished {
1004     my ( $self, $borrower ) = @_;
1005
1006     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
1007         {
1008             borrowernumber => $self->id(),
1009             -or          => [
1010                 { status => Koha::ArticleRequest::Status::Completed },
1011                 { status => Koha::ArticleRequest::Status::Canceled }
1012             ]
1013         }
1014     );
1015
1016     return $self->{_article_requests_finished};
1017 }
1018
1019 =head3 add_enrolment_fee_if_needed
1020
1021 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1022
1023 Add enrolment fee for a patron if needed.
1024
1025 $renewal - boolean denoting whether this is an account renewal or not
1026
1027 =cut
1028
1029 sub add_enrolment_fee_if_needed {
1030     my ($self, $renewal) = @_;
1031     my $enrolment_fee = $self->category->enrolmentfee;
1032     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1033         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1034         $self->account->add_debit(
1035             {
1036                 amount     => $enrolment_fee,
1037                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1038                 interface  => C4::Context->interface,
1039                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1040                 type       => $type
1041             }
1042         );
1043     }
1044     return $enrolment_fee || 0;
1045 }
1046
1047 =head3 checkouts
1048
1049 my $checkouts = $patron->checkouts
1050
1051 =cut
1052
1053 sub checkouts {
1054     my ($self) = @_;
1055     my $checkouts = $self->_result->issues;
1056     return Koha::Checkouts->_new_from_dbic( $checkouts );
1057 }
1058
1059 =head3 pending_checkouts
1060
1061 my $pending_checkouts = $patron->pending_checkouts
1062
1063 This method will return the same as $self->checkouts, but with a prefetch on
1064 items, biblio and biblioitems.
1065
1066 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1067
1068 It should not be used directly, prefer to access fields you need instead of
1069 retrieving all these fields in one go.
1070
1071 =cut
1072
1073 sub pending_checkouts {
1074     my( $self ) = @_;
1075     my $checkouts = $self->_result->issues->search(
1076         {},
1077         {
1078             order_by => [
1079                 { -desc => 'me.timestamp' },
1080                 { -desc => 'issuedate' },
1081                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1082             ],
1083             prefetch => { item => { biblio => 'biblioitems' } },
1084         }
1085     );
1086     return Koha::Checkouts->_new_from_dbic( $checkouts );
1087 }
1088
1089 =head3 old_checkouts
1090
1091 my $old_checkouts = $patron->old_checkouts
1092
1093 =cut
1094
1095 sub old_checkouts {
1096     my ($self) = @_;
1097     my $old_checkouts = $self->_result->old_issues;
1098     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1099 }
1100
1101 =head3 get_overdues
1102
1103 my $overdue_items = $patron->get_overdues
1104
1105 Return the overdue items
1106
1107 =cut
1108
1109 sub get_overdues {
1110     my ($self) = @_;
1111     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1112     return $self->checkouts->search(
1113         {
1114             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1115         },
1116         {
1117             prefetch => { item => { biblio => 'biblioitems' } },
1118         }
1119     );
1120 }
1121
1122 =head3 get_routing_lists
1123
1124 my @routinglists = $patron->get_routing_lists
1125
1126 Returns the routing lists a patron is subscribed to.
1127
1128 =cut
1129
1130 sub get_routing_lists {
1131     my ($self) = @_;
1132     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1133     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1134 }
1135
1136 =head3 get_age
1137
1138 my $age = $patron->get_age
1139
1140 Return the age of the patron
1141
1142 =cut
1143
1144 sub get_age {
1145     my ($self)    = @_;
1146     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1147     return unless $self->dateofbirth;
1148     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1149
1150     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1151     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1152
1153     my $age = $today_y - $dob_y;
1154     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1155         $age--;
1156     }
1157
1158     return $age;
1159 }
1160
1161 =head3 is_valid_age
1162
1163 my $is_valid = $patron->is_valid_age
1164
1165 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1166
1167 =cut
1168
1169 sub is_valid_age {
1170     my ($self) = @_;
1171     my $age = $self->get_age;
1172
1173     my $patroncategory = $self->category;
1174     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1175
1176     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1177 }
1178
1179 =head3 account
1180
1181 my $account = $patron->account
1182
1183 =cut
1184
1185 sub account {
1186     my ($self) = @_;
1187     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1188 }
1189
1190 =head3 holds
1191
1192 my $holds = $patron->holds
1193
1194 Return all the holds placed by this patron
1195
1196 =cut
1197
1198 sub holds {
1199     my ($self) = @_;
1200     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1201     return Koha::Holds->_new_from_dbic($holds_rs);
1202 }
1203
1204 =head3 old_holds
1205
1206 my $old_holds = $patron->old_holds
1207
1208 Return all the historical holds for this patron
1209
1210 =cut
1211
1212 sub old_holds {
1213     my ($self) = @_;
1214     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1215     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1216 }
1217
1218 =head3 return_claims
1219
1220 my $return_claims = $patron->return_claims
1221
1222 =cut
1223
1224 sub return_claims {
1225     my ($self) = @_;
1226     my $return_claims = $self->_result->return_claims_borrowernumbers;
1227     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1228 }
1229
1230 =head3 notice_email_address
1231
1232   my $email = $patron->notice_email_address;
1233
1234 Return the email address of patron used for notices.
1235 Returns the empty string if no email address.
1236
1237 =cut
1238
1239 sub notice_email_address{
1240     my ( $self ) = @_;
1241
1242     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1243     # if syspref is set to 'first valid' (value == OFF), look up email address
1244     if ( $which_address eq 'OFF' ) {
1245         return $self->first_valid_email_address;
1246     }
1247
1248     return $self->$which_address || '';
1249 }
1250
1251 =head3 first_valid_email_address
1252
1253 my $first_valid_email_address = $patron->first_valid_email_address
1254
1255 Return the first valid email address for a patron.
1256 For now, the order  is defined as email, emailpro, B_email.
1257 Returns the empty string if the borrower has no email addresses.
1258
1259 =cut
1260
1261 sub first_valid_email_address {
1262     my ($self) = @_;
1263
1264     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1265 }
1266
1267 =head3 get_club_enrollments
1268
1269 =cut
1270
1271 sub get_club_enrollments {
1272     my ( $self, $return_scalar ) = @_;
1273
1274     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1275
1276     return $e if $return_scalar;
1277
1278     return wantarray ? $e->as_list : $e;
1279 }
1280
1281 =head3 get_enrollable_clubs
1282
1283 =cut
1284
1285 sub get_enrollable_clubs {
1286     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1287
1288     my $params;
1289     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1290       if $is_enrollable_from_opac;
1291     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1292
1293     $params->{borrower} = $self;
1294
1295     my $e = Koha::Clubs->get_enrollable($params);
1296
1297     return $e if $return_scalar;
1298
1299     return wantarray ? $e->as_list : $e;
1300 }
1301
1302 =head3 account_locked
1303
1304 my $is_locked = $patron->account_locked
1305
1306 Return true if the patron has reached the maximum number of login attempts
1307 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1308 as an administrative lockout (independent of FailedLoginAttempts; see also
1309 Koha::Patron->lock).
1310 Otherwise return false.
1311 If the pref is not set (empty string, null or 0), the feature is considered as
1312 disabled.
1313
1314 =cut
1315
1316 sub account_locked {
1317     my ($self) = @_;
1318     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1319     return 1 if $FailedLoginAttempts
1320           and $self->login_attempts
1321           and $self->login_attempts >= $FailedLoginAttempts;
1322     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1323     return 0;
1324 }
1325
1326 =head3 can_see_patron_infos
1327
1328 my $can_see = $patron->can_see_patron_infos( $patron );
1329
1330 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1331
1332 =cut
1333
1334 sub can_see_patron_infos {
1335     my ( $self, $patron ) = @_;
1336     return unless $patron;
1337     return $self->can_see_patrons_from( $patron->library->branchcode );
1338 }
1339
1340 =head3 can_see_patrons_from
1341
1342 my $can_see = $patron->can_see_patrons_from( $branchcode );
1343
1344 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1345
1346 =cut
1347
1348 sub can_see_patrons_from {
1349     my ( $self, $branchcode ) = @_;
1350     my $can = 0;
1351     if ( $self->branchcode eq $branchcode ) {
1352         $can = 1;
1353     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1354         $can = 1;
1355     } elsif ( my $library_groups = $self->library->library_groups ) {
1356         while ( my $library_group = $library_groups->next ) {
1357             if ( $library_group->parent->has_child( $branchcode ) ) {
1358                 $can = 1;
1359                 last;
1360             }
1361         }
1362     }
1363     return $can;
1364 }
1365
1366 =head3 libraries_where_can_see_patrons
1367
1368 my $libraries = $patron-libraries_where_can_see_patrons;
1369
1370 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1371 The branchcodes are arbitrarily returned sorted.
1372 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1373
1374 An empty array means no restriction, the patron can see patron's infos from any libraries.
1375
1376 =cut
1377
1378 sub libraries_where_can_see_patrons {
1379     my ( $self ) = @_;
1380     my $userenv = C4::Context->userenv;
1381
1382     return () unless $userenv; # For tests, but userenv should be defined in tests...
1383
1384     my @restricted_branchcodes;
1385     if (C4::Context::only_my_library) {
1386         push @restricted_branchcodes, $self->branchcode;
1387     }
1388     else {
1389         unless (
1390             $self->has_permission(
1391                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1392             )
1393           )
1394         {
1395             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1396             if ( $library_groups->count )
1397             {
1398                 while ( my $library_group = $library_groups->next ) {
1399                     my $parent = $library_group->parent;
1400                     if ( $parent->has_child( $self->branchcode ) ) {
1401                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1402                     }
1403                 }
1404             }
1405
1406             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1407         }
1408     }
1409
1410     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1411     @restricted_branchcodes = uniq(@restricted_branchcodes);
1412     @restricted_branchcodes = sort(@restricted_branchcodes);
1413     return @restricted_branchcodes;
1414 }
1415
1416 =head3 has_permission
1417
1418 my $permission = $patron->has_permission($required);
1419
1420 See C4::Auth::haspermission for details of syntax for $required
1421
1422 =cut
1423
1424 sub has_permission {
1425     my ( $self, $flagsrequired ) = @_;
1426     return unless $self->userid;
1427     # TODO code from haspermission needs to be moved here!
1428     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1429 }
1430
1431 =head3 is_superlibrarian
1432
1433   my $is_superlibrarian = $patron->is_superlibrarian;
1434
1435 Return true if the patron is a superlibrarian.
1436
1437 =cut
1438
1439 sub is_superlibrarian {
1440     my ($self) = @_;
1441     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1442 }
1443
1444 =head3 is_adult
1445
1446 my $is_adult = $patron->is_adult
1447
1448 Return true if the patron has a category with a type Adult (A) or Organization (I)
1449
1450 =cut
1451
1452 sub is_adult {
1453     my ( $self ) = @_;
1454     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1455 }
1456
1457 =head3 is_child
1458
1459 my $is_child = $patron->is_child
1460
1461 Return true if the patron has a category with a type Child (C)
1462
1463 =cut
1464
1465 sub is_child {
1466     my( $self ) = @_;
1467     return $self->category->category_type eq 'C' ? 1 : 0;
1468 }
1469
1470 =head3 has_valid_userid
1471
1472 my $patron = Koha::Patrons->find(42);
1473 $patron->userid( $new_userid );
1474 my $has_a_valid_userid = $patron->has_valid_userid
1475
1476 my $patron = Koha::Patron->new( $params );
1477 my $has_a_valid_userid = $patron->has_valid_userid
1478
1479 Return true if the current userid of this patron is valid/unique, otherwise false.
1480
1481 Note that this should be done in $self->store instead and raise an exception if needed.
1482
1483 =cut
1484
1485 sub has_valid_userid {
1486     my ($self) = @_;
1487
1488     return 0 unless $self->userid;
1489
1490     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1491
1492     my $already_exists = Koha::Patrons->search(
1493         {
1494             userid => $self->userid,
1495             (
1496                 $self->in_storage
1497                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1498                 : ()
1499             ),
1500         }
1501     )->count;
1502     return $already_exists ? 0 : 1;
1503 }
1504
1505 =head3 generate_userid
1506
1507 my $patron = Koha::Patron->new( $params );
1508 $patron->generate_userid
1509
1510 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1511
1512 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1513
1514 =cut
1515
1516 sub generate_userid {
1517     my ($self) = @_;
1518     my $offset = 0;
1519     my $firstname = $self->firstname // q{};
1520     my $surname = $self->surname // q{};
1521     #The script will "do" the following code and increment the $offset until the generated userid is unique
1522     do {
1523       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1524       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1525       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1526       $userid = NFKD( $userid );
1527       $userid =~ s/\p{NonspacingMark}//g;
1528       $userid .= $offset unless $offset == 0;
1529       $self->userid( $userid );
1530       $offset++;
1531      } while (! $self->has_valid_userid );
1532
1533      return $self;
1534 }
1535
1536 =head3 add_extended_attribute
1537
1538 =cut
1539
1540 sub add_extended_attribute {
1541     my ($self, $attribute) = @_;
1542     $attribute->{borrowernumber} = $self->borrowernumber;
1543     return Koha::Patron::Attribute->new($attribute)->store;
1544 }
1545
1546 =head3 extended_attributes
1547
1548 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1549
1550 Or setter FIXME
1551
1552 =cut
1553
1554 sub extended_attributes {
1555     my ( $self, $attributes ) = @_;
1556     if ($attributes) {    # setter
1557         my $schema = $self->_result->result_source->schema;
1558         $schema->txn_do(
1559             sub {
1560                 # Remove the existing one
1561                 $self->extended_attributes->filter_by_branch_limitations->delete;
1562
1563                 # Insert the new ones
1564                 for my $attribute (@$attributes) {
1565                     $self->add_extended_attribute($attribute);
1566                 }
1567             }
1568         );
1569     }
1570
1571     my $rs = $self->_result->borrower_attributes;
1572     # We call search to use the filters in Koha::Patron::Attributes->search
1573     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1574 }
1575
1576 =head3 lock
1577
1578     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1579
1580     Lock and optionally expire a patron account.
1581     Remove holds and article requests if remove flag set.
1582     In order to distinguish from locking by entering a wrong password, let's
1583     call this an administrative lockout.
1584
1585 =cut
1586
1587 sub lock {
1588     my ( $self, $params ) = @_;
1589     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1590     if( $params->{expire} ) {
1591         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1592     }
1593     $self->store;
1594     if( $params->{remove} ) {
1595         $self->holds->delete;
1596         $self->article_requests->delete;
1597     }
1598     return $self;
1599 }
1600
1601 =head3 anonymize
1602
1603     Koha::Patrons->find($id)->anonymize;
1604
1605     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1606     are randomized, other personal data is cleared too.
1607     Patrons with issues are skipped.
1608
1609 =cut
1610
1611 sub anonymize {
1612     my ( $self ) = @_;
1613     if( $self->_result->issues->count ) {
1614         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1615         return;
1616     }
1617     # Mandatory fields come from the corresponding pref, but email fields
1618     # are removed since scrambled email addresses only generate errors
1619     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1620         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1621     $mandatory->{userid} = 1; # needed since sub store does not clear field
1622     my @columns = $self->_result->result_source->columns;
1623     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1624     push @columns, 'dateofbirth'; # add this date back in
1625     foreach my $col (@columns) {
1626         $self->_anonymize_column($col, $mandatory->{lc $col} );
1627     }
1628     $self->anonymized(1)->store;
1629 }
1630
1631 sub _anonymize_column {
1632     my ( $self, $col, $mandatory ) = @_;
1633     my $col_info = $self->_result->result_source->column_info($col);
1634     my $type = $col_info->{data_type};
1635     my $nullable = $col_info->{is_nullable};
1636     my $val;
1637     if( $type =~ /char|text/ ) {
1638         $val = $mandatory
1639             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1640             : $nullable
1641             ? undef
1642             : q{};
1643     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1644         $val = $nullable ? undef : 0;
1645     } elsif( $type =~ /date|time/ ) {
1646         $val = $nullable ? undef : dt_from_string;
1647     }
1648     $self->$col($val);
1649 }
1650
1651 =head3 add_guarantor
1652
1653     my @relationships = $patron->add_guarantor(
1654         {
1655             borrowernumber => $borrowernumber,
1656             relationships  => $relationship,
1657         }
1658     );
1659
1660     Adds a new guarantor to a patron.
1661
1662 =cut
1663
1664 sub add_guarantor {
1665     my ( $self, $params ) = @_;
1666
1667     my $guarantor_id = $params->{guarantor_id};
1668     my $relationship = $params->{relationship};
1669
1670     return Koha::Patron::Relationship->new(
1671         {
1672             guarantee_id => $self->id,
1673             guarantor_id => $guarantor_id,
1674             relationship => $relationship
1675         }
1676     )->store();
1677 }
1678
1679 =head3 get_extended_attribute
1680
1681 my $attribute_value = $patron->get_extended_attribute( $code );
1682
1683 Return the attribute for the code passed in parameter.
1684
1685 It not exist it returns undef
1686
1687 Note that this will not work for repeatable attribute types.
1688
1689 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1690 (which should be a real patron's attribute (not extended)
1691
1692 =cut
1693
1694 sub get_extended_attribute {
1695     my ( $self, $code, $value ) = @_;
1696     my $rs = $self->_result->borrower_attributes;
1697     return unless $rs;
1698     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1699     return unless $attribute->count;
1700     return $attribute->next;
1701 }
1702
1703 =head3 to_api
1704
1705     my $json = $patron->to_api;
1706
1707 Overloaded method that returns a JSON representation of the Koha::Patron object,
1708 suitable for API output.
1709
1710 =cut
1711
1712 sub to_api {
1713     my ( $self, $params ) = @_;
1714
1715     my $json_patron = $self->SUPER::to_api( $params );
1716
1717     $json_patron->{restricted} = ( $self->is_debarred )
1718                                     ? Mojo::JSON->true
1719                                     : Mojo::JSON->false;
1720
1721     return $json_patron;
1722 }
1723
1724 =head3 to_api_mapping
1725
1726 This method returns the mapping for representing a Koha::Patron object
1727 on the API.
1728
1729 =cut
1730
1731 sub to_api_mapping {
1732     return {
1733         borrowernotes       => 'staff_notes',
1734         borrowernumber      => 'patron_id',
1735         branchcode          => 'library_id',
1736         categorycode        => 'category_id',
1737         checkprevcheckout   => 'check_previous_checkout',
1738         contactfirstname    => undef,                     # Unused
1739         contactname         => undef,                     # Unused
1740         contactnote         => 'altaddress_notes',
1741         contacttitle        => undef,                     # Unused
1742         dateenrolled        => 'date_enrolled',
1743         dateexpiry          => 'expiry_date',
1744         dateofbirth         => 'date_of_birth',
1745         debarred            => undef,                     # replaced by 'restricted'
1746         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1747         emailpro            => 'secondary_email',
1748         flags               => undef,    # permissions manipulation handled in /permissions
1749         gonenoaddress       => 'incorrect_address',
1750         guarantorid         => 'guarantor_id',
1751         lastseen            => 'last_seen',
1752         lost                => 'patron_card_lost',
1753         opacnote            => 'opac_notes',
1754         othernames          => 'other_name',
1755         password            => undef,            # password manipulation handled in /password
1756         phonepro            => 'secondary_phone',
1757         relationship        => 'relationship_type',
1758         sex                 => 'gender',
1759         smsalertnumber      => 'sms_number',
1760         sort1               => 'statistics_1',
1761         sort2               => 'statistics_2',
1762         autorenew_checkouts => 'autorenew_checkouts',
1763         streetnumber        => 'street_number',
1764         streettype          => 'street_type',
1765         zipcode             => 'postal_code',
1766         B_address           => 'altaddress_address',
1767         B_address2          => 'altaddress_address2',
1768         B_city              => 'altaddress_city',
1769         B_country           => 'altaddress_country',
1770         B_email             => 'altaddress_email',
1771         B_phone             => 'altaddress_phone',
1772         B_state             => 'altaddress_state',
1773         B_streetnumber      => 'altaddress_street_number',
1774         B_streettype        => 'altaddress_street_type',
1775         B_zipcode           => 'altaddress_postal_code',
1776         altcontactaddress1  => 'altcontact_address',
1777         altcontactaddress2  => 'altcontact_address2',
1778         altcontactaddress3  => 'altcontact_city',
1779         altcontactcountry   => 'altcontact_country',
1780         altcontactfirstname => 'altcontact_firstname',
1781         altcontactphone     => 'altcontact_phone',
1782         altcontactsurname   => 'altcontact_surname',
1783         altcontactstate     => 'altcontact_state',
1784         altcontactzipcode   => 'altcontact_postal_code'
1785     };
1786 }
1787
1788 =head2 Internal methods
1789
1790 =head3 _type
1791
1792 =cut
1793
1794 sub _type {
1795     return 'Borrower';
1796 }
1797
1798 =head1 AUTHORS
1799
1800 Kyle M Hall <kyle@bywatersolutions.com>
1801 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1802 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1803
1804 =cut
1805
1806 1;