Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Log qw( logaction );
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use C4::Letters;
  33 use Koha::AuthUtils;
  34 use Koha::Checkouts;
  35 use Koha::CirculationRules;
  36 use Koha::Club::Enrollments;
  37 use Koha::Database;
  38 use Koha::DateUtils qw( dt_from_string );
  39 use Koha::Encryption;
  40 use Koha::Exceptions::Password;
  41 use Koha::Holds;
  42 use Koha::Old::Checkouts;
  43 use Koha::Patron::Attributes;
  44 use Koha::Patron::Categories;
  45 use Koha::Patron::Debarments;
  46 use Koha::Patron::HouseboundProfile;
  47 use Koha::Patron::HouseboundRole;
  48 use Koha::Patron::Images;
  49 use Koha::Patron::Messages;
  50 use Koha::Patron::Modifications;
  51 use Koha::Patron::Relationships;
  52 use Koha::Patrons;
  53 use Koha::Plugins;
  54 use Koha::Recalls;
  55 use Koha::Result::Boolean;
  56 use Koha::Subscription::Routinglists;
  57 use Koha::Token;
  58 use Koha::Virtualshelves;
  59
  60 use base qw(Koha::Object);
  61
  62 use constant ADMINISTRATIVE_LOCKOUT => -1;
  63
  64 our $RESULTSET_PATRON_ID_MAPPING = {
  65     Accountline          => 'borrowernumber',
  66     Aqbasketuser         => 'borrowernumber',
  67     Aqbudget             => 'budget_owner_id',
  68     Aqbudgetborrower     => 'borrowernumber',
  69     ArticleRequest       => 'borrowernumber',
  70     BorrowerDebarment    => 'borrowernumber',
  71     BorrowerFile         => 'borrowernumber',
  72     BorrowerModification => 'borrowernumber',
  73     ClubEnrollment       => 'borrowernumber',
  74     Issue                => 'borrowernumber',
  75     ItemsLastBorrower    => 'borrowernumber',
  76     Linktracker          => 'borrowernumber',
  77     Message              => 'borrowernumber',
  78     MessageQueue         => 'borrowernumber',
  79     OldIssue             => 'borrowernumber',
  80     OldReserve           => 'borrowernumber',
  81     Rating               => 'borrowernumber',
  82     Reserve              => 'borrowernumber',
  83     Review               => 'borrowernumber',
  84     SearchHistory        => 'userid',
  85     Statistic            => 'borrowernumber',
  86     Suggestion           => 'suggestedby',
  87     TagAll               => 'borrowernumber',
  88     Virtualshelfcontent  => 'borrowernumber',
  89     Virtualshelfshare    => 'borrowernumber',
  90     Virtualshelve        => 'owner',
  91 };
  92
  93 =head1 NAME
  94
  95 Koha::Patron - Koha Patron Object class
  96
  97 =head1 API
  98
  99 =head2 Class Methods
 100
 101 =head3 new
 102
 103 =cut
 104
 105 sub new {
 106     my ( $class, $params ) = @_;
 107
 108     return $class->SUPER::new($params);
 109 }
 110
 111 =head3 fixup_cardnumber
 112
 113 Autogenerate next cardnumber from highest value found in database
 114
 115 =cut
 116
 117 sub fixup_cardnumber {
 118     my ( $self ) = @_;
 119
 120     my $max = $self->cardnumber;
 121     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 122
 123     $max ||= Koha::Patrons->search({
 124         cardnumber => {-regexp => '^-?[0-9]+$'}
 125     }, {
 126         select => \'CAST(cardnumber AS SIGNED)',
 127         as => ['cast_cardnumber']
 128     })->_resultset->get_column('cast_cardnumber')->max;
 129     $self->cardnumber(($max || 0) +1);
 130 }
 131
 132 =head3 trim_whitespace
 133
 134 trim whitespace from data which has some non-whitespace in it.
 135 Could be moved to Koha::Object if need to be reused
 136
 137 =cut
 138
 139 sub trim_whitespaces {
 140     my( $self ) = @_;
 141
 142     my $schema  = Koha::Database->new->schema;
 143     my @columns = $schema->source($self->_type)->columns;
 144
 145     for my $column( @columns ) {
 146         my $value = $self->$column;
 147         if ( defined $value ) {
 148             $value =~ s/^\s*|\s*$//g;
 149             $self->$column($value);
 150         }
 151     }
 152     return $self;
 153 }
 154
 155 =head3 plain_text_password
 156
 157 $patron->plain_text_password( $password );
 158
 159 stores a copy of the unencrypted password in the object
 160 for use in code before encrypting for db
 161
 162 =cut
 163
 164 sub plain_text_password {
 165     my ( $self, $password ) = @_;
 166     if ( $password ) {
 167         $self->{_plain_text_password} = $password;
 168         return $self;
 169     }
 170     return $self->{_plain_text_password}
 171         if $self->{_plain_text_password};
 172
 173     return;
 174 }
 175
 176 =head3 store
 177
 178 Patron specific store method to cleanup record
 179 and do other necessary things before saving
 180 to db
 181
 182 =cut
 183
 184 sub store {
 185     my ($self) = @_;
 186
 187     $self->_result->result_source->schema->txn_do(
 188         sub {
 189             if (
 190                 C4::Context->preference("autoMemberNum")
 191                 and ( not defined $self->cardnumber
 192                     or $self->cardnumber eq '' )
 193               )
 194             {
 195                 # Warning: The caller is responsible for locking the members table in write
 196                 # mode, to avoid database corruption.
 197                 # We are in a transaction but the table is not locked
 198                 $self->fixup_cardnumber;
 199             }
 200
 201             unless( $self->category->in_storage ) {
 202                 Koha::Exceptions::Object::FKConstraint->throw(
 203                     broken_fk => 'categorycode',
 204                     value     => $self->categorycode,
 205                 );
 206             }
 207
 208             $self->trim_whitespaces;
 209
 210             my $new_cardnumber = $self->cardnumber;
 211             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 212             $self->cardnumber( $new_cardnumber );
 213
 214             # Set surname to uppercase if uppercasesurname is true
 215             $self->surname( uc($self->surname) )
 216                 if C4::Context->preference("uppercasesurnames");
 217
 218             $self->relationship(undef) # We do not want to store an empty string in this field
 219               if defined $self->relationship
 220                      and $self->relationship eq "";
 221
 222             unless ( $self->in_storage ) {    #AddMember
 223
 224                 # Generate a valid userid/login if needed
 225                 $self->generate_userid
 226                   if not $self->userid or not $self->has_valid_userid;
 227
 228                 # Add expiration date if it isn't already there
 229                 unless ( $self->dateexpiry ) {
 230                     $self->dateexpiry( $self->category->get_expiry_date );
 231                 }
 232
 233                 # Add enrollment date if it isn't already there
 234                 unless ( $self->dateenrolled ) {
 235                     $self->dateenrolled(dt_from_string);
 236                 }
 237
 238                 # Set the privacy depending on the patron's category
 239                 my $default_privacy = $self->category->default_privacy || q{};
 240                 $default_privacy =
 241                     $default_privacy eq 'default' ? 1
 242                   : $default_privacy eq 'never'   ? 2
 243                   : $default_privacy eq 'forever' ? 0
 244                   :                                                   undef;
 245                 $self->privacy($default_privacy);
 246
 247                 # Call any check_password plugins if password is passed
 248                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 249                     my @plugins = Koha::Plugins->new()->GetPlugins({
 250                         method => 'check_password',
 251                     });
 252                     foreach my $plugin ( @plugins ) {
 253                         # This plugin hook will also be used by a plugin for the Norwegian national
 254                         # patron database. This is why we need to pass both the password and the
 255                         # borrowernumber to the plugin.
 256                         my $ret = $plugin->check_password(
 257                             {
 258                                 password       => $self->password,
 259                                 borrowernumber => $self->borrowernumber
 260                             }
 261                         );
 262                         if ( $ret->{'error'} == 1 ) {
 263                             Koha::Exceptions::Password::Plugin->throw();
 264                         }
 265                     }
 266                 }
 267
 268                 # Make a copy of the plain text password for later use
 269                 $self->plain_text_password( $self->password );
 270
 271                 $self->password_expiration_date( $self->password
 272                     ? $self->category->get_password_expiry_date || undef
 273                     : undef );
 274                 # Create a disabled account if no password provided
 275                 $self->password( $self->password
 276                     ? Koha::AuthUtils::hash_password( $self->password )
 277                     : '!' );
 278
 279                 $self->borrowernumber(undef);
 280
 281                 $self = $self->SUPER::store;
 282
 283                 $self->add_enrolment_fee_if_needed(0);
 284
 285                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 286                   if C4::Context->preference("BorrowersLog");
 287             }
 288             else {    #ModMember
 289
 290                 my $self_from_storage = $self->get_from_storage;
 291                 # FIXME We should not deal with that here, callers have to do this job
 292                 # Moved from ModMember to prevent regressions
 293                 unless ( $self->userid ) {
 294                     my $stored_userid = $self_from_storage->userid;
 295                     $self->userid($stored_userid);
 296                 }
 297
 298                 # Password must be updated using $self->set_password
 299                 $self->password($self_from_storage->password);
 300
 301                 if ( $self->category->categorycode ne
 302                     $self_from_storage->category->categorycode )
 303                 {
 304                     # Add enrolement fee on category change if required
 305                     $self->add_enrolment_fee_if_needed(1)
 306                       if C4::Context->preference('FeeOnChangePatronCategory');
 307
 308                     # Clean up guarantors on category change if required
 309                     $self->guarantor_relationships->delete
 310                       unless ( $self->category->can_be_guarantee );
 311
 312                 }
 313
 314                 # Actionlogs
 315                 if ( C4::Context->preference("BorrowersLog") ) {
 316                     my $info;
 317                     my $from_storage = $self_from_storage->unblessed;
 318                     my $from_object  = $self->unblessed;
 319                     my @skip_fields  = (qw/lastseen updated_on/);
 320                     for my $key ( keys %{$from_storage} ) {
 321                         next if any { /$key/ } @skip_fields;
 322                         if (
 323                             (
 324                                   !defined( $from_storage->{$key} )
 325                                 && defined( $from_object->{$key} )
 326                             )
 327                             || ( defined( $from_storage->{$key} )
 328                                 && !defined( $from_object->{$key} ) )
 329                             || (
 330                                    defined( $from_storage->{$key} )
 331                                 && defined( $from_object->{$key} )
 332                                 && ( $from_storage->{$key} ne
 333                                     $from_object->{$key} )
 334                             )
 335                           )
 336                         {
 337                             $info->{$key} = {
 338                                 before => $from_storage->{$key},
 339                                 after  => $from_object->{$key}
 340                             };
 341                         }
 342                     }
 343
 344                     if ( defined($info) ) {
 345                         logaction(
 346                             "MEMBERS",
 347                             "MODIFY",
 348                             $self->borrowernumber,
 349                             to_json(
 350                                 $info,
 351                                 { utf8 => 1, pretty => 1, canonical => 1 }
 352                             )
 353                         );
 354                     }
 355                 }
 356
 357                 # Final store
 358                 $self = $self->SUPER::store;
 359             }
 360         }
 361     );
 362     return $self;
 363 }
 364
 365 =head3 delete
 366
 367 $patron->delete
 368
 369 Delete patron's holds, lists and finally the patron.
 370
 371 Lists owned by the borrower are deleted, but entries from the borrower to
 372 other lists are kept.
 373
 374 =cut
 375
 376 sub delete {
 377     my ($self) = @_;
 378
 379     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 380     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 381
 382     $self->_result->result_source->schema->txn_do(
 383         sub {
 384             # Cancel Patron's holds
 385             my $holds = $self->holds;
 386             while( my $hold = $holds->next ){
 387                 $hold->cancel;
 388             }
 389
 390             # Delete all lists and all shares of this borrower
 391             # Consistent with the approach Koha uses on deleting individual lists
 392             # Note that entries in virtualshelfcontents added by this borrower to
 393             # lists of others will be handled by a table constraint: the borrower
 394             # is set to NULL in those entries.
 395             # NOTE:
 396             # We could handle the above deletes via a constraint too.
 397             # But a new BZ report 11889 has been opened to discuss another approach.
 398             # Instead of deleting we could also disown lists (based on a pref).
 399             # In that way we could save shared and public lists.
 400             # The current table constraints support that idea now.
 401             # This pref should then govern the results of other routines/methods such as
 402             # Koha::Virtualshelf->new->delete too.
 403             # FIXME Could be $patron->get_lists
 404             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } )->as_list;
 405
 406             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 407             # for patron selfreg
 408             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 409
 410             $self->SUPER::delete;
 411
 412             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 413         }
 414     );
 415     return $self;
 416 }
 417
 418
 419 =head3 category
 420
 421 my $patron_category = $patron->category
 422
 423 Return the patron category for this patron
 424
 425 =cut
 426
 427 sub category {
 428     my ( $self ) = @_;
 429     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 430 }
 431
 432 =head3 image
 433
 434 =cut
 435
 436 sub image {
 437     my ( $self ) = @_;
 438
 439     return Koha::Patron::Images->find( $self->borrowernumber );
 440 }
 441
 442 =head3 library
 443
 444 Returns a Koha::Library object representing the patron's home library.
 445
 446 =cut
 447
 448 sub library {
 449     my ( $self ) = @_;
 450     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 451 }
 452
 453 =head3 sms_provider
 454
 455 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 456
 457 =cut
 458
 459 sub sms_provider {
 460     my ( $self ) = @_;
 461     my $sms_provider_rs = $self->_result->sms_provider;
 462     return unless $sms_provider_rs;
 463     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 464 }
 465
 466 =head3 guarantor_relationships
 467
 468 Returns Koha::Patron::Relationships object for this patron's guarantors
 469
 470 Returns the set of relationships for the patrons that are guarantors for this patron.
 471
 472 This is returned instead of a Koha::Patron object because the guarantor
 473 may not exist as a patron in Koha. If this is true, the guarantors name
 474 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 475
 476 =cut
 477
 478 sub guarantor_relationships {
 479     my ($self) = @_;
 480
 481     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 482 }
 483
 484 =head3 guarantee_relationships
 485
 486 Returns Koha::Patron::Relationships object for this patron's guarantors
 487
 488 Returns the set of relationships for the patrons that are guarantees for this patron.
 489
 490 The method returns Koha::Patron::Relationship objects for the sake
 491 of consistency with the guantors method.
 492 A guarantee by definition must exist as a patron in Koha.
 493
 494 =cut
 495
 496 sub guarantee_relationships {
 497     my ($self) = @_;
 498
 499     return Koha::Patron::Relationships->search(
 500         { guarantor_id => $self->id },
 501         {
 502             prefetch => 'guarantee',
 503             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 504         }
 505     );
 506 }
 507
 508 =head3 relationships_debt
 509
 510 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 511
 512 =cut
 513
 514 sub relationships_debt {
 515     my ($self, $params) = @_;
 516
 517     my $include_guarantors  = $params->{include_guarantors};
 518     my $only_this_guarantor = $params->{only_this_guarantor};
 519     my $include_this_patron = $params->{include_this_patron};
 520
 521     my @guarantors;
 522     if ( $only_this_guarantor ) {
 523         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 524         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 525     } elsif ( $self->guarantor_relationships->count ) {
 526         # I am a guarantee, just get all my guarantors
 527         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 528     } else {
 529         # I am a guarantor, I need to get all the guarantors of all my guarantees
 530         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 531     }
 532
 533     my $non_issues_charges = 0;
 534     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 535     foreach my $guarantor (@guarantors) {
 536         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 537
 538         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 539         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 540         my $guarantees_non_issues_charges = 0;
 541         foreach my $guarantee (@guarantees) {
 542             next if $seen->{ $guarantee->id };
 543             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 544             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 545             $seen->{ $guarantee->id } = 1;
 546         }
 547
 548         $non_issues_charges += $guarantees_non_issues_charges;
 549         $seen->{ $guarantor->id } = 1;
 550     }
 551
 552     return $non_issues_charges;
 553 }
 554
 555 =head3 housebound_profile
 556
 557 Returns the HouseboundProfile associated with this patron.
 558
 559 =cut
 560
 561 sub housebound_profile {
 562     my ( $self ) = @_;
 563     my $profile = $self->_result->housebound_profile;
 564     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 565         if ( $profile );
 566     return;
 567 }
 568
 569 =head3 housebound_role
 570
 571 Returns the HouseboundRole associated with this patron.
 572
 573 =cut
 574
 575 sub housebound_role {
 576     my ( $self ) = @_;
 577
 578     my $role = $self->_result->housebound_role;
 579     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 580     return;
 581 }
 582
 583 =head3 siblings
 584
 585 Returns the siblings of this patron.
 586
 587 =cut
 588
 589 sub siblings {
 590     my ($self) = @_;
 591
 592     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 593
 594     return unless @guarantors;
 595
 596     my @siblings =
 597       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 598
 599     return unless @siblings;
 600
 601     my %seen;
 602     @siblings =
 603       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 604
 605     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 606 }
 607
 608 =head3 merge_with
 609
 610     my $patron = Koha::Patrons->find($id);
 611     $patron->merge_with( \@patron_ids );
 612
 613     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 614     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 615     of the keeper patron.
 616
 617 =cut
 618
 619 sub merge_with {
 620     my ( $self, $patron_ids ) = @_;
 621
 622     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 623     return if $anonymous_patron && $self->id eq $anonymous_patron;
 624
 625     my @patron_ids = @{ $patron_ids };
 626
 627     # Ensure the keeper isn't in the list of patrons to merge
 628     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 629
 630     my $schema = Koha::Database->new()->schema();
 631
 632     my $results;
 633
 634     $self->_result->result_source->schema->txn_do( sub {
 635         foreach my $patron_id (@patron_ids) {
 636
 637             next if $patron_id eq $anonymous_patron;
 638
 639             my $patron = Koha::Patrons->find( $patron_id );
 640
 641             next unless $patron;
 642
 643             # Unbless for safety, the patron will end up being deleted
 644             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 645
 646             my $attributes = $patron->extended_attributes;
 647             my $new_attributes = [
 648                 map { { code => $_->code, attribute => $_->attribute } }
 649                     $attributes->as_list
 650             ];
 651             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 652             for my $attribute ( @$new_attributes ) {
 653                 try {
 654                     $self->add_extended_attribute($attribute);
 655                 } catch {
 656                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 657                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 658                         $_->rethrow;
 659                     }
 660                 };
 661             }
 662
 663             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 664                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 665                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 666                 $rs->update({ $field => $self->id });
 667                 if ( $r eq 'BorrowerDebarment' ) {
 668                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 669                 }
 670             }
 671
 672             $patron->move_to_deleted();
 673             $patron->delete();
 674         }
 675     });
 676
 677     return $results;
 678 }
 679
 680
 681
 682 =head3 wants_check_for_previous_checkout
 683
 684     $wants_check = $patron->wants_check_for_previous_checkout;
 685
 686 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 687
 688 =cut
 689
 690 sub wants_check_for_previous_checkout {
 691     my ( $self ) = @_;
 692     my $syspref = C4::Context->preference("checkPrevCheckout");
 693
 694     # Simple cases
 695     ## Hard syspref trumps all
 696     return 1 if ($syspref eq 'hardyes');
 697     return 0 if ($syspref eq 'hardno');
 698     ## Now, patron pref trumps all
 699     return 1 if ($self->checkprevcheckout eq 'yes');
 700     return 0 if ($self->checkprevcheckout eq 'no');
 701
 702     # More complex: patron inherits -> determine category preference
 703     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 704     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 705     return 0 if ($checkPrevCheckoutByCat eq 'no');
 706
 707     # Finally: category preference is inherit, default to 0
 708     if ($syspref eq 'softyes') {
 709         return 1;
 710     } else {
 711         return 0;
 712     }
 713 }
 714
 715 =head3 do_check_for_previous_checkout
 716
 717     $do_check = $patron->do_check_for_previous_checkout($item);
 718
 719 Return 1 if the bib associated with $ITEM has previously been checked out to
 720 $PATRON, 0 otherwise.
 721
 722 =cut
 723
 724 sub do_check_for_previous_checkout {
 725     my ( $self, $item ) = @_;
 726
 727     my @item_nos;
 728     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 729     if ( $biblio->is_serial ) {
 730         push @item_nos, $item->{itemnumber};
 731     } else {
 732         # Get all itemnumbers for given bibliographic record.
 733         @item_nos = $biblio->items->get_column( 'itemnumber' );
 734     }
 735
 736     # Create (old)issues search criteria
 737     my $criteria = {
 738         borrowernumber => $self->borrowernumber,
 739         itemnumber => \@item_nos,
 740     };
 741
 742     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 743     if ($delay) {
 744         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 745         my $newer_than = dt_from_string()->subtract( days => $delay );
 746         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 747     }
 748
 749     # Check current issues table
 750     my $issues = Koha::Checkouts->search($criteria);
 751     return 1 if $issues->count; # 0 || N
 752
 753     # Check old issues table
 754     my $old_issues = Koha::Old::Checkouts->search($criteria);
 755     return $old_issues->count;  # 0 || N
 756 }
 757
 758 =head3 is_debarred
 759
 760 my $debarment_expiration = $patron->is_debarred;
 761
 762 Returns the date a patron debarment will expire, or undef if the patron is not
 763 debarred
 764
 765 =cut
 766
 767 sub is_debarred {
 768     my ($self) = @_;
 769
 770     return unless $self->debarred;
 771     return $self->debarred
 772       if $self->debarred =~ '^9999'
 773       or dt_from_string( $self->debarred ) > dt_from_string;
 774     return;
 775 }
 776
 777 =head3 is_expired
 778
 779 my $is_expired = $patron->is_expired;
 780
 781 Returns 1 if the patron is expired or 0;
 782
 783 =cut
 784
 785 sub is_expired {
 786     my ($self) = @_;
 787     return 0 unless $self->dateexpiry;
 788     return 0 if $self->dateexpiry =~ '^9999';
 789     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 790     return 0;
 791 }
 792
 793 =head3 password_expired
 794
 795 my $password_expired = $patron->password_expired;
 796
 797 Returns 1 if the patron's password is expired or 0;
 798
 799 =cut
 800
 801 sub password_expired {
 802     my ($self) = @_;
 803     return 0 unless $self->password_expiration_date;
 804     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 805     return 0;
 806 }
 807
 808 =head3 is_going_to_expire
 809
 810 my $is_going_to_expire = $patron->is_going_to_expire;
 811
 812 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 813
 814 =cut
 815
 816 sub is_going_to_expire {
 817     my ($self) = @_;
 818
 819     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 820
 821     return 0 unless $delay;
 822     return 0 unless $self->dateexpiry;
 823     return 0 if $self->dateexpiry =~ '^9999';
 824     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 825     return 0;
 826 }
 827
 828 =head3 set_password
 829
 830     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 831
 832 Set the patron's password.
 833
 834 =head4 Exceptions
 835
 836 The passed string is validated against the current password enforcement policy.
 837 Validation can be skipped by passing the I<skip_validation> parameter.
 838
 839 Exceptions are thrown if the password is not good enough.
 840
 841 =over 4
 842
 843 =item Koha::Exceptions::Password::TooShort
 844
 845 =item Koha::Exceptions::Password::WhitespaceCharacters
 846
 847 =item Koha::Exceptions::Password::TooWeak
 848
 849 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 850
 851 =back
 852
 853 =cut
 854
 855 sub set_password {
 856     my ( $self, $args ) = @_;
 857
 858     my $password = $args->{password};
 859
 860     unless ( $args->{skip_validation} ) {
 861         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 862
 863         if ( !$is_valid ) {
 864             if ( $error eq 'too_short' ) {
 865                 my $min_length = $self->category->effective_min_password_length;
 866                 $min_length = 3 if not $min_length or $min_length < 3;
 867
 868                 my $password_length = length($password);
 869                 Koha::Exceptions::Password::TooShort->throw(
 870                     length => $password_length, min_length => $min_length );
 871             }
 872             elsif ( $error eq 'has_whitespaces' ) {
 873                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 874             }
 875             elsif ( $error eq 'too_weak' ) {
 876                 Koha::Exceptions::Password::TooWeak->throw();
 877             }
 878         }
 879     }
 880
 881     if ( C4::Context->config("enable_plugins") ) {
 882         # Call any check_password plugins
 883         my @plugins = Koha::Plugins->new()->GetPlugins({
 884             method => 'check_password',
 885         });
 886         foreach my $plugin ( @plugins ) {
 887             # This plugin hook will also be used by a plugin for the Norwegian national
 888             # patron database. This is why we need to pass both the password and the
 889             # borrowernumber to the plugin.
 890             my $ret = $plugin->check_password(
 891                 {
 892                     password       => $password,
 893                     borrowernumber => $self->borrowernumber
 894                 }
 895             );
 896             # This plugin hook will also be used by a plugin for the Norwegian national
 897             # patron database. This is why we need to call the actual plugins and then
 898             # check skip_validation afterwards.
 899             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 900                 Koha::Exceptions::Password::Plugin->throw();
 901             }
 902         }
 903     }
 904
 905     my $digest = Koha::AuthUtils::hash_password($password);
 906
 907     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 908
 909     # We do not want to call $self->store and retrieve password from DB
 910     $self->password($digest);
 911     $self->login_attempts(0);
 912     $self->SUPER::store;
 913
 914     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 915         if C4::Context->preference("BorrowersLog");
 916
 917     return $self;
 918 }
 919
 920
 921 =head3 renew_account
 922
 923 my $new_expiry_date = $patron->renew_account
 924
 925 Extending the subscription to the expiry date.
 926
 927 =cut
 928
 929 sub renew_account {
 930     my ($self) = @_;
 931     my $date;
 932     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 933         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 934     } else {
 935         $date =
 936             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 937             ? dt_from_string( $self->dateexpiry )
 938             : dt_from_string;
 939     }
 940     my $expiry_date = $self->category->get_expiry_date($date);
 941
 942     $self->dateexpiry($expiry_date);
 943     $self->date_renewed( dt_from_string() );
 944     $self->store();
 945
 946     $self->add_enrolment_fee_if_needed(1);
 947
 948     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 949     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 950 }
 951
 952 =head3 has_overdues
 953
 954 my $has_overdues = $patron->has_overdues;
 955
 956 Returns the number of patron's overdues
 957
 958 =cut
 959
 960 sub has_overdues {
 961     my ($self) = @_;
 962     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 963     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 964 }
 965
 966 =head3 track_login
 967
 968     $patron->track_login;
 969     $patron->track_login({ force => 1 });
 970
 971     Tracks a (successful) login attempt.
 972     The preference TrackLastPatronActivity must be enabled. Or you
 973     should pass the force parameter.
 974
 975 =cut
 976
 977 sub track_login {
 978     my ( $self, $params ) = @_;
 979     return if
 980         !$params->{force} &&
 981         !C4::Context->preference('TrackLastPatronActivity');
 982     $self->lastseen( dt_from_string() )->store;
 983 }
 984
 985 =head3 move_to_deleted
 986
 987 my $is_moved = $patron->move_to_deleted;
 988
 989 Move a patron to the deletedborrowers table.
 990 This can be done before deleting a patron, to make sure the data are not completely deleted.
 991
 992 =cut
 993
 994 sub move_to_deleted {
 995     my ($self) = @_;
 996     my $patron_infos = $self->unblessed;
 997     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 998     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
 999 }
1000
1001 =head3 can_request_article
1002
1003     if ( $patron->can_request_article( $library->id ) ) { ... }
1004
1005 Returns true if the patron can request articles. As limits apply for the patron
1006 on the same day, those completed the same day are considered as current.
1007
1008 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1009
1010 =cut
1011
1012 sub can_request_article {
1013     my ($self, $library_id) = @_;
1014
1015     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1016
1017     my $rule = Koha::CirculationRules->get_effective_rule(
1018         {
1019             branchcode   => $library_id,
1020             categorycode => $self->categorycode,
1021             rule_name    => 'open_article_requests_limit'
1022         }
1023     );
1024
1025     my $limit = ($rule) ? $rule->rule_value : undef;
1026
1027     return 1 unless defined $limit;
1028
1029     my $count = Koha::ArticleRequests->search(
1030         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1031             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1032         ]
1033     )->count;
1034     return $count < $limit ? 1 : 0;
1035 }
1036
1037 =head3 article_request_fee
1038
1039     my $fee = $patron->article_request_fee(
1040         {
1041           [ library_id => $library->id, ]
1042         }
1043     );
1044
1045 Returns the fee to be charged to the patron when it places an article request.
1046
1047 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1048
1049 =cut
1050
1051 sub article_request_fee {
1052     my ($self, $params) = @_;
1053
1054     my $library_id = $params->{library_id};
1055
1056     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1057
1058     my $rule = Koha::CirculationRules->get_effective_rule(
1059         {
1060             branchcode   => $library_id,
1061             categorycode => $self->categorycode,
1062             rule_name    => 'article_request_fee'
1063         }
1064     );
1065
1066     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1067
1068     return $fee;
1069 }
1070
1071 =head3 add_article_request_fee_if_needed
1072
1073     my $fee = $patron->add_article_request_fee_if_needed(
1074         {
1075           [ item_id    => $item->id,
1076             library_id => $library->id, ]
1077         }
1078     );
1079
1080 If an article request fee needs to be charged, it adds a debit to the patron's
1081 account.
1082
1083 Returns the fee line.
1084
1085 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1086
1087 =cut
1088
1089 sub add_article_request_fee_if_needed {
1090     my ($self, $params) = @_;
1091
1092     my $library_id = $params->{library_id};
1093     my $item_id    = $params->{item_id};
1094
1095     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1096
1097     my $amount = $self->article_request_fee(
1098         {
1099             library_id => $library_id,
1100         }
1101     );
1102
1103     my $debit_line;
1104
1105     if ( $amount > 0 ) {
1106         $debit_line = $self->account->add_debit(
1107             {
1108                 amount     => $amount,
1109                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1110                 interface  => C4::Context->interface,
1111                 library_id => $library_id,
1112                 type       => 'ARTICLE_REQUEST',
1113                 item_id    => $item_id,
1114             }
1115         );
1116     }
1117
1118     return $debit_line;
1119 }
1120
1121 =head3 article_requests
1122
1123     my $article_requests = $patron->article_requests;
1124
1125 Returns the patron article requests.
1126
1127 =cut
1128
1129 sub article_requests {
1130     my ($self) = @_;
1131
1132     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1133 }
1134
1135 =head3 add_enrolment_fee_if_needed
1136
1137 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1138
1139 Add enrolment fee for a patron if needed.
1140
1141 $renewal - boolean denoting whether this is an account renewal or not
1142
1143 =cut
1144
1145 sub add_enrolment_fee_if_needed {
1146     my ($self, $renewal) = @_;
1147     my $enrolment_fee = $self->category->enrolmentfee;
1148     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1149         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1150         $self->account->add_debit(
1151             {
1152                 amount     => $enrolment_fee,
1153                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1154                 interface  => C4::Context->interface,
1155                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1156                 type       => $type
1157             }
1158         );
1159     }
1160     return $enrolment_fee || 0;
1161 }
1162
1163 =head3 checkouts
1164
1165 my $checkouts = $patron->checkouts
1166
1167 =cut
1168
1169 sub checkouts {
1170     my ($self) = @_;
1171     my $checkouts = $self->_result->issues;
1172     return Koha::Checkouts->_new_from_dbic( $checkouts );
1173 }
1174
1175 =head3 pending_checkouts
1176
1177 my $pending_checkouts = $patron->pending_checkouts
1178
1179 This method will return the same as $self->checkouts, but with a prefetch on
1180 items, biblio and biblioitems.
1181
1182 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1183
1184 It should not be used directly, prefer to access fields you need instead of
1185 retrieving all these fields in one go.
1186
1187 =cut
1188
1189 sub pending_checkouts {
1190     my( $self ) = @_;
1191     my $checkouts = $self->_result->issues->search(
1192         {},
1193         {
1194             order_by => [
1195                 { -desc => 'me.timestamp' },
1196                 { -desc => 'issuedate' },
1197                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1198             ],
1199             prefetch => { item => { biblio => 'biblioitems' } },
1200         }
1201     );
1202     return Koha::Checkouts->_new_from_dbic( $checkouts );
1203 }
1204
1205 =head3 old_checkouts
1206
1207 my $old_checkouts = $patron->old_checkouts
1208
1209 =cut
1210
1211 sub old_checkouts {
1212     my ($self) = @_;
1213     my $old_checkouts = $self->_result->old_issues;
1214     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1215 }
1216
1217 =head3 overdues
1218
1219 my $overdue_items = $patron->overdues
1220
1221 Return the overdue items
1222
1223 =cut
1224
1225 sub overdues {
1226     my ($self) = @_;
1227     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1228     return $self->checkouts->search(
1229         {
1230             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1231         },
1232         {
1233             prefetch => { item => { biblio => 'biblioitems' } },
1234         }
1235     );
1236 }
1237
1238 =head3 get_routing_lists
1239
1240 my $routinglists = $patron->get_routing_lists
1241
1242 Returns the routing lists a patron is subscribed to.
1243
1244 =cut
1245
1246 sub get_routing_lists {
1247     my ($self) = @_;
1248     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1249     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1250 }
1251
1252 =head3 get_age
1253
1254     my $age = $patron->get_age
1255
1256 Return the age of the patron
1257
1258 =cut
1259
1260 sub get_age {
1261     my ($self)    = @_;
1262
1263     return unless $self->dateofbirth;
1264
1265     my $date_of_birth = dt_from_string( $self->dateofbirth );
1266     my $today         = dt_from_string->truncate( to => 'day' );
1267
1268     return $today->subtract_datetime( $date_of_birth )->years;
1269 }
1270
1271 =head3 is_valid_age
1272
1273 my $is_valid = $patron->is_valid_age
1274
1275 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1276
1277 =cut
1278
1279 sub is_valid_age {
1280     my ($self) = @_;
1281     my $age = $self->get_age;
1282
1283     my $patroncategory = $self->category;
1284     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1285
1286     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1287 }
1288
1289 =head3 account
1290
1291 my $account = $patron->account
1292
1293 =cut
1294
1295 sub account {
1296     my ($self) = @_;
1297     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1298 }
1299
1300 =head3 holds
1301
1302 my $holds = $patron->holds
1303
1304 Return all the holds placed by this patron
1305
1306 =cut
1307
1308 sub holds {
1309     my ($self) = @_;
1310     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1311     return Koha::Holds->_new_from_dbic($holds_rs);
1312 }
1313
1314 =head3 old_holds
1315
1316 my $old_holds = $patron->old_holds
1317
1318 Return all the historical holds for this patron
1319
1320 =cut
1321
1322 sub old_holds {
1323     my ($self) = @_;
1324     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1325     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1326 }
1327
1328 =head3 return_claims
1329
1330 my $return_claims = $patron->return_claims
1331
1332 =cut
1333
1334 sub return_claims {
1335     my ($self) = @_;
1336     my $return_claims = $self->_result->return_claims_borrowernumbers;
1337     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1338 }
1339
1340 =head3 notice_email_address
1341
1342   my $email = $patron->notice_email_address;
1343
1344 Return the email address of patron used for notices.
1345 Returns the empty string if no email address.
1346
1347 =cut
1348
1349 sub notice_email_address{
1350     my ( $self ) = @_;
1351
1352     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1353     # if syspref is set to 'first valid' (value == OFF), look up email address
1354     if ( $which_address eq 'OFF' ) {
1355         return $self->first_valid_email_address;
1356     }
1357
1358     return $self->$which_address || '';
1359 }
1360
1361 =head3 first_valid_email_address
1362
1363 my $first_valid_email_address = $patron->first_valid_email_address
1364
1365 Return the first valid email address for a patron.
1366 For now, the order  is defined as email, emailpro, B_email.
1367 Returns the empty string if the borrower has no email addresses.
1368
1369 =cut
1370
1371 sub first_valid_email_address {
1372     my ($self) = @_;
1373
1374     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1375 }
1376
1377 =head3 get_club_enrollments
1378
1379 =cut
1380
1381 sub get_club_enrollments {
1382     my ( $self ) = @_;
1383
1384     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1385 }
1386
1387 =head3 get_enrollable_clubs
1388
1389 =cut
1390
1391 sub get_enrollable_clubs {
1392     my ( $self, $is_enrollable_from_opac ) = @_;
1393
1394     my $params;
1395     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1396       if $is_enrollable_from_opac;
1397     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1398
1399     $params->{borrower} = $self;
1400
1401     return Koha::Clubs->get_enrollable($params);
1402 }
1403
1404 =head3 account_locked
1405
1406 my $is_locked = $patron->account_locked
1407
1408 Return true if the patron has reached the maximum number of login attempts
1409 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1410 as an administrative lockout (independent of FailedLoginAttempts; see also
1411 Koha::Patron->lock).
1412 Otherwise return false.
1413 If the pref is not set (empty string, null or 0), the feature is considered as
1414 disabled.
1415
1416 =cut
1417
1418 sub account_locked {
1419     my ($self) = @_;
1420     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1421     return 1 if $FailedLoginAttempts
1422           and $self->login_attempts
1423           and $self->login_attempts >= $FailedLoginAttempts;
1424     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1425     return 0;
1426 }
1427
1428 =head3 can_see_patron_infos
1429
1430 my $can_see = $patron->can_see_patron_infos( $patron );
1431
1432 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1433
1434 =cut
1435
1436 sub can_see_patron_infos {
1437     my ( $self, $patron ) = @_;
1438     return unless $patron;
1439     return $self->can_see_patrons_from( $patron->branchcode );
1440 }
1441
1442 =head3 can_see_patrons_from
1443
1444 my $can_see = $patron->can_see_patrons_from( $branchcode );
1445
1446 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1447
1448 =cut
1449
1450 sub can_see_patrons_from {
1451     my ( $self, $branchcode ) = @_;
1452     my $can = 0;
1453     if ( $self->branchcode eq $branchcode ) {
1454         $can = 1;
1455     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1456         $can = 1;
1457     } elsif ( my $library_groups = $self->library->library_groups ) {
1458         while ( my $library_group = $library_groups->next ) {
1459             if ( $library_group->parent->has_child( $branchcode ) ) {
1460                 $can = 1;
1461                 last;
1462             }
1463         }
1464     }
1465     return $can;
1466 }
1467
1468 =head3 can_log_into
1469
1470 my $can_log_into = $patron->can_log_into( $library );
1471
1472 Given a I<Koha::Library> object, it returns a boolean representing
1473 the fact the patron can log into a the library.
1474
1475 =cut
1476
1477 sub can_log_into {
1478     my ( $self, $library ) = @_;
1479
1480     my $can = 0;
1481
1482     if ( C4::Context->preference('IndependentBranches') ) {
1483         $can = 1
1484           if $self->is_superlibrarian
1485           or $self->branchcode eq $library->id;
1486     }
1487     else {
1488         # no restrictions
1489         $can = 1;
1490     }
1491
1492    return $can;
1493 }
1494
1495 =head3 libraries_where_can_see_patrons
1496
1497 my $libraries = $patron-libraries_where_can_see_patrons;
1498
1499 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1500 The branchcodes are arbitrarily returned sorted.
1501 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1502
1503 An empty array means no restriction, the patron can see patron's infos from any libraries.
1504
1505 =cut
1506
1507 sub libraries_where_can_see_patrons {
1508     my ( $self ) = @_;
1509     my $userenv = C4::Context->userenv;
1510
1511     return () unless $userenv; # For tests, but userenv should be defined in tests...
1512
1513     my @restricted_branchcodes;
1514     if (C4::Context::only_my_library) {
1515         push @restricted_branchcodes, $self->branchcode;
1516     }
1517     else {
1518         unless (
1519             $self->has_permission(
1520                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1521             )
1522           )
1523         {
1524             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1525             if ( $library_groups->count )
1526             {
1527                 while ( my $library_group = $library_groups->next ) {
1528                     my $parent = $library_group->parent;
1529                     if ( $parent->has_child( $self->branchcode ) ) {
1530                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1531                     }
1532                 }
1533             }
1534
1535             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1536         }
1537     }
1538
1539     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1540     @restricted_branchcodes = uniq(@restricted_branchcodes);
1541     @restricted_branchcodes = sort(@restricted_branchcodes);
1542     return @restricted_branchcodes;
1543 }
1544
1545 =head3 has_permission
1546
1547 my $permission = $patron->has_permission($required);
1548
1549 See C4::Auth::haspermission for details of syntax for $required
1550
1551 =cut
1552
1553 sub has_permission {
1554     my ( $self, $flagsrequired ) = @_;
1555     return unless $self->userid;
1556     # TODO code from haspermission needs to be moved here!
1557     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1558 }
1559
1560 =head3 is_superlibrarian
1561
1562   my $is_superlibrarian = $patron->is_superlibrarian;
1563
1564 Return true if the patron is a superlibrarian.
1565
1566 =cut
1567
1568 sub is_superlibrarian {
1569     my ($self) = @_;
1570     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1571 }
1572
1573 =head3 is_adult
1574
1575 my $is_adult = $patron->is_adult
1576
1577 Return true if the patron has a category with a type Adult (A) or Organization (I)
1578
1579 =cut
1580
1581 sub is_adult {
1582     my ( $self ) = @_;
1583     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1584 }
1585
1586 =head3 is_child
1587
1588 my $is_child = $patron->is_child
1589
1590 Return true if the patron has a category with a type Child (C)
1591
1592 =cut
1593
1594 sub is_child {
1595     my( $self ) = @_;
1596     return $self->category->category_type eq 'C' ? 1 : 0;
1597 }
1598
1599 =head3 has_valid_userid
1600
1601 my $patron = Koha::Patrons->find(42);
1602 $patron->userid( $new_userid );
1603 my $has_a_valid_userid = $patron->has_valid_userid
1604
1605 my $patron = Koha::Patron->new( $params );
1606 my $has_a_valid_userid = $patron->has_valid_userid
1607
1608 Return true if the current userid of this patron is valid/unique, otherwise false.
1609
1610 Note that this should be done in $self->store instead and raise an exception if needed.
1611
1612 =cut
1613
1614 sub has_valid_userid {
1615     my ($self) = @_;
1616
1617     return 0 unless $self->userid;
1618
1619     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1620
1621     my $already_exists = Koha::Patrons->search(
1622         {
1623             userid => $self->userid,
1624             (
1625                 $self->in_storage
1626                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1627                 : ()
1628             ),
1629         }
1630     )->count;
1631     return $already_exists ? 0 : 1;
1632 }
1633
1634 =head3 generate_userid
1635
1636 my $patron = Koha::Patron->new( $params );
1637 $patron->generate_userid
1638
1639 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1640
1641 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1642
1643 =cut
1644
1645 sub generate_userid {
1646     my ($self) = @_;
1647     my $offset = 0;
1648     my $firstname = $self->firstname // q{};
1649     my $surname = $self->surname // q{};
1650     #The script will "do" the following code and increment the $offset until the generated userid is unique
1651     do {
1652       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1653       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1654       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1655       $userid = NFKD( $userid );
1656       $userid =~ s/\p{NonspacingMark}//g;
1657       $userid .= $offset unless $offset == 0;
1658       $self->userid( $userid );
1659       $offset++;
1660      } while (! $self->has_valid_userid );
1661
1662      return $self;
1663 }
1664
1665 =head3 add_extended_attribute
1666
1667 =cut
1668
1669 sub add_extended_attribute {
1670     my ($self, $attribute) = @_;
1671
1672     return Koha::Patron::Attribute->new(
1673         {
1674             %$attribute,
1675             ( borrowernumber => $self->borrowernumber ),
1676         }
1677     )->store;
1678
1679 }
1680
1681 =head3 extended_attributes
1682
1683 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1684
1685 Or setter FIXME
1686
1687 =cut
1688
1689 sub extended_attributes {
1690     my ( $self, $attributes ) = @_;
1691     if ($attributes) {    # setter
1692         my $schema = $self->_result->result_source->schema;
1693         $schema->txn_do(
1694             sub {
1695                 # Remove the existing one
1696                 $self->extended_attributes->filter_by_branch_limitations->delete;
1697
1698                 # Insert the new ones
1699                 my $new_types = {};
1700                 for my $attribute (@$attributes) {
1701                     $self->add_extended_attribute($attribute);
1702                     $new_types->{$attribute->{code}} = 1;
1703                 }
1704
1705                 # Check globally mandatory types
1706                 my @required_attribute_types =
1707                     Koha::Patron::Attribute::Types->search(
1708                         {
1709                             mandatory => 1,
1710                             category_code => [ undef, $self->categorycode ],
1711                             'borrower_attribute_types_branches.b_branchcode' =>
1712                               undef,
1713                         },
1714                         { join => 'borrower_attribute_types_branches' }
1715                     )->get_column('code');
1716                 for my $type ( @required_attribute_types ) {
1717                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1718                         type => $type,
1719                     ) if !$new_types->{$type};
1720                 }
1721             }
1722         );
1723     }
1724
1725     my $rs = $self->_result->borrower_attributes;
1726     # We call search to use the filters in Koha::Patron::Attributes->search
1727     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1728 }
1729
1730 =head3 messages
1731
1732     my $messages = $patron->messages;
1733
1734 Return the message attached to the patron.
1735
1736 =cut
1737
1738 sub messages {
1739     my ( $self ) = @_;
1740     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1741     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1742 }
1743
1744 =head3 lock
1745
1746     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1747
1748     Lock and optionally expire a patron account.
1749     Remove holds and article requests if remove flag set.
1750     In order to distinguish from locking by entering a wrong password, let's
1751     call this an administrative lockout.
1752
1753 =cut
1754
1755 sub lock {
1756     my ( $self, $params ) = @_;
1757     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1758     if( $params->{expire} ) {
1759         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1760     }
1761     $self->store;
1762     if( $params->{remove} ) {
1763         $self->holds->delete;
1764         $self->article_requests->delete;
1765     }
1766     return $self;
1767 }
1768
1769 =head3 anonymize
1770
1771     Koha::Patrons->find($id)->anonymize;
1772
1773     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1774     are randomized, other personal data is cleared too.
1775     Patrons with issues are skipped.
1776
1777 =cut
1778
1779 sub anonymize {
1780     my ( $self ) = @_;
1781     if( $self->_result->issues->count ) {
1782         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1783         return;
1784     }
1785     # Mandatory fields come from the corresponding pref, but email fields
1786     # are removed since scrambled email addresses only generate errors
1787     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1788         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1789     $mandatory->{userid} = 1; # needed since sub store does not clear field
1790     my @columns = $self->_result->result_source->columns;
1791     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
1792     push @columns, 'dateofbirth'; # add this date back in
1793     foreach my $col (@columns) {
1794         $self->_anonymize_column($col, $mandatory->{lc $col} );
1795     }
1796     $self->anonymized(1)->store;
1797 }
1798
1799 sub _anonymize_column {
1800     my ( $self, $col, $mandatory ) = @_;
1801     my $col_info = $self->_result->result_source->column_info($col);
1802     my $type = $col_info->{data_type};
1803     my $nullable = $col_info->{is_nullable};
1804     my $val;
1805     if( $type =~ /char|text/ ) {
1806         $val = $mandatory
1807             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1808             : $nullable
1809             ? undef
1810             : q{};
1811     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1812         $val = $nullable ? undef : 0;
1813     } elsif( $type =~ /date|time/ ) {
1814         $val = $nullable ? undef : dt_from_string;
1815     }
1816     $self->$col($val);
1817 }
1818
1819 =head3 add_guarantor
1820
1821     my $relationship = $patron->add_guarantor(
1822         {
1823             borrowernumber => $borrowernumber,
1824             relationships  => $relationship,
1825         }
1826     );
1827
1828     Adds a new guarantor to a patron.
1829
1830 =cut
1831
1832 sub add_guarantor {
1833     my ( $self, $params ) = @_;
1834
1835     my $guarantor_id = $params->{guarantor_id};
1836     my $relationship = $params->{relationship};
1837
1838     return Koha::Patron::Relationship->new(
1839         {
1840             guarantee_id => $self->id,
1841             guarantor_id => $guarantor_id,
1842             relationship => $relationship
1843         }
1844     )->store();
1845 }
1846
1847 =head3 get_extended_attribute
1848
1849 my $attribute_value = $patron->get_extended_attribute( $code );
1850
1851 Return the attribute for the code passed in parameter.
1852
1853 It not exist it returns undef
1854
1855 Note that this will not work for repeatable attribute types.
1856
1857 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1858 (which should be a real patron's attribute (not extended)
1859
1860 =cut
1861
1862 sub get_extended_attribute {
1863     my ( $self, $code, $value ) = @_;
1864     my $rs = $self->_result->borrower_attributes;
1865     return unless $rs;
1866     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1867     return unless $attribute->count;
1868     return $attribute->next;
1869 }
1870
1871 =head3 to_api
1872
1873     my $json = $patron->to_api;
1874
1875 Overloaded method that returns a JSON representation of the Koha::Patron object,
1876 suitable for API output.
1877
1878 =cut
1879
1880 sub to_api {
1881     my ( $self, $params ) = @_;
1882
1883     my $json_patron = $self->SUPER::to_api( $params );
1884
1885     $json_patron->{restricted} = ( $self->is_debarred )
1886                                     ? Mojo::JSON->true
1887                                     : Mojo::JSON->false;
1888
1889     return $json_patron;
1890 }
1891
1892 =head3 to_api_mapping
1893
1894 This method returns the mapping for representing a Koha::Patron object
1895 on the API.
1896
1897 =cut
1898
1899 sub to_api_mapping {
1900     return {
1901         borrowernotes       => 'staff_notes',
1902         borrowernumber      => 'patron_id',
1903         branchcode          => 'library_id',
1904         categorycode        => 'category_id',
1905         checkprevcheckout   => 'check_previous_checkout',
1906         contactfirstname    => undef,                     # Unused
1907         contactname         => undef,                     # Unused
1908         contactnote         => 'altaddress_notes',
1909         contacttitle        => undef,                     # Unused
1910         dateenrolled        => 'date_enrolled',
1911         dateexpiry          => 'expiry_date',
1912         dateofbirth         => 'date_of_birth',
1913         debarred            => undef,                     # replaced by 'restricted'
1914         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1915         emailpro            => 'secondary_email',
1916         flags               => undef,    # permissions manipulation handled in /permissions
1917         gonenoaddress       => 'incorrect_address',
1918         lastseen            => 'last_seen',
1919         lost                => 'patron_card_lost',
1920         opacnote            => 'opac_notes',
1921         othernames          => 'other_name',
1922         password            => undef,            # password manipulation handled in /password
1923         phonepro            => 'secondary_phone',
1924         relationship        => 'relationship_type',
1925         sex                 => 'gender',
1926         smsalertnumber      => 'sms_number',
1927         sort1               => 'statistics_1',
1928         sort2               => 'statistics_2',
1929         autorenew_checkouts => 'autorenew_checkouts',
1930         streetnumber        => 'street_number',
1931         streettype          => 'street_type',
1932         zipcode             => 'postal_code',
1933         B_address           => 'altaddress_address',
1934         B_address2          => 'altaddress_address2',
1935         B_city              => 'altaddress_city',
1936         B_country           => 'altaddress_country',
1937         B_email             => 'altaddress_email',
1938         B_phone             => 'altaddress_phone',
1939         B_state             => 'altaddress_state',
1940         B_streetnumber      => 'altaddress_street_number',
1941         B_streettype        => 'altaddress_street_type',
1942         B_zipcode           => 'altaddress_postal_code',
1943         altcontactaddress1  => 'altcontact_address',
1944         altcontactaddress2  => 'altcontact_address2',
1945         altcontactaddress3  => 'altcontact_city',
1946         altcontactcountry   => 'altcontact_country',
1947         altcontactfirstname => 'altcontact_firstname',
1948         altcontactphone     => 'altcontact_phone',
1949         altcontactsurname   => 'altcontact_surname',
1950         altcontactstate     => 'altcontact_state',
1951         altcontactzipcode   => 'altcontact_postal_code',
1952         password_expiration_date => undef,
1953         primary_contact_method => undef,
1954         secret              => undef,
1955         auth_method         => undef,
1956     };
1957 }
1958
1959 =head3 queue_notice
1960
1961     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
1962     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
1963     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
1964
1965     Queue messages to a patron. Can pass a message that is part of the message_attributes
1966     table or supply the transport to use.
1967
1968     If passed a message name we retrieve the patrons preferences for transports
1969     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
1970     we have no address/number for sending
1971
1972     $letter_params is a hashref of the values to be passed to GetPreparedLetter
1973
1974     test_mode will only report which notices would be sent, but nothing will be queued
1975
1976 =cut
1977
1978 sub queue_notice {
1979     my ( $self, $params ) = @_;
1980     my $letter_params = $params->{letter_params};
1981     my $test_mode = $params->{test_mode};
1982
1983     return unless $letter_params;
1984     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
1985
1986     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
1987     my $from_email_address = $library->from_email_address;
1988
1989     my @message_transports;
1990     my $letter_code;
1991     $letter_code = $letter_params->{letter_code};
1992     if( $params->{message_name} ){
1993         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
1994                 borrowernumber => $letter_params->{borrowernumber},
1995                 message_name => $params->{message_name}
1996         } );
1997         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
1998         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
1999     } else {
2000         @message_transports = @{$params->{message_transports}};
2001     }
2002     return unless defined $letter_code;
2003     $letter_params->{letter_code} = $letter_code;
2004     my $print_sent = 0;
2005     my %return;
2006     foreach my $mtt (@message_transports){
2007         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2008         # Notice is handled by TalkingTech_itiva_outbound.pl
2009         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2010             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2011             or ( $mtt eq 'phone' and not $self->phone ) )
2012         {
2013             push @{ $return{fallback} }, $mtt;
2014             $mtt = 'print';
2015         }
2016         next if $mtt eq 'print' && $print_sent;
2017         $letter_params->{message_transport_type} = $mtt;
2018         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2019         C4::Letters::EnqueueLetter({
2020             letter => $letter,
2021             borrowernumber => $self->borrowernumber,
2022             from_address   => $from_email_address,
2023             message_transport_type => $mtt
2024         }) unless $test_mode;
2025         push @{$return{sent}}, $mtt;
2026         $print_sent = 1 if $mtt eq 'print';
2027     }
2028     return \%return;
2029 }
2030
2031 =head3 safe_to_delete
2032
2033     my $result = $patron->safe_to_delete;
2034     if ( $result eq 'has_guarantees' ) { ... }
2035     elsif ( $result ) { ... }
2036     else { # cannot delete }
2037
2038 This method tells if the Koha:Patron object can be deleted. Possible return values
2039
2040 =over 4
2041
2042 =item 'ok'
2043
2044 =item 'has_checkouts'
2045
2046 =item 'has_debt'
2047
2048 =item 'has_guarantees'
2049
2050 =item 'is_anonymous_patron'
2051
2052 =back
2053
2054 =cut
2055
2056 sub safe_to_delete {
2057     my ($self) = @_;
2058
2059     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2060
2061     my $error;
2062
2063     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2064         $error = 'is_anonymous_patron';
2065     }
2066     elsif ( $self->checkouts->count ) {
2067         $error = 'has_checkouts';
2068     }
2069     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2070         $error = 'has_debt';
2071     }
2072     elsif ( $self->guarantee_relationships->count ) {
2073         $error = 'has_guarantees';
2074     }
2075
2076     if ( $error ) {
2077         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2078     }
2079
2080     return Koha::Result::Boolean->new(1);
2081 }
2082
2083 =head3 recalls
2084
2085     my $recalls = $patron->recalls;
2086
2087 Return the patron's recalls.
2088
2089 =cut
2090
2091 sub recalls {
2092     my ( $self ) = @_;
2093
2094     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2095 }
2096
2097 =head3 account_balance
2098
2099     my $balance = $patron->account_balance
2100
2101 Return the patron's account balance
2102
2103 =cut
2104
2105 sub account_balance {
2106     my ($self) = @_;
2107     return $self->account->balance;
2108 }
2109
2110
2111 =head3 has_messaging_preference
2112
2113 my $bool = $patron->has_messaging_preference({
2114     message_name => $message_name, # A value from message_attributes.message_name
2115     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2116     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2117 });
2118
2119 =cut
2120
2121 sub has_messaging_preference {
2122     my ( $self, $params ) = @_;
2123
2124     my $message_name           = $params->{message_name};
2125     my $message_transport_type = $params->{message_transport_type};
2126     my $wants_digest           = $params->{wants_digest};
2127
2128     return $self->_result->search_related_rs(
2129         'borrower_message_preferences',
2130         $params,
2131         {
2132             prefetch =>
2133               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2134         }
2135     )->count;
2136 }
2137
2138 =head3 can_patron_change_staff_only_lists
2139
2140 $patron->can_patron_change_staff_only_lists;
2141
2142 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2143 Otherwise, return 0.
2144
2145 =cut
2146
2147 sub can_patron_change_staff_only_lists {
2148     my ( $self, $params ) = @_;
2149     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2150     return 0;
2151 }
2152
2153 =head3 encode_secret
2154
2155   $patron->encode_secret($secret32);
2156
2157 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2158 You still need to call ->store.
2159
2160 =cut
2161
2162 sub encode_secret {
2163     my ( $self, $secret ) = @_;
2164     if( $secret ) {
2165         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2166     }
2167     return $self->secret($secret);
2168 }
2169
2170 =head3 decoded_secret
2171
2172   my $secret32 = $patron->decoded_secret;
2173
2174 Decode the patron secret. We expect to get back a base32 string, but this
2175 is not checked here. Caller of encode_secret is responsible for that.
2176
2177 =cut
2178
2179 sub decoded_secret {
2180     my ( $self ) = @_;
2181     if( $self->secret ) {
2182         return Koha::Encryption->new->decrypt_hex( $self->secret );
2183     }
2184     return $self->secret;
2185 }
2186
2187 =head2 Internal methods
2188
2189 =head3 _type
2190
2191 =cut
2192
2193 sub _type {
2194     return 'Borrower';
2195 }
2196
2197 =head1 AUTHORS
2198
2199 Kyle M Hall <kyle@bywatersolutions.com>
2200 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2201 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2202
2203 =cut
2204
2205 1;