Koha/Plugins.pm

   1 package Koha::Plugins;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Array::Utils qw( array_minus );
  23 use Class::Inspector;
  24 use List::MoreUtils qw( any );
  25 use Module::Load::Conditional qw( can_load );
  26 use Module::Load;
  27 use Module::Pluggable search_path => ['Koha::Plugin'], except => qr/::Edifact(|::Line|::Message|::Order|::Segment|::Transport)$/;
  28 use Try::Tiny;
  29
  30 use C4::Context;
  31 use C4::Output;
  32
  33 use Koha::Cache::Memory::Lite;
  34 use Koha::Exceptions::Plugin;
  35 use Koha::Plugins::Methods;
  36
  37 use constant ENABLED_PLUGINS_CACHE_KEY => 'enabled_plugins';
  38
  39 BEGIN {
  40     my $pluginsdir = C4::Context->config("pluginsdir");
  41     my @pluginsdir = ref($pluginsdir) eq 'ARRAY' ? @$pluginsdir : $pluginsdir;
  42     push @INC, array_minus(@pluginsdir, @INC) ;
  43     pop @INC if $INC[-1] eq '.';
  44 }
  45
  46 =head1 NAME
  47
  48 Koha::Plugins - Module for loading and managing plugins.
  49
  50 =head2 new
  51
  52 Constructor
  53
  54 =cut
  55
  56 sub new {
  57     my ( $class, $args ) = @_;
  58
  59     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  60
  61     $args->{'pluginsdir'} = C4::Context->config("pluginsdir");
  62
  63     return bless( $args, $class );
  64 }
  65
  66 =head2 call
  67
  68 Calls a plugin method for all enabled plugins
  69
  70     @responses = Koha::Plugins->call($method, @args)
  71
  72 Note: Pass your arguments as refs, when you want subsequent plugins to use the value
  73 updated by preceding plugins, provided that these plugins support that.
  74
  75 =cut
  76
  77 sub call {
  78     my ($class, $method, @args) = @_;
  79
  80     return unless C4::Context->config('enable_plugins');
  81
  82     my @responses;
  83     my @plugins = $class->get_enabled_plugins();
  84     @plugins = grep { $_->can($method) } @plugins;
  85
  86     # TODO: Remove warn when after_hold_create is removed from the codebase
  87     warn "after_hold_create is deprecated and will be removed soon. Contact the following plugin's authors: " . join( ', ', map {$_->{metadata}->{name}} @plugins)
  88         if $method eq 'after_hold_create' and @plugins;
  89
  90     foreach my $plugin (@plugins) {
  91         my $response = eval { $plugin->$method(@args) };
  92         if ($@) {
  93             warn sprintf("Plugin error (%s): %s", $plugin->get_metadata->{name}, $@);
  94             next;
  95         }
  96
  97         push @responses, $response;
  98     }
  99
 100     return @responses;
 101 }
 102
 103 sub get_enabled_plugins {
 104     my ($class) = @_;
 105
 106     return unless C4::Context->config('enable_plugins');
 107
 108     my $enabled_plugins = Koha::Cache::Memory::Lite->get_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 109     unless ($enabled_plugins) {
 110         $enabled_plugins = [];
 111         my $rs = Koha::Database->schema->resultset('PluginData');
 112         $rs = $rs->search({ plugin_key => '__ENABLED__', plugin_value => 1 });
 113         my @plugin_classes = $rs->get_column('plugin_class')->all();
 114         foreach my $plugin_class (@plugin_classes) {
 115             unless (can_load(modules => { $plugin_class => undef }, nocache => 1)) {
 116                 warn "Failed to load $plugin_class: $Module::Load::Conditional::ERROR";
 117                 next;
 118             }
 119
 120             my $plugin = eval { $plugin_class->new() };
 121             if ($@ || !$plugin) {
 122                 warn "Failed to instantiate plugin $plugin_class: $@";
 123                 next;
 124             }
 125
 126             push @$enabled_plugins, $plugin;
 127         }
 128         Koha::Cache::Memory::Lite->set_in_cache(ENABLED_PLUGINS_CACHE_KEY, $enabled_plugins);
 129     }
 130
 131     return @$enabled_plugins;
 132 }
 133
 134 =head2 GetPlugins
 135
 136 This will return a list of all available plugins, optionally limited by
 137 method or metadata value.
 138
 139     my @plugins = Koha::Plugins::GetPlugins({
 140         method => 'some_method',
 141         metadata => { some_key => 'some_value' },
 142     });
 143
 144 The method and metadata parameters are optional.
 145 If you pass multiple keys in the metadata hash, all keys must match.
 146
 147 =cut
 148
 149 sub GetPlugins {
 150     my ( $self, $params ) = @_;
 151
 152     my $method       = $params->{method};
 153     my $req_metadata = $params->{metadata} // {};
 154
 155     my $filter = ( $method ) ? { plugin_method => $method } : undef;
 156
 157     my $plugin_classes = Koha::Plugins::Methods->search(
 158         $filter,
 159         {   columns  => 'plugin_class',
 160             distinct => 1
 161         }
 162     )->_resultset->get_column('plugin_class');
 163
 164     my @plugins;
 165
 166     # Loop through all plugins that implement at least a method
 167     while ( my $plugin_class = $plugin_classes->next ) {
 168
 169         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 170
 171             my $plugin;
 172             my $failed_instantiation;
 173
 174             try {
 175                 $plugin = $plugin_class->new({
 176                     enable_plugins => $self->{'enable_plugins'}
 177                         # loads even if plugins are disabled
 178                         # FIXME: is this for testing without bothering to mock config?
 179                 });
 180             }
 181             catch {
 182                 warn "$_";
 183                 $failed_instantiation = 1;
 184             };
 185
 186             next if $failed_instantiation;
 187
 188             next unless $plugin->is_enabled or
 189                         defined($params->{all}) && $params->{all};
 190
 191             # filter the plugin out by metadata
 192             my $plugin_metadata = $plugin->get_metadata;
 193             next
 194                 if $plugin_metadata
 195                 and %$req_metadata
 196                 and any { !$plugin_metadata->{$_} || $plugin_metadata->{$_} ne $req_metadata->{$_} } keys %$req_metadata;
 197
 198             push @plugins, $plugin;
 199         } elsif ( defined($params->{errors}) && $params->{errors} ){
 200             push @plugins, { error => 'cannot_load', name => $plugin_class };
 201         }
 202
 203     }
 204
 205     return @plugins;
 206 }
 207
 208 =head2 InstallPlugins
 209
 210 Koha::Plugins::InstallPlugins()
 211
 212 This method iterates through all plugins physically present on a system.
 213 For each plugin module found, it will test that the plugin can be loaded,
 214 and if it can, will store its available methods in the plugin_methods table.
 215
 216 NOTE: We reload all plugins here as a protective measure in case someone
 217 has removed a plugin directly from the system without using the UI
 218
 219 =cut
 220
 221 sub InstallPlugins {
 222     my ( $self, $params ) = @_;
 223
 224     my @plugin_classes = $self->plugins();
 225     my @plugins;
 226
 227     foreach my $plugin_class (@plugin_classes) {
 228         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 229             next unless $plugin_class->isa('Koha::Plugins::Base');
 230
 231             my $plugin;
 232             my $failed_instantiation;
 233
 234             try {
 235                 $plugin = $plugin_class->new({ enable_plugins => $self->{'enable_plugins'} });
 236             }
 237             catch {
 238                 warn "$_";
 239                 $failed_instantiation = 1;
 240             };
 241
 242             next if $failed_instantiation;
 243
 244             Koha::Plugins::Methods->search({ plugin_class => $plugin_class })->delete();
 245
 246             foreach my $method ( @{ Class::Inspector->methods( $plugin_class, 'public' ) } ) {
 247                 Koha::Plugins::Method->new(
 248                     {
 249                         plugin_class  => $plugin_class,
 250                         plugin_method => $method,
 251                     }
 252                 )->store();
 253             }
 254
 255             push @plugins, $plugin;
 256         } else {
 257             my $error = $Module::Load::Conditional::ERROR;
 258             # Do not warn the error if the plugin has been uninstalled
 259             warn $error unless $error =~ m|^Could not find or check module '$plugin_class'|;
 260         }
 261     }
 262
 263     Koha::Cache::Memory::Lite->clear_from_cache(ENABLED_PLUGINS_CACHE_KEY);
 264
 265     return @plugins;
 266 }
 267
 268 1;
 269 __END__
 270
 271 =head1 AUTHOR
 272
 273 Kyle M Hall <kyle.m.hall@gmail.com>
 274
 275 =cut