Koha/REST/V1/Biblios.pm

   1 package Koha::REST::V1::Biblios;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Mojo::Base 'Mojolicious::Controller';
  21
  22 use Koha::Biblios;
  23 use Koha::RecordProcessor;
  24 use C4::Biblio qw(DelBiblio);
  25
  26 use MARC::Record::MiJ;
  27
  28 use Try::Tiny;
  29
  30 =head1 API
  31
  32 =head2 Methods
  33
  34 =head3 get
  35
  36 Controller function that handles retrieving a single biblio object
  37
  38 =cut
  39
  40 sub get {
  41     my $c = shift->openapi->valid_input or return;
  42
  43     my $attributes;
  44     $attributes = { prefetch => [ 'metadata' ] } # don't prefetch metadata if not needed
  45         unless $c->req->headers->accept =~ m/application\/json/;
  46
  47     my $biblio = Koha::Biblios->find( { biblionumber => $c->validation->param('biblio_id') }, $attributes );
  48
  49     unless ( $biblio ) {
  50         return $c->render(
  51             status  => 404,
  52             openapi => {
  53                 error => "Object not found."
  54             }
  55         );
  56     }
  57
  58     return try {
  59
  60         if ( $c->req->headers->accept =~ m/application\/json/ ) {
  61             return $c->render(
  62                 status => 200,
  63                 json   => $biblio->to_api
  64             );
  65         }
  66         else {
  67             my $record = $biblio->metadata->record;
  68
  69             $c->respond_to(
  70                 marcxml => {
  71                     status => 200,
  72                     format => 'marcxml',
  73                     text   => $record->as_xml_record
  74                 },
  75                 mij => {
  76                     status => 200,
  77                     format => 'mij',
  78                     text   => $record->to_mij
  79                 },
  80                 marc => {
  81                     status => 200,
  82                     format => 'marc',
  83                     text   => $record->as_usmarc
  84                 },
  85                 any => {
  86                     status  => 406,
  87                     openapi => [
  88                         "application/json",
  89                         "application/marcxml+xml",
  90                         "application/marc-in-json",
  91                         "application/marc"
  92                     ]
  93                 }
  94             );
  95         }
  96     }
  97     catch {
  98         $c->unhandled_exception($_);
  99     };
 100 }
 101
 102 =head3 delete
 103
 104 Controller function that handles deleting a biblio object
 105
 106 =cut
 107
 108 sub delete {
 109     my $c = shift->openapi->valid_input or return;
 110
 111     my $biblio = Koha::Biblios->find( $c->validation->param('biblio_id') );
 112
 113     if ( not defined $biblio ) {
 114         return $c->render(
 115             status  => 404,
 116             openapi => { error => "Object not found" }
 117         );
 118     }
 119
 120     return try {
 121         my $error = DelBiblio( $biblio->id );
 122
 123         if ($error) {
 124             return $c->render(
 125                 status  => 409,
 126                 openapi => { error => $error }
 127             );
 128         }
 129         else {
 130             return $c->render( status => 204, openapi => "" );
 131         }
 132     }
 133     catch {
 134         $c->unhandled_exception($_);
 135     };
 136 }
 137
 138 =head3 get_public
 139
 140 Controller function that handles retrieving a single biblio object
 141
 142 =cut
 143
 144 sub get_public {
 145     my $c = shift->openapi->valid_input or return;
 146
 147     my $biblio = Koha::Biblios->find(
 148         { biblionumber => $c->validation->param('biblio_id') },
 149         { prefetch     => ['metadata'] } );
 150
 151     unless ($biblio) {
 152         return $c->render(
 153             status  => 404,
 154             openapi => {
 155                 error => "Object not found."
 156             }
 157         );
 158     }
 159
 160     return try {
 161
 162         my $record = $biblio->metadata->record;
 163
 164         my $opachiddenitems_rules = C4::Context->yaml_preference('OpacHiddenItems');
 165         my $patron = $c->stash('koha.user');
 166
 167         # Check if the biblio should be hidden for unprivileged access
 168         # unless there's a logged in user, and there's an exception for it's
 169         # category
 170         unless ( $patron and $patron->category->override_hidden_items ) {
 171             if ( $biblio->hidden_in_opac({ rules => $opachiddenitems_rules }) )
 172             {
 173                 return $c->render(
 174                     status  => 404,
 175                     openapi => {
 176                         error => "Object not found."
 177                     }
 178                 );
 179             }
 180         }
 181
 182         my $marcflavour = C4::Context->preference("marcflavour");
 183
 184         my $record_processor = Koha::RecordProcessor->new({
 185             filters => 'ViewPolicy',
 186             options => {
 187                 interface => 'opac',
 188                 frameworkcode => $biblio->frameworkcode
 189             }
 190         });
 191         # Apply framework's filtering to MARC::Record object
 192         $record_processor->process($record);
 193
 194         $c->respond_to(
 195             marcxml => {
 196                 status => 200,
 197                 format => 'marcxml',
 198                 text   => $record->as_xml_record
 199             },
 200             mij => {
 201                 status => 200,
 202                 format => 'mij',
 203                 text   => $record->to_mij
 204             },
 205             marc => {
 206                 status => 200,
 207                 format => 'marc',
 208                 text   => $record->as_usmarc
 209             },
 210             txt => {
 211                 status => 200,
 212                 format => 'text/plain',
 213                 text   => $record->as_formatted
 214             },
 215             any => {
 216                 status  => 406,
 217                 openapi => [
 218                     "application/marcxml+xml",
 219                     "application/marc-in-json",
 220                     "application/marc",
 221                     "text/plain"
 222                 ]
 223             }
 224         );
 225     }
 226     catch {
 227         return $c->render(
 228             status  => 500,
 229             openapi => { error => "Something went wrong, check the logs ($_)" }
 230         );
 231     };
 232 }
 233
 234 1;