Koha/Patron.pm

   1 package Koha::Patron;
   2
   3 # Copyright ByWater Solutions 2014
   4 # Copyright PTFS Europe 2016
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use List::MoreUtils qw( any uniq );
  24 use JSON qw( to_json );
  25 use Unicode::Normalize qw( NFKD );
  26 use Try::Tiny;
  27
  28 use C4::Context;
  29 use C4::Auth qw( checkpw_hash );
  30 use C4::Log qw( logaction );
  31 use Koha::Account;
  32 use Koha::ArticleRequests;
  33 use C4::Letters qw( GetPreparedLetter EnqueueLetter SendQueuedMessages );
  34 use Koha::AuthUtils;
  35 use Koha::Checkouts;
  36 use Koha::CirculationRules;
  37 use Koha::Club::Enrollments;
  38 use Koha::Database;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Encryption;
  41 use Koha::Exceptions::Password;
  42 use Koha::Holds;
  43 use Koha::CurbsidePickups;
  44 use Koha::Old::Checkouts;
  45 use Koha::Patron::Attributes;
  46 use Koha::Patron::Categories;
  47 use Koha::Patron::Debarments;
  48 use Koha::Patron::HouseboundProfile;
  49 use Koha::Patron::HouseboundRole;
  50 use Koha::Patron::Images;
  51 use Koha::Patron::Messages;
  52 use Koha::Patron::Modifications;
  53 use Koha::Patron::Message::Preferences;
  54 use Koha::Patron::Relationships;
  55 use Koha::Patron::Restrictions;
  56 use Koha::Patrons;
  57 use Koha::Plugins;
  58 use Koha::Recalls;
  59 use Koha::Result::Boolean;
  60 use Koha::Subscription::Routinglists;
  61 use Koha::Token;
  62 use Koha::Virtualshelves;
  63
  64 use base qw(Koha::Object);
  65
  66 use constant ADMINISTRATIVE_LOCKOUT => -1;
  67
  68 our $RESULTSET_PATRON_ID_MAPPING = {
  69     Accountline          => 'borrowernumber',
  70     Aqbasketuser         => 'borrowernumber',
  71     Aqbudget             => 'budget_owner_id',
  72     Aqbudgetborrower     => 'borrowernumber',
  73     ArticleRequest       => 'borrowernumber',
  74     BorrowerDebarment    => 'borrowernumber',
  75     BorrowerFile         => 'borrowernumber',
  76     BorrowerModification => 'borrowernumber',
  77     ClubEnrollment       => 'borrowernumber',
  78     Issue                => 'borrowernumber',
  79     ItemsLastBorrower    => 'borrowernumber',
  80     Linktracker          => 'borrowernumber',
  81     Message              => 'borrowernumber',
  82     MessageQueue         => 'borrowernumber',
  83     OldIssue             => 'borrowernumber',
  84     OldReserve           => 'borrowernumber',
  85     Rating               => 'borrowernumber',
  86     Reserve              => 'borrowernumber',
  87     Review               => 'borrowernumber',
  88     SearchHistory        => 'userid',
  89     Statistic            => 'borrowernumber',
  90     Suggestion           => 'suggestedby',
  91     TagAll               => 'borrowernumber',
  92     Virtualshelfcontent  => 'borrowernumber',
  93     Virtualshelfshare    => 'borrowernumber',
  94     Virtualshelve        => 'owner',
  95 };
  96
  97 =head1 NAME
  98
  99 Koha::Patron - Koha Patron Object class
 100
 101 =head1 API
 102
 103 =head2 Class Methods
 104
 105 =head3 new
 106
 107 =cut
 108
 109 sub new {
 110     my ( $class, $params ) = @_;
 111
 112     return $class->SUPER::new($params);
 113 }
 114
 115 =head3 fixup_cardnumber
 116
 117 Autogenerate next cardnumber from highest value found in database
 118
 119 =cut
 120
 121 sub fixup_cardnumber {
 122     my ( $self ) = @_;
 123
 124     my $max = $self->cardnumber;
 125     Koha::Plugins->call( 'patron_barcode_transform', \$max );
 126
 127     $max ||= Koha::Patrons->search({
 128         cardnumber => {-regexp => '^-?[0-9]+$'}
 129     }, {
 130         select => \'CAST(cardnumber AS SIGNED)',
 131         as => ['cast_cardnumber']
 132     })->_resultset->get_column('cast_cardnumber')->max;
 133     $self->cardnumber(($max || 0) +1);
 134 }
 135
 136 =head3 trim_whitespace
 137
 138 trim whitespace from data which has some non-whitespace in it.
 139 Could be moved to Koha::Object if need to be reused
 140
 141 =cut
 142
 143 sub trim_whitespaces {
 144     my( $self ) = @_;
 145
 146     my $schema  = Koha::Database->new->schema;
 147     my @columns = $schema->source($self->_type)->columns;
 148
 149     for my $column( @columns ) {
 150         my $value = $self->$column;
 151         if ( defined $value ) {
 152             $value =~ s/^\s*|\s*$//g;
 153             $self->$column($value);
 154         }
 155     }
 156     return $self;
 157 }
 158
 159 =head3 plain_text_password
 160
 161 $patron->plain_text_password( $password );
 162
 163 stores a copy of the unencrypted password in the object
 164 for use in code before encrypting for db
 165
 166 =cut
 167
 168 sub plain_text_password {
 169     my ( $self, $password ) = @_;
 170     if ( $password ) {
 171         $self->{_plain_text_password} = $password;
 172         return $self;
 173     }
 174     return $self->{_plain_text_password}
 175         if $self->{_plain_text_password};
 176
 177     return;
 178 }
 179
 180 =head3 store
 181
 182 Patron specific store method to cleanup record
 183 and do other necessary things before saving
 184 to db
 185
 186 =cut
 187
 188 sub store {
 189     my ($self) = @_;
 190
 191     $self->_result->result_source->schema->txn_do(
 192         sub {
 193             if (
 194                 C4::Context->preference("autoMemberNum")
 195                 and ( not defined $self->cardnumber
 196                     or $self->cardnumber eq '' )
 197               )
 198             {
 199                 # Warning: The caller is responsible for locking the members table in write
 200                 # mode, to avoid database corruption.
 201                 # We are in a transaction but the table is not locked
 202                 $self->fixup_cardnumber;
 203             }
 204
 205             unless( $self->category->in_storage ) {
 206                 Koha::Exceptions::Object::FKConstraint->throw(
 207                     broken_fk => 'categorycode',
 208                     value     => $self->categorycode,
 209                 );
 210             }
 211
 212             $self->trim_whitespaces;
 213
 214             my $new_cardnumber = $self->cardnumber;
 215             Koha::Plugins->call( 'patron_barcode_transform', \$new_cardnumber );
 216             $self->cardnumber( $new_cardnumber );
 217
 218             # Set surname to uppercase if uppercasesurname is true
 219             $self->surname( uc($self->surname) )
 220                 if C4::Context->preference("uppercasesurnames");
 221
 222             $self->relationship(undef) # We do not want to store an empty string in this field
 223               if defined $self->relationship
 224                      and $self->relationship eq "";
 225
 226             unless ( $self->in_storage ) {    #AddMember
 227
 228                 # Generate a valid userid/login if needed
 229                 $self->generate_userid unless $self->userid;
 230                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 231                     unless $self->has_valid_userid;
 232
 233                 # Add expiration date if it isn't already there
 234                 unless ( $self->dateexpiry ) {
 235                     $self->dateexpiry( $self->category->get_expiry_date );
 236                 }
 237
 238                 # Add enrollment date if it isn't already there
 239                 unless ( $self->dateenrolled ) {
 240                     $self->dateenrolled(dt_from_string);
 241                 }
 242
 243                 # Set the privacy depending on the patron's category
 244                 my $default_privacy = $self->category->default_privacy || q{};
 245                 $default_privacy =
 246                     $default_privacy eq 'default' ? 1
 247                   : $default_privacy eq 'never'   ? 2
 248                   : $default_privacy eq 'forever' ? 0
 249                   :                                                   undef;
 250                 $self->privacy($default_privacy);
 251
 252                 # Call any check_password plugins if password is passed
 253                 if ( C4::Context->config("enable_plugins") && $self->password ) {
 254                     my @plugins = Koha::Plugins->new()->GetPlugins({
 255                         method => 'check_password',
 256                     });
 257                     foreach my $plugin ( @plugins ) {
 258                         # This plugin hook will also be used by a plugin for the Norwegian national
 259                         # patron database. This is why we need to pass both the password and the
 260                         # borrowernumber to the plugin.
 261                         my $ret = $plugin->check_password(
 262                             {
 263                                 password       => $self->password,
 264                                 borrowernumber => $self->borrowernumber
 265                             }
 266                         );
 267                         if ( $ret->{'error'} == 1 ) {
 268                             Koha::Exceptions::Password::Plugin->throw();
 269                         }
 270                     }
 271                 }
 272
 273                 # Make a copy of the plain text password for later use
 274                 $self->plain_text_password( $self->password );
 275
 276                 $self->password_expiration_date( $self->password
 277                     ? $self->category->get_password_expiry_date || undef
 278                     : undef );
 279                 # Create a disabled account if no password provided
 280                 $self->password( $self->password
 281                     ? Koha::AuthUtils::hash_password( $self->password )
 282                     : '!' );
 283
 284                 $self->borrowernumber(undef);
 285
 286                 $self = $self->SUPER::store;
 287
 288                 $self->add_enrolment_fee_if_needed(0);
 289
 290                 logaction( "MEMBERS", "CREATE", $self->borrowernumber, "" )
 291                   if C4::Context->preference("BorrowersLog");
 292             }
 293             else {    #ModMember
 294
 295                 my $self_from_storage = $self->get_from_storage;
 296
 297                 # Do not accept invalid userid here
 298                 $self->generate_userid unless $self->userid;
 299                 Koha::Exceptions::Patron::InvalidUserid->throw( userid => $self->userid )
 300                       unless $self->has_valid_userid;
 301
 302                 # If a borrower has set their privacy to never we should immediately anonymize
 303                 # their checkouts
 304                 if( $self->privacy() == 2 && $self_from_storage->privacy() != 2 ){
 305                     try{
 306                         $self->old_checkouts->anonymize;
 307                     }
 308                     catch {
 309                         Koha::Exceptions::Patron::FailedAnonymizing->throw(
 310                             error => @_
 311                         );
 312                     };
 313                 }
 314
 315                 # Password must be updated using $self->set_password
 316                 $self->password($self_from_storage->password);
 317
 318                 if ( $self->category->categorycode ne
 319                     $self_from_storage->category->categorycode )
 320                 {
 321                     # Add enrolement fee on category change if required
 322                     $self->add_enrolment_fee_if_needed(1)
 323                       if C4::Context->preference('FeeOnChangePatronCategory');
 324
 325                     # Clean up guarantors on category change if required
 326                     $self->guarantor_relationships->delete
 327                       unless ( $self->category->can_be_guarantee );
 328
 329                 }
 330
 331                 # Actionlogs
 332                 if ( C4::Context->preference("BorrowersLog") ) {
 333                     my $info;
 334                     my $from_storage = $self_from_storage->unblessed;
 335                     my $from_object  = $self->unblessed;
 336                     my @skip_fields  = (qw/lastseen updated_on/);
 337                     for my $key ( keys %{$from_storage} ) {
 338                         next if any { /$key/ } @skip_fields;
 339                         if (
 340                             (
 341                                   !defined( $from_storage->{$key} )
 342                                 && defined( $from_object->{$key} )
 343                             )
 344                             || ( defined( $from_storage->{$key} )
 345                                 && !defined( $from_object->{$key} ) )
 346                             || (
 347                                    defined( $from_storage->{$key} )
 348                                 && defined( $from_object->{$key} )
 349                                 && ( $from_storage->{$key} ne
 350                                     $from_object->{$key} )
 351                             )
 352                           )
 353                         {
 354                             $info->{$key} = {
 355                                 before => $from_storage->{$key},
 356                                 after  => $from_object->{$key}
 357                             };
 358                         }
 359                     }
 360
 361                     if ( defined($info) ) {
 362                         logaction(
 363                             "MEMBERS",
 364                             "MODIFY",
 365                             $self->borrowernumber,
 366                             to_json(
 367                                 $info,
 368                                 { utf8 => 1, pretty => 1, canonical => 1 }
 369                             )
 370                         );
 371                     }
 372                 }
 373
 374                 # Final store
 375                 $self = $self->SUPER::store;
 376             }
 377         }
 378     );
 379     return $self;
 380 }
 381
 382 =head3 delete
 383
 384 $patron->delete
 385
 386 Delete patron's holds, lists and finally the patron.
 387
 388 Lists owned by the borrower are deleted or ownership is transferred depending on the
 389 ListOwnershipUponPatronDeletion pref, but entries from the borrower to other lists are kept.
 390
 391 =cut
 392
 393 sub delete {
 394     my ($self) = @_;
 395
 396     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 397     Koha::Exceptions::Patron::FailedDeleteAnonymousPatron->throw() if $anonymous_patron && $self->id eq $anonymous_patron;
 398
 399     $self->_result->result_source->schema->txn_do(
 400         sub {
 401             # Cancel Patron's holds
 402             my $holds = $self->holds;
 403             while( my $hold = $holds->next ){
 404                 $hold->cancel;
 405             }
 406
 407             # Handle lists (virtualshelves)
 408             $self->virtualshelves->disown_or_delete;
 409
 410             # We cannot have a FK on borrower_modifications.borrowernumber, the table is also used
 411             # for patron selfreg
 412             $_->delete for Koha::Patron::Modifications->search( { borrowernumber => $self->borrowernumber } )->as_list;
 413
 414             $self->SUPER::delete;
 415
 416             logaction( "MEMBERS", "DELETE", $self->borrowernumber, "" ) if C4::Context->preference("BorrowersLog");
 417         }
 418     );
 419     return $self;
 420 }
 421
 422 =head3 category
 423
 424 my $patron_category = $patron->category
 425
 426 Return the patron category for this patron
 427
 428 =cut
 429
 430 sub category {
 431     my ( $self ) = @_;
 432     return Koha::Patron::Category->_new_from_dbic( $self->_result->categorycode );
 433 }
 434
 435 =head3 image
 436
 437 =cut
 438
 439 sub image {
 440     my ( $self ) = @_;
 441
 442     return Koha::Patron::Images->find( $self->borrowernumber );
 443 }
 444
 445 =head3 library
 446
 447 Returns a Koha::Library object representing the patron's home library.
 448
 449 =cut
 450
 451 sub library {
 452     my ( $self ) = @_;
 453     return Koha::Library->_new_from_dbic($self->_result->branchcode);
 454 }
 455
 456 =head3 sms_provider
 457
 458 Returns a Koha::SMS::Provider object representing the patron's SMS provider.
 459
 460 =cut
 461
 462 sub sms_provider {
 463     my ( $self ) = @_;
 464     my $sms_provider_rs = $self->_result->sms_provider;
 465     return unless $sms_provider_rs;
 466     return Koha::SMS::Provider->_new_from_dbic($sms_provider_rs);
 467 }
 468
 469 =head3 guarantor_relationships
 470
 471 Returns Koha::Patron::Relationships object for this patron's guarantors
 472
 473 Returns the set of relationships for the patrons that are guarantors for this patron.
 474
 475 Note that a guarantor should exist as a patron in Koha; it was not possible
 476 to add them without a guarantor_id in the interface for some time. Bug 30472
 477 restricts it on db level.
 478
 479 =cut
 480
 481 sub guarantor_relationships {
 482     my ($self) = @_;
 483
 484     return Koha::Patron::Relationships->search( { guarantee_id => $self->id } );
 485 }
 486
 487 =head3 guarantee_relationships
 488
 489 Returns Koha::Patron::Relationships object for this patron's guarantors
 490
 491 Returns the set of relationships for the patrons that are guarantees for this patron.
 492
 493 The method returns Koha::Patron::Relationship objects for the sake
 494 of consistency with the guantors method.
 495 A guarantee by definition must exist as a patron in Koha.
 496
 497 =cut
 498
 499 sub guarantee_relationships {
 500     my ($self) = @_;
 501
 502     return Koha::Patron::Relationships->search(
 503         { guarantor_id => $self->id },
 504         {
 505             prefetch => 'guarantee',
 506             order_by => { -asc => [ 'guarantee.surname', 'guarantee.firstname' ] },
 507         }
 508     );
 509 }
 510
 511 =head3 relationships_debt
 512
 513 Returns the amount owed by the patron's guarantors *and* the other guarantees of those guarantors
 514
 515 =cut
 516
 517 sub relationships_debt {
 518     my ($self, $params) = @_;
 519
 520     my $include_guarantors  = $params->{include_guarantors};
 521     my $only_this_guarantor = $params->{only_this_guarantor};
 522     my $include_this_patron = $params->{include_this_patron};
 523
 524     my @guarantors;
 525     if ( $only_this_guarantor ) {
 526         @guarantors = $self->guarantee_relationships->count ? ( $self ) : ();
 527         Koha::Exceptions::BadParameter->throw( { parameter => 'only_this_guarantor' } ) unless @guarantors;
 528     } elsif ( $self->guarantor_relationships->count ) {
 529         # I am a guarantee, just get all my guarantors
 530         @guarantors = $self->guarantor_relationships->guarantors->as_list;
 531     } else {
 532         # I am a guarantor, I need to get all the guarantors of all my guarantees
 533         @guarantors = map { $_->guarantor_relationships->guarantors->as_list } $self->guarantee_relationships->guarantees->as_list;
 534     }
 535
 536     my $non_issues_charges = 0;
 537     my $seen = $include_this_patron ? {} : { $self->id => 1 }; # For tracking members already added to the total
 538     foreach my $guarantor (@guarantors) {
 539         $non_issues_charges += $guarantor->account->non_issues_charges if $include_guarantors && !$seen->{ $guarantor->id };
 540
 541         # We've added what the guarantor owes, not added in that guarantor's guarantees as well
 542         my @guarantees = map { $_->guarantee } $guarantor->guarantee_relationships->as_list;
 543         my $guarantees_non_issues_charges = 0;
 544         foreach my $guarantee (@guarantees) {
 545             next if $seen->{ $guarantee->id };
 546             $guarantees_non_issues_charges += $guarantee->account->non_issues_charges;
 547             # Mark this guarantee as seen so we don't double count a guarantee linked to multiple guarantors
 548             $seen->{ $guarantee->id } = 1;
 549         }
 550
 551         $non_issues_charges += $guarantees_non_issues_charges;
 552         $seen->{ $guarantor->id } = 1;
 553     }
 554
 555     return $non_issues_charges;
 556 }
 557
 558 =head3 housebound_profile
 559
 560 Returns the HouseboundProfile associated with this patron.
 561
 562 =cut
 563
 564 sub housebound_profile {
 565     my ( $self ) = @_;
 566     my $profile = $self->_result->housebound_profile;
 567     return Koha::Patron::HouseboundProfile->_new_from_dbic($profile)
 568         if ( $profile );
 569     return;
 570 }
 571
 572 =head3 housebound_role
 573
 574 Returns the HouseboundRole associated with this patron.
 575
 576 =cut
 577
 578 sub housebound_role {
 579     my ( $self ) = @_;
 580
 581     my $role = $self->_result->housebound_role;
 582     return Koha::Patron::HouseboundRole->_new_from_dbic($role) if ( $role );
 583     return;
 584 }
 585
 586 =head3 siblings
 587
 588 Returns the siblings of this patron.
 589
 590 =cut
 591
 592 sub siblings {
 593     my ($self) = @_;
 594
 595     my @guarantors = $self->guarantor_relationships()->guarantors()->as_list;
 596
 597     return unless @guarantors;
 598
 599     my @siblings =
 600       map { $_->guarantee_relationships()->guarantees()->as_list } @guarantors;
 601
 602     return unless @siblings;
 603
 604     my %seen;
 605     @siblings =
 606       grep { !$seen{ $_->id }++ && ( $_->id != $self->id ) } @siblings;
 607
 608     return Koha::Patrons->search( { borrowernumber => { -in => [ map { $_->id } @siblings ] } } );
 609 }
 610
 611 =head3 merge_with
 612
 613     my $patron = Koha::Patrons->find($id);
 614     $patron->merge_with( \@patron_ids );
 615
 616     This subroutine merges a list of patrons into the patron record. This is accomplished by finding
 617     all related patron ids for the patrons to be merged in other tables and changing the ids to be that
 618     of the keeper patron.
 619
 620 =cut
 621
 622 sub merge_with {
 623     my ( $self, $patron_ids ) = @_;
 624
 625     my $anonymous_patron = C4::Context->preference("AnonymousPatron");
 626     return if $anonymous_patron && $self->id eq $anonymous_patron;
 627
 628     my @patron_ids = @{ $patron_ids };
 629
 630     # Ensure the keeper isn't in the list of patrons to merge
 631     @patron_ids = grep { $_ ne $self->id } @patron_ids;
 632
 633     my $schema = Koha::Database->new()->schema();
 634
 635     my $results;
 636
 637     $self->_result->result_source->schema->txn_do( sub {
 638         foreach my $patron_id (@patron_ids) {
 639
 640             next if $patron_id eq $anonymous_patron;
 641
 642             my $patron = Koha::Patrons->find( $patron_id );
 643
 644             next unless $patron;
 645
 646             # Unbless for safety, the patron will end up being deleted
 647             $results->{merged}->{$patron_id}->{patron} = $patron->unblessed;
 648
 649             my $attributes = $patron->extended_attributes;
 650             my $new_attributes = [
 651                 map { { code => $_->code, attribute => $_->attribute } }
 652                     $attributes->as_list
 653             ];
 654             $attributes->delete; # We need to delete before trying to merge them to prevent exception on unique and repeatable
 655             for my $attribute ( @$new_attributes ) {
 656                 try {
 657                     $self->add_extended_attribute($attribute);
 658                 } catch {
 659                     # Don't block the merge if there is a non-repeatable attribute that cannot be added to the current patron.
 660                     unless ( $_->isa('Koha::Exceptions::Patron::Attribute::NonRepeatable') ) {
 661                         $_->rethrow;
 662                     }
 663                 };
 664             }
 665
 666             while (my ($r, $field) = each(%$RESULTSET_PATRON_ID_MAPPING)) {
 667                 my $rs = $schema->resultset($r)->search({ $field => $patron_id });
 668                 $results->{merged}->{ $patron_id }->{updated}->{$r} = $rs->count();
 669                 $rs->update({ $field => $self->id });
 670                 if ( $r eq 'BorrowerDebarment' ) {
 671                     Koha::Patron::Debarments::UpdateBorrowerDebarmentFlags($self->id);
 672                 }
 673             }
 674
 675             $patron->move_to_deleted();
 676             $patron->delete();
 677         }
 678     });
 679
 680     return $results;
 681 }
 682
 683
 684
 685 =head3 wants_check_for_previous_checkout
 686
 687     $wants_check = $patron->wants_check_for_previous_checkout;
 688
 689 Return 1 if Koha needs to perform PrevIssue checking, else 0.
 690
 691 =cut
 692
 693 sub wants_check_for_previous_checkout {
 694     my ( $self ) = @_;
 695     my $syspref = C4::Context->preference("checkPrevCheckout");
 696
 697     # Simple cases
 698     ## Hard syspref trumps all
 699     return 1 if ($syspref eq 'hardyes');
 700     return 0 if ($syspref eq 'hardno');
 701     ## Now, patron pref trumps all
 702     return 1 if ($self->checkprevcheckout eq 'yes');
 703     return 0 if ($self->checkprevcheckout eq 'no');
 704
 705     # More complex: patron inherits -> determine category preference
 706     my $checkPrevCheckoutByCat = $self->category->checkprevcheckout;
 707     return 1 if ($checkPrevCheckoutByCat eq 'yes');
 708     return 0 if ($checkPrevCheckoutByCat eq 'no');
 709
 710     # Finally: category preference is inherit, default to 0
 711     if ($syspref eq 'softyes') {
 712         return 1;
 713     } else {
 714         return 0;
 715     }
 716 }
 717
 718 =head3 do_check_for_previous_checkout
 719
 720     $do_check = $patron->do_check_for_previous_checkout($item);
 721
 722 Return 1 if the bib associated with $ITEM has previously been checked out to
 723 $PATRON, 0 otherwise.
 724
 725 =cut
 726
 727 sub do_check_for_previous_checkout {
 728     my ( $self, $item ) = @_;
 729
 730     my @item_nos;
 731     my $biblio = Koha::Biblios->find( $item->{biblionumber} );
 732     if ( $biblio->is_serial ) {
 733         push @item_nos, $item->{itemnumber};
 734     } else {
 735         # Get all itemnumbers for given bibliographic record.
 736         @item_nos = $biblio->items->get_column( 'itemnumber' );
 737     }
 738
 739     # Create (old)issues search criteria
 740     my $criteria = {
 741         borrowernumber => $self->borrowernumber,
 742         itemnumber => \@item_nos,
 743     };
 744
 745     my $delay = C4::Context->preference('CheckPrevCheckoutDelay') || 0;
 746     if ($delay) {
 747         my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 748         my $newer_than = dt_from_string()->subtract( days => $delay );
 749         $criteria->{'returndate'} = { '>'   =>  $dtf->format_datetime($newer_than), };
 750     }
 751
 752     # Check current issues table
 753     my $issues = Koha::Checkouts->search($criteria);
 754     return 1 if $issues->count; # 0 || N
 755
 756     # Check old issues table
 757     my $old_issues = Koha::Old::Checkouts->search($criteria);
 758     return $old_issues->count;  # 0 || N
 759 }
 760
 761 =head3 is_debarred
 762
 763 my $debarment_expiration = $patron->is_debarred;
 764
 765 Returns the date a patron debarment will expire, or undef if the patron is not
 766 debarred
 767
 768 =cut
 769
 770 sub is_debarred {
 771     my ($self) = @_;
 772
 773     return unless $self->debarred;
 774     return $self->debarred
 775       if $self->debarred =~ '^9999'
 776       or dt_from_string( $self->debarred ) > dt_from_string;
 777     return;
 778 }
 779
 780 =head3 is_expired
 781
 782 my $is_expired = $patron->is_expired;
 783
 784 Returns 1 if the patron is expired or 0;
 785
 786 =cut
 787
 788 sub is_expired {
 789     my ($self) = @_;
 790     return 0 unless $self->dateexpiry;
 791     return 0 if $self->dateexpiry =~ '^9999';
 792     return 1 if dt_from_string( $self->dateexpiry ) < dt_from_string->truncate( to => 'day' );
 793     return 0;
 794 }
 795
 796 =head3 password_expired
 797
 798 my $password_expired = $patron->password_expired;
 799
 800 Returns 1 if the patron's password is expired or 0;
 801
 802 =cut
 803
 804 sub password_expired {
 805     my ($self) = @_;
 806     return 0 unless $self->password_expiration_date;
 807     return 1 if dt_from_string( $self->password_expiration_date ) <= dt_from_string->truncate( to => 'day' );
 808     return 0;
 809 }
 810
 811 =head3 is_going_to_expire
 812
 813 my $is_going_to_expire = $patron->is_going_to_expire;
 814
 815 Returns 1 if the patron is going to expired, depending on the NotifyBorrowerDeparture pref or 0
 816
 817 =cut
 818
 819 sub is_going_to_expire {
 820     my ($self) = @_;
 821
 822     my $delay = C4::Context->preference('NotifyBorrowerDeparture') || 0;
 823
 824     return 0 unless $delay;
 825     return 0 unless $self->dateexpiry;
 826     return 0 if $self->dateexpiry =~ '^9999';
 827     return 1 if dt_from_string( $self->dateexpiry, undef, 'floating' )->subtract( days => $delay ) < dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
 828     return 0;
 829 }
 830
 831 =head3 set_password
 832
 833     $patron->set_password({ password => $plain_text_password [, skip_validation => 1 ] });
 834
 835 Set the patron's password.
 836
 837 =head4 Exceptions
 838
 839 The passed string is validated against the current password enforcement policy.
 840 Validation can be skipped by passing the I<skip_validation> parameter.
 841
 842 Exceptions are thrown if the password is not good enough.
 843
 844 =over 4
 845
 846 =item Koha::Exceptions::Password::TooShort
 847
 848 =item Koha::Exceptions::Password::WhitespaceCharacters
 849
 850 =item Koha::Exceptions::Password::TooWeak
 851
 852 =item Koha::Exceptions::Password::Plugin (if a "check password" plugin is enabled)
 853
 854 =back
 855
 856 =cut
 857
 858 sub set_password {
 859     my ( $self, $args ) = @_;
 860
 861     my $password = $args->{password};
 862
 863     unless ( $args->{skip_validation} ) {
 864         my ( $is_valid, $error ) = Koha::AuthUtils::is_password_valid( $password, $self->category );
 865
 866         if ( !$is_valid ) {
 867             if ( $error eq 'too_short' ) {
 868                 my $min_length = $self->category->effective_min_password_length;
 869                 $min_length = 3 if not $min_length or $min_length < 3;
 870
 871                 my $password_length = length($password);
 872                 Koha::Exceptions::Password::TooShort->throw(
 873                     length => $password_length, min_length => $min_length );
 874             }
 875             elsif ( $error eq 'has_whitespaces' ) {
 876                 Koha::Exceptions::Password::WhitespaceCharacters->throw();
 877             }
 878             elsif ( $error eq 'too_weak' ) {
 879                 Koha::Exceptions::Password::TooWeak->throw();
 880             }
 881         }
 882     }
 883
 884     if ( C4::Context->config("enable_plugins") ) {
 885         # Call any check_password plugins
 886         my @plugins = Koha::Plugins->new()->GetPlugins({
 887             method => 'check_password',
 888         });
 889         foreach my $plugin ( @plugins ) {
 890             # This plugin hook will also be used by a plugin for the Norwegian national
 891             # patron database. This is why we need to pass both the password and the
 892             # borrowernumber to the plugin.
 893             my $ret = $plugin->check_password(
 894                 {
 895                     password       => $password,
 896                     borrowernumber => $self->borrowernumber
 897                 }
 898             );
 899             # This plugin hook will also be used by a plugin for the Norwegian national
 900             # patron database. This is why we need to call the actual plugins and then
 901             # check skip_validation afterwards.
 902             if ( $ret->{'error'} == 1 && !$args->{skip_validation} ) {
 903                 Koha::Exceptions::Password::Plugin->throw();
 904             }
 905         }
 906     }
 907
 908     if ( C4::Context->preference('NotifyPasswordChange') ) {
 909         my $self_from_storage = $self->get_from_storage;
 910         if ( !C4::Auth::checkpw_hash( $password, $self_from_storage->password ) ) {
 911             my $emailaddr = $self_from_storage->notice_email_address;
 912
 913             # if we manage to find a valid email address, send notice
 914             if ($emailaddr) {
 915                 my $letter = C4::Letters::GetPreparedLetter(
 916                     module      => 'members',
 917                     letter_code => 'PASSWORD_CHANGE',
 918                     branchcode  => $self_from_storage->branchcode,
 919                     ,
 920                     lang   => $self_from_storage->lang || 'default',
 921                     tables => {
 922                         'branches'  => $self_from_storage->branchcode,
 923                         'borrowers' => $self_from_storage->borrowernumber,
 924                     },
 925                     want_librarian => 1,
 926                 ) or return;
 927
 928                 my $message_id = C4::Letters::EnqueueLetter(
 929                     {
 930                         letter                 => $letter,
 931                         borrowernumber         => $self_from_storage->id,
 932                         to_address             => $emailaddr,
 933                         message_transport_type => 'email'
 934                     }
 935                 );
 936                 C4::Letters::SendQueuedMessages( { message_id => $message_id } ) if $message_id;
 937             }
 938         }
 939     }
 940
 941     my $digest = Koha::AuthUtils::hash_password($password);
 942
 943     $self->password_expiration_date( $self->category->get_password_expiry_date || undef );
 944
 945     # We do not want to call $self->store and retrieve password from DB
 946     $self->password($digest);
 947     $self->login_attempts(0);
 948     $self->SUPER::store;
 949
 950     logaction( "MEMBERS", "CHANGE PASS", $self->borrowernumber, "" )
 951         if C4::Context->preference("BorrowersLog");
 952
 953     return $self;
 954 }
 955
 956
 957 =head3 renew_account
 958
 959 my $new_expiry_date = $patron->renew_account
 960
 961 Extending the subscription to the expiry date.
 962
 963 =cut
 964
 965 sub renew_account {
 966     my ($self) = @_;
 967     my $date;
 968     if ( C4::Context->preference('BorrowerRenewalPeriodBase') eq 'combination' ) {
 969         $date = ( dt_from_string gt dt_from_string( $self->dateexpiry ) ) ? dt_from_string : dt_from_string( $self->dateexpiry );
 970     } else {
 971         $date =
 972             C4::Context->preference('BorrowerRenewalPeriodBase') eq 'dateexpiry'
 973             ? dt_from_string( $self->dateexpiry )
 974             : dt_from_string;
 975     }
 976     my $expiry_date = $self->category->get_expiry_date($date);
 977
 978     $self->dateexpiry($expiry_date);
 979     $self->date_renewed( dt_from_string() );
 980     $self->store();
 981
 982     $self->add_enrolment_fee_if_needed(1);
 983
 984     logaction( "MEMBERS", "RENEW", $self->borrowernumber, "Membership renewed" ) if C4::Context->preference("BorrowersLog");
 985     return dt_from_string( $expiry_date )->truncate( to => 'day' );
 986 }
 987
 988 =head3 has_overdues
 989
 990 my $has_overdues = $patron->has_overdues;
 991
 992 Returns the number of patron's overdues
 993
 994 =cut
 995
 996 sub has_overdues {
 997     my ($self) = @_;
 998     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 999     return $self->_result->issues->search({ date_due => { '<' => $dtf->format_datetime( dt_from_string() ) } })->count;
1000 }
1001
1002 =head3 track_login
1003
1004     $patron->track_login;
1005     $patron->track_login({ force => 1 });
1006
1007     Tracks a (successful) login attempt.
1008     The preference TrackLastPatronActivity must be enabled. Or you
1009     should pass the force parameter.
1010
1011 =cut
1012
1013 sub track_login {
1014     my ( $self, $params ) = @_;
1015     return if
1016         !$params->{force} &&
1017         !C4::Context->preference('TrackLastPatronActivity');
1018     $self->lastseen( dt_from_string() )->store;
1019 }
1020
1021 =head3 move_to_deleted
1022
1023 my $is_moved = $patron->move_to_deleted;
1024
1025 Move a patron to the deletedborrowers table.
1026 This can be done before deleting a patron, to make sure the data are not completely deleted.
1027
1028 =cut
1029
1030 sub move_to_deleted {
1031     my ($self) = @_;
1032     my $patron_infos = $self->unblessed;
1033     delete $patron_infos->{updated_on}; #This ensures the updated_on date in deletedborrowers will be set to the current timestamp
1034     return Koha::Database->new->schema->resultset('Deletedborrower')->create($patron_infos);
1035 }
1036
1037 =head3 can_request_article
1038
1039     if ( $patron->can_request_article( $library->id ) ) { ... }
1040
1041 Returns true if the patron can request articles. As limits apply for the patron
1042 on the same day, those completed the same day are considered as current.
1043
1044 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1045
1046 =cut
1047
1048 sub can_request_article {
1049     my ($self, $library_id) = @_;
1050
1051     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1052
1053     my $rule = Koha::CirculationRules->get_effective_rule(
1054         {
1055             branchcode   => $library_id,
1056             categorycode => $self->categorycode,
1057             rule_name    => 'open_article_requests_limit'
1058         }
1059     );
1060
1061     my $limit = ($rule) ? $rule->rule_value : undef;
1062
1063     return 1 unless defined $limit;
1064
1065     my $count = Koha::ArticleRequests->search(
1066         [   { borrowernumber => $self->borrowernumber, status => [ 'REQUESTED', 'PENDING', 'PROCESSING' ] },
1067             { borrowernumber => $self->borrowernumber, status => 'COMPLETED', updated_on => { '>=' => \'CAST(NOW() AS DATE)' } },
1068         ]
1069     )->count;
1070     return $count < $limit ? 1 : 0;
1071 }
1072
1073 =head3 article_request_fee
1074
1075     my $fee = $patron->article_request_fee(
1076         {
1077           [ library_id => $library->id, ]
1078         }
1079     );
1080
1081 Returns the fee to be charged to the patron when it places an article request.
1082
1083 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1084
1085 =cut
1086
1087 sub article_request_fee {
1088     my ($self, $params) = @_;
1089
1090     my $library_id = $params->{library_id};
1091
1092     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1093
1094     my $rule = Koha::CirculationRules->get_effective_rule(
1095         {
1096             branchcode   => $library_id,
1097             categorycode => $self->categorycode,
1098             rule_name    => 'article_request_fee'
1099         }
1100     );
1101
1102     my $fee = ($rule) ? $rule->rule_value + 0 : 0;
1103
1104     return $fee;
1105 }
1106
1107 =head3 add_article_request_fee_if_needed
1108
1109     my $fee = $patron->add_article_request_fee_if_needed(
1110         {
1111           [ item_id    => $item->id,
1112             library_id => $library->id, ]
1113         }
1114     );
1115
1116 If an article request fee needs to be charged, it adds a debit to the patron's
1117 account.
1118
1119 Returns the fee line.
1120
1121 A I<library_id> can be passed as parameter, falling back to userenv if absent.
1122
1123 =cut
1124
1125 sub add_article_request_fee_if_needed {
1126     my ($self, $params) = @_;
1127
1128     my $library_id = $params->{library_id};
1129     my $item_id    = $params->{item_id};
1130
1131     $library_id //= C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
1132
1133     my $amount = $self->article_request_fee(
1134         {
1135             library_id => $library_id,
1136         }
1137     );
1138
1139     my $debit_line;
1140
1141     if ( $amount > 0 ) {
1142         $debit_line = $self->account->add_debit(
1143             {
1144                 amount     => $amount,
1145                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1146                 interface  => C4::Context->interface,
1147                 library_id => $library_id,
1148                 type       => 'ARTICLE_REQUEST',
1149                 item_id    => $item_id,
1150             }
1151         );
1152     }
1153
1154     return $debit_line;
1155 }
1156
1157 =head3 article_requests
1158
1159     my $article_requests = $patron->article_requests;
1160
1161 Returns the patron article requests.
1162
1163 =cut
1164
1165 sub article_requests {
1166     my ($self) = @_;
1167
1168     return Koha::ArticleRequests->_new_from_dbic( scalar $self->_result->article_requests );
1169 }
1170
1171 =head3 add_enrolment_fee_if_needed
1172
1173 my $enrolment_fee = $patron->add_enrolment_fee_if_needed($renewal);
1174
1175 Add enrolment fee for a patron if needed.
1176
1177 $renewal - boolean denoting whether this is an account renewal or not
1178
1179 =cut
1180
1181 sub add_enrolment_fee_if_needed {
1182     my ($self, $renewal) = @_;
1183     my $enrolment_fee = $self->category->enrolmentfee;
1184     if ( $enrolment_fee && $enrolment_fee > 0 ) {
1185         my $type = $renewal ? 'ACCOUNT_RENEW' : 'ACCOUNT';
1186         $self->account->add_debit(
1187             {
1188                 amount     => $enrolment_fee,
1189                 user_id    => C4::Context->userenv ? C4::Context->userenv->{'number'} : undef,
1190                 interface  => C4::Context->interface,
1191                 library_id => C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef,
1192                 type       => $type
1193             }
1194         );
1195     }
1196     return $enrolment_fee || 0;
1197 }
1198
1199 =head3 checkouts
1200
1201 my $checkouts = $patron->checkouts
1202
1203 =cut
1204
1205 sub checkouts {
1206     my ($self) = @_;
1207     my $checkouts = $self->_result->issues;
1208     return Koha::Checkouts->_new_from_dbic( $checkouts );
1209 }
1210
1211 =head3 pending_checkouts
1212
1213 my $pending_checkouts = $patron->pending_checkouts
1214
1215 This method will return the same as $self->checkouts, but with a prefetch on
1216 items, biblio and biblioitems.
1217
1218 It has been introduced to replaced the C4::Members::GetPendingIssues subroutine
1219
1220 It should not be used directly, prefer to access fields you need instead of
1221 retrieving all these fields in one go.
1222
1223 =cut
1224
1225 sub pending_checkouts {
1226     my( $self ) = @_;
1227     my $checkouts = $self->_result->issues->search(
1228         {},
1229         {
1230             order_by => [
1231                 { -desc => 'me.timestamp' },
1232                 { -desc => 'issuedate' },
1233                 { -desc => 'issue_id' }, # Sort by issue_id should be enough
1234             ],
1235             prefetch => { item => { biblio => 'biblioitems' } },
1236         }
1237     );
1238     return Koha::Checkouts->_new_from_dbic( $checkouts );
1239 }
1240
1241 =head3 old_checkouts
1242
1243 my $old_checkouts = $patron->old_checkouts
1244
1245 =cut
1246
1247 sub old_checkouts {
1248     my ($self) = @_;
1249     my $old_checkouts = $self->_result->old_issues;
1250     return Koha::Old::Checkouts->_new_from_dbic( $old_checkouts );
1251 }
1252
1253 =head3 overdues
1254
1255 my $overdue_items = $patron->overdues
1256
1257 Return the overdue items
1258
1259 =cut
1260
1261 sub overdues {
1262     my ($self) = @_;
1263     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
1264     return $self->checkouts->search(
1265         {
1266             'me.date_due' => { '<' => $dtf->format_datetime(dt_from_string) },
1267         },
1268         {
1269             prefetch => { item => { biblio => 'biblioitems' } },
1270         }
1271     );
1272 }
1273
1274
1275 =head3 restrictions
1276
1277   my $restrictions = $patron->restrictions;
1278
1279 Returns the patron restrictions.
1280
1281 =cut
1282
1283 sub restrictions {
1284     my ($self) = @_;
1285     my $restrictions_rs = $self->_result->restrictions;
1286     return Koha::Patron::Restrictions->_new_from_dbic($restrictions_rs);
1287 }
1288
1289 =head3 get_routing_lists
1290
1291 my $routinglists = $patron->get_routing_lists
1292
1293 Returns the routing lists a patron is subscribed to.
1294
1295 =cut
1296
1297 sub get_routing_lists {
1298     my ($self) = @_;
1299     my $routing_list_rs = $self->_result->subscriptionroutinglists;
1300     return Koha::Subscription::Routinglists->_new_from_dbic($routing_list_rs);
1301 }
1302
1303 =head3 get_age
1304
1305     my $age = $patron->get_age
1306
1307 Return the age of the patron
1308
1309 =cut
1310
1311 sub get_age {
1312     my ($self)    = @_;
1313
1314     return unless $self->dateofbirth;
1315
1316     #Set timezone to floating to avoid any datetime math issues caused by DST
1317     my $date_of_birth = dt_from_string( $self->dateofbirth, undef, 'floating' );
1318     my $today         = dt_from_string(undef, undef, 'floating')->truncate( to => 'day' );
1319
1320     return $today->subtract_datetime( $date_of_birth )->years;
1321 }
1322
1323 =head3 is_valid_age
1324
1325 my $is_valid = $patron->is_valid_age
1326
1327 Return 1 if patron's age is between allowed limits, returns 0 if it's not.
1328
1329 =cut
1330
1331 sub is_valid_age {
1332     my ($self) = @_;
1333     my $age = $self->get_age;
1334
1335     my $patroncategory = $self->category;
1336     my ($low,$high) = ($patroncategory->dateofbirthrequired, $patroncategory->upperagelimit);
1337
1338     return (defined($age) && (($high && ($age > $high)) or ($low && ($age < $low)))) ? 0 : 1;
1339 }
1340
1341 =head3 account
1342
1343 my $account = $patron->account
1344
1345 =cut
1346
1347 sub account {
1348     my ($self) = @_;
1349     return Koha::Account->new( { patron_id => $self->borrowernumber } );
1350 }
1351
1352 =head3 holds
1353
1354 my $holds = $patron->holds
1355
1356 Return all the holds placed by this patron
1357
1358 =cut
1359
1360 sub holds {
1361     my ($self) = @_;
1362     my $holds_rs = $self->_result->reserves->search( {}, { order_by => 'reservedate' } );
1363     return Koha::Holds->_new_from_dbic($holds_rs);
1364 }
1365
1366 =head3 old_holds
1367
1368 my $old_holds = $patron->old_holds
1369
1370 Return all the historical holds for this patron
1371
1372 =cut
1373
1374 sub old_holds {
1375     my ($self) = @_;
1376     my $old_holds_rs = $self->_result->old_reserves->search( {}, { order_by => 'reservedate' } );
1377     return Koha::Old::Holds->_new_from_dbic($old_holds_rs);
1378 }
1379
1380 =head3 curbside_pickups
1381
1382 my $curbside_pickups = $patron->curbside_pickups;
1383
1384 Return all the curbside pickups for this patron
1385
1386 =cut
1387
1388 sub curbside_pickups {
1389     my ($self) = @_;
1390     my $curbside_pickups_rs = $self->_result->curbside_pickups_borrowernumbers->search;
1391     return Koha::CurbsidePickups->_new_from_dbic($curbside_pickups_rs);
1392 }
1393
1394 =head3 return_claims
1395
1396 my $return_claims = $patron->return_claims
1397
1398 =cut
1399
1400 sub return_claims {
1401     my ($self) = @_;
1402     my $return_claims = $self->_result->return_claims_borrowernumbers;
1403     return Koha::Checkouts::ReturnClaims->_new_from_dbic( $return_claims );
1404 }
1405
1406 =head3 notice_email_address
1407
1408   my $email = $patron->notice_email_address;
1409
1410 Return the email address of patron used for notices.
1411 Returns the empty string if no email address.
1412
1413 =cut
1414
1415 sub notice_email_address{
1416     my ( $self ) = @_;
1417
1418     my $which_address = C4::Context->preference("EmailFieldPrimary");
1419     # if syspref is set to 'first valid' (value == OFF), look up email address
1420     if ( $which_address eq 'OFF' ) {
1421         return $self->first_valid_email_address;
1422     }
1423
1424     return $self->$which_address || '';
1425 }
1426
1427 =head3 first_valid_email_address
1428
1429 my $first_valid_email_address = $patron->first_valid_email_address
1430
1431 Return the first valid email address for a patron.
1432 For now, the order  is defined as email, emailpro, B_email.
1433 Returns the empty string if the borrower has no email addresses.
1434
1435 =cut
1436
1437 sub first_valid_email_address {
1438     my ($self) = @_;
1439
1440     my $email = q{};
1441
1442     my @fields = split /\s*\|\s*/,
1443       C4::Context->preference('EmailFieldPrecedence');
1444     for my $field (@fields) {
1445         $email = $self->$field;
1446         last if ($email);
1447     }
1448
1449     return $email;
1450 }
1451
1452 =head3 get_club_enrollments
1453
1454 =cut
1455
1456 sub get_club_enrollments {
1457     my ( $self ) = @_;
1458
1459     return Koha::Club::Enrollments->search( { borrowernumber => $self->borrowernumber(), date_canceled => undef } );
1460 }
1461
1462 =head3 get_enrollable_clubs
1463
1464 =cut
1465
1466 sub get_enrollable_clubs {
1467     my ( $self, $is_enrollable_from_opac ) = @_;
1468
1469     my $params;
1470     $params->{is_enrollable_from_opac} = $is_enrollable_from_opac
1471       if $is_enrollable_from_opac;
1472     $params->{is_email_required} = 0 unless $self->first_valid_email_address();
1473
1474     $params->{borrower} = $self;
1475
1476     return Koha::Clubs->get_enrollable($params);
1477 }
1478
1479 =head3 account_locked
1480
1481 my $is_locked = $patron->account_locked
1482
1483 Return true if the patron has reached the maximum number of login attempts
1484 (see pref FailedLoginAttempts). If login_attempts is < 0, this is interpreted
1485 as an administrative lockout (independent of FailedLoginAttempts; see also
1486 Koha::Patron->lock).
1487 Otherwise return false.
1488 If the pref is not set (empty string, null or 0), the feature is considered as
1489 disabled.
1490
1491 =cut
1492
1493 sub account_locked {
1494     my ($self) = @_;
1495     my $FailedLoginAttempts = C4::Context->preference('FailedLoginAttempts');
1496     return 1 if $FailedLoginAttempts
1497           and $self->login_attempts
1498           and $self->login_attempts >= $FailedLoginAttempts;
1499     return 1 if ($self->login_attempts || 0) < 0; # administrative lockout
1500     return 0;
1501 }
1502
1503 =head3 can_see_patron_infos
1504
1505 my $can_see = $patron->can_see_patron_infos( $patron );
1506
1507 Return true if the patron (usually the logged in user) can see the patron's infos for a given patron
1508
1509 =cut
1510
1511 sub can_see_patron_infos {
1512     my ( $self, $patron ) = @_;
1513     return unless $patron;
1514     return $self->can_see_patrons_from( $patron->branchcode );
1515 }
1516
1517 =head3 can_see_patrons_from
1518
1519 my $can_see = $patron->can_see_patrons_from( $branchcode );
1520
1521 Return true if the patron (usually the logged in user) can see the patron's infos from a given library
1522
1523 =cut
1524
1525 sub can_see_patrons_from {
1526     my ( $self, $branchcode ) = @_;
1527
1528     return $self->can_see_things_from(
1529         {
1530             branchcode => $branchcode,
1531             permission => 'borrowers',
1532             subpermission => 'view_borrower_infos_from_any_libraries',
1533         }
1534     );
1535 }
1536
1537 =head3 can_edit_items_from
1538
1539     my $can_edit = $patron->can_edit_items_from( $branchcode );
1540
1541 Return true if the I<Koha::Patron> can edit items from the given branchcode
1542
1543 =cut
1544
1545 sub can_edit_items_from {
1546     my ( $self, $branchcode ) = @_;
1547
1548     return 1 if C4::Context->IsSuperLibrarian();
1549
1550     my $userenv = C4::Context->userenv();
1551     if ( $userenv && C4::Context->preference('IndependentBranches') ) {
1552         return $userenv->{branch} eq $branchcode;
1553     }
1554
1555     return $self->can_see_things_from(
1556         {
1557             branchcode    => $branchcode,
1558             permission    => 'editcatalogue',
1559             subpermission => 'edit_any_item',
1560         }
1561     );
1562 }
1563
1564 =head3 libraries_where_can_edit_items
1565
1566     my $libraries = $patron->libraries_where_can_edit_items;
1567
1568 Return the list of branchcodes(!) of libraries the patron is allowed to items for.
1569 The branchcodes are arbitrarily returned sorted.
1570 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1571
1572 An empty array means no restriction, the user can edit any item.
1573
1574 =cut
1575
1576 sub libraries_where_can_edit_items {
1577     my ($self) = @_;
1578
1579     return $self->libraries_where_can_see_things(
1580         {
1581             permission    => 'editcatalogue',
1582             subpermission => 'edit_any_item',
1583             group_feature => 'ft_limit_item_editing',
1584         }
1585     );
1586 }
1587
1588 =head3 libraries_where_can_see_patrons
1589
1590 my $libraries = $patron->libraries_where_can_see_patrons;
1591
1592 Return the list of branchcodes(!) of libraries the patron is allowed to see other patron's infos.
1593 The branchcodes are arbitrarily returned sorted.
1594 We are supposing here that the object is related to the logged in patron (use of C4::Context::only_my_library)
1595
1596 An empty array means no restriction, the patron can see patron's infos from any libraries.
1597
1598 =cut
1599
1600 sub libraries_where_can_see_patrons {
1601     my ($self) = @_;
1602
1603     return $self->libraries_where_can_see_things(
1604         {
1605             permission    => 'borrowers',
1606             subpermission => 'view_borrower_infos_from_any_libraries',
1607             group_feature => 'ft_hide_patron_info',
1608         }
1609     );
1610 }
1611
1612 =head3 can_see_things_from
1613
1614 my $can_see = $patron->can_see_things_from( $branchcode );
1615
1616 Return true if the I<Koha::Patron> can perform some action on the given thing
1617
1618 =cut
1619
1620 sub can_see_things_from {
1621     my ( $self, $params ) = @_;
1622
1623     my $branchcode    = $params->{branchcode};
1624     my $permission    = $params->{permission};
1625     my $subpermission = $params->{subpermission};
1626
1627     return 1 if C4::Context->IsSuperLibrarian();
1628
1629     my $can = 0;
1630     if ( $self->branchcode eq $branchcode ) {
1631         $can = 1;
1632     } elsif ( $self->has_permission( { $permission => $subpermission } ) ) {
1633         $can = 1;
1634     } elsif ( my $library_groups = $self->library->library_groups ) {
1635         while ( my $library_group = $library_groups->next ) {
1636             if ( $library_group->parent->has_child( $branchcode ) ) {
1637                 $can = 1;
1638                 last;
1639             }
1640         }
1641     }
1642     return $can;
1643 }
1644
1645 =head3 can_log_into
1646
1647 my $can_log_into = $patron->can_log_into( $library );
1648
1649 Given a I<Koha::Library> object, it returns a boolean representing
1650 the fact the patron can log into a the library.
1651
1652 =cut
1653
1654 sub can_log_into {
1655     my ( $self, $library ) = @_;
1656
1657     my $can = 0;
1658
1659     if ( C4::Context->preference('IndependentBranches') ) {
1660         $can = 1
1661           if $self->is_superlibrarian
1662           or $self->branchcode eq $library->id;
1663     }
1664     else {
1665         # no restrictions
1666         $can = 1;
1667     }
1668
1669    return $can;
1670 }
1671
1672 =head3 libraries_where_can_see_things
1673
1674     my $libraries = $patron->libraries_where_can_see_things;
1675
1676 Returns a list of libraries where an aribitarary action is allowed to be taken by the logged in librarian
1677 against an object based on some branchcode related to the object ( patron branchcode, item homebranch, etc ).
1678
1679 We are supposing here that the object is related to the logged in librarian (use of C4::Context::only_my_library)
1680
1681 An empty array means no restriction, the thing can see thing's infos from any libraries.
1682
1683 =cut
1684
1685 sub libraries_where_can_see_things {
1686     my ( $self, $params ) = @_;
1687     my $permission    = $params->{permission};
1688     my $subpermission = $params->{subpermission};
1689     my $group_feature = $params->{group_feature};
1690
1691     my $userenv = C4::Context->userenv;
1692
1693     return () unless $userenv; # For tests, but userenv should be defined in tests...
1694
1695     my @restricted_branchcodes;
1696     if (C4::Context::only_my_library) {
1697         push @restricted_branchcodes, $self->branchcode;
1698     }
1699     else {
1700         unless (
1701             $self->has_permission(
1702                 { $permission => $subpermission }
1703             )
1704           )
1705         {
1706             my $library_groups = $self->library->library_groups({ $group_feature => 1 });
1707             if ( $library_groups->count )
1708             {
1709                 while ( my $library_group = $library_groups->next ) {
1710                     my $parent = $library_group->parent;
1711                     if ( $parent->has_child( $self->branchcode ) ) {
1712                         push @restricted_branchcodes, $parent->children->get_column('branchcode');
1713                     }
1714                 }
1715             }
1716
1717             @restricted_branchcodes = ( $self->branchcode ) unless @restricted_branchcodes;
1718         }
1719     }
1720
1721     @restricted_branchcodes = grep { defined $_ } @restricted_branchcodes;
1722     @restricted_branchcodes = uniq(@restricted_branchcodes);
1723     @restricted_branchcodes = sort(@restricted_branchcodes);
1724     return @restricted_branchcodes;
1725 }
1726
1727 =head3 has_permission
1728
1729 my $permission = $patron->has_permission($required);
1730
1731 See C4::Auth::haspermission for details of syntax for $required
1732
1733 =cut
1734
1735 sub has_permission {
1736     my ( $self, $flagsrequired ) = @_;
1737     return unless $self->userid;
1738     # TODO code from haspermission needs to be moved here!
1739     return C4::Auth::haspermission( $self->userid, $flagsrequired );
1740 }
1741
1742 =head3 is_superlibrarian
1743
1744   my $is_superlibrarian = $patron->is_superlibrarian;
1745
1746 Return true if the patron is a superlibrarian.
1747
1748 =cut
1749
1750 sub is_superlibrarian {
1751     my ($self) = @_;
1752     return $self->has_permission( { superlibrarian => 1 } ) ? 1 : 0;
1753 }
1754
1755 =head3 is_adult
1756
1757 my $is_adult = $patron->is_adult
1758
1759 Return true if the patron has a category with a type Adult (A) or Organization (I)
1760
1761 =cut
1762
1763 sub is_adult {
1764     my ( $self ) = @_;
1765     return $self->category->category_type =~ /^(A|I)$/ ? 1 : 0;
1766 }
1767
1768 =head3 is_child
1769
1770 my $is_child = $patron->is_child
1771
1772 Return true if the patron has a category with a type Child (C)
1773
1774 =cut
1775
1776 sub is_child {
1777     my( $self ) = @_;
1778     return $self->category->category_type eq 'C' ? 1 : 0;
1779 }
1780
1781 =head3 has_valid_userid
1782
1783 my $patron = Koha::Patrons->find(42);
1784 $patron->userid( $new_userid );
1785 my $has_a_valid_userid = $patron->has_valid_userid
1786
1787 my $patron = Koha::Patron->new( $params );
1788 my $has_a_valid_userid = $patron->has_valid_userid
1789
1790 Return true if the current userid of this patron is valid/unique, otherwise false.
1791
1792 Note that this should be done in $self->store instead and raise an exception if needed.
1793
1794 =cut
1795
1796 sub has_valid_userid {
1797     my ($self) = @_;
1798
1799     return 0 unless $self->userid;
1800
1801     return 0 if ( $self->userid eq C4::Context->config('user') );    # DB user
1802
1803     my $already_exists = Koha::Patrons->search(
1804         {
1805             userid => $self->userid,
1806             (
1807                 $self->in_storage
1808                 ? ( borrowernumber => { '!=' => $self->borrowernumber } )
1809                 : ()
1810             ),
1811         }
1812     )->count;
1813     return $already_exists ? 0 : 1;
1814 }
1815
1816 =head3 generate_userid
1817
1818     $patron->generate_userid;
1819
1820     If you do not have a plugin for generating a userid, we will call
1821     the internal method here that returns firstname.surname[.number],
1822     where number is an optional suffix to make the userid unique.
1823     (Its behavior has not been changed on bug 32426.)
1824
1825     If you have plugin(s), the first valid response will be used.
1826     A plugin is assumed to return a valid userid as suggestion, but not
1827     assumed to save it already.
1828     Does not fallback to internal (you could arrange for that in your plugin).
1829     Clears userid when there are no valid plugin responses.
1830
1831 =cut
1832
1833 sub generate_userid {
1834     my ( $self ) = @_;
1835     my @responses = Koha::Plugins->call(
1836         'patron_generate_userid', { patron => $self },
1837     );
1838     unless( @responses ) {
1839         # Empty list only possible when there are NO enabled plugins for this method.
1840         # In that case we provide internal response.
1841         return $self->_generate_userid_internal;
1842     }
1843     # If a plugin returned false value or invalid value, we do however not return
1844     # internal response. The plugins should deal with that themselves. So we prevent
1845     # unexpected/unwelcome internal codes for plugin failures.
1846     foreach my $response ( grep { $_ } @responses ) {
1847         $self->userid( $response );
1848         return $self if $self->has_valid_userid;
1849     }
1850     $self->userid(undef);
1851     return $self;
1852 }
1853
1854 sub _generate_userid_internal { # as we always did
1855     my ($self) = @_;
1856     my $offset = 0;
1857     my $firstname = $self->firstname // q{};
1858     my $surname = $self->surname // q{};
1859     #The script will "do" the following code and increment the $offset until the generated userid is unique
1860     do {
1861       $firstname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1862       $surname =~ s/[[:digit:][:space:][:blank:][:punct:][:cntrl:]]//g;
1863       my $userid = lc(($firstname)? "$firstname.$surname" : $surname);
1864       $userid = NFKD( $userid );
1865       $userid =~ s/\p{NonspacingMark}//g;
1866       $userid .= $offset unless $offset == 0;
1867       $self->userid( $userid );
1868       $offset++;
1869      } while (! $self->has_valid_userid );
1870
1871      return $self;
1872 }
1873
1874 =head3 add_extended_attribute
1875
1876 =cut
1877
1878 sub add_extended_attribute {
1879     my ($self, $attribute) = @_;
1880
1881     return Koha::Patron::Attribute->new(
1882         {
1883             %$attribute,
1884             ( borrowernumber => $self->borrowernumber ),
1885         }
1886     )->store;
1887
1888 }
1889
1890 =head3 extended_attributes
1891
1892 Return object of Koha::Patron::Attributes type with all attributes set for this patron
1893
1894 Or setter FIXME
1895
1896 =cut
1897
1898 sub extended_attributes {
1899     my ( $self, $attributes ) = @_;
1900     if ($attributes) {    # setter
1901         my $schema = $self->_result->result_source->schema;
1902         $schema->txn_do(
1903             sub {
1904                 # Remove the existing one
1905                 $self->extended_attributes->filter_by_branch_limitations->delete;
1906
1907                 # Insert the new ones
1908                 my $new_types = {};
1909                 for my $attribute (@$attributes) {
1910                     $self->add_extended_attribute($attribute);
1911                     $new_types->{$attribute->{code}} = 1;
1912                 }
1913
1914                 # Check globally mandatory types
1915                 my @required_attribute_types =
1916                     Koha::Patron::Attribute::Types->search(
1917                         {
1918                             mandatory => 1,
1919                             category_code => [ undef, $self->categorycode ],
1920                             'borrower_attribute_types_branches.b_branchcode' =>
1921                               undef,
1922                         },
1923                         { join => 'borrower_attribute_types_branches' }
1924                     )->get_column('code');
1925                 for my $type ( @required_attribute_types ) {
1926                     Koha::Exceptions::Patron::MissingMandatoryExtendedAttribute->throw(
1927                         type => $type,
1928                     ) if !$new_types->{$type};
1929                 }
1930             }
1931         );
1932     }
1933
1934     my $rs = $self->_result->borrower_attributes;
1935     # We call search to use the filters in Koha::Patron::Attributes->search
1936     return Koha::Patron::Attributes->_new_from_dbic($rs)->search;
1937 }
1938
1939 =head3 messages
1940
1941     my $messages = $patron->messages;
1942
1943 Return the message attached to the patron.
1944
1945 =cut
1946
1947 sub messages {
1948     my ( $self ) = @_;
1949     my $messages_rs = $self->_result->messages_borrowernumbers->search;
1950     return Koha::Patron::Messages->_new_from_dbic($messages_rs);
1951 }
1952
1953 =head3 lock
1954
1955     Koha::Patrons->find($id)->lock({ expire => 1, remove => 1 });
1956
1957     Lock and optionally expire a patron account.
1958     Remove holds and article requests if remove flag set.
1959     In order to distinguish from locking by entering a wrong password, let's
1960     call this an administrative lockout.
1961
1962 =cut
1963
1964 sub lock {
1965     my ( $self, $params ) = @_;
1966     $self->login_attempts( ADMINISTRATIVE_LOCKOUT );
1967     if( $params->{expire} ) {
1968         $self->dateexpiry( dt_from_string->subtract(days => 1) );
1969     }
1970     $self->store;
1971     if( $params->{remove} ) {
1972         $self->holds->delete;
1973         $self->article_requests->delete;
1974     }
1975     return $self;
1976 }
1977
1978 =head3 anonymize
1979
1980     Koha::Patrons->find($id)->anonymize;
1981
1982     Anonymize or clear borrower fields. Fields in BorrowerMandatoryField
1983     are randomized, other personal data is cleared too.
1984     Patrons with issues are skipped.
1985
1986 =cut
1987
1988 sub anonymize {
1989     my ( $self ) = @_;
1990     if( $self->_result->issues->count ) {
1991         warn "Exiting anonymize: patron ".$self->borrowernumber." still has issues";
1992         return;
1993     }
1994     # Mandatory fields come from the corresponding pref, but email fields
1995     # are removed since scrambled email addresses only generate errors
1996     my $mandatory = { map { (lc $_, 1); } grep { !/email/ }
1997         split /\s*\|\s*/, C4::Context->preference('BorrowerMandatoryField') };
1998     $mandatory->{userid} = 1; # needed since sub store does not clear field
1999     my @columns = $self->_result->result_source->columns;
2000     @columns = grep { !/borrowernumber|branchcode|categorycode|^date|password|flags|updated_on|lastseen|lang|login_attempts|anonymized|auth_method/ } @columns;
2001     push @columns, 'dateofbirth'; # add this date back in
2002     foreach my $col (@columns) {
2003         $self->_anonymize_column($col, $mandatory->{lc $col} );
2004     }
2005     $self->anonymized(1)->store;
2006 }
2007
2008 sub _anonymize_column {
2009     my ( $self, $col, $mandatory ) = @_;
2010     my $col_info = $self->_result->result_source->column_info($col);
2011     my $type = $col_info->{data_type};
2012     my $nullable = $col_info->{is_nullable};
2013     my $val;
2014     if( $type =~ /char|text/ ) {
2015         $val = $mandatory
2016             ? Koha::Token->new->generate({ pattern => '\w{10}' })
2017             : $nullable
2018             ? undef
2019             : q{};
2020     } elsif( $type =~ /integer|int$|float|dec|double/ ) {
2021         $val = $nullable ? undef : 0;
2022     } elsif( $type =~ /date|time/ ) {
2023         $val = $nullable ? undef : dt_from_string;
2024     }
2025     $self->$col($val);
2026 }
2027
2028 =head3 add_guarantor
2029
2030     my $relationship = $patron->add_guarantor(
2031         {
2032             borrowernumber => $borrowernumber,
2033             relationships  => $relationship,
2034         }
2035     );
2036
2037     Adds a new guarantor to a patron.
2038
2039 =cut
2040
2041 sub add_guarantor {
2042     my ( $self, $params ) = @_;
2043
2044     my $guarantor_id = $params->{guarantor_id};
2045     my $relationship = $params->{relationship};
2046
2047     return Koha::Patron::Relationship->new(
2048         {
2049             guarantee_id => $self->id,
2050             guarantor_id => $guarantor_id,
2051             relationship => $relationship
2052         }
2053     )->store();
2054 }
2055
2056 =head3 get_extended_attribute
2057
2058 my $attribute_value = $patron->get_extended_attribute( $code );
2059
2060 Return the attribute for the code passed in parameter.
2061
2062 It not exist it returns undef
2063
2064 Note that this will not work for repeatable attribute types.
2065
2066 Maybe you certainly not want to use this method, it is actually only used for SHOW_BARCODE
2067 (which should be a real patron's attribute (not extended)
2068
2069 =cut
2070
2071 sub get_extended_attribute {
2072     my ( $self, $code, $value ) = @_;
2073     my $rs = $self->_result->borrower_attributes;
2074     return unless $rs;
2075     my $attribute = $rs->search({ code => $code, ( $value ? ( attribute => $value ) : () ) });
2076     return unless $attribute->count;
2077     return $attribute->next;
2078 }
2079
2080 =head3 set_default_messaging_preferences
2081
2082     $patron->set_default_messaging_preferences
2083
2084 Sets default messaging preferences on patron.
2085
2086 See Koha::Patron::Message::Preference(s) for more documentation, especially on
2087 thrown exceptions.
2088
2089 =cut
2090
2091 sub set_default_messaging_preferences {
2092     my ($self, $categorycode) = @_;
2093
2094     my $options = Koha::Patron::Message::Preferences->get_options;
2095
2096     foreach my $option (@$options) {
2097         # Check that this option has preference configuration for this category
2098         unless (Koha::Patron::Message::Preferences->search({
2099             message_attribute_id => $option->{message_attribute_id},
2100             categorycode         => $categorycode || $self->categorycode,
2101         })->count) {
2102             next;
2103         }
2104
2105         # Delete current setting
2106         Koha::Patron::Message::Preferences->search({
2107              borrowernumber => $self->borrowernumber,
2108              message_attribute_id => $option->{message_attribute_id},
2109         })->delete;
2110
2111         Koha::Patron::Message::Preference->new_from_default({
2112             borrowernumber => $self->borrowernumber,
2113             categorycode   => $categorycode || $self->categorycode,
2114             message_attribute_id => $option->{message_attribute_id},
2115         });
2116     }
2117
2118     return $self;
2119 }
2120
2121 =head3 to_api
2122
2123     my $json = $patron->to_api;
2124
2125 Overloaded method that returns a JSON representation of the Koha::Patron object,
2126 suitable for API output.
2127
2128 =cut
2129
2130 sub to_api {
2131     my ( $self, $params ) = @_;
2132
2133     my $json_patron = $self->SUPER::to_api( $params );
2134
2135     $json_patron->{restricted} = ( $self->is_debarred )
2136                                     ? Mojo::JSON->true
2137                                     : Mojo::JSON->false;
2138
2139     return $json_patron;
2140 }
2141
2142 =head3 to_api_mapping
2143
2144 This method returns the mapping for representing a Koha::Patron object
2145 on the API.
2146
2147 =cut
2148
2149 sub to_api_mapping {
2150     return {
2151         borrowernotes       => 'staff_notes',
2152         borrowernumber      => 'patron_id',
2153         branchcode          => 'library_id',
2154         categorycode        => 'category_id',
2155         checkprevcheckout   => 'check_previous_checkout',
2156         contactfirstname    => undef,                     # Unused
2157         contactname         => undef,                     # Unused
2158         contactnote         => 'altaddress_notes',
2159         contacttitle        => undef,                     # Unused
2160         dateenrolled        => 'date_enrolled',
2161         dateexpiry          => 'expiry_date',
2162         dateofbirth         => 'date_of_birth',
2163         debarred            => undef,                     # replaced by 'restricted'
2164         debarredcomment     => undef,    # calculated, API consumers will use /restrictions instead
2165         emailpro            => 'secondary_email',
2166         flags               => undef,    # permissions manipulation handled in /permissions
2167         gonenoaddress       => 'incorrect_address',
2168         lastseen            => 'last_seen',
2169         lost                => 'patron_card_lost',
2170         opacnote            => 'opac_notes',
2171         othernames          => 'other_name',
2172         password            => undef,            # password manipulation handled in /password
2173         phonepro            => 'secondary_phone',
2174         relationship        => 'relationship_type',
2175         sex                 => 'gender',
2176         smsalertnumber      => 'sms_number',
2177         sort1               => 'statistics_1',
2178         sort2               => 'statistics_2',
2179         autorenew_checkouts => 'autorenew_checkouts',
2180         streetnumber        => 'street_number',
2181         streettype          => 'street_type',
2182         zipcode             => 'postal_code',
2183         B_address           => 'altaddress_address',
2184         B_address2          => 'altaddress_address2',
2185         B_city              => 'altaddress_city',
2186         B_country           => 'altaddress_country',
2187         B_email             => 'altaddress_email',
2188         B_phone             => 'altaddress_phone',
2189         B_state             => 'altaddress_state',
2190         B_streetnumber      => 'altaddress_street_number',
2191         B_streettype        => 'altaddress_street_type',
2192         B_zipcode           => 'altaddress_postal_code',
2193         altcontactaddress1  => 'altcontact_address',
2194         altcontactaddress2  => 'altcontact_address2',
2195         altcontactaddress3  => 'altcontact_city',
2196         altcontactcountry   => 'altcontact_country',
2197         altcontactfirstname => 'altcontact_firstname',
2198         altcontactphone     => 'altcontact_phone',
2199         altcontactsurname   => 'altcontact_surname',
2200         altcontactstate     => 'altcontact_state',
2201         altcontactzipcode   => 'altcontact_postal_code',
2202         password_expiration_date => undef,
2203         primary_contact_method => undef,
2204         secret              => undef,
2205         auth_method         => undef,
2206     };
2207 }
2208
2209 =head3 queue_notice
2210
2211     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_name => 'DUE'});
2212     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports });
2213     Koha::Patrons->queue_notice({ letter_params => $letter_params, message_transports => \@message_transports, test_mode => 1 });
2214
2215     Queue messages to a patron. Can pass a message that is part of the message_attributes
2216     table or supply the transport to use.
2217
2218     If passed a message name we retrieve the patrons preferences for transports
2219     Otherwise we use the supplied transport. In the case of email or sms we fall back to print if
2220     we have no address/number for sending
2221
2222     $letter_params is a hashref of the values to be passed to GetPreparedLetter
2223
2224     test_mode will only report which notices would be sent, but nothing will be queued
2225
2226 =cut
2227
2228 sub queue_notice {
2229     my ( $self, $params ) = @_;
2230     my $letter_params = $params->{letter_params};
2231     my $test_mode = $params->{test_mode};
2232
2233     return unless $letter_params;
2234     return unless exists $params->{message_name} xor $params->{message_transports}; # We only want one of these
2235
2236     my $library = Koha::Libraries->find( $letter_params->{branchcode} );
2237     my $from_email_address = $library->from_email_address;
2238
2239     my @message_transports;
2240     my $letter_code;
2241     $letter_code = $letter_params->{letter_code};
2242     if( $params->{message_name} ){
2243         my $messaging_prefs = C4::Members::Messaging::GetMessagingPreferences( {
2244                 borrowernumber => $letter_params->{borrowernumber},
2245                 message_name => $params->{message_name}
2246         } );
2247         @message_transports = ( keys %{ $messaging_prefs->{transports} } );
2248         $letter_code = $messaging_prefs->{transports}->{$message_transports[0]} unless $letter_code;
2249     } else {
2250         @message_transports = @{$params->{message_transports}};
2251     }
2252     return unless defined $letter_code;
2253     $letter_params->{letter_code} = $letter_code;
2254     my $print_sent = 0;
2255     my %return;
2256     foreach my $mtt (@message_transports){
2257         next if ($mtt eq 'itiva' and C4::Context->preference('TalkingTechItivaPhoneNotification') );
2258         # Notice is handled by TalkingTech_itiva_outbound.pl
2259         if (   ( $mtt eq 'email' and not $self->notice_email_address )
2260             or ( $mtt eq 'sms'   and not $self->smsalertnumber )
2261             or ( $mtt eq 'phone' and not $self->phone ) )
2262         {
2263             push @{ $return{fallback} }, $mtt;
2264             $mtt = 'print';
2265         }
2266         next if $mtt eq 'print' && $print_sent;
2267         $letter_params->{message_transport_type} = $mtt;
2268         my $letter = C4::Letters::GetPreparedLetter( %$letter_params );
2269         C4::Letters::EnqueueLetter({
2270             letter => $letter,
2271             borrowernumber => $self->borrowernumber,
2272             from_address   => $from_email_address,
2273             message_transport_type => $mtt
2274         }) unless $test_mode;
2275         push @{$return{sent}}, $mtt;
2276         $print_sent = 1 if $mtt eq 'print';
2277     }
2278     return \%return;
2279 }
2280
2281 =head3 safe_to_delete
2282
2283     my $result = $patron->safe_to_delete;
2284     if ( $result eq 'has_guarantees' ) { ... }
2285     elsif ( $result ) { ... }
2286     else { # cannot delete }
2287
2288 This method tells if the Koha:Patron object can be deleted. Possible return values
2289
2290 =over 4
2291
2292 =item 'ok'
2293
2294 =item 'has_checkouts'
2295
2296 =item 'has_debt'
2297
2298 =item 'has_guarantees'
2299
2300 =item 'is_anonymous_patron'
2301
2302 =back
2303
2304 =cut
2305
2306 sub safe_to_delete {
2307     my ($self) = @_;
2308
2309     my $anonymous_patron = C4::Context->preference('AnonymousPatron');
2310
2311     my $error;
2312
2313     if ( $anonymous_patron && $self->id eq $anonymous_patron ) {
2314         $error = 'is_anonymous_patron';
2315     }
2316     elsif ( $self->checkouts->count ) {
2317         $error = 'has_checkouts';
2318     }
2319     elsif ( $self->account->outstanding_debits->total_outstanding > 0 ) {
2320         $error = 'has_debt';
2321     }
2322     elsif ( $self->guarantee_relationships->count ) {
2323         $error = 'has_guarantees';
2324     }
2325
2326     if ( $error ) {
2327         return Koha::Result::Boolean->new(0)->add_message({ message => $error });
2328     }
2329
2330     return Koha::Result::Boolean->new(1);
2331 }
2332
2333 =head3 recalls
2334
2335     my $recalls = $patron->recalls;
2336
2337 Return the patron's recalls.
2338
2339 =cut
2340
2341 sub recalls {
2342     my ( $self ) = @_;
2343
2344     return Koha::Recalls->search({ patron_id => $self->borrowernumber });
2345 }
2346
2347 =head3 account_balance
2348
2349     my $balance = $patron->account_balance
2350
2351 Return the patron's account balance
2352
2353 =cut
2354
2355 sub account_balance {
2356     my ($self) = @_;
2357     return $self->account->balance;
2358 }
2359
2360 =head3 notify_library_of_registration
2361
2362 $patron->notify_library_of_registration( $email_patron_registrations );
2363
2364 Send patron registration email to library if EmailPatronRegistrations system preference is enabled.
2365
2366 =cut
2367
2368 sub notify_library_of_registration {
2369     my ( $self, $email_patron_registrations ) = @_;
2370
2371     if (
2372         my $letter = C4::Letters::GetPreparedLetter(
2373             module      => 'members',
2374             letter_code => 'OPAC_REG',
2375             branchcode  => $self->branchcode,
2376             lang        => $self->lang || 'default',
2377             tables      => {
2378                 'borrowers' => $self->borrowernumber
2379             },
2380         )
2381     ) {
2382         my $to_address;
2383         if ( $email_patron_registrations eq "BranchEmailAddress" ) {
2384             my $library = Koha::Libraries->find( $self->branchcode );
2385             $to_address = $library->inbound_email_address;
2386         }
2387         elsif ( $email_patron_registrations eq "KohaAdminEmailAddress" ) {
2388             $to_address = C4::Context->preference('ReplytoDefault')
2389             || C4::Context->preference('KohaAdminEmailAddress');
2390         }
2391         else {
2392             $to_address =
2393                 C4::Context->preference('EmailAddressForPatronRegistrations')
2394                 || C4::Context->preference('ReplytoDefault')
2395                 || C4::Context->preference('KohaAdminEmailAddress');
2396         }
2397
2398         my $message_id = C4::Letters::EnqueueLetter(
2399             {
2400                 letter                 => $letter,
2401                 borrowernumber         => $self->borrowernumber,
2402                 to_address             => $to_address,
2403                 message_transport_type => 'email'
2404             }
2405         ) or warn "can't enqueue letter $letter";
2406         if ( $message_id ) {
2407             return 1;
2408         }
2409     }
2410 }
2411
2412 =head3 has_messaging_preference
2413
2414 my $bool = $patron->has_messaging_preference({
2415     message_name => $message_name, # A value from message_attributes.message_name
2416     message_transport_type => $message_transport_type, # email, sms, phone, itiva, etc...
2417     wants_digest => $wants_digest, # 1 if you are looking for the digest version, don't pass if you just want either
2418 });
2419
2420 =cut
2421
2422 sub has_messaging_preference {
2423     my ( $self, $params ) = @_;
2424
2425     my $message_name           = $params->{message_name};
2426     my $message_transport_type = $params->{message_transport_type};
2427     my $wants_digest           = $params->{wants_digest};
2428
2429     return $self->_result->search_related_rs(
2430         'borrower_message_preferences',
2431         $params,
2432         {
2433             prefetch =>
2434               [ 'borrower_message_transport_preferences', 'message_attribute' ]
2435         }
2436     )->count;
2437 }
2438
2439 =head3 can_patron_change_staff_only_lists
2440
2441 $patron->can_patron_change_staff_only_lists;
2442
2443 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' permission.
2444 Otherwise, return 0.
2445
2446 =cut
2447
2448 sub can_patron_change_staff_only_lists {
2449     my ( $self, $params ) = @_;
2450     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1 });
2451     return 0;
2452 }
2453
2454 =head3 can_patron_change_permitted_staff_lists
2455
2456 $patron->can_patron_change_permitted_staff_lists;
2457
2458 Return 1 if a patron has 'Superlibrarian' or 'Catalogue' and 'edit_public_list_contents' permissions.
2459 Otherwise, return 0.
2460
2461 =cut
2462
2463 sub can_patron_change_permitted_staff_lists {
2464     my ( $self, $params ) = @_;
2465     return 1 if C4::Auth::haspermission( $self->userid, { 'catalogue' => 1, lists => 'edit_public_list_contents' } );
2466     return 0;
2467 }
2468
2469 =head3 encode_secret
2470
2471   $patron->encode_secret($secret32);
2472
2473 Secret (TwoFactorAuth expects it in base32 format) is encrypted.
2474 You still need to call ->store.
2475
2476 =cut
2477
2478 sub encode_secret {
2479     my ( $self, $secret ) = @_;
2480     if( $secret ) {
2481         return $self->secret( Koha::Encryption->new->encrypt_hex($secret) );
2482     }
2483     return $self->secret($secret);
2484 }
2485
2486 =head3 decoded_secret
2487
2488   my $secret32 = $patron->decoded_secret;
2489
2490 Decode the patron secret. We expect to get back a base32 string, but this
2491 is not checked here. Caller of encode_secret is responsible for that.
2492
2493 =cut
2494
2495 sub decoded_secret {
2496     my ( $self ) = @_;
2497     if( $self->secret ) {
2498         return Koha::Encryption->new->decrypt_hex( $self->secret );
2499     }
2500     return $self->secret;
2501 }
2502
2503 =head3 virtualshelves
2504
2505     my $shelves = $patron->virtualshelves;
2506
2507 =cut
2508
2509 sub virtualshelves {
2510     my $self = shift;
2511     return Koha::Virtualshelves->_new_from_dbic( scalar $self->_result->virtualshelves );
2512 }
2513
2514 =head3 get_savings
2515
2516     my $savings = $patron->get_savings;
2517
2518 Use the replacement price of patron's old and current issues to calculate how much they have 'saved' by using the library.
2519
2520 =cut
2521
2522 sub get_savings {
2523     my ($self) = @_;
2524
2525     my @itemnumbers = grep { defined $_ } ( $self->old_checkouts->get_column('itemnumber'), $self->checkouts->get_column('itemnumber') );
2526
2527     return Koha::Items->search(
2528         { itemnumber => { -in => \@itemnumbers } },
2529         {   select => [ { sum => 'me.replacementprice' } ],
2530             as     => ['total_savings']
2531         }
2532     )->next->get_column('total_savings') // 0;
2533 }
2534
2535 =head2 Internal methods
2536
2537 =head3 _type
2538
2539 =cut
2540
2541 sub _type {
2542     return 'Borrower';
2543 }
2544
2545 =head1 AUTHORS
2546
2547 Kyle M Hall <kyle@bywatersolutions.com>
2548 Alex Sassmannshausen <alex.sassmannshausen@ptfs-europe.com>
2549 Martin Renvoize <martin.renvoize@ptfs-europe.com>
2550
2551 =cut
2552
2553 1;