Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Log qw( logaction );
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use C4::Letters;
  33 use Koha::AuthUtils;
  34 use Koha::Checkouts;
  35 use Koha::CirculationRules;
  36 use Koha::Club::Enrollments;
  37 use Koha::Database;
  38 use Koha::DateUtils qw( dt_from_string );
  39 use Koha::Encryption;
  40 use Koha::Exceptions::Password;
  41 use Koha::Holds;
  42 use Koha::CurbsidePickups;
  43 use Koha::Old::Checkouts;
  44 use Koha::Patron::Attributes;
  45 use Koha::Patron::Categories;
  46 use Koha::Patron::Debarments;
  47 use Koha::Patron::HouseboundProfile;
  48 use Koha::Patron::HouseboundRole;
  49 use Koha::Patron::Images;
  50 use Koha::Patron::Messages;
  51 use Koha::Patron::Modifications;
  52 use Koha::Patron::Relationships;
  53 use Koha::Patrons;
  54 use Koha::Plugins;
  55 use Koha::Recalls;
  56 use Koha::Result::Boolean;
  57 use Koha::Subscription::Routinglists;
  58 use Koha::Token;
  59 use Koha::Virtualshelves;
  60
  61 use base qw(Koha::Object);
  62
  63 use constant ADMINISTRATIVE_LOCKOUT => -1;
  64
  65 our $RESULTSET_PATRON_ID_MAPPING = {
  66     Accountline          => 'borrowernumber',
  67     Aqbasketuser         => 'borrowernumber',
  68     Aqbudget             => 'budget_owner_id',
  69     Aqbudgetborrower     => 'borrowernumber',
  70     ArticleRequest       => 'borrowernumber',
  71     BorrowerDebarment    => 'borrowernumber',
  72     BorrowerFile         => 'borrowernumber',
  73     BorrowerModification => 'borrowernumber',
  74     ClubEnrollment       => 'borrowernumber',
  75     Issue                => 'borrowernumber',
  76     ItemsLastBorrower    => 'borrowernumber',
  77     Linktracker          => 'borrowernumber',
  78     Message              => 'borrowernumber',
  79     MessageQueue         => 'borrowernumber',
  80     OldIssue             => 'borrowernumber',
  81     OldReserve           => 'borrowernumber',
  82     Rating               => 'borrowernumber',
  83     Reserve              => 'borrowernumber',
  84     Review               => 'borrowernumber',
  85     SearchHistory        => 'userid',
  86     Statistic            => 'borrowernumber',
  87     Suggestion           => 'suggestedby',
  88     TagAll               => 'borrowernumber',
  89     Virtualshelfcontent  => 'borrowernumber',
  90     Virtualshelfshare    => 'borrowernumber',
  91     Virtualshelve        => 'owner',
  92 };
  93
  94 =head1 NAME
  95
  96 Koha::Patron - Koha Patron Object class
  97
  98 =head1 API
  99
 100 =head2 Class Methods
 101
 102 =head3 new
 103
 104 =cut
 105
 106 sub new {
 107     my ( $class, $params ) = @_;
 108
 109     return $class->SUPER::new($params);
 110 }
 111
 112 =head3 fixup_cardnumber
 113
 114 Autogenerate next cardnumber from highest value found in database
 115
 116 =cut
 117
 118 sub fixup_cardnumber {
 119     my ( $self ) = @_;
 120
 121     my $max = $self->cardnumber;
 122     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 123
 124     $max ||= Koha::Patrons->search({
 125         cardnumber => {-regexp => '^-?[0-9]+$'}
 126     }, {
 127         select => \'CAST(cardnumber AS SIGNED)',
 128         as => ['cast_cardnumber']
 129     })->_resultset->get_column('cast_cardnumber')->max;
 130     $self->cardnumber(($max || 0) +1);
 131 }
 132
 133 =head3 trim_whitespace
 134
 135 trim whitespace from data which has some non-whitespace in it.
 136 Could be moved to Koha::Object if need to be reused
 137
 138 =cut
 139
 140 sub trim_whitespaces {
 141     my( $self ) = @_;
 142
 143     my $schema  = Koha::Database->new->schema;
 144     my @columns = $schema->source($self->_type)->columns;
 145
 146     for my $column( @columns ) {
 147         my $value = $self->$column;
 148         if ( defined $value ) {
 149             $value =~ s/^\s*|\s*$//g;
 150             $self->$column($value);
 151         }
 152     }
 153     return $self;
 154 }
 155
 156 =head3 plain_text_password
 157
 158 $patron->plain_text_password( $password );
 159
 160 stores a copy of the unencrypted password in the object
 161 for use in code before encrypting for db
 162
 163 =cut
 164
 165 sub plain_text_password {
 166     my ( $self, $password ) = @_;
 167     if ( $password ) {
 168         $self->{_plain_text_password} = $password;
 169         return $self;
 170     }
 171     return $self->{_plain_text_password}
 172         if $self->{_plain_text_password};
 173
 174     return;
 175 }
 176
 177 =head3 store
 178
 179 Patron specific store method to cleanup record
 180 and do other necessary things before saving
 181 to db
 182
 183 =cut
 184
 185 sub store {
 186     my ($self) = @_;
 187
 188     $self->_result->result_source->schema->txn_do(
 189         sub {
 190             if (
 191                 C4::Context->preference("autoMemberNum")
 192                 and ( not defined $self->cardnumber
 193                     or $self->cardnumber eq '' )
 194               )
 195             {
 196                 # Warning: The caller is responsible for locking the members table in write
 197                 # mode, to avoid database corruption.
 198                 # We are in a transaction but the table is not locked
 199                 $self->fixup_cardnumber;
 200             }
 201
 202             unless( $self->category->in_storage ) {
 203                 Koha::Exceptions::Object::FKConstraint->throw(
 204                     broken_fk => 'categorycode',
 205                     value     => $self->categorycode,
 206                 );
 207             }
 208
 209             $self->trim_whitespaces;
 210
 211             my $new_cardnumber = $self->cardnumber;
 212             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 213             $self->cardnumber( $new_cardnumber );
 214
 215             # Set surname to uppercase if uppercasesurname is true
 216             $self->surname( uc($self->surname) )
 217                 if C4::Context->preference("uppercasesurnames");
 218
 219             $self->relationship(undef) # We do not want to store an empty string in this field
 220               if defined $self->relationship
 221                      and $self->relationship eq "";
 222
 223             unless ( $self->in_storage ) {    #AddMember
 224
 225                 # Generate a valid userid/login if needed
 226                 $self->generate_userid
 227                   if not $self->userid or not $self->has_valid_userid;
 228
 229                 # Add expiration date if it isn't already there
 230                 unless ( $self->dateexpiry ) {
 231                     $self->dateexpiry( $self->category->get_expiry_date );
 232                 }
 233
 234                 # Add enrollment date if it isn't already there
 235                 unless ( $self->dateenrolled ) {
 236                     $self->dateenrolled(dt_from_string);
 237                 }
 238
 239                 # Set the privacy depending on the patron's category
 240                 my $default_privacy = $self->category->default_privacy || q{};
 241                 $default_privacy =
 242                     $default_privacy eq 'default' ? 1
 243                   : $default_privacy eq 'never'   ? 2
 244                   : $default_privacy eq 'forever' ? 0
 245                   :                                                   undef;
 246                 $self->privacy($default_privacy);
 247
 248                 # Call any check_password plugins if password is passed
 249                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 250                     my @plugins = Koha::Plugins->new()->GetPlugins({
 251                         method => 'check_password',
 252                     });
 253                     foreach my $plugin ( @plugins ) {
 254                         # This plugin hook will also be used by a plugin for the Norwegian national
 255                         # patron database. This is why we need to pass both the password and the
 256                         # borrowernumber to the plugin.
 257                         my $ret = $plugin->check_password(
 258                             {
 259                                 password       => $self->password,
 260                                 borrowernumber => $self->borrowernumber
 261                             }
 262                         );
 263                         if ( $ret->{'error'} == 1 ) {
 264                             Koha::Exceptions::Password::Plugin->throw();
 265                         }
 266                     }
 267                 }
 268
 269                 # Make a copy of the plain text password for later use
 270                 $self->plain_text_password( $self->password );
 271
 272                 $self->password_expiration_date( $self->password
 273                     ? $self->category->get_password_expiry_date || undef
 274                     : undef );
 275                 # Create a disabled account if no password provided
 276                 $self->password( $self->password
 277                     ? Koha::AuthUtils::hash_password( $self->password )
 278                     : '!' );
 279
 280                 $self->borrowernumber(undef);
 281
 282                 $self = $self->SUPER::store;
 283
 284                 $self->add_enrolment_fee_if_needed(0);
 285
 286                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 287                   if C4::Context->preference("BorrowersLog");
 288             }
 289             else {    #ModMember
 290
 291                 my $self_from_storage = $self->get_from_storage;
 292                 # FIXME We should not deal with that here, callers have to do this job
 293                 # Moved from ModMember to prevent regressions
 294                 unless ( $self->userid ) {
 295                     my $stored_userid = $self_from_storage->userid;
 296                     $self->userid($stored_userid);
 297                 }
 298
 299                 # Password must be updated using $self->set_password
 300                 $self->password($self_from_storage->password);
 301
 302                 if ( $self->category->categorycode ne
 303                     $self_from_storage->category->categorycode )
 304                 {
 305                     # Add enrolement fee on category change if required
 306                     $self->add_enrolment_fee_if_needed(1)
 307                       if C4::Context->preference('FeeOnChangePatronCategory');
 308
 309                     # Clean up guarantors on category change if required
 310                     $self->guarantor_relationships->delete
 311                       unless ( $self->category->can_be_guarantee );
 312
 313                 }
 314
 315                 # Actionlogs
 316                 if ( C4::Context->preference("BorrowersLog") ) {
 317                     my $info;
 318                     my $from_storage = $self_from_storage->unblessed;
 319                     my $from_object  = $self->unblessed;
 320                     my @skip_fields  = (qw/lastseen updated_on/);
 321                     for my $key ( keys %{$from_storage} ) {
 322                         next if any { /$key/ } @skip_fields;
 323                         if (
 324                             (
 325                                   !defined( $from_storage->{$key} )
 326                                 && defined( $from_object->{$key} )
 327                             )
 328                             || ( defined( $from_storage->{$key} )
 329                                 && !defined( $from_object->{$key} ) )
 330                             || (
 331                                    defined( $from_storage->{$key} )
 332                                 && defined( $from_object->{$key} )
 333                                 && ( $from_storage->{$key} ne
 334                                     $from_object->{$key} )
 335                             )
 336                           )
 337                         {
 338                             $info->{$key} = {
 339                                 before => $from_storage->{$key},
 340                                 after  => $from_object->{$key}
 341                             };
 342                         }
 343                     }
 344
 345                     if ( defined($info) ) {
 346                         logaction(
 347                             "MEMBERS",
 348                             "MODIFY",
 349                             $self->borrowernumber,
 350                             to_json(
 351                                 $info,
 352                                 { utf8 => 1, pretty => 1, canonical => 1 }
 353                             )
 354                         );
 355                     }
 356                 }
 357
 358                 # Final store
 359                 $self = $self->SUPER::store;
 360             }
 361         }
 362     );
 363     return $self;
 364 }
 365
 366 =head3 delete
 367
 368 $patron->delete
 369
 370 Delete patron's holds, lists and finally the patron.
 371
 372 Lists owned by the borrower are deleted or ownership is transferred depending on the
 373 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 374
 375 =cut
 376
 377 sub delete {
 378     my ($self) = @_;
 379
 380     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 381     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 382
 383     $self->_result->result_source->schema->txn_do(
 384         sub {
 385             # Cancel Patron's holds
 386             my $holds = $self->holds;
 387             while( my $hold = $holds->next ){
 388                 $hold->cancel;
 389             }
 390
 391             # Handle lists (virtualshelves)
 392             $self->virtualshelves->disown_or_delete;
 393
 394             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 395             # for patron selfreg
 396             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 397
 398             $self->SUPER::delete;
 399
 400             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 401         }
 402     );
 403     return $self;
 404 }
 405
 406 =head3 category
 407
 408 my $patron_category = $patron->category
 409
 410 Return the patron category for this patron
 411
 412 =cut
 413
 414 sub category {
 415     my ( $self ) = @_;
 416     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 417 }
 418
 419 =head3 image
 420
 421 =cut
 422
 423 sub image {
 424     my ( $self ) = @_;
 425
 426     return Koha::Patron::Images->find( $self->borrowernumber );
 427 }
 428
 429 =head3 library
 430
 431 Returns a Koha::Library object representing the patron's home library.
 432
 433 =cut
 434
 435 sub library {
 436     my ( $self ) = @_;
 437     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 438 }
 439
 440 =head3 sms_provider
 441
 442 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 443
 444 =cut
 445
 446 sub sms_provider {
 447     my ( $self ) = @_;
 448     my $sms_provider_rs = $self->_result->sms_provider;
 449     return unless $sms_provider_rs;
 450     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 451 }
 452
 453 =head3 guarantor_relationships
 454
 455 Returns Koha::Patron::Relationships object for this patron's guarantors
 456
 457 Returns the set of relationships for the patrons that are guarantors for this patron.
 458
 459 This is returned instead of a Koha::Patron object because the guarantor
 460 may not exist as a patron in Koha. If this is true, the guarantors name
 461 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 462
 463 =cut
 464
 465 sub guarantor_relationships {
 466     my ($self) = @_;
 467
 468     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 469 }
 470
 471 =head3 guarantee_relationships
 472
 473 Returns Koha::Patron::Relationships object for this patron's guarantors
 474
 475 Returns the set of relationships for the patrons that are guarantees for this patron.
 476
 477 The method returns Koha::Patron::Relationship objects for the sake
 478 of consistency with the guantors method.
 479 A guarantee by definition must exist as a patron in Koha.
 480
 481 =cut
 482
 483 sub guarantee_relationships {
 484     my ($self) = @_;
 485
 486     return Koha::Patron::Relationships->search(
 487         { guarantor_id => $self->id },
 488         {
 489             prefetch => 'guarantee',
 490             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 491         }
 492     );
 493 }
 494
 495 =head3 relationships_debt
 496
 497 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 498
 499 =cut
 500
 501 sub relationships_debt {
 502     my ($self, $params) = @_;
 503
 504     my $include_guarantors  = $params->{include_guarantors};
 505     my $only_this_guarantor = $params->{only_this_guarantor};
 506     my $include_this_patron = $params->{include_this_patron};
 507
 508     my @guarantors;
 509     if ( $only_this_guarantor ) {
 510         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 511         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 512     } elsif ( $self->guarantor_relationships->count ) {
 513         # I am a guarantee, just get all my guarantors
 514         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 515     } else {
 516         # I am a guarantor, I need to get all the guarantors of all my guarantees
 517         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 518     }
 519
 520     my $non_issues_charges = 0;
 521     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 522     foreach my $guarantor (@guarantors) {
 523         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 524
 525         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 526         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 527         my $guarantees_non_issues_charges = 0;
 528         foreach my $guarantee (@guarantees) {
 529             next if $seen->{ $guarantee->id };
 530             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 531             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 532             $seen->{ $guarantee->id } = 1;
 533         }
 534
 535         $non_issues_charges += $guarantees_non_issues_charges;
 536         $seen->{ $guarantor->id } = 1;
 537     }
 538
 539     return $non_issues_charges;
 540 }
 541
 542 =head3 housebound_profile
 543
 544 Returns the HouseboundProfile associated with this patron.
 545
 546 =cut
 547
 548 sub housebound_profile {
 549     my ( $self ) = @_;
 550     my $profile = $self->_result->housebound_profile;
 551     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 552         if ( $profile );
 553     return;
 554 }
 555
 556 =head3 housebound_role
 557
 558 Returns the HouseboundRole associated with this patron.
 559
 560 =cut
 561
 562 sub housebound_role {
 563     my ( $self ) = @_;
 564
 565     my $role = $self->_result->housebound_role;
 566     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 567     return;
 568 }
 569
 570 =head3 siblings
 571
 572 Returns the siblings of this patron.
 573
 574 =cut
 575
 576 sub siblings {
 577     my ($self) = @_;
 578
 579     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 580
 581     return unless @guarantors;
 582
 583     my @siblings =
 584       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 585
 586     return unless @siblings;
 587
 588     my %seen;
 589     @siblings =
 590       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 591
 592     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 593 }
 594
 595 =head3 merge_with
 596
 597     my $patron = Koha::Patrons->find($id);
 598     $patron->merge_with( \@patron_ids );
 599
 600     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 601     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 602     of the keeper patron.
 603
 604 =cut
 605
 606 sub merge_with {
 607     my ( $self, $patron_ids ) = @_;
 608
 609     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 610     return if $anonymous_patron && $self->id eq $anonymous_patron;
 611
 612     my @patron_ids = @{ $patron_ids };
 613
 614     # Ensure the keeper isn't in the list of patrons to merge
 615     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 616
 617     my $schema = Koha::Database->new()->schema();
 618
 619     my $results;
 620
 621     $self->_result->result_source->schema->txn_do( sub {
 622         foreach my $patron_id (@patron_ids) {
 623
 624             next if $patron_id eq $anonymous_patron;
 625
 626             my $patron = Koha::Patrons->find( $patron_id );
 627
 628             next unless $patron;
 629
 630             # Unbless for safety, the patron will end up being deleted
 631             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 632
 633             my $attributes = $patron->extended_attributes;
 634             my $new_attributes = [
 635                 map { { code => $_->code, attribute => $_->attribute } }
 636                     $attributes->as_list
 637             ];
 638             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 639             for my $attribute ( @$new_attributes ) {
 640                 try {
 641                     $self->add_extended_attribute($attribute);
 642                 } catch {
 643                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 644                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 645                         $_->rethrow;
 646                     }
 647                 };
 648             }
 649
 650             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 651                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 652                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 653                 $rs->update({ $field => $self->id });
 654                 if ( $r eq 'BorrowerDebarment' ) {
 655                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 656                 }
 657             }
 658
 659             $patron->move_to_deleted();
 660             $patron->delete();
 661         }
 662     });
 663
 664     return $results;
 665 }
 666
 667
 668
 669 =head3 wants_check_for_previous_checkout
 670
 671     $wants_check = $patron->wants_check_for_previous_checkout;
 672
 673 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 674
 675 =cut
 676
 677 sub wants_check_for_previous_checkout {
 678     my ( $self ) = @_;
 679     my $syspref = C4::Context->preference("checkPrevCheckout");
 680
 681     # Simple cases
 682     ## Hard syspref trumps all
 683     return 1 if ($syspref eq 'hardyes');
 684     return 0 if ($syspref eq 'hardno');
 685     ## Now, patron pref trumps all
 686     return 1 if ($self->checkprevcheckout eq 'yes');
 687     return 0 if ($self->checkprevcheckout eq 'no');
 688
 689     # More complex: patron inherits -> determine category preference
 690     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 691     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 692     return 0 if ($checkPrevCheckoutByCat eq 'no');
 693
 694     # Finally: category preference is inherit, default to 0
 695     if ($syspref eq 'softyes') {
 696         return 1;
 697     } else {
 698         return 0;
 699     }
 700 }
 701
 702 =head3 do_check_for_previous_checkout
 703
 704     $do_check = $patron->do_check_for_previous_checkout($item);
 705
 706 Return 1 if the bib associated with $ITEM has previously been checked out to
 707 $PATRON, 0 otherwise.
 708
 709 =cut
 710
 711 sub do_check_for_previous_checkout {
 712     my ( $self, $item ) = @_;
 713
 714     my @item_nos;
 715     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 716     if ( $biblio->is_serial ) {
 717         push @item_nos, $item->{itemnumber};
 718     } else {
 719         # Get all itemnumbers for given bibliographic record.
 720         @item_nos = $biblio->items->get_column( 'itemnumber' );
 721     }
 722
 723     # Create (old)issues search criteria
 724     my $criteria = {
 725         borrowernumber => $self->borrowernumber,
 726         itemnumber => \@item_nos,
 727     };
 728
 729     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 730     if ($delay) {
 731         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 732         my $newer_than = dt_from_string()->subtract( days => $delay );
 733         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 734     }
 735
 736     # Check current issues table
 737     my $issues = Koha::Checkouts->search($criteria);
 738     return 1 if $issues->count; # 0 || N
 739
 740     # Check old issues table
 741     my $old_issues = Koha::Old::Checkouts->search($criteria);
 742     return $old_issues->count;  # 0 || N
 743 }
 744
 745 =head3 is_debarred
 746
 747 my $debarment_expiration = $patron->is_debarred;
 748
 749 Returns the date a patron debarment will expire, or undef if the patron is not
 750 debarred
 751
 752 =cut
 753
 754 sub is_debarred {
 755     my ($self) = @_;
 756
 757     return unless $self->debarred;
 758     return $self->debarred
 759       if $self->debarred =~ '^9999'
 760       or dt_from_string( $self->debarred ) > dt_from_string;
 761     return;
 762 }
 763
 764 =head3 is_expired
 765
 766 my $is_expired = $patron->is_expired;
 767
 768 Returns 1 if the patron is expired or 0;
 769
 770 =cut
 771
 772 sub is_expired {
 773     my ($self) = @_;
 774     return 0 unless $self->dateexpiry;
 775     return 0 if $self->dateexpiry =~ '^9999';
 776     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 777     return 0;
 778 }
 779
 780 =head3 password_expired
 781
 782 my $password_expired = $patron->password_expired;
 783
 784 Returns 1 if the patron's password is expired or 0;
 785
 786 =cut
 787
 788 sub password_expired {
 789     my ($self) = @_;
 790     return 0 unless $self->password_expiration_date;
 791     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 792     return 0;
 793 }
 794
 795 =head3 is_going_to_expire
 796
 797 my $is_going_to_expire = $patron->is_going_to_expire;
 798
 799 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 800
 801 =cut
 802
 803 sub is_going_to_expire {
 804     my ($self) = @_;
 805
 806     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 807
 808     return 0 unless $delay;
 809     return 0 unless $self->dateexpiry;
 810     return 0 if $self->dateexpiry =~ '^9999';
 811     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 812     return 0;
 813 }
 814
 815 =head3 set_password
 816
 817     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 818
 819 Set the patron's password.
 820
 821 =head4 Exceptions
 822
 823 The passed string is validated against the current password enforcement policy.
 824 Validation can be skipped by passing the I<skip_validation> parameter.
 825
 826 Exceptions are thrown if the password is not good enough.
 827
 828 =over 4
 829
 830 =item Koha::Exceptions::Password::TooShort
 831
 832 =item Koha::Exceptions::Password::WhitespaceCharacters
 833
 834 =item Koha::Exceptions::Password::TooWeak
 835
 836 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 837
 838 =back
 839
 840 =cut
 841
 842 sub set_password {
 843     my ( $self, $args ) = @_;
 844
 845     my $password = $args->{password};
 846
 847     unless ( $args->{skip_validation} ) {
 848         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 849
 850         if ( !$is_valid ) {
 851             if ( $error eq 'too_short' ) {
 852                 my $min_length = $self->category->effective_min_password_length;
 853                 $min_length = 3 if not $min_length or $min_length < 3;
 854
 855                 my $password_length = length($password);
 856                 Koha::Exceptions::Password::TooShort->throw(
 857                     length => $password_length, min_length => $min_length );
 858             }
 859             elsif ( $error eq 'has_whitespaces' ) {
 860                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 861             }
 862             elsif ( $error eq 'too_weak' ) {
 863                 Koha::Exceptions::Password::TooWeak->throw();
 864             }
 865         }
 866     }
 867
 868     if ( C4::Context->config("enable_plugins") ) {
 869         # Call any check_password plugins
 870         my @plugins = Koha::Plugins->new()->GetPlugins({
 871             method => 'check_password',
 872         });
 873         foreach my $plugin ( @plugins ) {
 874             # This plugin hook will also be used by a plugin for the Norwegian national
 875             # patron database. This is why we need to pass both the password and the
 876             # borrowernumber to the plugin.
 877             my $ret = $plugin->check_password(
 878                 {
 879                     password       => $password,
 880                     borrowernumber => $self->borrowernumber
 881                 }
 882             );
 883             # This plugin hook will also be used by a plugin for the Norwegian national
 884             # patron database. This is why we need to call the actual plugins and then
 885             # check skip_validation afterwards.
 886             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 887                 Koha::Exceptions::Password::Plugin->throw();
 888             }
 889         }
 890     }
 891
 892     my $digest = Koha::AuthUtils::hash_password($password);
 893
 894     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 895
 896     # We do not want to call $self->store and retrieve password from DB
 897     $self->password($digest);
 898     $self->login_attempts(0);
 899     $self->SUPER::store;
 900
 901     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 902         if C4::Context->preference("BorrowersLog");
 903
 904     return $self;
 905 }
 906
 907
 908 =head3 renew_account
 909
 910 my $new_expiry_date = $patron->renew_account
 911
 912 Extending the subscription to the expiry date.
 913
 914 =cut
 915
 916 sub renew_account {
 917     my ($self) = @_;
 918     my $date;
 919     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 920         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 921     } else {
 922         $date =
 923             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 924             ? dt_from_string( $self->dateexpiry )
 925             : dt_from_string;
 926     }
 927     my $expiry_date = $self->category->get_expiry_date($date);
 928
 929     $self->dateexpiry($expiry_date);
 930     $self->date_renewed( dt_from_string() );
 931     $self->store();
 932
 933     $self->add_enrolment_fee_if_needed(1);
 934
 935     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 936     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 937 }
 938
 939 =head3 has_overdues
 940
 941 my $has_overdues = $patron->has_overdues;
 942
 943 Returns the number of patron's overdues
 944
 945 =cut
 946
 947 sub has_overdues {
 948     my ($self) = @_;
 949     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 950     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 951 }
 952
 953 =head3 track_login
 954
 955     $patron->track_login;
 956     $patron->track_login({ force => 1 });
 957
 958     Tracks a (successful) login attempt.
 959     The preference TrackLastPatronActivity must be enabled. Or you
 960     should pass the force parameter.
 961
 962 =cut
 963
 964 sub track_login {
 965     my ( $self, $params ) = @_;
 966     return if
 967         !$params->{force} &&
 968         !C4::Context->preference('TrackLastPatronActivity');
 969     $self->lastseen( dt_from_string() )->store;
 970 }
 971
 972 =head3 move_to_deleted
 973
 974 my $is_moved = $patron->move_to_deleted;
 975
 976 Move a patron to the deletedborrowers table.
 977 This can be done before deleting a patron, to make sure the data are not completely deleted.
 978
 979 =cut
 980
 981 sub move_to_deleted {
 982     my ($self) = @_;
 983     my $patron_infos = $self->unblessed;
 984     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 985     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 986 }
 987
 988 =head3 can_request_article
 989
 990     if ( $patron->can_request_article( $library->id ) ) { ... }
 991
 992 Returns true if the patron can request articles. As limits apply for the patron
 993 on the same day, those completed the same day are considered as current.
 994
 995 A I<library_id> can be passed as parameter, falling back to userenv if absent.
 996
 997 =cut
 998
 999 sub can_request_article {
1000     my ($self, $library_id) = @_;
1001
1002     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1003
1004     my $rule = Koha::CirculationRules->get_effective_rule(
1005         {
1006             branchcode   => $library_id,
1007             categorycode => $self->categorycode,
1008             rule_name    => 'open_article_requests_limit'
1009         }
1010     );
1011
1012     my $limit = ($rule) ? $rule->rule_value : undef;
1013
1014     return 1 unless defined $limit;
1015
1016     my $count = Koha::ArticleRequests->search(
1017         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1018             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1019         ]
1020     )->count;
1021     return $count < $limit ? 1 : 0;
1022 }
1023
1024 =head3 article_request_fee
1025
1026     my $fee = $patron->article_request_fee(
1027         {
1028           [ library_id => $library->id, ]
1029         }
1030     );
1031
1032 Returns the fee to be charged to the patron when it places an article request.
1033
1034 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1035
1036 =cut
1037
1038 sub article_request_fee {
1039     my ($self, $params) = @_;
1040
1041     my $library_id = $params->{library_id};
1042
1043     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1044
1045     my $rule = Koha::CirculationRules->get_effective_rule(
1046         {
1047             branchcode   => $library_id,
1048             categorycode => $self->categorycode,
1049             rule_name    => 'article_request_fee'
1050         }
1051     );
1052
1053     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1054
1055     return $fee;
1056 }
1057
1058 =head3 add_article_request_fee_if_needed
1059
1060     my $fee = $patron->add_article_request_fee_if_needed(
1061         {
1062           [ item_id    => $item->id,
1063             library_id => $library->id, ]
1064         }
1065     );
1066
1067 If an article request fee needs to be charged, it adds a debit to the patron's
1068 account.
1069
1070 Returns the fee line.
1071
1072 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1073
1074 =cut
1075
1076 sub add_article_request_fee_if_needed {
1077     my ($self, $params) = @_;
1078
1079     my $library_id = $params->{library_id};
1080     my $item_id    = $params->{item_id};
1081
1082     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1083
1084     my $amount = $self->article_request_fee(
1085         {
1086             library_id => $library_id,
1087         }
1088     );
1089
1090     my $debit_line;
1091
1092     if ( $amount > 0 ) {
1093         $debit_line = $self->account->add_debit(
1094             {
1095                 amount     => $amount,
1096                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1097                 interface  => C4::Context->interface,
1098                 library_id => $library_id,
1099                 type       => 'ARTICLE_REQUEST',
1100                 item_id    => $item_id,
1101             }
1102         );
1103     }
1104
1105     return $debit_line;
1106 }
1107
1108 =head3 article_requests
1109
1110     my $article_requests = $patron->article_requests;
1111
1112 Returns the patron article requests.
1113
1114 =cut
1115
1116 sub article_requests {
1117     my ($self) = @_;
1118
1119     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1120 }
1121
1122 =head3 add_enrolment_fee_if_needed
1123
1124 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1125
1126 Add enrolment fee for a patron if needed.
1127
1128 $renewal - boolean denoting whether this is an account renewal or not
1129
1130 =cut
1131
1132 sub add_enrolment_fee_if_needed {
1133     my ($self, $renewal) = @_;
1134     my $enrolment_fee = $self->category->enrolmentfee;
1135     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1136         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1137         $self->account->add_debit(
1138             {
1139                 amount     => $enrolment_fee,
1140                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1141                 interface  => C4::Context->interface,
1142                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1143                 type       => $type
1144             }
1145         );
1146     }
1147     return $enrolment_fee || 0;
1148 }
1149
1150 =head3 checkouts
1151
1152 my $checkouts = $patron->checkouts
1153
1154 =cut
1155
1156 sub checkouts {
1157     my ($self) = @_;
1158     my $checkouts = $self->_result->issues;
1159     return Koha::Checkouts->_new_from_dbic( $checkouts );
1160 }
1161
1162 =head3 pending_checkouts
1163
1164 my $pending_checkouts = $patron->pending_checkouts
1165
1166 This method will return the same as $self->checkouts, but with a prefetch on
1167 items, biblio and biblioitems.
1168
1169 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1170
1171 It should not be used directly, prefer to access fields you need instead of
1172 retrieving all these fields in one go.
1173
1174 =cut
1175
1176 sub pending_checkouts {
1177     my( $self ) = @_;
1178     my $checkouts = $self->_result->issues->search(
1179         {},
1180         {
1181             order_by => [
1182                 { -desc => 'me.timestamp' },
1183                 { -desc => 'issuedate' },
1184                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1185             ],
1186             prefetch => { item => { biblio => 'biblioitems' } },
1187         }
1188     );
1189     return Koha::Checkouts->_new_from_dbic( $checkouts );
1190 }
1191
1192 =head3 old_checkouts
1193
1194 my $old_checkouts = $patron->old_checkouts
1195
1196 =cut
1197
1198 sub old_checkouts {
1199     my ($self) = @_;
1200     my $old_checkouts = $self->_result->old_issues;
1201     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1202 }
1203
1204 =head3 overdues
1205
1206 my $overdue_items = $patron->overdues
1207
1208 Return the overdue items
1209
1210 =cut
1211
1212 sub overdues {
1213     my ($self) = @_;
1214     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1215     return $self->checkouts->search(
1216         {
1217             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1218         },
1219         {
1220             prefetch => { item => { biblio => 'biblioitems' } },
1221         }
1222     );
1223 }
1224
1225 =head3 get_routing_lists
1226
1227 my $routinglists = $patron->get_routing_lists
1228
1229 Returns the routing lists a patron is subscribed to.
1230
1231 =cut
1232
1233 sub get_routing_lists {
1234     my ($self) = @_;
1235     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1236     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1237 }
1238
1239 =head3 get_age
1240
1241     my $age = $patron->get_age
1242
1243 Return the age of the patron
1244
1245 =cut
1246
1247 sub get_age {
1248     my ($self)    = @_;
1249
1250     return unless $self->dateofbirth;
1251
1252     my $date_of_birth = dt_from_string( $self->dateofbirth );
1253     my $today         = dt_from_string->truncate( to => 'day' );
1254
1255     return $today->subtract_datetime( $date_of_birth )->years;
1256 }
1257
1258 =head3 is_valid_age
1259
1260 my $is_valid = $patron->is_valid_age
1261
1262 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1263
1264 =cut
1265
1266 sub is_valid_age {
1267     my ($self) = @_;
1268     my $age = $self->get_age;
1269
1270     my $patroncategory = $self->category;
1271     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1272
1273     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1274 }
1275
1276 =head3 account
1277
1278 my $account = $patron->account
1279
1280 =cut
1281
1282 sub account {
1283     my ($self) = @_;
1284     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1285 }
1286
1287 =head3 holds
1288
1289 my $holds = $patron->holds
1290
1291 Return all the holds placed by this patron
1292
1293 =cut
1294
1295 sub holds {
1296     my ($self) = @_;
1297     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1298     return Koha::Holds->_new_from_dbic($holds_rs);
1299 }
1300
1301 =head3 old_holds
1302
1303 my $old_holds = $patron->old_holds
1304
1305 Return all the historical holds for this patron
1306
1307 =cut
1308
1309 sub old_holds {
1310     my ($self) = @_;
1311     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1312     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1313 }
1314
1315 =head3 curbside_pickups
1316
1317 my $curbside_pickups = $patron->curbside_pickups;
1318
1319 Return all the curbside pickups for this patron
1320
1321 =cut
1322
1323 sub curbside_pickups {
1324     my ($self) = @_;
1325     my $curbside_pickups_rs = $self->_result->curbside_pickups_borrowernumbers->search;
1326     return Koha::CurbsidePickups->_new_from_dbic($curbside_pickups_rs);
1327 }
1328
1329 =head3 return_claims
1330
1331 my $return_claims = $patron->return_claims
1332
1333 =cut
1334
1335 sub return_claims {
1336     my ($self) = @_;
1337     my $return_claims = $self->_result->return_claims_borrowernumbers;
1338     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1339 }
1340
1341 =head3 notice_email_address
1342
1343   my $email = $patron->notice_email_address;
1344
1345 Return the email address of patron used for notices.
1346 Returns the empty string if no email address.
1347
1348 =cut
1349
1350 sub notice_email_address{
1351     my ( $self ) = @_;
1352
1353     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1354     # if syspref is set to 'first valid' (value == OFF), look up email address
1355     if ( $which_address eq 'OFF' ) {
1356         return $self->first_valid_email_address;
1357     }
1358
1359     return $self->$which_address || '';
1360 }
1361
1362 =head3 first_valid_email_address
1363
1364 my $first_valid_email_address = $patron->first_valid_email_address
1365
1366 Return the first valid email address for a patron.
1367 For now, the order  is defined as email, emailpro, B_email.
1368 Returns the empty string if the borrower has no email addresses.
1369
1370 =cut
1371
1372 sub first_valid_email_address {
1373     my ($self) = @_;
1374
1375     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1376 }
1377
1378 =head3 get_club_enrollments
1379
1380 =cut
1381
1382 sub get_club_enrollments {
1383     my ( $self ) = @_;
1384
1385     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1386 }
1387
1388 =head3 get_enrollable_clubs
1389
1390 =cut
1391
1392 sub get_enrollable_clubs {
1393     my ( $self, $is_enrollable_from_opac ) = @_;
1394
1395     my $params;
1396     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1397       if $is_enrollable_from_opac;
1398     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1399
1400     $params->{borrower} = $self;
1401
1402     return Koha::Clubs->get_enrollable($params);
1403 }
1404
1405 =head3 account_locked
1406
1407 my $is_locked = $patron->account_locked
1408
1409 Return true if the patron has reached the maximum number of login attempts
1410 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1411 as an administrative lockout (independent of FailedLoginAttempts; see also
1412 Koha::Patron->lock).
1413 Otherwise return false.
1414 If the pref is not set (empty string, null or 0), the feature is considered as
1415 disabled.
1416
1417 =cut
1418
1419 sub account_locked {
1420     my ($self) = @_;
1421     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1422     return 1 if $FailedLoginAttempts
1423           and $self->login_attempts
1424           and $self->login_attempts >= $FailedLoginAttempts;
1425     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1426     return 0;
1427 }
1428
1429 =head3 can_see_patron_infos
1430
1431 my $can_see = $patron->can_see_patron_infos( $patron );
1432
1433 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1434
1435 =cut
1436
1437 sub can_see_patron_infos {
1438     my ( $self, $patron ) = @_;
1439     return unless $patron;
1440     return $self->can_see_patrons_from( $patron->branchcode );
1441 }
1442
1443 =head3 can_see_patrons_from
1444
1445 my $can_see = $patron->can_see_patrons_from( $branchcode );
1446
1447 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1448
1449 =cut
1450
1451 sub can_see_patrons_from {
1452     my ( $self, $branchcode ) = @_;
1453     my $can = 0;
1454     if ( $self->branchcode eq $branchcode ) {
1455         $can = 1;
1456     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1457         $can = 1;
1458     } elsif ( my $library_groups = $self->library->library_groups ) {
1459         while ( my $library_group = $library_groups->next ) {
1460             if ( $library_group->parent->has_child( $branchcode ) ) {
1461                 $can = 1;
1462                 last;
1463             }
1464         }
1465     }
1466     return $can;
1467 }
1468
1469 =head3 can_log_into
1470
1471 my $can_log_into = $patron->can_log_into( $library );
1472
1473 Given a I<Koha::Library> object, it returns a boolean representing
1474 the fact the patron can log into a the library.
1475
1476 =cut
1477
1478 sub can_log_into {
1479     my ( $self, $library ) = @_;
1480
1481     my $can = 0;
1482
1483     if ( C4::Context->preference('IndependentBranches') ) {
1484         $can = 1
1485           if $self->is_superlibrarian
1486           or $self->branchcode eq $library->id;
1487     }
1488     else {
1489         # no restrictions
1490         $can = 1;
1491     }
1492
1493    return $can;
1494 }
1495
1496 =head3 libraries_where_can_see_patrons
1497
1498 my $libraries = $patron-libraries_where_can_see_patrons;
1499
1500 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1501 The branchcodes are arbitrarily returned sorted.
1502 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1503
1504 An empty array means no restriction, the patron can see patron's infos from any libraries.
1505
1506 =cut
1507
1508 sub libraries_where_can_see_patrons {
1509     my ( $self ) = @_;
1510     my $userenv = C4::Context->userenv;
1511
1512     return () unless $userenv; # For tests, but userenv should be defined in tests...
1513
1514     my @restricted_branchcodes;
1515     if (C4::Context::only_my_library) {
1516         push @restricted_branchcodes, $self->branchcode;
1517     }
1518     else {
1519         unless (
1520             $self->has_permission(
1521                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1522             )
1523           )
1524         {
1525             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1526             if ( $library_groups->count )
1527             {
1528                 while ( my $library_group = $library_groups->next ) {
1529                     my $parent = $library_group->parent;
1530                     if ( $parent->has_child( $self->branchcode ) ) {
1531                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1532                     }
1533                 }
1534             }
1535
1536             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1537         }
1538     }
1539
1540     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1541     @restricted_branchcodes = uniq(@restricted_branchcodes);
1542     @restricted_branchcodes = sort(@restricted_branchcodes);
1543     return @restricted_branchcodes;
1544 }
1545
1546 =head3 has_permission
1547
1548 my $permission = $patron->has_permission($required);
1549
1550 See C4::Auth::haspermission for details of syntax for $required
1551
1552 =cut
1553
1554 sub has_permission {
1555     my ( $self, $flagsrequired ) = @_;
1556     return unless $self->userid;
1557     # TODO code from haspermission needs to be moved here!
1558     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1559 }
1560
1561 =head3 is_superlibrarian
1562
1563   my $is_superlibrarian = $patron->is_superlibrarian;
1564
1565 Return true if the patron is a superlibrarian.
1566
1567 =cut
1568
1569 sub is_superlibrarian {
1570     my ($self) = @_;
1571     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1572 }
1573
1574 =head3 is_adult
1575
1576 my $is_adult = $patron->is_adult
1577
1578 Return true if the patron has a category with a type Adult (A) or Organization (I)
1579
1580 =cut
1581
1582 sub is_adult {
1583     my ( $self ) = @_;
1584     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1585 }
1586
1587 =head3 is_child
1588
1589 my $is_child = $patron->is_child
1590
1591 Return true if the patron has a category with a type Child (C)
1592
1593 =cut
1594
1595 sub is_child {
1596     my( $self ) = @_;
1597     return $self->category->category_type eq 'C' ? 1 : 0;
1598 }
1599
1600 =head3 has_valid_userid
1601
1602 my $patron = Koha::Patrons->find(42);
1603 $patron->userid( $new_userid );
1604 my $has_a_valid_userid = $patron->has_valid_userid
1605
1606 my $patron = Koha::Patron->new( $params );
1607 my $has_a_valid_userid = $patron->has_valid_userid
1608
1609 Return true if the current userid of this patron is valid/unique, otherwise false.
1610
1611 Note that this should be done in $self->store instead and raise an exception if needed.
1612
1613 =cut
1614
1615 sub has_valid_userid {
1616     my ($self) = @_;
1617
1618     return 0 unless $self->userid;
1619
1620     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1621
1622     my $already_exists = Koha::Patrons->search(
1623         {
1624             userid => $self->userid,
1625             (
1626                 $self->in_storage
1627                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1628                 : ()
1629             ),
1630         }
1631     )->count;
1632     return $already_exists ? 0 : 1;
1633 }
1634
1635 =head3 generate_userid
1636
1637 my $patron = Koha::Patron->new( $params );
1638 $patron->generate_userid
1639
1640 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1641
1642 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1643
1644 =cut
1645
1646 sub generate_userid {
1647     my ($self) = @_;
1648     my $offset = 0;
1649     my $firstname = $self->firstname // q{};
1650     my $surname = $self->surname // q{};
1651     #The script will "do" the following code and increment the $offset until the generated userid is unique
1652     do {
1653       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1654       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1655       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1656       $userid = NFKD( $userid );
1657       $userid =~ s/\p{NonspacingMark}//g;
1658       $userid .= $offset unless $offset == 0;
1659       $self->userid( $userid );
1660       $offset++;
1661      } while (! $self->has_valid_userid );
1662
1663      return $self;
1664 }
1665
1666 =head3 add_extended_attribute
1667
1668 =cut
1669
1670 sub add_extended_attribute {
1671     my ($self, $attribute) = @_;
1672
1673     return Koha::Patron::Attribute->new(
1674         {
1675             %$attribute,
1676             ( borrowernumber => $self->borrowernumber ),
1677         }
1678     )->store;
1679
1680 }
1681
1682 =head3 extended_attributes
1683
1684 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1685
1686 Or setter FIXME
1687
1688 =cut
1689
1690 sub extended_attributes {
1691     my ( $self, $attributes ) = @_;
1692     if ($attributes) {    # setter
1693         my $schema = $self->_result->result_source->schema;
1694         $schema->txn_do(
1695             sub {
1696                 # Remove the existing one
1697                 $self->extended_attributes->filter_by_branch_limitations->delete;
1698
1699                 # Insert the new ones
1700                 my $new_types = {};
1701                 for my $attribute (@$attributes) {
1702                     $self->add_extended_attribute($attribute);
1703                     $new_types->{$attribute->{code}} = 1;
1704                 }
1705
1706                 # Check globally mandatory types
1707                 my @required_attribute_types =
1708                     Koha::Patron::Attribute::Types->search(
1709                         {
1710                             mandatory => 1,
1711                             category_code => [ undef, $self->categorycode ],
1712                             'borrower_attribute_types_branches.b_branchcode' =>
1713                               undef,
1714                         },
1715                         { join => 'borrower_attribute_types_branches' }
1716                     )->get_column('code');
1717                 for my $type ( @required_attribute_types ) {
1718                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1719                         type => $type,
1720                     ) if !$new_types->{$type};
1721                 }
1722             }
1723         );
1724     }
1725
1726     my $rs = $self->_result->borrower_attributes;
1727     # We call search to use the filters in Koha::Patron::Attributes->search
1728     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1729 }
1730
1731 =head3 messages
1732
1733     my $messages = $patron->messages;
1734
1735 Return the message attached to the patron.
1736
1737 =cut
1738
1739 sub messages {
1740     my ( $self ) = @_;
1741     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1742     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1743 }
1744
1745 =head3 lock
1746
1747     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1748
1749     Lock and optionally expire a patron account.
1750     Remove holds and article requests if remove flag set.
1751     In order to distinguish from locking by entering a wrong password, let's
1752     call this an administrative lockout.
1753
1754 =cut
1755
1756 sub lock {
1757     my ( $self, $params ) = @_;
1758     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1759     if( $params->{expire} ) {
1760         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1761     }
1762     $self->store;
1763     if( $params->{remove} ) {
1764         $self->holds->delete;
1765         $self->article_requests->delete;
1766     }
1767     return $self;
1768 }
1769
1770 =head3 anonymize
1771
1772     Koha::Patrons->find($id)->anonymize;
1773
1774     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1775     are randomized, other personal data is cleared too.
1776     Patrons with issues are skipped.
1777
1778 =cut
1779
1780 sub anonymize {
1781     my ( $self ) = @_;
1782     if( $self->_result->issues->count ) {
1783         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1784         return;
1785     }
1786     # Mandatory fields come from the corresponding pref, but email fields
1787     # are removed since scrambled email addresses only generate errors
1788     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1789         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1790     $mandatory->{userid} = 1; # needed since sub store does not clear field
1791     my @columns = $self->_result->result_source->columns;
1792     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
1793     push @columns, 'dateofbirth'; # add this date back in
1794     foreach my $col (@columns) {
1795         $self->_anonymize_column($col, $mandatory->{lc $col} );
1796     }
1797     $self->anonymized(1)->store;
1798 }
1799
1800 sub _anonymize_column {
1801     my ( $self, $col, $mandatory ) = @_;
1802     my $col_info = $self->_result->result_source->column_info($col);
1803     my $type = $col_info->{data_type};
1804     my $nullable = $col_info->{is_nullable};
1805     my $val;
1806     if( $type =~ /char|text/ ) {
1807         $val = $mandatory
1808             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1809             : $nullable
1810             ? undef
1811             : q{};
1812     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1813         $val = $nullable ? undef : 0;
1814     } elsif( $type =~ /date|time/ ) {
1815         $val = $nullable ? undef : dt_from_string;
1816     }
1817     $self->$col($val);
1818 }
1819
1820 =head3 add_guarantor
1821
1822     my $relationship = $patron->add_guarantor(
1823         {
1824             borrowernumber => $borrowernumber,
1825             relationships  => $relationship,
1826         }
1827     );
1828
1829     Adds a new guarantor to a patron.
1830
1831 =cut
1832
1833 sub add_guarantor {
1834     my ( $self, $params ) = @_;
1835
1836     my $guarantor_id = $params->{guarantor_id};
1837     my $relationship = $params->{relationship};
1838
1839     return Koha::Patron::Relationship->new(
1840         {
1841             guarantee_id => $self->id,
1842             guarantor_id => $guarantor_id,
1843             relationship => $relationship
1844         }
1845     )->store();
1846 }
1847
1848 =head3 get_extended_attribute
1849
1850 my $attribute_value = $patron->get_extended_attribute( $code );
1851
1852 Return the attribute for the code passed in parameter.
1853
1854 It not exist it returns undef
1855
1856 Note that this will not work for repeatable attribute types.
1857
1858 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1859 (which should be a real patron's attribute (not extended)
1860
1861 =cut
1862
1863 sub get_extended_attribute {
1864     my ( $self, $code, $value ) = @_;
1865     my $rs = $self->_result->borrower_attributes;
1866     return unless $rs;
1867     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1868     return unless $attribute->count;
1869     return $attribute->next;
1870 }
1871
1872 =head3 to_api
1873
1874     my $json = $patron->to_api;
1875
1876 Overloaded method that returns a JSON representation of the Koha::Patron object,
1877 suitable for API output.
1878
1879 =cut
1880
1881 sub to_api {
1882     my ( $self, $params ) = @_;
1883
1884     my $json_patron = $self->SUPER::to_api( $params );
1885
1886     $json_patron->{restricted} = ( $self->is_debarred )
1887                                     ? Mojo::JSON->true
1888                                     : Mojo::JSON->false;
1889
1890     return $json_patron;
1891 }
1892
1893 =head3 to_api_mapping
1894
1895 This method returns the mapping for representing a Koha::Patron object
1896 on the API.
1897
1898 =cut
1899
1900 sub to_api_mapping {
1901     return {
1902         borrowernotes       => 'staff_notes',
1903         borrowernumber      => 'patron_id',
1904         branchcode          => 'library_id',
1905         categorycode        => 'category_id',
1906         checkprevcheckout   => 'check_previous_checkout',
1907         contactfirstname    => undef,                     # Unused
1908         contactname         => undef,                     # Unused
1909         contactnote         => 'altaddress_notes',
1910         contacttitle        => undef,                     # Unused
1911         dateenrolled        => 'date_enrolled',
1912         dateexpiry          => 'expiry_date',
1913         dateofbirth         => 'date_of_birth',
1914         debarred            => undef,                     # replaced by 'restricted'
1915         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1916         emailpro            => 'secondary_email',
1917         flags               => undef,    # permissions manipulation handled in /permissions
1918         gonenoaddress       => 'incorrect_address',
1919         lastseen            => 'last_seen',
1920         lost                => 'patron_card_lost',
1921         opacnote            => 'opac_notes',
1922         othernames          => 'other_name',
1923         password            => undef,            # password manipulation handled in /password
1924         phonepro            => 'secondary_phone',
1925         relationship        => 'relationship_type',
1926         sex                 => 'gender',
1927         smsalertnumber      => 'sms_number',
1928         sort1               => 'statistics_1',
1929         sort2               => 'statistics_2',
1930         autorenew_checkouts => 'autorenew_checkouts',
1931         streetnumber        => 'street_number',
1932         streettype          => 'street_type',
1933         zipcode             => 'postal_code',
1934         B_address           => 'altaddress_address',
1935         B_address2          => 'altaddress_address2',
1936         B_city              => 'altaddress_city',
1937         B_country           => 'altaddress_country',
1938         B_email             => 'altaddress_email',
1939         B_phone             => 'altaddress_phone',
1940         B_state             => 'altaddress_state',
1941         B_streetnumber      => 'altaddress_street_number',
1942         B_streettype        => 'altaddress_street_type',
1943         B_zipcode           => 'altaddress_postal_code',
1944         altcontactaddress1  => 'altcontact_address',
1945         altcontactaddress2  => 'altcontact_address2',
1946         altcontactaddress3  => 'altcontact_city',
1947         altcontactcountry   => 'altcontact_country',
1948         altcontactfirstname => 'altcontact_firstname',
1949         altcontactphone     => 'altcontact_phone',
1950         altcontactsurname   => 'altcontact_surname',
1951         altcontactstate     => 'altcontact_state',
1952         altcontactzipcode   => 'altcontact_postal_code',
1953         password_expiration_date => undef,
1954         primary_contact_method => undef,
1955         secret              => undef,
1956         auth_method         => undef,
1957     };
1958 }
1959
1960 =head3 queue_notice
1961
1962     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
1963     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
1964     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
1965
1966     Queue messages to a patron. Can pass a message that is part of the message_attributes
1967     table or supply the transport to use.
1968
1969     If passed a message name we retrieve the patrons preferences for transports
1970     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
1971     we have no address/number for sending
1972
1973     $letter_params is a hashref of the values to be passed to GetPreparedLetter
1974
1975     test_mode will only report which notices would be sent, but nothing will be queued
1976
1977 =cut
1978
1979 sub queue_notice {
1980     my ( $self, $params ) = @_;
1981     my $letter_params = $params->{letter_params};
1982     my $test_mode = $params->{test_mode};
1983
1984     return unless $letter_params;
1985     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
1986
1987     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
1988     my $from_email_address = $library->from_email_address;
1989
1990     my @message_transports;
1991     my $letter_code;
1992     $letter_code = $letter_params->{letter_code};
1993     if( $params->{message_name} ){
1994         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
1995                 borrowernumber => $letter_params->{borrowernumber},
1996                 message_name => $params->{message_name}
1997         } );
1998         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
1999         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2000     } else {
2001         @message_transports = @{$params->{message_transports}};
2002     }
2003     return unless defined $letter_code;
2004     $letter_params->{letter_code} = $letter_code;
2005     my $print_sent = 0;
2006     my %return;
2007     foreach my $mtt (@message_transports){
2008         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2009         # Notice is handled by TalkingTech_itiva_outbound.pl
2010         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2011             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2012             or ( $mtt eq 'phone' and not $self->phone ) )
2013         {
2014             push @{ $return{fallback} }, $mtt;
2015             $mtt = 'print';
2016         }
2017         next if $mtt eq 'print' && $print_sent;
2018         $letter_params->{message_transport_type} = $mtt;
2019         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2020         C4::Letters::EnqueueLetter({
2021             letter => $letter,
2022             borrowernumber => $self->borrowernumber,
2023             from_address   => $from_email_address,
2024             message_transport_type => $mtt
2025         }) unless $test_mode;
2026         push @{$return{sent}}, $mtt;
2027         $print_sent = 1 if $mtt eq 'print';
2028     }
2029     return \%return;
2030 }
2031
2032 =head3 safe_to_delete
2033
2034     my $result = $patron->safe_to_delete;
2035     if ( $result eq 'has_guarantees' ) { ... }
2036     elsif ( $result ) { ... }
2037     else { # cannot delete }
2038
2039 This method tells if the Koha:Patron object can be deleted. Possible return values
2040
2041 =over 4
2042
2043 =item 'ok'
2044
2045 =item 'has_checkouts'
2046
2047 =item 'has_debt'
2048
2049 =item 'has_guarantees'
2050
2051 =item 'is_anonymous_patron'
2052
2053 =back
2054
2055 =cut
2056
2057 sub safe_to_delete {
2058     my ($self) = @_;
2059
2060     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2061
2062     my $error;
2063
2064     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2065         $error = 'is_anonymous_patron';
2066     }
2067     elsif ( $self->checkouts->count ) {
2068         $error = 'has_checkouts';
2069     }
2070     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2071         $error = 'has_debt';
2072     }
2073     elsif ( $self->guarantee_relationships->count ) {
2074         $error = 'has_guarantees';
2075     }
2076
2077     if ( $error ) {
2078         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2079     }
2080
2081     return Koha::Result::Boolean->new(1);
2082 }
2083
2084 =head3 recalls
2085
2086     my $recalls = $patron->recalls;
2087
2088 Return the patron's recalls.
2089
2090 =cut
2091
2092 sub recalls {
2093     my ( $self ) = @_;
2094
2095     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2096 }
2097
2098 =head3 account_balance
2099
2100     my $balance = $patron->account_balance
2101
2102 Return the patron's account balance
2103
2104 =cut
2105
2106 sub account_balance {
2107     my ($self) = @_;
2108     return $self->account->balance;
2109 }
2110
2111
2112 =head3 has_messaging_preference
2113
2114 my $bool = $patron->has_messaging_preference({
2115     message_name => $message_name, # A value from message_attributes.message_name
2116     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2117     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2118 });
2119
2120 =cut
2121
2122 sub has_messaging_preference {
2123     my ( $self, $params ) = @_;
2124
2125     my $message_name           = $params->{message_name};
2126     my $message_transport_type = $params->{message_transport_type};
2127     my $wants_digest           = $params->{wants_digest};
2128
2129     return $self->_result->search_related_rs(
2130         'borrower_message_preferences',
2131         $params,
2132         {
2133             prefetch =>
2134               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2135         }
2136     )->count;
2137 }
2138
2139 =head3 can_patron_change_staff_only_lists
2140
2141 $patron->can_patron_change_staff_only_lists;
2142
2143 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2144 Otherwise, return 0.
2145
2146 =cut
2147
2148 sub can_patron_change_staff_only_lists {
2149     my ( $self, $params ) = @_;
2150     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2151     return 0;
2152 }
2153
2154 =head3 encode_secret
2155
2156   $patron->encode_secret($secret32);
2157
2158 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2159 You still need to call ->store.
2160
2161 =cut
2162
2163 sub encode_secret {
2164     my ( $self, $secret ) = @_;
2165     if( $secret ) {
2166         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2167     }
2168     return $self->secret($secret);
2169 }
2170
2171 =head3 decoded_secret
2172
2173   my $secret32 = $patron->decoded_secret;
2174
2175 Decode the patron secret. We expect to get back a base32 string, but this
2176 is not checked here. Caller of encode_secret is responsible for that.
2177
2178 =cut
2179
2180 sub decoded_secret {
2181     my ( $self ) = @_;
2182     if( $self->secret ) {
2183         return Koha::Encryption->new->decrypt_hex( $self->secret );
2184     }
2185     return $self->secret;
2186 }
2187
2188 =head3 virtualshelves
2189
2190     my $shelves = $patron->virtualshelves;
2191
2192 =cut
2193
2194 sub virtualshelves {
2195     my $self = shift;
2196     return Koha::Virtualshelves->_new_from_dbic( scalar $self->_result->virtualshelves );
2197 }
2198
2199 =head2 Internal methods
2200
2201 =head3 _type
2202
2203 =cut
2204
2205 sub _type {
2206     return 'Borrower';
2207 }
2208
2209 =head1 AUTHORS
2210
2211 Kyle M Hall <kyle@bywatersolutions.com>
2212 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2213 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2214
2215 =cut
2216
2217 1;