Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Log qw( logaction );
  30 use Koha::Account;
  31 use Koha::ArticleRequests;
  32 use C4::Letters;
  33 use Koha::AuthUtils;
  34 use Koha::Checkouts;
  35 use Koha::CirculationRules;
  36 use Koha::Club::Enrollments;
  37 use Koha::Database;
  38 use Koha::DateUtils qw( dt_from_string );
  39 use Koha::Encryption;
  40 use Koha::Exceptions::Password;
  41 use Koha::Holds;
  42 use Koha::Old::Checkouts;
  43 use Koha::Patron::Attributes;
  44 use Koha::Patron::Categories;
  45 use Koha::Patron::Debarments;
  46 use Koha::Patron::HouseboundProfile;
  47 use Koha::Patron::HouseboundRole;
  48 use Koha::Patron::Images;
  49 use Koha::Patron::Messages;
  50 use Koha::Patron::Modifications;
  51 use Koha::Patron::Relationships;
  52 use Koha::Patrons;
  53 use Koha::Plugins;
  54 use Koha::Recalls;
  55 use Koha::Result::Boolean;
  56 use Koha::Subscription::Routinglists;
  57 use Koha::Token;
  58 use Koha::Virtualshelves;
  59
  60 use base qw(Koha::Object);
  61
  62 use constant ADMINISTRATIVE_LOCKOUT => -1;
  63
  64 our $RESULTSET_PATRON_ID_MAPPING = {
  65     Accountline          => 'borrowernumber',
  66     Aqbasketuser         => 'borrowernumber',
  67     Aqbudget             => 'budget_owner_id',
  68     Aqbudgetborrower     => 'borrowernumber',
  69     ArticleRequest       => 'borrowernumber',
  70     BorrowerDebarment    => 'borrowernumber',
  71     BorrowerFile         => 'borrowernumber',
  72     BorrowerModification => 'borrowernumber',
  73     ClubEnrollment       => 'borrowernumber',
  74     Issue                => 'borrowernumber',
  75     ItemsLastBorrower    => 'borrowernumber',
  76     Linktracker          => 'borrowernumber',
  77     Message              => 'borrowernumber',
  78     MessageQueue         => 'borrowernumber',
  79     OldIssue             => 'borrowernumber',
  80     OldReserve           => 'borrowernumber',
  81     Rating               => 'borrowernumber',
  82     Reserve              => 'borrowernumber',
  83     Review               => 'borrowernumber',
  84     SearchHistory        => 'userid',
  85     Statistic            => 'borrowernumber',
  86     Suggestion           => 'suggestedby',
  87     TagAll               => 'borrowernumber',
  88     Virtualshelfcontent  => 'borrowernumber',
  89     Virtualshelfshare    => 'borrowernumber',
  90     Virtualshelve        => 'owner',
  91 };
  92
  93 =head1 NAME
  94
  95 Koha::Patron - Koha Patron Object class
  96
  97 =head1 API
  98
  99 =head2 Class Methods
 100
 101 =head3 new
 102
 103 =cut
 104
 105 sub new {
 106     my ( $class, $params ) = @_;
 107
 108     return $class->SUPER::new($params);
 109 }
 110
 111 =head3 fixup_cardnumber
 112
 113 Autogenerate next cardnumber from highest value found in database
 114
 115 =cut
 116
 117 sub fixup_cardnumber {
 118     my ( $self ) = @_;
 119
 120     my $max = $self->cardnumber;
 121     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 122
 123     $max ||= Koha::Patrons->search({
 124         cardnumber => {-regexp => '^-?[0-9]+$'}
 125     }, {
 126         select => \'CAST(cardnumber AS SIGNED)',
 127         as => ['cast_cardnumber']
 128     })->_resultset->get_column('cast_cardnumber')->max;
 129     $self->cardnumber(($max || 0) +1);
 130 }
 131
 132 =head3 trim_whitespace
 133
 134 trim whitespace from data which has some non-whitespace in it.
 135 Could be moved to Koha::Object if need to be reused
 136
 137 =cut
 138
 139 sub trim_whitespaces {
 140     my( $self ) = @_;
 141
 142     my $schema  = Koha::Database->new->schema;
 143     my @columns = $schema->source($self->_type)->columns;
 144
 145     for my $column( @columns ) {
 146         my $value = $self->$column;
 147         if ( defined $value ) {
 148             $value =~ s/^\s*|\s*$//g;
 149             $self->$column($value);
 150         }
 151     }
 152     return $self;
 153 }
 154
 155 =head3 plain_text_password
 156
 157 $patron->plain_text_password( $password );
 158
 159 stores a copy of the unencrypted password in the object
 160 for use in code before encrypting for db
 161
 162 =cut
 163
 164 sub plain_text_password {
 165     my ( $self, $password ) = @_;
 166     if ( $password ) {
 167         $self->{_plain_text_password} = $password;
 168         return $self;
 169     }
 170     return $self->{_plain_text_password}
 171         if $self->{_plain_text_password};
 172
 173     return;
 174 }
 175
 176 =head3 store
 177
 178 Patron specific store method to cleanup record
 179 and do other necessary things before saving
 180 to db
 181
 182 =cut
 183
 184 sub store {
 185     my ($self) = @_;
 186
 187     $self->_result->result_source->schema->txn_do(
 188         sub {
 189             if (
 190                 C4::Context->preference("autoMemberNum")
 191                 and ( not defined $self->cardnumber
 192                     or $self->cardnumber eq '' )
 193               )
 194             {
 195                 # Warning: The caller is responsible for locking the members table in write
 196                 # mode, to avoid database corruption.
 197                 # We are in a transaction but the table is not locked
 198                 $self->fixup_cardnumber;
 199             }
 200
 201             unless( $self->category->in_storage ) {
 202                 Koha::Exceptions::Object::FKConstraint->throw(
 203                     broken_fk => 'categorycode',
 204                     value     => $self->categorycode,
 205                 );
 206             }
 207
 208             $self->trim_whitespaces;
 209
 210             my $new_cardnumber = $self->cardnumber;
 211             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 212             $self->cardnumber( $new_cardnumber );
 213
 214             # Set surname to uppercase if uppercasesurname is true
 215             $self->surname( uc($self->surname) )
 216                 if C4::Context->preference("uppercasesurnames");
 217
 218             $self->relationship(undef) # We do not want to store an empty string in this field
 219               if defined $self->relationship
 220                      and $self->relationship eq "";
 221
 222             unless ( $self->in_storage ) {    #AddMember
 223
 224                 # Generate a valid userid/login if needed
 225                 $self->generate_userid
 226                   if not $self->userid or not $self->has_valid_userid;
 227
 228                 # Add expiration date if it isn't already there
 229                 unless ( $self->dateexpiry ) {
 230                     $self->dateexpiry( $self->category->get_expiry_date );
 231                 }
 232
 233                 # Add enrollment date if it isn't already there
 234                 unless ( $self->dateenrolled ) {
 235                     $self->dateenrolled(dt_from_string);
 236                 }
 237
 238                 # Set the privacy depending on the patron's category
 239                 my $default_privacy = $self->category->default_privacy || q{};
 240                 $default_privacy =
 241                     $default_privacy eq 'default' ? 1
 242                   : $default_privacy eq 'never'   ? 2
 243                   : $default_privacy eq 'forever' ? 0
 244                   :                                                   undef;
 245                 $self->privacy($default_privacy);
 246
 247                 # Call any check_password plugins if password is passed
 248                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 249                     my @plugins = Koha::Plugins->new()->GetPlugins({
 250                         method => 'check_password',
 251                     });
 252                     foreach my $plugin ( @plugins ) {
 253                         # This plugin hook will also be used by a plugin for the Norwegian national
 254                         # patron database. This is why we need to pass both the password and the
 255                         # borrowernumber to the plugin.
 256                         my $ret = $plugin->check_password(
 257                             {
 258                                 password       => $self->password,
 259                                 borrowernumber => $self->borrowernumber
 260                             }
 261                         );
 262                         if ( $ret->{'error'} == 1 ) {
 263                             Koha::Exceptions::Password::Plugin->throw();
 264                         }
 265                     }
 266                 }
 267
 268                 # Make a copy of the plain text password for later use
 269                 $self->plain_text_password( $self->password );
 270
 271                 $self->password_expiration_date( $self->password
 272                     ? $self->category->get_password_expiry_date || undef
 273                     : undef );
 274                 # Create a disabled account if no password provided
 275                 $self->password( $self->password
 276                     ? Koha::AuthUtils::hash_password( $self->password )
 277                     : '!' );
 278
 279                 $self->borrowernumber(undef);
 280
 281                 $self = $self->SUPER::store;
 282
 283                 $self->add_enrolment_fee_if_needed(0);
 284
 285                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 286                   if C4::Context->preference("BorrowersLog");
 287             }
 288             else {    #ModMember
 289
 290                 my $self_from_storage = $self->get_from_storage;
 291                 # FIXME We should not deal with that here, callers have to do this job
 292                 # Moved from ModMember to prevent regressions
 293                 unless ( $self->userid ) {
 294                     my $stored_userid = $self_from_storage->userid;
 295                     $self->userid($stored_userid);
 296                 }
 297
 298                 # Password must be updated using $self->set_password
 299                 $self->password($self_from_storage->password);
 300
 301                 if ( $self->category->categorycode ne
 302                     $self_from_storage->category->categorycode )
 303                 {
 304                     # Add enrolement fee on category change if required
 305                     $self->add_enrolment_fee_if_needed(1)
 306                       if C4::Context->preference('FeeOnChangePatronCategory');
 307
 308                     # Clean up guarantors on category change if required
 309                     $self->guarantor_relationships->delete
 310                       if ( $self->category->category_type ne 'C'
 311                         && $self->category->category_type ne 'P' );
 312
 313                 }
 314
 315                 # Actionlogs
 316                 if ( C4::Context->preference("BorrowersLog") ) {
 317                     my $info;
 318                     my $from_storage = $self_from_storage->unblessed;
 319                     my $from_object  = $self->unblessed;
 320                     my @skip_fields  = (qw/lastseen updated_on/);
 321                     for my $key ( keys %{$from_storage} ) {
 322                         next if any { /$key/ } @skip_fields;
 323                         if (
 324                             (
 325                                   !defined( $from_storage->{$key} )
 326                                 && defined( $from_object->{$key} )
 327                             )
 328                             || ( defined( $from_storage->{$key} )
 329                                 && !defined( $from_object->{$key} ) )
 330                             || (
 331                                    defined( $from_storage->{$key} )
 332                                 && defined( $from_object->{$key} )
 333                                 && ( $from_storage->{$key} ne
 334                                     $from_object->{$key} )
 335                             )
 336                           )
 337                         {
 338                             $info->{$key} = {
 339                                 before => $from_storage->{$key},
 340                                 after  => $from_object->{$key}
 341                             };
 342                         }
 343                     }
 344
 345                     if ( defined($info) ) {
 346                         logaction(
 347                             "MEMBERS",
 348                             "MODIFY",
 349                             $self->borrowernumber,
 350                             to_json(
 351                                 $info,
 352                                 { utf8 => 1, pretty => 1, canonical => 1 }
 353                             )
 354                         );
 355                     }
 356                 }
 357
 358                 # Final store
 359                 $self = $self->SUPER::store;
 360             }
 361         }
 362     );
 363     return $self;
 364 }
 365
 366 =head3 delete
 367
 368 $patron->delete
 369
 370 Delete patron's holds, lists and finally the patron.
 371
 372 Lists owned by the borrower are deleted, but entries from the borrower to
 373 other lists are kept.
 374
 375 =cut
 376
 377 sub delete {
 378     my ($self) = @_;
 379
 380     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 381     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 382
 383     $self->_result->result_source->schema->txn_do(
 384         sub {
 385             # Cancel Patron's holds
 386             my $holds = $self->holds;
 387             while( my $hold = $holds->next ){
 388                 $hold->cancel;
 389             }
 390
 391             # Delete all lists and all shares of this borrower
 392             # Consistent with the approach Koha uses on deleting individual lists
 393             # Note that entries in virtualshelfcontents added by this borrower to
 394             # lists of others will be handled by a table constraint: the borrower
 395             # is set to NULL in those entries.
 396             # NOTE:
 397             # We could handle the above deletes via a constraint too.
 398             # But a new BZ report 11889 has been opened to discuss another approach.
 399             # Instead of deleting we could also disown lists (based on a pref).
 400             # In that way we could save shared and public lists.
 401             # The current table constraints support that idea now.
 402             # This pref should then govern the results of other routines/methods such as
 403             # Koha::Virtualshelf->new->delete too.
 404             # FIXME Could be $patron->get_lists
 405             $_->delete for Koha::Virtualshelves->search( { owner => $self->borrowernumber } )->as_list;
 406
 407             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 408             # for patron selfreg
 409             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 410
 411             $self->SUPER::delete;
 412
 413             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 414         }
 415     );
 416     return $self;
 417 }
 418
 419
 420 =head3 category
 421
 422 my $patron_category = $patron->category
 423
 424 Return the patron category for this patron
 425
 426 =cut
 427
 428 sub category {
 429     my ( $self ) = @_;
 430     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 431 }
 432
 433 =head3 image
 434
 435 =cut
 436
 437 sub image {
 438     my ( $self ) = @_;
 439
 440     return Koha::Patron::Images->find( $self->borrowernumber );
 441 }
 442
 443 =head3 library
 444
 445 Returns a Koha::Library object representing the patron's home library.
 446
 447 =cut
 448
 449 sub library {
 450     my ( $self ) = @_;
 451     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 452 }
 453
 454 =head3 sms_provider
 455
 456 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 457
 458 =cut
 459
 460 sub sms_provider {
 461     my ( $self ) = @_;
 462     my $sms_provider_rs = $self->_result->sms_provider;
 463     return unless $sms_provider_rs;
 464     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 465 }
 466
 467 =head3 guarantor_relationships
 468
 469 Returns Koha::Patron::Relationships object for this patron's guarantors
 470
 471 Returns the set of relationships for the patrons that are guarantors for this patron.
 472
 473 This is returned instead of a Koha::Patron object because the guarantor
 474 may not exist as a patron in Koha. If this is true, the guarantors name
 475 exists in the Koha::Patron::Relationship object and will have no guarantor_id.
 476
 477 =cut
 478
 479 sub guarantor_relationships {
 480     my ($self) = @_;
 481
 482     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 483 }
 484
 485 =head3 guarantee_relationships
 486
 487 Returns Koha::Patron::Relationships object for this patron's guarantors
 488
 489 Returns the set of relationships for the patrons that are guarantees for this patron.
 490
 491 The method returns Koha::Patron::Relationship objects for the sake
 492 of consistency with the guantors method.
 493 A guarantee by definition must exist as a patron in Koha.
 494
 495 =cut
 496
 497 sub guarantee_relationships {
 498     my ($self) = @_;
 499
 500     return Koha::Patron::Relationships->search(
 501         { guarantor_id => $self->id },
 502         {
 503             prefetch => 'guarantee',
 504             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 505         }
 506     );
 507 }
 508
 509 =head3 relationships_debt
 510
 511 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 512
 513 =cut
 514
 515 sub relationships_debt {
 516     my ($self, $params) = @_;
 517
 518     my $include_guarantors  = $params->{include_guarantors};
 519     my $only_this_guarantor = $params->{only_this_guarantor};
 520     my $include_this_patron = $params->{include_this_patron};
 521
 522     my @guarantors;
 523     if ( $only_this_guarantor ) {
 524         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 525         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 526     } elsif ( $self->guarantor_relationships->count ) {
 527         # I am a guarantee, just get all my guarantors
 528         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 529     } else {
 530         # I am a guarantor, I need to get all the guarantors of all my guarantees
 531         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 532     }
 533
 534     my $non_issues_charges = 0;
 535     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 536     foreach my $guarantor (@guarantors) {
 537         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 538
 539         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 540         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 541         my $guarantees_non_issues_charges = 0;
 542         foreach my $guarantee (@guarantees) {
 543             next if $seen->{ $guarantee->id };
 544             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 545             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 546             $seen->{ $guarantee->id } = 1;
 547         }
 548
 549         $non_issues_charges += $guarantees_non_issues_charges;
 550         $seen->{ $guarantor->id } = 1;
 551     }
 552
 553     return $non_issues_charges;
 554 }
 555
 556 =head3 housebound_profile
 557
 558 Returns the HouseboundProfile associated with this patron.
 559
 560 =cut
 561
 562 sub housebound_profile {
 563     my ( $self ) = @_;
 564     my $profile = $self->_result->housebound_profile;
 565     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 566         if ( $profile );
 567     return;
 568 }
 569
 570 =head3 housebound_role
 571
 572 Returns the HouseboundRole associated with this patron.
 573
 574 =cut
 575
 576 sub housebound_role {
 577     my ( $self ) = @_;
 578
 579     my $role = $self->_result->housebound_role;
 580     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 581     return;
 582 }
 583
 584 =head3 siblings
 585
 586 Returns the siblings of this patron.
 587
 588 =cut
 589
 590 sub siblings {
 591     my ($self) = @_;
 592
 593     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 594
 595     return unless @guarantors;
 596
 597     my @siblings =
 598       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 599
 600     return unless @siblings;
 601
 602     my %seen;
 603     @siblings =
 604       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 605
 606     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 607 }
 608
 609 =head3 merge_with
 610
 611     my $patron = Koha::Patrons->find($id);
 612     $patron->merge_with( \@patron_ids );
 613
 614     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 615     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 616     of the keeper patron.
 617
 618 =cut
 619
 620 sub merge_with {
 621     my ( $self, $patron_ids ) = @_;
 622
 623     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 624     return if $anonymous_patron && $self->id eq $anonymous_patron;
 625
 626     my @patron_ids = @{ $patron_ids };
 627
 628     # Ensure the keeper isn't in the list of patrons to merge
 629     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 630
 631     my $schema = Koha::Database->new()->schema();
 632
 633     my $results;
 634
 635     $self->_result->result_source->schema->txn_do( sub {
 636         foreach my $patron_id (@patron_ids) {
 637
 638             next if $patron_id eq $anonymous_patron;
 639
 640             my $patron = Koha::Patrons->find( $patron_id );
 641
 642             next unless $patron;
 643
 644             # Unbless for safety, the patron will end up being deleted
 645             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 646
 647             my $attributes = $patron->extended_attributes;
 648             my $new_attributes = [
 649                 map { { code => $_->code, attribute => $_->attribute } }
 650                     $attributes->as_list
 651             ];
 652             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 653             for my $attribute ( @$new_attributes ) {
 654                 try {
 655                     $self->add_extended_attribute($attribute);
 656                 } catch {
 657                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 658                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 659                         $_->rethrow;
 660                     }
 661                 };
 662             }
 663
 664             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 665                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 666                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 667                 $rs->update({ $field => $self->id });
 668                 if ( $r eq 'BorrowerDebarment' ) {
 669                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 670                 }
 671             }
 672
 673             $patron->move_to_deleted();
 674             $patron->delete();
 675         }
 676     });
 677
 678     return $results;
 679 }
 680
 681
 682
 683 =head3 wants_check_for_previous_checkout
 684
 685     $wants_check = $patron->wants_check_for_previous_checkout;
 686
 687 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 688
 689 =cut
 690
 691 sub wants_check_for_previous_checkout {
 692     my ( $self ) = @_;
 693     my $syspref = C4::Context->preference("checkPrevCheckout");
 694
 695     # Simple cases
 696     ## Hard syspref trumps all
 697     return 1 if ($syspref eq 'hardyes');
 698     return 0 if ($syspref eq 'hardno');
 699     ## Now, patron pref trumps all
 700     return 1 if ($self->checkprevcheckout eq 'yes');
 701     return 0 if ($self->checkprevcheckout eq 'no');
 702
 703     # More complex: patron inherits -> determine category preference
 704     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 705     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 706     return 0 if ($checkPrevCheckoutByCat eq 'no');
 707
 708     # Finally: category preference is inherit, default to 0
 709     if ($syspref eq 'softyes') {
 710         return 1;
 711     } else {
 712         return 0;
 713     }
 714 }
 715
 716 =head3 do_check_for_previous_checkout
 717
 718     $do_check = $patron->do_check_for_previous_checkout($item);
 719
 720 Return 1 if the bib associated with $ITEM has previously been checked out to
 721 $PATRON, 0 otherwise.
 722
 723 =cut
 724
 725 sub do_check_for_previous_checkout {
 726     my ( $self, $item ) = @_;
 727
 728     my @item_nos;
 729     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 730     if ( $biblio->is_serial ) {
 731         push @item_nos, $item->{itemnumber};
 732     } else {
 733         # Get all itemnumbers for given bibliographic record.
 734         @item_nos = $biblio->items->get_column( 'itemnumber' );
 735     }
 736
 737     # Create (old)issues search criteria
 738     my $criteria = {
 739         borrowernumber => $self->borrowernumber,
 740         itemnumber => \@item_nos,
 741     };
 742
 743     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 744     if ($delay) {
 745         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 746         my $newer_than = dt_from_string()->subtract( days => $delay );
 747         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 748     }
 749
 750     # Check current issues table
 751     my $issues = Koha::Checkouts->search($criteria);
 752     return 1 if $issues->count; # 0 || N
 753
 754     # Check old issues table
 755     my $old_issues = Koha::Old::Checkouts->search($criteria);
 756     return $old_issues->count;  # 0 || N
 757 }
 758
 759 =head3 is_debarred
 760
 761 my $debarment_expiration = $patron->is_debarred;
 762
 763 Returns the date a patron debarment will expire, or undef if the patron is not
 764 debarred
 765
 766 =cut
 767
 768 sub is_debarred {
 769     my ($self) = @_;
 770
 771     return unless $self->debarred;
 772     return $self->debarred
 773       if $self->debarred =~ '^9999'
 774       or dt_from_string( $self->debarred ) > dt_from_string;
 775     return;
 776 }
 777
 778 =head3 is_expired
 779
 780 my $is_expired = $patron->is_expired;
 781
 782 Returns 1 if the patron is expired or 0;
 783
 784 =cut
 785
 786 sub is_expired {
 787     my ($self) = @_;
 788     return 0 unless $self->dateexpiry;
 789     return 0 if $self->dateexpiry =~ '^9999';
 790     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 791     return 0;
 792 }
 793
 794 =head3 password_expired
 795
 796 my $password_expired = $patron->password_expired;
 797
 798 Returns 1 if the patron's password is expired or 0;
 799
 800 =cut
 801
 802 sub password_expired {
 803     my ($self) = @_;
 804     return 0 unless $self->password_expiration_date;
 805     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 806     return 0;
 807 }
 808
 809 =head3 is_going_to_expire
 810
 811 my $is_going_to_expire = $patron->is_going_to_expire;
 812
 813 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 814
 815 =cut
 816
 817 sub is_going_to_expire {
 818     my ($self) = @_;
 819
 820     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 821
 822     return 0 unless $delay;
 823     return 0 unless $self->dateexpiry;
 824     return 0 if $self->dateexpiry =~ '^9999';
 825     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 826     return 0;
 827 }
 828
 829 =head3 set_password
 830
 831     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 832
 833 Set the patron's password.
 834
 835 =head4 Exceptions
 836
 837 The passed string is validated against the current password enforcement policy.
 838 Validation can be skipped by passing the I<skip_validation> parameter.
 839
 840 Exceptions are thrown if the password is not good enough.
 841
 842 =over 4
 843
 844 =item Koha::Exceptions::Password::TooShort
 845
 846 =item Koha::Exceptions::Password::WhitespaceCharacters
 847
 848 =item Koha::Exceptions::Password::TooWeak
 849
 850 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 851
 852 =back
 853
 854 =cut
 855
 856 sub set_password {
 857     my ( $self, $args ) = @_;
 858
 859     my $password = $args->{password};
 860
 861     unless ( $args->{skip_validation} ) {
 862         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 863
 864         if ( !$is_valid ) {
 865             if ( $error eq 'too_short' ) {
 866                 my $min_length = $self->category->effective_min_password_length;
 867                 $min_length = 3 if not $min_length or $min_length < 3;
 868
 869                 my $password_length = length($password);
 870                 Koha::Exceptions::Password::TooShort->throw(
 871                     length => $password_length, min_length => $min_length );
 872             }
 873             elsif ( $error eq 'has_whitespaces' ) {
 874                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 875             }
 876             elsif ( $error eq 'too_weak' ) {
 877                 Koha::Exceptions::Password::TooWeak->throw();
 878             }
 879         }
 880     }
 881
 882     if ( C4::Context->config("enable_plugins") ) {
 883         # Call any check_password plugins
 884         my @plugins = Koha::Plugins->new()->GetPlugins({
 885             method => 'check_password',
 886         });
 887         foreach my $plugin ( @plugins ) {
 888             # This plugin hook will also be used by a plugin for the Norwegian national
 889             # patron database. This is why we need to pass both the password and the
 890             # borrowernumber to the plugin.
 891             my $ret = $plugin->check_password(
 892                 {
 893                     password       => $password,
 894                     borrowernumber => $self->borrowernumber
 895                 }
 896             );
 897             # This plugin hook will also be used by a plugin for the Norwegian national
 898             # patron database. This is why we need to call the actual plugins and then
 899             # check skip_validation afterwards.
 900             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 901                 Koha::Exceptions::Password::Plugin->throw();
 902             }
 903         }
 904     }
 905
 906     my $digest = Koha::AuthUtils::hash_password($password);
 907
 908     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 909
 910     # We do not want to call $self->store and retrieve password from DB
 911     $self->password($digest);
 912     $self->login_attempts(0);
 913     $self->SUPER::store;
 914
 915     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 916         if C4::Context->preference("BorrowersLog");
 917
 918     return $self;
 919 }
 920
 921
 922 =head3 renew_account
 923
 924 my $new_expiry_date = $patron->renew_account
 925
 926 Extending the subscription to the expiry date.
 927
 928 =cut
 929
 930 sub renew_account {
 931     my ($self) = @_;
 932     my $date;
 933     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 934         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 935     } else {
 936         $date =
 937             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 938             ? dt_from_string( $self->dateexpiry )
 939             : dt_from_string;
 940     }
 941     my $expiry_date = $self->category->get_expiry_date($date);
 942
 943     $self->dateexpiry($expiry_date);
 944     $self->date_renewed( dt_from_string() );
 945     $self->store();
 946
 947     $self->add_enrolment_fee_if_needed(1);
 948
 949     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 950     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 951 }
 952
 953 =head3 has_overdues
 954
 955 my $has_overdues = $patron->has_overdues;
 956
 957 Returns the number of patron's overdues
 958
 959 =cut
 960
 961 sub has_overdues {
 962     my ($self) = @_;
 963     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 964     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
 965 }
 966
 967 =head3 track_login
 968
 969     $patron->track_login;
 970     $patron->track_login({ force => 1 });
 971
 972     Tracks a (successful) login attempt.
 973     The preference TrackLastPatronActivity must be enabled. Or you
 974     should pass the force parameter.
 975
 976 =cut
 977
 978 sub track_login {
 979     my ( $self, $params ) = @_;
 980     return if
 981         !$params->{force} &&
 982         !C4::Context->preference('TrackLastPatronActivity');
 983     $self->lastseen( dt_from_string() )->store;
 984 }
 985
 986 =head3 move_to_deleted
 987
 988 my $is_moved = $patron->move_to_deleted;
 989
 990 Move a patron to the deletedborrowers table.
 991 This can be done before deleting a patron, to make sure the data are not completely deleted.
 992
 993 =cut
 994
 995 sub move_to_deleted {
 996     my ($self) = @_;
 997     my $patron_infos = $self->unblessed;
 998     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
 999     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1000 }
1001
1002 =head3 can_request_article
1003
1004     if ( $patron->can_request_article( $library->id ) ) { ... }
1005
1006 Returns true if the patron can request articles. As limits apply for the patron
1007 on the same day, those completed the same day are considered as current.
1008
1009 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1010
1011 =cut
1012
1013 sub can_request_article {
1014     my ($self, $library_id) = @_;
1015
1016     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1017
1018     my $rule = Koha::CirculationRules->get_effective_rule(
1019         {
1020             branchcode   => $library_id,
1021             categorycode => $self->categorycode,
1022             rule_name    => 'open_article_requests_limit'
1023         }
1024     );
1025
1026     my $limit = ($rule) ? $rule->rule_value : undef;
1027
1028     return 1 unless defined $limit;
1029
1030     my $count = Koha::ArticleRequests->search(
1031         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1032             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1033         ]
1034     )->count;
1035     return $count < $limit ? 1 : 0;
1036 }
1037
1038 =head3 article_request_fee
1039
1040     my $fee = $patron->article_request_fee(
1041         {
1042           [ library_id => $library->id, ]
1043         }
1044     );
1045
1046 Returns the fee to be charged to the patron when it places an article request.
1047
1048 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1049
1050 =cut
1051
1052 sub article_request_fee {
1053     my ($self, $params) = @_;
1054
1055     my $library_id = $params->{library_id};
1056
1057     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1058
1059     my $rule = Koha::CirculationRules->get_effective_rule(
1060         {
1061             branchcode   => $library_id,
1062             categorycode => $self->categorycode,
1063             rule_name    => 'article_request_fee'
1064         }
1065     );
1066
1067     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1068
1069     return $fee;
1070 }
1071
1072 =head3 add_article_request_fee_if_needed
1073
1074     my $fee = $patron->add_article_request_fee_if_needed(
1075         {
1076           [ item_id    => $item->id,
1077             library_id => $library->id, ]
1078         }
1079     );
1080
1081 If an article request fee needs to be charged, it adds a debit to the patron's
1082 account.
1083
1084 Returns the fee line.
1085
1086 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1087
1088 =cut
1089
1090 sub add_article_request_fee_if_needed {
1091     my ($self, $params) = @_;
1092
1093     my $library_id = $params->{library_id};
1094     my $item_id    = $params->{item_id};
1095
1096     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1097
1098     my $amount = $self->article_request_fee(
1099         {
1100             library_id => $library_id,
1101         }
1102     );
1103
1104     my $debit_line;
1105
1106     if ( $amount > 0 ) {
1107         $debit_line = $self->account->add_debit(
1108             {
1109                 amount     => $amount,
1110                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1111                 interface  => C4::Context->interface,
1112                 library_id => $library_id,
1113                 type       => 'ARTICLE_REQUEST',
1114                 item_id    => $item_id,
1115             }
1116         );
1117     }
1118
1119     return $debit_line;
1120 }
1121
1122 =head3 article_requests
1123
1124     my $article_requests = $patron->article_requests;
1125
1126 Returns the patron article requests.
1127
1128 =cut
1129
1130 sub article_requests {
1131     my ($self) = @_;
1132
1133     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1134 }
1135
1136 =head3 add_enrolment_fee_if_needed
1137
1138 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1139
1140 Add enrolment fee for a patron if needed.
1141
1142 $renewal - boolean denoting whether this is an account renewal or not
1143
1144 =cut
1145
1146 sub add_enrolment_fee_if_needed {
1147     my ($self, $renewal) = @_;
1148     my $enrolment_fee = $self->category->enrolmentfee;
1149     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1150         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1151         $self->account->add_debit(
1152             {
1153                 amount     => $enrolment_fee,
1154                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1155                 interface  => C4::Context->interface,
1156                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1157                 type       => $type
1158             }
1159         );
1160     }
1161     return $enrolment_fee || 0;
1162 }
1163
1164 =head3 checkouts
1165
1166 my $checkouts = $patron->checkouts
1167
1168 =cut
1169
1170 sub checkouts {
1171     my ($self) = @_;
1172     my $checkouts = $self->_result->issues;
1173     return Koha::Checkouts->_new_from_dbic( $checkouts );
1174 }
1175
1176 =head3 pending_checkouts
1177
1178 my $pending_checkouts = $patron->pending_checkouts
1179
1180 This method will return the same as $self->checkouts, but with a prefetch on
1181 items, biblio and biblioitems.
1182
1183 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1184
1185 It should not be used directly, prefer to access fields you need instead of
1186 retrieving all these fields in one go.
1187
1188 =cut
1189
1190 sub pending_checkouts {
1191     my( $self ) = @_;
1192     my $checkouts = $self->_result->issues->search(
1193         {},
1194         {
1195             order_by => [
1196                 { -desc => 'me.timestamp' },
1197                 { -desc => 'issuedate' },
1198                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1199             ],
1200             prefetch => { item => { biblio => 'biblioitems' } },
1201         }
1202     );
1203     return Koha::Checkouts->_new_from_dbic( $checkouts );
1204 }
1205
1206 =head3 old_checkouts
1207
1208 my $old_checkouts = $patron->old_checkouts
1209
1210 =cut
1211
1212 sub old_checkouts {
1213     my ($self) = @_;
1214     my $old_checkouts = $self->_result->old_issues;
1215     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1216 }
1217
1218 =head3 get_overdues
1219
1220 my $overdue_items = $patron->get_overdues
1221
1222 Return the overdue items
1223
1224 =cut
1225
1226 sub get_overdues {
1227     my ($self) = @_;
1228     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1229     return $self->checkouts->search(
1230         {
1231             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1232         },
1233         {
1234             prefetch => { item => { biblio => 'biblioitems' } },
1235         }
1236     );
1237 }
1238
1239 sub overdues { my $self = shift; return $self->get_overdues(@_); }
1240
1241 =head3 get_routing_lists
1242
1243 my $routinglists = $patron->get_routing_lists
1244
1245 Returns the routing lists a patron is subscribed to.
1246
1247 =cut
1248
1249 sub get_routing_lists {
1250     my ($self) = @_;
1251     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1252     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1253 }
1254
1255 =head3 get_age
1256
1257     my $age = $patron->get_age
1258
1259 Return the age of the patron
1260
1261 =cut
1262
1263 sub get_age {
1264     my ($self)    = @_;
1265
1266     return unless $self->dateofbirth;
1267
1268     my $date_of_birth = dt_from_string( $self->dateofbirth );
1269     my $today         = dt_from_string->truncate( to => 'day' );
1270
1271     return $today->subtract_datetime( $date_of_birth )->years;
1272 }
1273
1274 =head3 is_valid_age
1275
1276 my $is_valid = $patron->is_valid_age
1277
1278 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1279
1280 =cut
1281
1282 sub is_valid_age {
1283     my ($self) = @_;
1284     my $age = $self->get_age;
1285
1286     my $patroncategory = $self->category;
1287     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1288
1289     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1290 }
1291
1292 =head3 account
1293
1294 my $account = $patron->account
1295
1296 =cut
1297
1298 sub account {
1299     my ($self) = @_;
1300     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1301 }
1302
1303 =head3 holds
1304
1305 my $holds = $patron->holds
1306
1307 Return all the holds placed by this patron
1308
1309 =cut
1310
1311 sub holds {
1312     my ($self) = @_;
1313     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1314     return Koha::Holds->_new_from_dbic($holds_rs);
1315 }
1316
1317 =head3 old_holds
1318
1319 my $old_holds = $patron->old_holds
1320
1321 Return all the historical holds for this patron
1322
1323 =cut
1324
1325 sub old_holds {
1326     my ($self) = @_;
1327     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1328     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1329 }
1330
1331 =head3 return_claims
1332
1333 my $return_claims = $patron->return_claims
1334
1335 =cut
1336
1337 sub return_claims {
1338     my ($self) = @_;
1339     my $return_claims = $self->_result->return_claims_borrowernumbers;
1340     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1341 }
1342
1343 =head3 notice_email_address
1344
1345   my $email = $patron->notice_email_address;
1346
1347 Return the email address of patron used for notices.
1348 Returns the empty string if no email address.
1349
1350 =cut
1351
1352 sub notice_email_address{
1353     my ( $self ) = @_;
1354
1355     my $which_address = C4::Context->preference("AutoEmailPrimaryAddress");
1356     # if syspref is set to 'first valid' (value == OFF), look up email address
1357     if ( $which_address eq 'OFF' ) {
1358         return $self->first_valid_email_address;
1359     }
1360
1361     return $self->$which_address || '';
1362 }
1363
1364 =head3 first_valid_email_address
1365
1366 my $first_valid_email_address = $patron->first_valid_email_address
1367
1368 Return the first valid email address for a patron.
1369 For now, the order  is defined as email, emailpro, B_email.
1370 Returns the empty string if the borrower has no email addresses.
1371
1372 =cut
1373
1374 sub first_valid_email_address {
1375     my ($self) = @_;
1376
1377     return $self->email() || $self->emailpro() || $self->B_email() || q{};
1378 }
1379
1380 =head3 get_club_enrollments
1381
1382 =cut
1383
1384 sub get_club_enrollments {
1385     my ( $self ) = @_;
1386
1387     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1388 }
1389
1390 =head3 get_enrollable_clubs
1391
1392 =cut
1393
1394 sub get_enrollable_clubs {
1395     my ( $self, $is_enrollable_from_opac ) = @_;
1396
1397     my $params;
1398     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1399       if $is_enrollable_from_opac;
1400     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1401
1402     $params->{borrower} = $self;
1403
1404     return Koha::Clubs->get_enrollable($params);
1405 }
1406
1407 =head3 account_locked
1408
1409 my $is_locked = $patron->account_locked
1410
1411 Return true if the patron has reached the maximum number of login attempts
1412 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1413 as an administrative lockout (independent of FailedLoginAttempts; see also
1414 Koha::Patron->lock).
1415 Otherwise return false.
1416 If the pref is not set (empty string, null or 0), the feature is considered as
1417 disabled.
1418
1419 =cut
1420
1421 sub account_locked {
1422     my ($self) = @_;
1423     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1424     return 1 if $FailedLoginAttempts
1425           and $self->login_attempts
1426           and $self->login_attempts >= $FailedLoginAttempts;
1427     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1428     return 0;
1429 }
1430
1431 =head3 can_see_patron_infos
1432
1433 my $can_see = $patron->can_see_patron_infos( $patron );
1434
1435 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1436
1437 =cut
1438
1439 sub can_see_patron_infos {
1440     my ( $self, $patron ) = @_;
1441     return unless $patron;
1442     return $self->can_see_patrons_from( $patron->branchcode );
1443 }
1444
1445 =head3 can_see_patrons_from
1446
1447 my $can_see = $patron->can_see_patrons_from( $branchcode );
1448
1449 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1450
1451 =cut
1452
1453 sub can_see_patrons_from {
1454     my ( $self, $branchcode ) = @_;
1455     my $can = 0;
1456     if ( $self->branchcode eq $branchcode ) {
1457         $can = 1;
1458     } elsif ( $self->has_permission( { borrowers => 'view_borrower_infos_from_any_libraries' } ) ) {
1459         $can = 1;
1460     } elsif ( my $library_groups = $self->library->library_groups ) {
1461         while ( my $library_group = $library_groups->next ) {
1462             if ( $library_group->parent->has_child( $branchcode ) ) {
1463                 $can = 1;
1464                 last;
1465             }
1466         }
1467     }
1468     return $can;
1469 }
1470
1471 =head3 can_log_into
1472
1473 my $can_log_into = $patron->can_log_into( $library );
1474
1475 Given a I<Koha::Library> object, it returns a boolean representing
1476 the fact the patron can log into a the library.
1477
1478 =cut
1479
1480 sub can_log_into {
1481     my ( $self, $library ) = @_;
1482
1483     my $can = 0;
1484
1485     if ( C4::Context->preference('IndependentBranches') ) {
1486         $can = 1
1487           if $self->is_superlibrarian
1488           or $self->branchcode eq $library->id;
1489     }
1490     else {
1491         # no restrictions
1492         $can = 1;
1493     }
1494
1495    return $can;
1496 }
1497
1498 =head3 libraries_where_can_see_patrons
1499
1500 my $libraries = $patron-libraries_where_can_see_patrons;
1501
1502 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1503 The branchcodes are arbitrarily returned sorted.
1504 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1505
1506 An empty array means no restriction, the patron can see patron's infos from any libraries.
1507
1508 =cut
1509
1510 sub libraries_where_can_see_patrons {
1511     my ( $self ) = @_;
1512     my $userenv = C4::Context->userenv;
1513
1514     return () unless $userenv; # For tests, but userenv should be defined in tests...
1515
1516     my @restricted_branchcodes;
1517     if (C4::Context::only_my_library) {
1518         push @restricted_branchcodes, $self->branchcode;
1519     }
1520     else {
1521         unless (
1522             $self->has_permission(
1523                 { borrowers => 'view_borrower_infos_from_any_libraries' }
1524             )
1525           )
1526         {
1527             my $library_groups = $self->library->library_groups({ ft_hide_patron_info => 1 });
1528             if ( $library_groups->count )
1529             {
1530                 while ( my $library_group = $library_groups->next ) {
1531                     my $parent = $library_group->parent;
1532                     if ( $parent->has_child( $self->branchcode ) ) {
1533                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1534                     }
1535                 }
1536             }
1537
1538             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1539         }
1540     }
1541
1542     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1543     @restricted_branchcodes = uniq(@restricted_branchcodes);
1544     @restricted_branchcodes = sort(@restricted_branchcodes);
1545     return @restricted_branchcodes;
1546 }
1547
1548 =head3 has_permission
1549
1550 my $permission = $patron->has_permission($required);
1551
1552 See C4::Auth::haspermission for details of syntax for $required
1553
1554 =cut
1555
1556 sub has_permission {
1557     my ( $self, $flagsrequired ) = @_;
1558     return unless $self->userid;
1559     # TODO code from haspermission needs to be moved here!
1560     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1561 }
1562
1563 =head3 is_superlibrarian
1564
1565   my $is_superlibrarian = $patron->is_superlibrarian;
1566
1567 Return true if the patron is a superlibrarian.
1568
1569 =cut
1570
1571 sub is_superlibrarian {
1572     my ($self) = @_;
1573     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1574 }
1575
1576 =head3 is_adult
1577
1578 my $is_adult = $patron->is_adult
1579
1580 Return true if the patron has a category with a type Adult (A) or Organization (I)
1581
1582 =cut
1583
1584 sub is_adult {
1585     my ( $self ) = @_;
1586     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1587 }
1588
1589 =head3 is_child
1590
1591 my $is_child = $patron->is_child
1592
1593 Return true if the patron has a category with a type Child (C)
1594
1595 =cut
1596
1597 sub is_child {
1598     my( $self ) = @_;
1599     return $self->category->category_type eq 'C' ? 1 : 0;
1600 }
1601
1602 =head3 has_valid_userid
1603
1604 my $patron = Koha::Patrons->find(42);
1605 $patron->userid( $new_userid );
1606 my $has_a_valid_userid = $patron->has_valid_userid
1607
1608 my $patron = Koha::Patron->new( $params );
1609 my $has_a_valid_userid = $patron->has_valid_userid
1610
1611 Return true if the current userid of this patron is valid/unique, otherwise false.
1612
1613 Note that this should be done in $self->store instead and raise an exception if needed.
1614
1615 =cut
1616
1617 sub has_valid_userid {
1618     my ($self) = @_;
1619
1620     return 0 unless $self->userid;
1621
1622     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1623
1624     my $already_exists = Koha::Patrons->search(
1625         {
1626             userid => $self->userid,
1627             (
1628                 $self->in_storage
1629                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1630                 : ()
1631             ),
1632         }
1633     )->count;
1634     return $already_exists ? 0 : 1;
1635 }
1636
1637 =head3 generate_userid
1638
1639 my $patron = Koha::Patron->new( $params );
1640 $patron->generate_userid
1641
1642 Generate a userid using the $surname and the $firstname (if there is a value in $firstname).
1643
1644 Set a generated userid ($firstname.$surname if there is a $firstname, or $surname if there is no value in $firstname) plus offset (0 if the $userid is unique, or a higher numeric value if not unique).
1645
1646 =cut
1647
1648 sub generate_userid {
1649     my ($self) = @_;
1650     my $offset = 0;
1651     my $firstname = $self->firstname // q{};
1652     my $surname = $self->surname // q{};
1653     #The script will "do" the following code and increment the $offset until the generated userid is unique
1654     do {
1655       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1656       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1657       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1658       $userid = NFKD( $userid );
1659       $userid =~ s/\p{NonspacingMark}//g;
1660       $userid .= $offset unless $offset == 0;
1661       $self->userid( $userid );
1662       $offset++;
1663      } while (! $self->has_valid_userid );
1664
1665      return $self;
1666 }
1667
1668 =head3 add_extended_attribute
1669
1670 =cut
1671
1672 sub add_extended_attribute {
1673     my ($self, $attribute) = @_;
1674
1675     return Koha::Patron::Attribute->new(
1676         {
1677             %$attribute,
1678             ( borrowernumber => $self->borrowernumber ),
1679         }
1680     )->store;
1681
1682 }
1683
1684 =head3 extended_attributes
1685
1686 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1687
1688 Or setter FIXME
1689
1690 =cut
1691
1692 sub extended_attributes {
1693     my ( $self, $attributes ) = @_;
1694     if ($attributes) {    # setter
1695         my $schema = $self->_result->result_source->schema;
1696         $schema->txn_do(
1697             sub {
1698                 # Remove the existing one
1699                 $self->extended_attributes->filter_by_branch_limitations->delete;
1700
1701                 # Insert the new ones
1702                 my $new_types = {};
1703                 for my $attribute (@$attributes) {
1704                     $self->add_extended_attribute($attribute);
1705                     $new_types->{$attribute->{code}} = 1;
1706                 }
1707
1708                 # Check globally mandatory types
1709                 my @required_attribute_types =
1710                     Koha::Patron::Attribute::Types->search(
1711                         {
1712                             mandatory => 1,
1713                             'borrower_attribute_types_branches.b_branchcode' =>
1714                               undef
1715                         },
1716                         { join => 'borrower_attribute_types_branches' }
1717                     )->get_column('code');
1718                 for my $type ( @required_attribute_types ) {
1719                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1720                         type => $type,
1721                     ) if !$new_types->{$type};
1722                 }
1723             }
1724         );
1725     }
1726
1727     my $rs = $self->_result->borrower_attributes;
1728     # We call search to use the filters in Koha::Patron::Attributes->search
1729     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1730 }
1731
1732 =head3 messages
1733
1734     my $messages = $patron->messages;
1735
1736 Return the message attached to the patron.
1737
1738 =cut
1739
1740 sub messages {
1741     my ( $self ) = @_;
1742     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1743     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1744 }
1745
1746 =head3 lock
1747
1748     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1749
1750     Lock and optionally expire a patron account.
1751     Remove holds and article requests if remove flag set.
1752     In order to distinguish from locking by entering a wrong password, let's
1753     call this an administrative lockout.
1754
1755 =cut
1756
1757 sub lock {
1758     my ( $self, $params ) = @_;
1759     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1760     if( $params->{expire} ) {
1761         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1762     }
1763     $self->store;
1764     if( $params->{remove} ) {
1765         $self->holds->delete;
1766         $self->article_requests->delete;
1767     }
1768     return $self;
1769 }
1770
1771 =head3 anonymize
1772
1773     Koha::Patrons->find($id)->anonymize;
1774
1775     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1776     are randomized, other personal data is cleared too.
1777     Patrons with issues are skipped.
1778
1779 =cut
1780
1781 sub anonymize {
1782     my ( $self ) = @_;
1783     if( $self->_result->issues->count ) {
1784         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1785         return;
1786     }
1787     # Mandatory fields come from the corresponding pref, but email fields
1788     # are removed since scrambled email addresses only generate errors
1789     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1790         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1791     $mandatory->{userid} = 1; # needed since sub store does not clear field
1792     my @columns = $self->_result->result_source->columns;
1793     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
1794     push @columns, 'dateofbirth'; # add this date back in
1795     foreach my $col (@columns) {
1796         $self->_anonymize_column($col, $mandatory->{lc $col} );
1797     }
1798     $self->anonymized(1)->store;
1799 }
1800
1801 sub _anonymize_column {
1802     my ( $self, $col, $mandatory ) = @_;
1803     my $col_info = $self->_result->result_source->column_info($col);
1804     my $type = $col_info->{data_type};
1805     my $nullable = $col_info->{is_nullable};
1806     my $val;
1807     if( $type =~ /char|text/ ) {
1808         $val = $mandatory
1809             ? Koha::Token->new->generate({ pattern => '\w{10}' })
1810             : $nullable
1811             ? undef
1812             : q{};
1813     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
1814         $val = $nullable ? undef : 0;
1815     } elsif( $type =~ /date|time/ ) {
1816         $val = $nullable ? undef : dt_from_string;
1817     }
1818     $self->$col($val);
1819 }
1820
1821 =head3 add_guarantor
1822
1823     my $relationship = $patron->add_guarantor(
1824         {
1825             borrowernumber => $borrowernumber,
1826             relationships  => $relationship,
1827         }
1828     );
1829
1830     Adds a new guarantor to a patron.
1831
1832 =cut
1833
1834 sub add_guarantor {
1835     my ( $self, $params ) = @_;
1836
1837     my $guarantor_id = $params->{guarantor_id};
1838     my $relationship = $params->{relationship};
1839
1840     return Koha::Patron::Relationship->new(
1841         {
1842             guarantee_id => $self->id,
1843             guarantor_id => $guarantor_id,
1844             relationship => $relationship
1845         }
1846     )->store();
1847 }
1848
1849 =head3 get_extended_attribute
1850
1851 my $attribute_value = $patron->get_extended_attribute( $code );
1852
1853 Return the attribute for the code passed in parameter.
1854
1855 It not exist it returns undef
1856
1857 Note that this will not work for repeatable attribute types.
1858
1859 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
1860 (which should be a real patron's attribute (not extended)
1861
1862 =cut
1863
1864 sub get_extended_attribute {
1865     my ( $self, $code, $value ) = @_;
1866     my $rs = $self->_result->borrower_attributes;
1867     return unless $rs;
1868     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
1869     return unless $attribute->count;
1870     return $attribute->next;
1871 }
1872
1873 =head3 to_api
1874
1875     my $json = $patron->to_api;
1876
1877 Overloaded method that returns a JSON representation of the Koha::Patron object,
1878 suitable for API output.
1879
1880 =cut
1881
1882 sub to_api {
1883     my ( $self, $params ) = @_;
1884
1885     my $json_patron = $self->SUPER::to_api( $params );
1886
1887     $json_patron->{restricted} = ( $self->is_debarred )
1888                                     ? Mojo::JSON->true
1889                                     : Mojo::JSON->false;
1890
1891     return $json_patron;
1892 }
1893
1894 =head3 to_api_mapping
1895
1896 This method returns the mapping for representing a Koha::Patron object
1897 on the API.
1898
1899 =cut
1900
1901 sub to_api_mapping {
1902     return {
1903         borrowernotes       => 'staff_notes',
1904         borrowernumber      => 'patron_id',
1905         branchcode          => 'library_id',
1906         categorycode        => 'category_id',
1907         checkprevcheckout   => 'check_previous_checkout',
1908         contactfirstname    => undef,                     # Unused
1909         contactname         => undef,                     # Unused
1910         contactnote         => 'altaddress_notes',
1911         contacttitle        => undef,                     # Unused
1912         dateenrolled        => 'date_enrolled',
1913         dateexpiry          => 'expiry_date',
1914         dateofbirth         => 'date_of_birth',
1915         debarred            => undef,                     # replaced by 'restricted'
1916         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
1917         emailpro            => 'secondary_email',
1918         flags               => undef,    # permissions manipulation handled in /permissions
1919         gonenoaddress       => 'incorrect_address',
1920         lastseen            => 'last_seen',
1921         lost                => 'patron_card_lost',
1922         opacnote            => 'opac_notes',
1923         othernames          => 'other_name',
1924         password            => undef,            # password manipulation handled in /password
1925         phonepro            => 'secondary_phone',
1926         relationship        => 'relationship_type',
1927         sex                 => 'gender',
1928         smsalertnumber      => 'sms_number',
1929         sort1               => 'statistics_1',
1930         sort2               => 'statistics_2',
1931         autorenew_checkouts => 'autorenew_checkouts',
1932         streetnumber        => 'street_number',
1933         streettype          => 'street_type',
1934         zipcode             => 'postal_code',
1935         B_address           => 'altaddress_address',
1936         B_address2          => 'altaddress_address2',
1937         B_city              => 'altaddress_city',
1938         B_country           => 'altaddress_country',
1939         B_email             => 'altaddress_email',
1940         B_phone             => 'altaddress_phone',
1941         B_state             => 'altaddress_state',
1942         B_streetnumber      => 'altaddress_street_number',
1943         B_streettype        => 'altaddress_street_type',
1944         B_zipcode           => 'altaddress_postal_code',
1945         altcontactaddress1  => 'altcontact_address',
1946         altcontactaddress2  => 'altcontact_address2',
1947         altcontactaddress3  => 'altcontact_city',
1948         altcontactcountry   => 'altcontact_country',
1949         altcontactfirstname => 'altcontact_firstname',
1950         altcontactphone     => 'altcontact_phone',
1951         altcontactsurname   => 'altcontact_surname',
1952         altcontactstate     => 'altcontact_state',
1953         altcontactzipcode   => 'altcontact_postal_code',
1954         password_expiration_date => undef,
1955         primary_contact_method => undef,
1956         secret              => undef,
1957         auth_method         => undef,
1958     };
1959 }
1960
1961 =head3 queue_notice
1962
1963     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
1964     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
1965     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
1966
1967     Queue messages to a patron. Can pass a message that is part of the message_attributes
1968     table or supply the transport to use.
1969
1970     If passed a message name we retrieve the patrons preferences for transports
1971     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
1972     we have no address/number for sending
1973
1974     $letter_params is a hashref of the values to be passed to GetPreparedLetter
1975
1976     test_mode will only report which notices would be sent, but nothing will be queued
1977
1978 =cut
1979
1980 sub queue_notice {
1981     my ( $self, $params ) = @_;
1982     my $letter_params = $params->{letter_params};
1983     my $test_mode = $params->{test_mode};
1984
1985     return unless $letter_params;
1986     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
1987
1988     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
1989     my $from_email_address = $library->from_email_address;
1990
1991     my @message_transports;
1992     my $letter_code;
1993     $letter_code = $letter_params->{letter_code};
1994     if( $params->{message_name} ){
1995         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
1996                 borrowernumber => $letter_params->{borrowernumber},
1997                 message_name => $params->{message_name}
1998         } );
1999         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2000         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2001     } else {
2002         @message_transports = @{$params->{message_transports}};
2003     }
2004     return unless defined $letter_code;
2005     $letter_params->{letter_code} = $letter_code;
2006     my $print_sent = 0;
2007     my %return;
2008     foreach my $mtt (@message_transports){
2009         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2010         # Notice is handled by TalkingTech_itiva_outbound.pl
2011         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2012             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2013             or ( $mtt eq 'phone' and not $self->phone ) )
2014         {
2015             push @{ $return{fallback} }, $mtt;
2016             $mtt = 'print';
2017         }
2018         next if $mtt eq 'print' && $print_sent;
2019         $letter_params->{message_transport_type} = $mtt;
2020         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2021         C4::Letters::EnqueueLetter({
2022             letter => $letter,
2023             borrowernumber => $self->borrowernumber,
2024             from_address   => $from_email_address,
2025             message_transport_type => $mtt
2026         }) unless $test_mode;
2027         push @{$return{sent}}, $mtt;
2028         $print_sent = 1 if $mtt eq 'print';
2029     }
2030     return \%return;
2031 }
2032
2033 =head3 safe_to_delete
2034
2035     my $result = $patron->safe_to_delete;
2036     if ( $result eq 'has_guarantees' ) { ... }
2037     elsif ( $result ) { ... }
2038     else { # cannot delete }
2039
2040 This method tells if the Koha:Patron object can be deleted. Possible return values
2041
2042 =over 4
2043
2044 =item 'ok'
2045
2046 =item 'has_checkouts'
2047
2048 =item 'has_debt'
2049
2050 =item 'has_guarantees'
2051
2052 =item 'is_anonymous_patron'
2053
2054 =back
2055
2056 =cut
2057
2058 sub safe_to_delete {
2059     my ($self) = @_;
2060
2061     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2062
2063     my $error;
2064
2065     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2066         $error = 'is_anonymous_patron';
2067     }
2068     elsif ( $self->checkouts->count ) {
2069         $error = 'has_checkouts';
2070     }
2071     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2072         $error = 'has_debt';
2073     }
2074     elsif ( $self->guarantee_relationships->count ) {
2075         $error = 'has_guarantees';
2076     }
2077
2078     if ( $error ) {
2079         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2080     }
2081
2082     return Koha::Result::Boolean->new(1);
2083 }
2084
2085 =head3 recalls
2086
2087     my $recalls = $patron->recalls;
2088
2089 Return the patron's recalls.
2090
2091 =cut
2092
2093 sub recalls {
2094     my ( $self ) = @_;
2095
2096     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2097 }
2098
2099 =head3 account_balance
2100
2101     my $balance = $patron->account_balance
2102
2103 Return the patron's account balance
2104
2105 =cut
2106
2107 sub account_balance {
2108     my ($self) = @_;
2109     return $self->account->balance;
2110 }
2111
2112
2113 =head3 has_messaging_preference
2114
2115 my $bool = $patron->has_messaging_preference({
2116     message_name => $message_name, # A value from message_attributes.message_name
2117     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2118     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2119 });
2120
2121 =cut
2122
2123 sub has_messaging_preference {
2124     my ( $self, $params ) = @_;
2125
2126     my $message_name           = $params->{message_name};
2127     my $message_transport_type = $params->{message_transport_type};
2128     my $wants_digest           = $params->{wants_digest};
2129
2130     return $self->_result->search_related_rs(
2131         'borrower_message_preferences',
2132         $params,
2133         {
2134             prefetch =>
2135               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2136         }
2137     )->count;
2138 }
2139
2140 =head3 can_patron_change_staff_only_lists
2141
2142 $patron->can_patron_change_staff_only_lists;
2143
2144 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2145 Otherwise, return 0.
2146
2147 =cut
2148
2149 sub can_patron_change_staff_only_lists {
2150     my ( $self, $params ) = @_;
2151     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2152     return 0;
2153 }
2154
2155 =head3 encode_secret
2156
2157   $patron->encode_secret($secret32);
2158
2159 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2160 You still need to call ->store.
2161
2162 =cut
2163
2164 sub encode_secret {
2165     my ( $self, $secret ) = @_;
2166     if( $secret ) {
2167         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2168     }
2169     return $self->secret($secret);
2170 }
2171
2172 =head3 decoded_secret
2173
2174   my $secret32 = $patron->decoded_secret;
2175
2176 Decode the patron secret. We expect to get back a base32 string, but this
2177 is not checked here. Caller of encode_secret is responsible for that.
2178
2179 =cut
2180
2181 sub decoded_secret {
2182     my ( $self ) = @_;
2183     if( $self->secret ) {
2184         return Koha::Encryption->new->decrypt_hex( $self->secret );
2185     }
2186     return $self->secret;
2187 }
2188
2189 =head2 Internal methods
2190
2191 =head3 _type
2192
2193 =cut
2194
2195 sub _type {
2196     return 'Borrower';
2197 }
2198
2199 =head1 AUTHORS
2200
2201 Kyle M Hall <kyle@bywatersolutions.com>
2202 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2203 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2204
2205 =cut
2206
2207 1;