Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Carp;
  24 use List::MoreUtils qw( any uniq );
  25 use JSON qw( to_json );
  26 use Unicode::Normalize;
  27
  28 use C4::Context;
  29 use C4::Log;
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use Koha::AuthUtils;
  33 use Koha::Checkouts;
  34 use Koha::Club::Enrollments;
  35 use Koha::Database;
  36 use Koha::DateUtils;
  37 use Koha::Exceptions::Password;
  38 use Koha::Holds;
  39 use Koha::Old::Checkouts;
  40 use Koha::Patron::Attributes;
  41 use Koha::Patron::Categories;
  42 use Koha::Patron::Debarments;
  43 use Koha::Patron::HouseboundProfile;
  44 use Koha::Patron::HouseboundRole;
  45 use Koha::Patron::Images;
  46 use Koha::Patron::Modifications;
  47 use Koha::Patron::Relationships;
  48 use Koha::Patrons;
  49 use Koha::Plugins;
  50 use Koha::Subscription::Routinglists;
  51 use Koha::Token;
  52 use Koha::Virtualshelves;
  53
  54 use base qw(Koha::Object);
  55
  56 use constant ADMINISTRATIVE_LOCKOUT => -1;
  57
  58 our $RESULTSET_PATRON_ID_MAPPING = {
  59     Accountline          => 'borrowernumber',
  60     Aqbasketuser         => 'borrowernumber',
  61     Aqbudget             => 'budget_owner_id',
  62     Aqbudgetborrower     => 'borrowernumber',
  63     ArticleRequest       => 'borrowernumber',
  64     BorrowerDebarment    => 'borrowernumber',
  65     BorrowerFile         => 'borrowernumber',
  66     BorrowerModification => 'borrowernumber',
  67     ClubEnrollment       => 'borrowernumber',
  68     Issue                => 'borrowernumber',
  69     ItemsLastBorrower    => 'borrowernumber',
  70     Linktracker          => 'borrowernumber',
  71     Message              => 'borrowernumber',
  72     MessageQueue         => 'borrowernumber',
  73     OldIssue             => 'borrowernumber',
  74     OldReserve           => 'borrowernumber',
  75     Rating               => 'borrowernumber',
  76     Reserve              => 'borrowernumber',
  77     Review               => 'borrowernumber',
  78     SearchHistory        => 'userid',
  79     Statistic            => 'borrowernumber',
  80     Suggestion           => 'suggestedby',
  81     TagAll               => 'borrowernumber',
  82     Virtualshelfcontent  => 'borrowernumber',
  83     Virtualshelfshare    => 'borrowernumber',
  84     Virtualshelve        => 'owner',
  85 };
  86
  87 =head1 NAME
  88
  89 Koha::Patron - Koha Patron Object class
  90
  91 =head1 API
  92
  93 =head2 Class Methods
  94
  95 =head3 new
  96
  97 =cut
  98
  99 sub new {
 100     my ( $class, $params ) = @_;
 101
 102     return $class->SUPER::new($params);
 103 }
 104
 105 =head3 fixup_cardnumber
 106
 107 Autogenerate next cardnumber from highest value found in database
 108
 109 =cut
 110
 111 sub fixup_cardnumber {
 112     my ( $self ) = @_;
 113     my $max = Koha::Patrons->search({
 114         cardnumber => {-regexp => '^-?[0-9]+$'}
 115     }, {
 116         select => \'CAST(cardnumber AS SIGNED)',
 117         as => ['cast_cardnumber']
 118     })->_resultset->get_column('cast_cardnumber')->max;
 119     $self->cardnumber(($max || 0) +1);
 120 }
 121
 122 =head3 trim_whitespace
 123
 124 trim whitespace from data which has some non-whitespace in it.
 125 Could be moved to Koha::Object if need to be reused
 126
 127 =cut
 128
 129 sub trim_whitespaces {
 130     my( $self ) = @_;
 131
 132     my $schema  = Koha::Database->new->schema;
 133     my @columns = $schema->source($self->_type)->columns;
 134
 135     for my $column( @columns ) {
 136         my $value = $self->$column;
 137         if ( defined $value ) {
 138             $value =~ s/^\s*|\s*$//g;
 139             $self->$column($value);
 140         }
 141     }
 142     return $self;
 143 }
 144
 145 =head3 plain_text_password
 146
 147 $patron->plain_text_password( $password );
 148
 149 stores a copy of the unencrypted password in the object
 150 for use in code before encrypting for db
 151
 152 =cut
 153
 154 sub plain_text_password {
 155     my ( $self, $password ) = @_;
 156     if ( $password ) {
 157         $self->{_plain_text_password} = $password;
 158         return $self;
 159     }
 160     return $self->{_plain_text_password}
 161         if $self->{_plain_text_password};
 162
 163     return;
 164 }
 165
 166 =head3 store
 167
 168 Patron specific store method to cleanup record
 169 and do other necessary things before saving
 170 to db
 171
 172 =cut
 173
 174 sub store {
 175     my ($self) = @_;
 176
 177     $self->_result->result_source->schema->txn_do(
 178         sub {
 179             if (
 180                 C4::Context->preference("autoMemberNum")
 181                 and ( not defined $self->cardnumber
 182                     or $self->cardnumber eq '' )
 183               )
 184             {
 185                 # Warning: The caller is responsible for locking the members table in write
 186                 # mode, to avoid database corruption.
 187                 # We are in a transaction but the table is not locked
 188                 $self->fixup_cardnumber;
 189             }
 190
 191             unless( $self->category->in_storage ) {
 192                 Koha::Exceptions::Object::FKConstraint->throw(
 193                     broken_fk => 'categorycode',
 194                     value     => $self->categorycode,
 195                 );
 196             }
 197
 198             $self->trim_whitespaces;
 199
 200             # Set surname to uppercase if uppercasesurname is true
 201             $self->surname( uc($self->surname) )
 202                 if C4::Context->preference("uppercasesurnames");
 203
 204             $self->relationship(undef) # We do not want to store an empty string in this field
 205               if defined $self->relationship
 206                      and $self->relationship eq "";
 207
 208             unless ( $self->in_storage ) {    #AddMember
 209
 210                 # Generate a valid userid/login if needed
 211                 $self->generate_userid
 212                   if not $self->userid or not $self->has_valid_userid;
 213
 214                 # Add expiration date if it isn't already there
 215                 unless ( $self->dateexpiry ) {
 216                     $self->dateexpiry( $self->category->get_expiry_date );
 217                 }
 218
 219                 # Add enrollment date if it isn't already there
 220                 unless ( $self->dateenrolled ) {
 221                     $self->dateenrolled(dt_from_string);
 222                 }
 223
 224                 # Set the privacy depending on the patron's category
 225                 my $default_privacy = $self->category->default_privacy || q{};
 226                 $default_privacy =
 227                     $default_privacy eq 'default' ? 1
 228                   : $default_privacy eq 'never'   ? 2
 229                   : $default_privacy eq 'forever' ? 0
 230                   :                                                   undef;
 231                 $self->privacy($default_privacy);
 232
 233                 # Call any check_password plugins if password is passed
 234                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 235                     my @plugins = Koha::Plugins->new()->GetPlugins({
 236                         method => 'check_password',
 237                     });
 238                     foreach my $plugin ( @plugins ) {
 239                         # This plugin hook will also be used by a plugin for the Norwegian national
 240                         # patron database. This is why we need to pass both the password and the
 241                         # borrowernumber to the plugin.
 242                         my $ret = $plugin->check_password(
 243                             {
 244                                 password       => $self->password,
 245                                 borrowernumber => $self->borrowernumber
 246                             }
 247                         );
 248                         if ( $ret->{'error'} == 1 ) {
 249                             Koha::Exceptions::Password::Plugin->throw();
 250                         }
 251                     }
 252                 }
 253
 254                 # Make a copy of the plain text password for later use
 255                 $self->plain_text_password( $self->password );
 256
 257                 # Create a disabled account if no password provided
 258                 $self->password( $self->password
 259                     ? Koha::AuthUtils::hash_password( $self->password )
 260                     : '!' );
 261
 262                 $self->borrowernumber(undef);
 263
 264                 $self = $self->SUPER::store;
 265
 266                 $self->add_enrolment_fee_if_needed(0);
 267
 268                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 269                   if C4::Context->preference("BorrowersLog");
 270             }
 271             else {    #ModMember
 272
 273                 my $self_from_storage = $self->get_from_storage;
 274                 # FIXME We should not deal with that here, callers have to do this job
 275                 # Moved from ModMember to prevent regressions
 276                 unless ( $self->userid ) {
 277                     my $stored_userid = $self_from_storage->userid;
 278                     $self->userid($stored_userid);
 279                 }
 280
 281                 # Password must be updated using $self->set_password
 282                 $self->password($self_from_storage->password);
 283
 284                 if ( $self->category->categorycode ne
 285                     $self_from_storage->category->categorycode )
 286                 {
 287                     # Add enrolement fee on category change if required
 288                     $self->add_enrolment_fee_if_needed(1)
 289                       if C4::Context->preference('FeeOnChangePatronCategory');
 290
 291                     # Clean up guarantors on category change if required
 292                     $self->guarantor_relationships->delete
 293                       if ( $self->category->category_type ne 'C'
 294                         && $self->category->category_type ne 'P' );
 295
 296                 }
 297
 298                 # Actionlogs
 299                 if ( C4::Context->preference("BorrowersLog") ) {
 300                     my $info;
 301                     my $from_storage = $self_from_storage->unblessed;
 302                     my $from_object  = $self->unblessed;
 303                     my @skip_fields  = (qw/lastseen updated_on/);
 304                     for my $key ( keys %{$from_storage} ) {
 305                         next if any { /$key/ } @skip_fields;
 306                         if (
 307                             (
 308                                   !defined( $from_storage->{$key} )
 309                                 && defined( $from_object->{$key} )
 310                             )
 311                             || ( defined( $from_storage->{$key} )
 312                                 && !defined( $from_object->{$key} ) )
 313                             || (
 314                                    defined( $from_storage->{$key} )
 315                                 && defined( $from_object->{$key} )
 316                                 && ( $from_storage->{$key} ne
 317                                     $from_object->{$key} )
 318                             )
 319                           )
 320                         {
 321                             $info->{$key} = {
 322                                 before => $from_storage->{$key},
 323                                 after  => $from_object->{$key}
 324                             };
 325                         }
 326                     }
 327
 328                     if ( defined($info) ) {
 329                         logaction(
 330                             "MEMBERS",
 331                             "MODIFY",
 332                             $self->borrowernumber,
 333                             to_json(
 334                                 $info,
 335                                 { utf8 => 1, pretty => 1, canonical => 1 }
 336                             )
 337                         );
 338                     }
 339                 }
 340
 341                 # Final store
 342                 $self = $self->SUPER::store;
 343             }
 344         }
 345     );
 346     return $self;
 347 }
 348
 349 =head3 delete
 350
 351 $patron->delete
 352
 353 Delete patron's holds, lists and finally the patron.
 354
 355 Lists owned by the borrower are deleted, but entries from the borrower to
 356 other lists are kept.
 357
 358 =cut
 359
 360 sub delete {
 361     my ($self) = @_;
 362
 363     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 364     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 365
 366     $self->_result->result_source->schema->txn_do(
 367         sub {
 368             # Cancel Patron's holds
 369             my $holds = $self->holds;
 370             while( my $hold = $holds->next ){
 371                 $hold->cancel;
 372             }
 373
 374             # Delete all lists and all shares of this borrower
 375             # Consistent with the approach Koha uses on deleting individual lists
 376             # Note that entries in virtualshelfcontents added by this borrower to
 377             # lists of others will be handled by a table constraint: the borrower
 378             # is set to NULL in those entries.
 379             # NOTE:
 380             # We could handle the above deletes via a constraint too.
 381             # But a new BZ report 11889 has been opened to discuss another approach.
 382             # Instead of deleting we could also disown lists (based on a pref).
 383             # In that way we could save shared and public lists.
 384             # The current table constraints support that idea now.
 385             # This pref should then govern the results of other routines/methods such as
 386             # Koha::Virtualshelf->new->delete too.
 387             # FIXME Could be $patron->get_lists
 388             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } );
 389
 390             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 391             # for patron selfreg
 392             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } );
 393
 394             $self->SUPER::delete;
 395
 396             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 397         }
 398     );
 399     return $self;
 400 }
 401
 402
 403 =head3 category
 404
 405 my $patron_category = $patron->category
 406
 407 Return the patron category for this patron
 408
 409 =cut
 410
 411 sub category {
 412     my ( $self ) = @_;
 413     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 414 }
 415
 416 =head3 image
 417
 418 =cut
 419
 420 sub image {
 421     my ( $self ) = @_;
 422
 423     return Koha::Patron::Images->find( $self->borrowernumber );
 424 }
 425
 426 =head3 library
 427
 428 Returns a Koha::Library object representing the patron's home library.
 429
 430 =cut
 431
 432 sub library {
 433     my ( $self ) = @_;
 434     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 435 }
 436
 437 =head3 sms_provider
 438
 439 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 440
 441 =cut
 442
 443 sub sms_provider {
 444     my ( $self ) = @_;
 445     my $sms_provider_rs = $self->_result->sms_provider;
 446     return unless $sms_provider_rs;
 447     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 448 }
 449
 450 =head3 guarantor_relationships
 451
 452 Returns Koha::Patron::Relationships object for this patron's guarantors
 453
 454 Returns the set of relationships for the patrons that are guarantors for this patron.
 455
 456 This is returned instead of a Koha::Patron object because the guarantor
 457 may not exist as a patron in Koha. If this is true, the guarantors name
 458 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 459
 460 =cut
 461
 462 sub guarantor_relationships {
 463     my ($self) = @_;
 464
 465     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 466 }
 467
 468 =head3 guarantee_relationships
 469
 470 Returns Koha::Patron::Relationships object for this patron's guarantors
 471
 472 Returns the set of relationships for the patrons that are guarantees for this patron.
 473
 474 The method returns Koha::Patron::Relationship objects for the sake
 475 of consistency with the guantors method.
 476 A guarantee by definition must exist as a patron in Koha.
 477
 478 =cut
 479
 480 sub guarantee_relationships {
 481     my ($self) = @_;
 482
 483     return Koha::Patron::Relationships->search(
 484         { guarantor_id => $self->id },
 485         {
 486             prefetch => 'guarantee',
 487             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 488         }
 489     );
 490 }
 491
 492 =head3 relationships_debt
 493
 494 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 495
 496 =cut
 497
 498 sub relationships_debt {
 499     my ($self, $params) = @_;
 500
 501     my $include_guarantors  = $params->{include_guarantors};
 502     my $only_this_guarantor = $params->{only_this_guarantor};
 503     my $include_this_patron = $params->{include_this_patron};
 504
 505     my @guarantors;
 506     if ( $only_this_guarantor ) {
 507         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 508         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 509     } elsif ( $self->guarantor_relationships->count ) {
 510         # I am a guarantee, just get all my guarantors
 511         @guarantors = $self->guarantor_relationships->guarantors;
 512     } else {
 513         # I am a guarantor, I need to get all the guarantors of all my guarantees
 514         @guarantors = map { $_->guarantor_relationships->guarantors } $self->guarantee_relationships->guarantees;
 515     }
 516
 517     my $non_issues_charges = 0;
 518     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 519     foreach my $guarantor (@guarantors) {
 520         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 521
 522         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 523         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships();
 524         my $guarantees_non_issues_charges = 0;
 525         foreach my $guarantee (@guarantees) {
 526             next if $seen->{ $guarantee->id };
 527             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 528             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 529             $seen->{ $guarantee->id } = 1;
 530         }
 531
 532         $non_issues_charges += $guarantees_non_issues_charges;
 533         $seen->{ $guarantor->id } = 1;
 534     }
 535
 536     return $non_issues_charges;
 537 }
 538
 539 =head3 housebound_profile
 540
 541 Returns the HouseboundProfile associated with this patron.
 542
 543 =cut
 544
 545 sub housebound_profile {
 546     my ( $self ) = @_;
 547     my $profile = $self->_result->housebound_profile;
 548     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 549         if ( $profile );
 550     return;
 551 }
 552
 553 =head3 housebound_role
 554
 555 Returns the HouseboundRole associated with this patron.
 556
 557 =cut
 558
 559 sub housebound_role {
 560     my ( $self ) = @_;
 561
 562     my $role = $self->_result->housebound_role;
 563     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 564     return;
 565 }
 566
 567 =head3 siblings
 568
 569 Returns the siblings of this patron.
 570
 571 =cut
 572
 573 sub siblings {
 574     my ($self) = @_;
 575
 576     my @guarantors = $self->guarantor_relationships()->guarantors();
 577
 578     return unless @guarantors;
 579
 580     my @siblings =
 581       map { $_->guarantee_relationships()->guarantees() } @guarantors;
 582
 583     return unless @siblings;
 584
 585     my %seen;
 586     @siblings =
 587       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 588
 589     return wantarray ? @siblings : Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 590 }
 591
 592 =head3 merge_with
 593
 594     my $patron = Koha::Patrons->find($id);
 595     $patron->merge_with( \@patron_ids );
 596
 597     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 598     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 599     of the keeper patron.
 600
 601 =cut
 602
 603 sub merge_with {
 604     my ( $self, $patron_ids ) = @_;
 605
 606     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 607     return if $anonymous_patron && $self->id eq $anonymous_patron;
 608
 609     my @patron_ids = @{ $patron_ids };
 610
 611     # Ensure the keeper isn't in the list of patrons to merge
 612     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 613
 614     my $schema = Koha::Database->new()->schema();
 615
 616     my $results;
 617
 618     $self->_result->result_source->schema->txn_do( sub {
 619         foreach my $patron_id (@patron_ids) {
 620
 621             next if $patron_id eq $anonymous_patron;
 622
 623             my $patron = Koha::Patrons->find( $patron_id );
 624
 625             next unless $patron;
 626
 627             # Unbless for safety, the patron will end up being deleted
 628             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 629
 630             my $attributes = $patron->extended_attributes;
 631             my $new_attributes = [
 632                 map { { code => $_->code, attribute => $_->attribute } }
 633                     $attributes->as_list
 634             ];
 635             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 636             for my $attribute ( @$new_attributes ) {
 637                 $self->add_extended_attribute($attribute);
 638             }
 639
 640             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 641                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 642                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 643                 $rs->update({ $field => $self->id });
 644                 if ( $r eq 'BorrowerDebarment' ) {
 645                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 646                 }
 647             }
 648
 649             $patron->move_to_deleted();
 650             $patron->delete();
 651         }
 652     });
 653
 654     return $results;
 655 }
 656
 657
 658
 659 =head3 wants_check_for_previous_checkout
 660
 661     $wants_check = $patron->wants_check_for_previous_checkout;
 662
 663 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 664
 665 =cut
 666
 667 sub wants_check_for_previous_checkout {
 668     my ( $self ) = @_;
 669     my $syspref = C4::Context->preference("checkPrevCheckout");
 670
 671     # Simple cases
 672     ## Hard syspref trumps all
 673     return 1 if ($syspref eq 'hardyes');
 674     return 0 if ($syspref eq 'hardno');
 675     ## Now, patron pref trumps all
 676     return 1 if ($self->checkprevcheckout eq 'yes');
 677     return 0 if ($self->checkprevcheckout eq 'no');
 678
 679     # More complex: patron inherits -> determine category preference
 680     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 681     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 682     return 0 if ($checkPrevCheckoutByCat eq 'no');
 683
 684     # Finally: category preference is inherit, default to 0
 685     if ($syspref eq 'softyes') {
 686         return 1;
 687     } else {
 688         return 0;
 689     }
 690 }
 691
 692 =head3 do_check_for_previous_checkout
 693
 694     $do_check = $patron->do_check_for_previous_checkout($item);
 695
 696 Return 1 if the bib associated with $ITEM has previously been checked out to
 697 $PATRON, 0 otherwise.
 698
 699 =cut
 700
 701 sub do_check_for_previous_checkout {
 702     my ( $self, $item ) = @_;
 703
 704     my @item_nos;
 705     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 706     if ( $biblio->is_serial ) {
 707         push @item_nos, $item->{itemnumber};
 708     } else {
 709         # Get all itemnumbers for given bibliographic record.
 710         @item_nos = $biblio->items->get_column( 'itemnumber' );
 711     }
 712
 713     # Create (old)issues search criteria
 714     my $criteria = {
 715         borrowernumber => $self->borrowernumber,
 716         itemnumber => \@item_nos,
 717     };
 718
 719     # Check current issues table
 720     my $issues = Koha::Checkouts->search($criteria);
 721     return 1 if $issues->count; # 0 || N
 722
 723     # Check old issues table
 724     my $old_issues = Koha::Old::Checkouts->search($criteria);
 725     return $old_issues->count;  # 0 || N
 726 }
 727
 728 =head3 is_debarred
 729
 730 my $debarment_expiration = $patron->is_debarred;
 731
 732 Returns the date a patron debarment will expire, or undef if the patron is not
 733 debarred
 734
 735 =cut
 736
 737 sub is_debarred {
 738     my ($self) = @_;
 739
 740     return unless $self->debarred;
 741     return $self->debarred
 742       if $self->debarred =~ '^9999'
 743       or dt_from_string( $self->debarred ) > dt_from_string;
 744     return;
 745 }
 746
 747 =head3 is_expired
 748
 749 my $is_expired = $patron->is_expired;
 750
 751 Returns 1 if the patron is expired or 0;
 752
 753 =cut
 754
 755 sub is_expired {
 756     my ($self) = @_;
 757     return 0 unless $self->dateexpiry;
 758     return 0 if $self->dateexpiry =~ '^9999';
 759     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 760     return 0;
 761 }
 762
 763 =head3 is_going_to_expire
 764
 765 my $is_going_to_expire = $patron->is_going_to_expire;
 766
 767 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 768
 769 =cut
 770
 771 sub is_going_to_expire {
 772     my ($self) = @_;
 773
 774     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 775
 776     return 0 unless $delay;
 777     return 0 unless $self->dateexpiry;
 778     return 0 if $self->dateexpiry =~ '^9999';
 779     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 780     return 0;
 781 }
 782
 783 =head3 set_password
 784
 785     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 786
 787 Set the patron's password.
 788
 789 =head4 Exceptions
 790
 791 The passed string is validated against the current password enforcement policy.
 792 Validation can be skipped by passing the I<skip_validation> parameter.
 793
 794 Exceptions are thrown if the password is not good enough.
 795
 796 =over 4
 797
 798 =item Koha::Exceptions::Password::TooShort
 799
 800 =item Koha::Exceptions::Password::WhitespaceCharacters
 801
 802 =item Koha::Exceptions::Password::TooWeak
 803
 804 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 805
 806 =back
 807
 808 =cut
 809
 810 sub set_password {
 811     my ( $self, $args ) = @_;
 812
 813     my $password = $args->{password};
 814
 815     unless ( $args->{skip_validation} ) {
 816         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 817
 818         if ( !$is_valid ) {
 819             if ( $error eq 'too_short' ) {
 820                 my $min_length = $self->category->effective_min_password_length;
 821                 $min_length = 3 if not $min_length or $min_length < 3;
 822
 823                 my $password_length = length($password);
 824                 Koha::Exceptions::Password::TooShort->throw(
 825                     length => $password_length, min_length => $min_length );
 826             }
 827             elsif ( $error eq 'has_whitespaces' ) {
 828                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 829             }
 830             elsif ( $error eq 'too_weak' ) {
 831                 Koha::Exceptions::Password::TooWeak->throw();
 832             }
 833         }
 834     }
 835
 836     if ( C4::Context->config("enable_plugins") ) {
 837         # Call any check_password plugins
 838         my @plugins = Koha::Plugins->new()->GetPlugins({
 839             method => 'check_password',
 840         });
 841         foreach my $plugin ( @plugins ) {
 842             # This plugin hook will also be used by a plugin for the Norwegian national
 843             # patron database. This is why we need to pass both the password and the
 844             # borrowernumber to the plugin.
 845             my $ret = $plugin->check_password(
 846                 {
 847                     password       => $password,
 848                     borrowernumber => $self->borrowernumber
 849                 }
 850             );
 851             # This plugin hook will also be used by a plugin for the Norwegian national
 852             # patron database. This is why we need to call the actual plugins and then
 853             # check skip_validation afterwards.
 854             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 855                 Koha::Exceptions::Password::Plugin->throw();
 856             }
 857         }
 858     }
 859
 860     my $digest = Koha::AuthUtils::hash_password($password);
 861
 862     # We do not want to call $self->store and retrieve password from DB
 863     $self->password($digest);
 864     $self->login_attempts(0);
 865     $self->SUPER::store;
 866
 867     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 868         if C4::Context->preference("BorrowersLog");
 869
 870     return $self;
 871 }
 872
 873
 874 =head3 renew_account
 875
 876 my $new_expiry_date = $patron->renew_account
 877
 878 Extending the subscription to the expiry date.
 879
 880 =cut
 881
 882 sub renew_account {
 883     my ($self) = @_;
 884     my $date;
 885     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 886         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 887     } else {
 888         $date =
 889             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 890             ? dt_from_string( $self->dateexpiry )
 891             : dt_from_string;
 892     }
 893     my $expiry_date = $self->category->get_expiry_date($date);
 894
 895     $self->dateexpiry($expiry_date);
 896     $self->date_renewed( dt_from_string() );
 897     $self->store();
 898
 899     $self->add_enrolment_fee_if_needed(1);
 900
 901     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 902     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 903 }
 904
 905 =head3 has_overdues
 906
 907 my $has_overdues = $patron->has_overdues;
 908
 909 Returns the number of patron's overdues
 910
 911 =cut
 912
 913 sub has_overdues {
 914     my ($self) = @_;
 915     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 916     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 917 }
 918
 919 =head3 track_login
 920
 921     $patron->track_login;
 922     $patron->track_login({ force => 1 });
 923
 924     Tracks a (successful) login attempt.
 925     The preference TrackLastPatronActivity must be enabled. Or you
 926     should pass the force parameter.
 927
 928 =cut
 929
 930 sub track_login {
 931     my ( $self, $params ) = @_;
 932     return if
 933         !$params->{force} &&
 934         !C4::Context->preference('TrackLastPatronActivity');
 935     $self->lastseen( dt_from_string() )->store;
 936 }
 937
 938 =head3 move_to_deleted
 939
 940 my $is_moved = $patron->move_to_deleted;
 941
 942 Move a patron to the deletedborrowers table.
 943 This can be done before deleting a patron, to make sure the data are not completely deleted.
 944
 945 =cut
 946
 947 sub move_to_deleted {
 948     my ($self) = @_;
 949     my $patron_infos = $self->unblessed;
 950     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 951     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 952 }
 953
 954 =head3 article_requests
 955
 956 my @requests = $borrower->article_requests();
 957 my $requests = $borrower->article_requests();
 958
 959 Returns either a list of ArticleRequests objects,
 960 or an ArtitleRequests object, depending on the
 961 calling context.
 962
 963 =cut
 964
 965 sub article_requests {
 966     my ( $self ) = @_;
 967
 968     $self->{_article_requests} ||= Koha::ArticleRequests->search({ borrowernumber => $self->borrowernumber() });
 969
 970     return $self->{_article_requests};
 971 }
 972
 973 =head3 article_requests_current
 974
 975 my @requests = $patron->article_requests_current
 976
 977 Returns the article requests associated with this patron that are incomplete
 978
 979 =cut
 980
 981 sub article_requests_current {
 982     my ( $self ) = @_;
 983
 984     $self->{_article_requests_current} ||= Koha::ArticleRequests->search(
 985         {
 986             borrowernumber => $self->id(),
 987             -or          => [
 988                 { status => Koha::ArticleRequest::Status::Pending },
 989                 { status => Koha::ArticleRequest::Status::Processing }
 990             ]
 991         }
 992     );
 993
 994     return $self->{_article_requests_current};
 995 }
 996
 997 =head3 article_requests_finished
 998
 999 my @requests = $biblio->article_requests_finished
1000
1001 Returns the article requests associated with this patron that are completed
1002
1003 =cut
1004
1005 sub article_requests_finished {
1006     my ( $self, $borrower ) = @_;
1007
1008     $self->{_article_requests_finished} ||= Koha::ArticleRequests->search(
1009         {
1010             borrowernumber => $self->id(),
1011             -or          => [
1012                 { status => Koha::ArticleRequest::Status::Completed },
1013                 { status => Koha::ArticleRequest::Status::Canceled }
1014             ]
1015         }
1016     );
1017
1018     return $self->{_article_requests_finished};
1019 }
1020
1021 =head3 add_enrolment_fee_if_needed
1022
1023 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1024
1025 Add enrolment fee for a patron if needed.
1026
1027 $renewal - boolean denoting whether this is an account renewal or not
1028
1029 =cut
1030
1031 sub add_enrolment_fee_if_needed {
1032     my ($self, $renewal) = @_;
1033     my $enrolment_fee = $self->category->enrolmentfee;
1034     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1035         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1036         $self->account->add_debit(
1037             {
1038                 amount     => $enrolment_fee,
1039                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1040                 interface  => C4::Context->interface,
1041                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1042                 type       => $type
1043             }
1044         );
1045     }
1046     return $enrolment_fee || 0;
1047 }
1048
1049 =head3 checkouts
1050
1051 my $checkouts = $patron->checkouts
1052
1053 =cut
1054
1055 sub checkouts {
1056     my ($self) = @_;
1057     my $checkouts = $self->_result->issues;
1058     return Koha::Checkouts->_new_from_dbic( $checkouts );
1059 }
1060
1061 =head3 pending_checkouts
1062
1063 my $pending_checkouts = $patron->pending_checkouts
1064
1065 This method will return the same as $self->checkouts, but with a prefetch on
1066 items, biblio and biblioitems.
1067
1068 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1069
1070 It should not be used directly, prefer to access fields you need instead of
1071 retrieving all these fields in one go.
1072
1073 =cut
1074
1075 sub pending_checkouts {
1076     my( $self ) = @_;
1077     my $checkouts = $self->_result->issues->search(
1078         {},
1079         {
1080             order_by => [
1081                 { -desc => 'me.timestamp' },
1082                 { -desc => 'issuedate' },
1083                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1084             ],
1085             prefetch => { item => { biblio => 'biblioitems' } },
1086         }
1087     );
1088     return Koha::Checkouts->_new_from_dbic( $checkouts );
1089 }
1090
1091 =head3 old_checkouts
1092
1093 my $old_checkouts = $patron->old_checkouts
1094
1095 =cut
1096
1097 sub old_checkouts {
1098     my ($self) = @_;
1099     my $old_checkouts = $self->_result->old_issues;
1100     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1101 }
1102
1103 =head3 get_overdues
1104
1105 my $overdue_items = $patron->get_overdues
1106
1107 Return the overdue items
1108
1109 =cut
1110
1111 sub get_overdues {
1112     my ($self) = @_;
1113     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1114     return $self->checkouts->search(
1115         {
1116             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1117         },
1118         {
1119             prefetch => { item => { biblio => 'biblioitems' } },
1120         }
1121     );
1122 }
1123
1124 =head3 get_routing_lists
1125
1126 my @routinglists = $patron->get_routing_lists
1127
1128 Returns the routing lists a patron is subscribed to.
1129
1130 =cut
1131
1132 sub get_routing_lists {
1133     my ($self) = @_;
1134     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1135     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1136 }
1137
1138 =head3 get_age
1139
1140 my $age = $patron->get_age
1141
1142 Return the age of the patron
1143
1144 =cut
1145
1146 sub get_age {
1147     my ($self)    = @_;
1148     my $today_str = dt_from_string->strftime("%Y-%m-%d");
1149     return unless $self->dateofbirth;
1150     my $dob_str   = dt_from_string( $self->dateofbirth )->strftime("%Y-%m-%d");
1151
1152     my ( $dob_y,   $dob_m,   $dob_d )   = split /-/, $dob_str;
1153     my ( $today_y, $today_m, $today_d ) = split /-/, $today_str;
1154
1155     my $age = $today_y - $dob_y;
1156     if ( $dob_m . $dob_d > $today_m . $today_d ) {
1157         $age--;
1158     }
1159
1160     return $age;
1161 }
1162
1163 =head3 is_valid_age
1164
1165 my $is_valid = $patron->is_valid_age
1166
1167 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1168
1169 =cut
1170
1171 sub is_valid_age {
1172     my ($self) = @_;
1173     my $age = $self->get_age;
1174
1175     my $patroncategory = $self->category;
1176     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1177
1178     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1179 }
1180
1181 =head3 account
1182
1183 my $account = $patron->account
1184
1185 =cut
1186
1187 sub account {
1188     my ($self) = @_;
1189     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1190 }
1191
1192 =head3 holds
1193
1194 my $holds = $patron->holds
1195
1196 Return all the holds placed by this patron
1197
1198 =cut
1199
1200 sub holds {
1201     my ($self) = @_;
1202     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1203     return Koha::Holds->_new_from_dbic($holds_rs);
1204 }
1205
1206 =head3 old_holds
1207
1208 my $old_holds = $patron->old_holds
1209
1210 Return all the historical holds for this patron
1211
1212 =cut
1213
1214 sub old_holds {
1215     my ($self) = @_;
1216     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1217     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1218 }
1219
1220 =head3 return_claims
1221
1222 my $return_claims = $patron->return_claims
1223
1224 =cut
1225
1226 sub return_claims {
1227     my ($self) = @_;
1228     my $return_claims = $self->_result->return_claims_borrowernumbers;
1229     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1230 }
1231
1232 =head3 notice_email_address
1233
1234   my $email = $patron->notice_email_address;
1235
1236 Return the email address of patron used for notices.
1237 Returns the empty string if no email address.
1238
1239 =cut
1240
1241 sub notice_email_address{
1242     my ( $self ) = @_;
1243
1244     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1245     # if syspref is set to 'first valid' (value == OFF), look up email address
1246     if ( $which_address eq 'OFF' ) {
1247         return $self->first_valid_email_address;
1248     }
1249
1250     return $self->$which_address || '';
1251 }
1252
1253 =head3 first_valid_email_address
1254
1255 my $first_valid_email_address = $patron->first_valid_email_address
1256
1257 Return the first valid email address for a patron.
1258 For now, the order  is defined as email, emailpro, B_email.
1259 Returns the empty string if the borrower has no email addresses.
1260
1261 =cut
1262
1263 sub first_valid_email_address {
1264     my ($self) = @_;
1265
1266     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1267 }
1268
1269 =head3 get_club_enrollments
1270
1271 =cut
1272
1273 sub get_club_enrollments {
1274     my ( $self, $return_scalar ) = @_;
1275
1276     my $e = Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1277
1278     return $e if $return_scalar;
1279
1280     return wantarray ? $e->as_list : $e;
1281 }
1282
1283 =head3 get_enrollable_clubs
1284
1285 =cut
1286
1287 sub get_enrollable_clubs {
1288     my ( $self, $is_enrollable_from_opac, $return_scalar ) = @_;
1289
1290     my $params;
1291     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1292       if $is_enrollable_from_opac;
1293     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1294
1295     $params->{borrower} = $self;
1296
1297     my $e = Koha::Clubs->get_enrollable($params);
1298
1299     return $e if $return_scalar;
1300
1301     return wantarray ? $e->as_list : $e;
1302 }
1303
1304 =head3 account_locked
1305
1306 my $is_locked = $patron->account_locked
1307
1308 Return true if the patron has reached the maximum number of login attempts
1309 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1310 as an administrative lockout (independent of FailedLoginAttempts; see also
1311 Koha::Patron->lock).
1312 Otherwise return false.
1313 If the pref is not set (empty string, null or 0), the feature is considered as
1314 disabled.
1315
1316 =cut
1317
1318 sub account_locked {
1319     my ($self) = @_;
1320     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1321     return 1 if $FailedLoginAttempts
1322           and $self->login_attempts
1323           and $self->login_attempts >= $FailedLoginAttempts;
1324     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1325     return 0;
1326 }
1327
1328 =head3 can_see_patron_infos
1329
1330 my $can_see = $patron->can_see_patron_infos( $patron );
1331
1332 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1333
1334 =cut
1335
1336 sub can_see_patron_infos {
1337     my ( $self, $patron ) = @_;
1338     return unless $patron;
1339     return $self->can_see_patrons_from( $patron->branchcode );
1340 }
1341
1342 =head3 can_see_patrons_from
1343
1344 my $can_see = $patron->can_see_patrons_from( $branchcode );
1345
1346 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1347
1348 =cut
1349
1350 sub can_see_patrons_from {
1351     my ( $self, $branchcode ) = @_;
1352     my $can = 0;
1353     if ( $self->branchcode eq $branchcode ) {
1354         $can = 1;
1355     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1356         $can = 1;
1357     } elsif ( my $library_groups = $self->library->library_groups ) {
1358         while ( my $library_group = $library_groups->next ) {
1359             if ( $library_group->parent->has_child( $branchcode ) ) {
1360                 $can = 1;
1361                 last;
1362             }
1363         }
1364     }
1365     return $can;
1366 }
1367
1368 =head3 libraries_where_can_see_patrons
1369
1370 my $libraries = $patron-libraries_where_can_see_patrons;
1371
1372 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1373 The branchcodes are arbitrarily returned sorted.
1374 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1375
1376 An empty array means no restriction, the patron can see patron's infos from any libraries.
1377
1378 =cut
1379
1380 sub libraries_where_can_see_patrons {
1381     my ( $self ) = @_;
1382     my $userenv = C4::Context->userenv;
1383
1384     return () unless $userenv; # For tests, but userenv should be defined in tests...
1385
1386     my @restricted_branchcodes;
1387     if (C4::Context::only_my_library) {
1388         push @restricted_branchcodes, $self->branchcode;
1389     }
1390     else {
1391         unless (
1392             $self->has_permission(
1393                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1394             )
1395           )
1396         {
1397             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1398             if ( $library_groups->count )
1399             {
1400                 while ( my $library_group = $library_groups->next ) {
1401                     my $parent = $library_group->parent;
1402                     if ( $parent->has_child( $self->branchcode ) ) {
1403                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1404                     }
1405                 }
1406             }
1407
1408             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1409         }
1410     }
1411
1412     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1413     @restricted_branchcodes = uniq(@restricted_branchcodes);
1414     @restricted_branchcodes = sort(@restricted_branchcodes);
1415     return @restricted_branchcodes;
1416 }
1417
1418 =head3 has_permission
1419
1420 my $permission = $patron->has_permission($required);
1421
1422 See C4::Auth::haspermission for details of syntax for $required
1423
1424 =cut
1425
1426 sub has_permission {
1427     my ( $self, $flagsrequired ) = @_;
1428     return unless $self->userid;
1429     # TODO code from haspermission needs to be moved here!
1430     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1431 }
1432
1433 =head3 is_superlibrarian
1434
1435   my $is_superlibrarian = $patron->is_superlibrarian;
1436
1437 Return true if the patron is a superlibrarian.
1438
1439 =cut
1440
1441 sub is_superlibrarian {
1442     my ($self) = @_;
1443     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1444 }
1445
1446 =head3 is_adult
1447
1448 my $is_adult = $patron->is_adult
1449
1450 Return true if the patron has a category with a type Adult (A) or Organization (I)
1451
1452 =cut
1453
1454 sub is_adult {
1455     my ( $self ) = @_;
1456     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1457 }
1458
1459 =head3 is_child
1460
1461 my $is_child = $patron->is_child
1462
1463 Return true if the patron has a category with a type Child (C)
1464
1465 =cut
1466
1467 sub is_child {
1468     my( $self ) = @_;
1469     return $self->category->category_type eq 'C' ? 1 : 0;
1470 }
1471
1472 =head3 has_valid_userid
1473
1474 my $patron = Koha::Patrons->find(42);
1475 $patron->userid( $new_userid );
1476 my $has_a_valid_userid = $patron->has_valid_userid
1477
1478 my $patron = Koha::Patron->new( $params );
1479 my $has_a_valid_userid = $patron->has_valid_userid
1480
1481 Return true if the current userid of this patron is valid/unique, otherwise false.
1482
1483 Note that this should be done in $self->store instead and raise an exception if needed.
1484
1485 =cut
1486
1487 sub has_valid_userid {
1488     my ($self) = @_;
1489
1490     return 0 unless $self->userid;
1491
1492     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1493
1494     my $already_exists = Koha::Patrons->search(
1495         {
1496             userid => $self->userid,
1497             (
1498                 $self->in_storage
1499                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1500                 : ()
1501             ),
1502         }
1503     )->count;
1504     return $already_exists ? 0 : 1;
1505 }
1506
1507 =head3 generate_userid
1508
1509 my $patron = Koha::Patron->new( $params );
1510 $patron->generate_userid
1511
1512 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1513
1514 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1515
1516 =cut
1517
1518 sub generate_userid {
1519     my ($self) = @_;
1520     my $offset = 0;
1521     my $firstname = $self->firstname // q{};
1522     my $surname = $self->surname // q{};
1523     #The script will "do" the following code and increment the $offset until the generated userid is unique
1524     do {
1525       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1526       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1527       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1528       $userid = NFKD( $userid );
1529       $userid =~ s/\p{NonspacingMark}//g;
1530       $userid .= $offset unless $offset == 0;
1531       $self->userid( $userid );
1532       $offset++;
1533      } while (! $self->has_valid_userid );
1534
1535      return $self;
1536 }
1537
1538 =head3 add_extended_attribute
1539
1540 =cut
1541
1542 sub add_extended_attribute {
1543     my ($self, $attribute) = @_;
1544     $attribute->{borrowernumber} = $self->borrowernumber;
1545     return Koha::Patron::Attribute->new($attribute)->store;
1546 }
1547
1548 =head3 extended_attributes
1549
1550 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1551
1552 Or setter FIXME
1553
1554 =cut
1555
1556 sub extended_attributes {
1557     my ( $self, $attributes ) = @_;
1558     if ($attributes) {    # setter
1559         my $schema = $self->_result->result_source->schema;
1560         $schema->txn_do(
1561             sub {
1562                 # Remove the existing one
1563                 $self->extended_attributes->filter_by_branch_limitations->delete;
1564
1565                 # Insert the new ones
1566                 for my $attribute (@$attributes) {
1567                     eval {
1568                         $self->_result->create_related('borrower_attributes', $attribute);
1569                     };
1570                     # FIXME We should:
1571                     # 1 - Raise an exception
1572                     # 2 - Execute in a transaction and don't save
1573                     #  or Insert anyway but display a message on the UI
1574                     warn $@ if $@;
1575                 }
1576             }
1577         );
1578     }
1579
1580     my $rs = $self->_result->borrower_attributes;
1581     # We call search to use the filters in Koha::Patron::Attributes->search
1582     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1583 }
1584
1585 =head3 lock
1586
1587     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1588
1589     Lock and optionally expire a patron account.
1590     Remove holds and article requests if remove flag set.
1591     In order to distinguish from locking by entering a wrong password, let's
1592     call this an administrative lockout.
1593
1594 =cut
1595
1596 sub lock {
1597     my ( $self, $params ) = @_;
1598     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1599     if( $params->{expire} ) {
1600         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1601     }
1602     $self->store;
1603     if( $params->{remove} ) {
1604         $self->holds->delete;
1605         $self->article_requests->delete;
1606     }
1607     return $self;
1608 }
1609
1610 =head3 anonymize
1611
1612     Koha::Patrons->find($id)->anonymize;
1613
1614     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1615     are randomized, other personal data is cleared too.
1616     Patrons with issues are skipped.
1617
1618 =cut
1619
1620 sub anonymize {
1621     my ( $self ) = @_;
1622     if( $self->_result->issues->count ) {
1623         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1624         return;
1625     }
1626     # Mandatory fields come from the corresponding pref, but email fields
1627     # are removed since scrambled email addresses only generate errors
1628     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1629         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1630     $mandatory->{userid} = 1; # needed since sub store does not clear field
1631     my @columns = $self->_result->result_source->columns;
1632     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized/ } @columns;
1633     push @columns, 'dateofbirth'; # add this date back in
1634     foreach my $col (@columns) {
1635         $self->_anonymize_column($col, $mandatory->{lc $col} );
1636     }
1637     $self->anonymized(1)->store;
1638 }
1639
1640 sub _anonymize_column {
1641     my ( $self, $col, $mandatory ) = @_;
1642     my $col_info = $self->_result->result_source->column_info($col);
1643     my $type = $col_info->{data_type};
1644     my $nullable = $col_info->{is_nullable};
1645     my $val;
1646     if( $type =~ /char|text/ ) {
1647         $val = $mandatory
1648             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1649             : $nullable
1650             ? undef
1651             : q{};
1652     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1653         $val = $nullable ? undef : 0;
1654     } elsif( $type =~ /date|time/ ) {
1655         $val = $nullable ? undef : dt_from_string;
1656     }
1657     $self->$col($val);
1658 }
1659
1660 =head3 add_guarantor
1661
1662     my @relationships = $patron->add_guarantor(
1663         {
1664             borrowernumber => $borrowernumber,
1665             relationships  => $relationship,
1666         }
1667     );
1668
1669     Adds a new guarantor to a patron.
1670
1671 =cut
1672
1673 sub add_guarantor {
1674     my ( $self, $params ) = @_;
1675
1676     my $guarantor_id = $params->{guarantor_id};
1677     my $relationship = $params->{relationship};
1678
1679     return Koha::Patron::Relationship->new(
1680         {
1681             guarantee_id => $self->id,
1682             guarantor_id => $guarantor_id,
1683             relationship => $relationship
1684         }
1685     )->store();
1686 }
1687
1688 =head3 get_extended_attribute
1689
1690 my $attribute_value = $patron->get_extended_attribute( $code );
1691
1692 Return the attribute for the code passed in parameter.
1693
1694 It not exist it returns undef
1695
1696 Note that this will not work for repeatable attribute types.
1697
1698 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1699 (which should be a real patron's attribute (not extended)
1700
1701 =cut
1702
1703 sub get_extended_attribute {
1704     my ( $self, $code, $value ) = @_;
1705     my $rs = $self->_result->borrower_attributes;
1706     return unless $rs;
1707     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1708     return unless $attribute->count;
1709     return $attribute->next;
1710 }
1711
1712 =head3 to_api
1713
1714     my $json = $patron->to_api;
1715
1716 Overloaded method that returns a JSON representation of the Koha::Patron object,
1717 suitable for API output.
1718
1719 =cut
1720
1721 sub to_api {
1722     my ( $self, $params ) = @_;
1723
1724     my $json_patron = $self->SUPER::to_api( $params );
1725
1726     $json_patron->{restricted} = ( $self->is_debarred )
1727                                     ? Mojo::JSON->true
1728                                     : Mojo::JSON->false;
1729
1730     return $json_patron;
1731 }
1732
1733 =head3 to_api_mapping
1734
1735 This method returns the mapping for representing a Koha::Patron object
1736 on the API.
1737
1738 =cut
1739
1740 sub to_api_mapping {
1741     return {
1742         borrowernotes       => 'staff_notes',
1743         borrowernumber      => 'patron_id',
1744         branchcode          => 'library_id',
1745         categorycode        => 'category_id',
1746         checkprevcheckout   => 'check_previous_checkout',
1747         contactfirstname    => undef,                     # Unused
1748         contactname         => undef,                     # Unused
1749         contactnote         => 'altaddress_notes',
1750         contacttitle        => undef,                     # Unused
1751         dateenrolled        => 'date_enrolled',
1752         dateexpiry          => 'expiry_date',
1753         dateofbirth         => 'date_of_birth',
1754         debarred            => undef,                     # replaced by 'restricted'
1755         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1756         emailpro            => 'secondary_email',
1757         flags               => undef,    # permissions manipulation handled in /permissions
1758         gonenoaddress       => 'incorrect_address',
1759         guarantorid         => 'guarantor_id',
1760         lastseen            => 'last_seen',
1761         lost                => 'patron_card_lost',
1762         opacnote            => 'opac_notes',
1763         othernames          => 'other_name',
1764         password            => undef,            # password manipulation handled in /password
1765         phonepro            => 'secondary_phone',
1766         relationship        => 'relationship_type',
1767         sex                 => 'gender',
1768         smsalertnumber      => 'sms_number',
1769         sort1               => 'statistics_1',
1770         sort2               => 'statistics_2',
1771         autorenew_checkouts => 'autorenew_checkouts',
1772         streetnumber        => 'street_number',
1773         streettype          => 'street_type',
1774         zipcode             => 'postal_code',
1775         B_address           => 'altaddress_address',
1776         B_address2          => 'altaddress_address2',
1777         B_city              => 'altaddress_city',
1778         B_country           => 'altaddress_country',
1779         B_email             => 'altaddress_email',
1780         B_phone             => 'altaddress_phone',
1781         B_state             => 'altaddress_state',
1782         B_streetnumber      => 'altaddress_street_number',
1783         B_streettype        => 'altaddress_street_type',
1784         B_zipcode           => 'altaddress_postal_code',
1785         altcontactaddress1  => 'altcontact_address',
1786         altcontactaddress2  => 'altcontact_address2',
1787         altcontactaddress3  => 'altcontact_city',
1788         altcontactcountry   => 'altcontact_country',
1789         altcontactfirstname => 'altcontact_firstname',
1790         altcontactphone     => 'altcontact_phone',
1791         altcontactsurname   => 'altcontact_surname',
1792         altcontactstate     => 'altcontact_state',
1793         altcontactzipcode   => 'altcontact_postal_code'
1794     };
1795 }
1796
1797 =head2 Internal methods
1798
1799 =head3 _type
1800
1801 =cut
1802
1803 sub _type {
1804     return 'Borrower';
1805 }
1806
1807 =head1 AUTHORS
1808
1809 Kyle M Hall <kyle@bywatersolutions.com>
1810 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
1811 Martin Renvoize <martin.renvoize@ptfs-europe.com>
1812
1813 =cut
1814
1815 1;