Koha/Plugins.pm

   1 package Koha::Plugins;
   2
   3 # Copyright 2012 Kyle Hall
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Array::Utils qw( array_minus );
  23 use Class::Inspector;
  24 use List::MoreUtils qw( any );
  25 use Module::Load::Conditional qw( can_load );
  26 use Module::Load;
  27 use Module::Pluggable search_path => ['Koha::Plugin'], except => qr/::Edifact(|::Line|::Message|::Order|::Segment|::Transport)$/;
  28 use Try::Tiny;
  29
  30 use C4::Context;
  31 use C4::Output;
  32
  33 use Koha::Exceptions::Plugin;
  34 use Koha::Plugins::Methods;
  35
  36 BEGIN {
  37     my $pluginsdir = C4::Context->config("pluginsdir");
  38     my @pluginsdir = ref($pluginsdir) eq 'ARRAY' ? @$pluginsdir : $pluginsdir;
  39     push @INC, array_minus(@pluginsdir, @INC) ;
  40     pop @INC if $INC[-1] eq '.';
  41 }
  42
  43 =head1 NAME
  44
  45 Koha::Plugins - Module for loading and managing plugins.
  46
  47 =cut
  48
  49 sub new {
  50     my ( $class, $args ) = @_;
  51
  52     return unless ( C4::Context->config("enable_plugins") || $args->{'enable_plugins'} );
  53
  54     $args->{'pluginsdir'} = C4::Context->config("pluginsdir");
  55
  56     return bless( $args, $class );
  57 }
  58
  59 =head2 call
  60
  61 Calls a plugin method for all enabled plugins
  62
  63     @responses = Koha::Plugins->call($method, @args)
  64
  65 =cut
  66
  67 sub call {
  68     my ($class, $method, @args) = @_;
  69
  70     my @responses;
  71     if (C4::Context->config('enable_plugins')) {
  72         my @plugins = $class->new({ enable_plugins => 1 })->GetPlugins({ method => $method });
  73         @plugins = grep { $_->can($method) } @plugins;
  74         foreach my $plugin (@plugins) {
  75             my $response = eval { $plugin->$method(@args) };
  76             if ($@) {
  77                 warn sprintf("Plugin error (%s): %s", $plugin->get_metadata->{name}, $@);
  78                 next;
  79             }
  80
  81             push @responses, $response;
  82         }
  83
  84     }
  85     return @responses;
  86 }
  87
  88 =head2 GetPlugins
  89
  90 This will return a list of all available plugins, optionally limited by
  91 method or metadata value.
  92
  93     my @plugins = Koha::Plugins::GetPlugins({
  94         method => 'some_method',
  95         metadata => { some_key => 'some_value' },
  96     });
  97
  98 The method and metadata parameters are optional.
  99 Available methods currently are: 'report', 'tool', 'to_marc', 'edifact'.
 100 If you pass multiple keys in the metadata hash, all keys must match.
 101
 102 =cut
 103
 104 sub GetPlugins {
 105     my ( $self, $params ) = @_;
 106
 107     my $method       = $params->{method};
 108     my $req_metadata = $params->{metadata} // {};
 109
 110     my $filter = ( $method ) ? { plugin_method => $method } : undef;
 111
 112     my $plugin_classes = Koha::Plugins::Methods->search(
 113         $filter,
 114         {   columns  => 'plugin_class',
 115             distinct => 1
 116         }
 117     )->_resultset->get_column('plugin_class');
 118
 119     my @plugins;
 120
 121     # Loop through all plugins that implement at least a method
 122     while ( my $plugin_class = $plugin_classes->next ) {
 123
 124         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 125
 126             my $plugin;
 127             my $failed_instantiation;
 128
 129             try {
 130                 $plugin = $plugin_class->new({
 131                     enable_plugins => $self->{'enable_plugins'}
 132                         # loads even if plugins are disabled
 133                         # FIXME: is this for testing without bothering to mock config?
 134                 });
 135             }
 136             catch {
 137                 warn "$_";
 138                 $failed_instantiation = 1;
 139             };
 140
 141             next if $failed_instantiation;
 142
 143             next unless $plugin->is_enabled or
 144                         defined($params->{all}) && $params->{all};
 145
 146             # filter the plugin out by metadata
 147             my $plugin_metadata = $plugin->get_metadata;
 148             next
 149                 if $plugin_metadata
 150                 and %$req_metadata
 151                 and any { !$plugin_metadata->{$_} || $plugin_metadata->{$_} ne $req_metadata->{$_} } keys %$req_metadata;
 152
 153             push @plugins, $plugin;
 154         } elsif ( defined($params->{errors}) && $params->{errors} ){
 155             push @plugins, { error => 'cannot_load', name => $plugin_class };
 156         }
 157
 158     }
 159
 160     return @plugins;
 161 }
 162
 163 =head2 InstallPlugins
 164
 165 Koha::Plugins::InstallPlugins()
 166
 167 This method iterates through all plugins physically present on a system.
 168 For each plugin module found, it will test that the plugin can be loaded,
 169 and if it can, will store its available methods in the plugin_methods table.
 170
 171 NOTE: We re-load all plugins here as a protective measure in case someone
 172 has removed a plugin directly from the system without using the UI
 173
 174 =cut
 175
 176 sub InstallPlugins {
 177     my ( $self, $params ) = @_;
 178
 179     my @plugin_classes = $self->plugins();
 180     my @plugins;
 181
 182     foreach my $plugin_class (@plugin_classes) {
 183         if ( can_load( modules => { $plugin_class => undef }, nocache => 1 ) ) {
 184             next unless $plugin_class->isa('Koha::Plugins::Base');
 185
 186             my $plugin;
 187             my $failed_instantiation;
 188
 189             try {
 190                 $plugin = $plugin_class->new({ enable_plugins => $self->{'enable_plugins'} });
 191             }
 192             catch {
 193                 warn "$_";
 194                 $failed_instantiation = 1;
 195             };
 196
 197             next if $failed_instantiation;
 198
 199             Koha::Plugins::Methods->search({ plugin_class => $plugin_class })->delete();
 200
 201             foreach my $method ( @{ Class::Inspector->methods( $plugin_class, 'public' ) } ) {
 202                 Koha::Plugins::Method->new(
 203                     {
 204                         plugin_class  => $plugin_class,
 205                         plugin_method => $method,
 206                     }
 207                 )->store();
 208             }
 209
 210             push @plugins, $plugin;
 211         } else {
 212             my $error = $Module::Load::Conditional::ERROR;
 213             # Do not warn the error if the plugin has been uninstalled
 214             warn $error unless $error =~ m|^Could not find or check module '$plugin_class'|;
 215         }
 216     }
 217     return @plugins;
 218 }
 219
 220 1;
 221 __END__
 222
 223 =head1 AVAILABLE HOOKS
 224
 225 =head2 after_hold_create
 226
 227 =head3 Parameters
 228
 229 =over
 230
 231 =item * C<$hold> - A Koha::Hold object that has just been inserted in database
 232
 233 =back
 234
 235 =head3 Return value
 236
 237 None
 238
 239 =head3 Example
 240
 241     sub after_hold_create {
 242         my ($self, $hold) = @_;
 243
 244         warn "New hold for borrower " . $hold->borrower->borrowernumber;
 245     }
 246
 247 =head1 AUTHOR
 248
 249 Kyle M Hall <kyle.m.hall@gmail.com>
 250
 251 =cut