Koha/SearchEngine/Elasticsearch/QueryBuilder.pm

   1 package Koha::SearchEngine::Elasticsearch::QueryBuilder;
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2014 Catalyst IT Ltd.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 Koha::SearchEngine::Elasticsearch::QueryBuilder - constructs elasticsearch
  23 query objects from user-supplied queries
  24
  25 =head1 DESCRIPTION
  26
  27 This provides the functions that take a user-supplied search query, and
  28 provides something that can be given to elasticsearch to get answers.
  29
  30 =head1 SYNOPSIS
  31
  32     use Koha::SearchEngine::Elasticsearch::QueryBuilder;
  33     $builder = Koha::SearchEngine::Elasticsearch->new({ index => $index });
  34     my $simple_query = $builder->build_query("hello");
  35     # This is currently undocumented because the original code is undocumented
  36     my $adv_query = $builder->build_advanced_query($indexes, $operands, $operators);
  37
  38 =head1 METHODS
  39
  40 =cut
  41
  42 use base qw(Koha::SearchEngine::Elasticsearch);
  43 use Carp;
  44 use JSON;
  45 use List::MoreUtils qw/ each_array /;
  46 use Modern::Perl;
  47 use URI::Escape;
  48
  49 use C4::Context;
  50 use Data::Dumper;    # TODO remove
  51
  52 =head2 build_query
  53
  54     my $simple_query = $builder->build_query("hello", %options)
  55
  56 This will build a query that can be issued to elasticsearch from the provided
  57 string input. This expects a lucene style search form (see
  58 L<http://www.elasticsearch.org/guide/en/elasticsearch/reference/current/query-dsl-query-string-query.html#query-string-syntax>
  59 for details.)
  60
  61 It'll make an attempt to respect the various query options.
  62
  63 Additional options can be provided with the C<%options> hash.
  64
  65 =over 4
  66
  67 =item sort
  68
  69 This should be an arrayref of hashrefs, each containing a C<field> and an
  70 C<direction> (optional, defaults to C<asc>.) The results will be sorted
  71 according to these values. Valid values for C<direction> are 'asc' and 'desc'.
  72
  73 =back
  74
  75 =cut
  76
  77 sub build_query {
  78     my ( $self, $query, %options ) = @_;
  79
  80     my $stemming         = C4::Context->preference("QueryStemming")        || 0;
  81     my $auto_truncation  = C4::Context->preference("QueryAutoTruncate")    || 0;
  82     my $weight_fields    = C4::Context->preference("QueryWeightFields")    || 0;
  83     my $fuzzy_enabled    = C4::Context->preference("QueryFuzzy")           || 0;
  84
  85     $query = '*' unless defined $query;
  86
  87     my $res;
  88     $res->{query} = {
  89         query_string => {
  90             query            => $query,
  91             fuzziness        => $fuzzy_enabled ? 'auto' : '0',
  92             default_operator => 'AND',
  93             default_field    => '_all',
  94             lenient          => JSON::true,
  95         }
  96     };
  97
  98     if ( $options{sort} ) {
  99         foreach my $sort ( @{ $options{sort} } ) {
 100             my ( $f, $d ) = @$sort{qw/ field direction /};
 101             die "Invalid sort direction, $d"
 102               if $d && ( $d ne 'asc' && $d ne 'desc' );
 103             $d = 'asc' unless $d;
 104
 105             # TODO account for fields that don't have a 'phrase' type
 106
 107             $f = $self->_sort_field($f);
 108             push @{ $res->{sort} }, { "$f.phrase" => { order => $d } };
 109         }
 110     }
 111
 112     # See _convert_facets in Search.pm for how these get turned into
 113     # things that Koha can use.
 114     $res->{aggregations} = {
 115         author   => { terms => { field => "author__facet" } },
 116         subject  => { terms => { field => "subject__facet" } },
 117         itype    => { terms => { field => "itype__facet" } },
 118         location => { terms => { field => "location__facet" } },
 119         'su-geo' => { terms => { field => "su-geo__facet" } },
 120         se       => { terms => { field => "se__facet" } },
 121         ccode    => { terms => { field => "ccode__facet" } },
 122     };
 123
 124     my $display_library_facets = C4::Context->preference('DisplayLibraryFacets');
 125     if (   $display_library_facets eq 'both'
 126         or $display_library_facets eq 'home' ) {
 127         $res->{aggregations}{homebranch} = { terms => { field => "homebranch__facet" } };
 128     }
 129     if (   $display_library_facets eq 'both'
 130         or $display_library_facets eq 'holding' ) {
 131         $res->{aggregations}{holdingbranch} = { terms => { field => "holdingbranch__facet" } };
 132     }
 133     if ( my $ef = $options{expanded_facet} ) {
 134         $res->{aggregations}{$ef}{terms}{size} = C4::Context->preference('FacetMaxCount');
 135     };
 136     return $res;
 137 }
 138
 139 =head2 build_browse_query
 140
 141     my $browse_query = $builder->build_browse_query($field, $query);
 142
 143 This performs a "starts with" style query on a particular field. The field
 144 to be searched must have been indexed with an appropriate mapping as a
 145 "phrase" subfield, which pretty much everything has.
 146
 147 =cut
 148
 149 # XXX this isn't really a browse query like we want in the end
 150 sub build_browse_query {
 151     my ( $self, $field, $query ) = @_;
 152
 153     my $fuzzy_enabled = C4::Context->preference("QueryFuzzy") || 0;
 154
 155     return { query => '*' } if !defined $query;
 156
 157     # TODO this should come from Koha::SearchEngine::Elasticsearch
 158     my %field_whitelist = (
 159         title  => 1,
 160         author => 1,
 161     );
 162     $field = 'title' if !exists $field_whitelist{$field};
 163     my $sort = $self->_sort_field($field);
 164     my $res = {
 165         query => {
 166             match_phrase_prefix => {
 167                 "$field.phrase" => {
 168                     query     => $query,
 169                     operator  => 'or',
 170                     fuzziness => $fuzzy_enabled ? 'auto' : '0',
 171                 }
 172             }
 173         },
 174         sort => [ { "$sort.phrase" => { order => "asc" } } ],
 175     };
 176 }
 177
 178 =head2 build_query_compat
 179
 180     my (
 181         $error,             $query, $simple_query, $query_cgi,
 182         $query_desc,        $limit, $limit_cgi,    $limit_desc,
 183         $stopwords_removed, $query_type
 184       )
 185       = $builder->build_query_compat( \@operators, \@operands, \@indexes,
 186         \@limits, \@sort_by, $scan, $lang );
 187
 188 This handles a search using the same api as L<C4::Search::buildQuery> does.
 189
 190 A very simple query will go in with C<$operands> set to ['query'], and
 191 C<$sort_by> set to ['pubdate_dsc']. This simple case will return with
 192 C<$query> set to something that can perform the search, C<$simple_query>
 193 set to just the search term, C<$query_cgi> set to something that can
 194 reproduce this search, and C<$query_desc> set to something else.
 195
 196 =cut
 197
 198 sub build_query_compat {
 199     my ( $self, $operators, $operands, $indexes, $orig_limits, $sort_by, $scan,
 200         $lang, $params )
 201       = @_;
 202
 203 #die Dumper ( $self, $operators, $operands, $indexes, $orig_limits, $sort_by, $scan, $lang );
 204     my @sort_params  = $self->_convert_sort_fields(@$sort_by);
 205     my @index_params = $self->_convert_index_fields(@$indexes);
 206     my $limits       = $self->_fix_limit_special_cases($orig_limits);
 207
 208     # Merge the indexes in with the search terms and the operands so that
 209     # each search thing is a handy unit.
 210     unshift @$operators, undef;    # The first one can't have an op
 211     my @search_params;
 212     my $ea = each_array( @$operands, @$operators, @index_params );
 213     while ( my ( $oand, $otor, $index ) = $ea->() ) {
 214         next if ( !defined($oand) || $oand eq '' );
 215         push @search_params, {
 216             operand => $self->_clean_search_term($oand),      # the search terms
 217             operator => defined($otor) ? uc $otor : undef,    # AND and so on
 218             $index ? %$index : (),
 219         };
 220     }
 221
 222     # We build a string query from limits and the queries. An alternative
 223     # would be to pass them separately into build_query and let it build
 224     # them into a structured ES query itself. Maybe later, though that'd be
 225     # more robust.
 226     my $query_str = join( ' AND ',
 227         join( ' ', $self->_create_query_string(@search_params) ) || (),
 228         $self->_join_queries( $self->_convert_index_strings(@$limits) ) || () );
 229
 230     # If there's no query on the left, let's remove the junk left behind
 231     $query_str =~ s/^ AND //;
 232     my %options;
 233     $options{sort} = \@sort_params;
 234     $options{expanded_facet} = $params->{expanded_facet};
 235     my $query = $self->build_query( $query_str, %options );
 236
 237     #die Dumper($query);
 238     # We roughly emulate the CGI parameters of the zebra query builder
 239     my $query_cgi;
 240     $query_cgi = 'idx=kw&q=' . uri_escape_utf8( $operands->[0] ) if @$operands;
 241     my $simple_query;
 242     $simple_query = $operands->[0] if @$operands == 1;
 243     my $query_desc   = $simple_query;
 244     my $limit        = $self->_join_queries( $self->_convert_index_strings(@$limits));
 245     my $limit_cgi = ( $orig_limits and @$orig_limits )
 246       ? '&limit=' . join( '&limit=', map { uri_escape_utf8($_) } @$orig_limits )
 247       : '';
 248     my $limit_desc;
 249     $limit_desc = "$limit" if $limit;
 250     return (
 251         undef,  $query,     $simple_query, $query_cgi, $query_desc,
 252         $limit, $limit_cgi, $limit_desc,   undef,      undef
 253     );
 254 }
 255
 256 =head2 build_authorities_query
 257
 258     my $query = $builder->build_authorities_query(\%search);
 259
 260 This takes a nice description of an authority search and turns it into a black-box
 261 query that can then be passed to the appropriate searcher.
 262
 263 The search description is a hashref that looks something like:
 264
 265     {
 266         searches => [
 267             {
 268                 where    => 'Heading',    # search the main entry
 269                 operator => 'exact',        # require an exact match
 270                 value    => 'frogs',        # the search string
 271             },
 272             {
 273                 where    => '',             # search all entries
 274                 operator => '',             # default keyword, right truncation
 275                 value    => 'pond',
 276             },
 277         ],
 278         sort => {
 279             field => 'Heading',
 280             order => 'desc',
 281         },
 282         authtypecode => 'TOPIC_TERM',
 283     }
 284
 285 =cut
 286
 287 sub build_authorities_query {
 288     my ( $self, $search ) = @_;
 289
 290     # Start by making the query parts
 291     my @query_parts;
 292     my @filter_parts;
 293     foreach my $s ( @{ $search->{searches} } ) {
 294         my ( $wh, $op, $val ) = @{$s}{qw(where operator value)};
 295         $wh = '_all' if $wh eq '';
 296         if ( $op eq 'is' || $op eq '=' ) {
 297
 298             # look for something that matches completely
 299             # note, '=' is about numerical vals. May need special handling.
 300             # _allphrase is a special field that only groups the exact
 301             # matches. Also, we lowercase our search because the ES
 302             # index lowercases its values, and term searches don't get the
 303             # search analyzer applied to them.
 304             push @filter_parts, { term => { "$wh.phrase" => lc $val } };
 305         }
 306         elsif ( $op eq 'exact' ) {
 307
 308             # left and right truncation, otherwise an exact phrase
 309             push @query_parts, { match_phrase => { $wh => $val } };
 310         }
 311         elsif ( $op eq 'start' ) {
 312
 313             # startswith search
 314             push @query_parts, { wildcard => { "$wh.phrase" => lc "$val*" } };
 315         }
 316         else {
 317             # regular wordlist stuff
 318             push @query_parts, { match => { $wh => $val } };
 319         }
 320     }
 321
 322     # Merge the query and filter parts appropriately
 323     # 'should' behaves like 'or', if we want 'and', use 'must'
 324     my $query_part  = { bool => { should => \@query_parts } };
 325     my $filter_part = { bool => { should => \@filter_parts } };
 326
 327     # We need to add '.phrase' to all the sort headings otherwise it'll sort
 328     # based on the tokenised form.
 329     my %s;
 330     if ( exists $search->{sort} ) {
 331         foreach my $k ( keys %{ $search->{sort} } ) {
 332             my $f = $self->_sort_field($k);
 333             $s{"$f.phrase"} = $search->{sort}{$k};
 334         }
 335         $search->{sort} = \%s;
 336     }
 337
 338     # extract the sort stuff
 339     my %sort;
 340     %sort = ( sort => [ $search->{sort} ] ) if exists $search->{sort};
 341     my $query;
 342     if (@filter_parts) {
 343         $query =
 344           { query =>
 345               { filtered => { filter => $filter_part, query => $query_part } }
 346           };
 347     }
 348     else {
 349         $query = { query => $query_part };
 350     }
 351     $query = { %$query, %sort };
 352     return $query;
 353 }
 354
 355
 356 =head2 build_authorities_query_compat
 357
 358     my ($query) =
 359       $builder->build_authorities_query_compat( \@marclist, \@and_or,
 360         \@excluding, \@operator, \@value, $authtypecode, $orderby );
 361
 362 This builds a query for searching for authorities, in the style of
 363 L<C4::AuthoritiesMarc::SearchAuthorities>.
 364
 365 Arguments:
 366
 367 =over 4
 368
 369 =item marclist
 370
 371 An arrayref containing where the particular term should be searched for.
 372 Options are: mainmainentry, mainentry, match, match-heading, see-from, and
 373 thesaurus. If left blank, any field is used.
 374
 375 =item and_or
 376
 377 Totally ignored. It is never used in L<C4::AuthoritiesMarc::SearchAuthorities>.
 378
 379 =item excluding
 380
 381 Also ignored.
 382
 383 =item operator
 384
 385 What form of search to do. Options are: is (phrase, no trunction, whole field
 386 must match), = (number exact match), exact (phrase, but with left and right
 387 truncation). If left blank, then word list, right truncted, anywhere is used.
 388
 389 =item value
 390
 391 The actual user-provided string value to search for.
 392
 393 =item authtypecode
 394
 395 The authority type code to search within. If blank, then all will be searched.
 396
 397 =item orderby
 398
 399 The order to sort the results by. Options are Relevance, HeadingAsc,
 400 HeadingDsc, AuthidAsc, AuthidDsc.
 401
 402 =back
 403
 404 marclist, operator, and value must be the same length, and the values at
 405 index /i/ all relate to each other.
 406
 407 This returns a query, which is a black box object that can be passed to the
 408 appropriate search object.
 409
 410 =cut
 411
 412 sub build_authorities_query_compat {
 413     my ( $self, $marclist, $and_or, $excluding, $operator, $value,
 414         $authtypecode, $orderby )
 415       = @_;
 416
 417     # This turns the old-style many-options argument form into a more
 418     # extensible hash form that is understood by L<build_authorities_query>.
 419     my @searches;
 420
 421     my %koha_to_index_name = (
 422         mainmainentry   => 'Heading-Main',
 423         mainentry       => 'Heading',
 424         match           => 'Match',
 425         'match-heading' => 'Match-heading',
 426         'see-from'      => 'Match-heading-see-from',
 427         thesaurus       => 'Subject-heading-thesaurus',
 428         any              => '',
 429     );
 430
 431     # Make sure everything exists
 432     foreach my $m (@$marclist) {
 433         confess "Invalid marclist field provided: $m" unless exists $koha_to_index_name{$m};
 434     }
 435     for ( my $i = 0 ; $i < @$value ; $i++ ) {
 436         push @searches,
 437           {
 438             where    => $koha_to_index_name{$marclist->[$i]},
 439             operator => $operator->[$i],
 440             value    => $value->[$i],
 441           };
 442     }
 443
 444     my %sort;
 445     my $sort_field =
 446         ( $orderby =~ /^Heading/ ) ? 'Heading'
 447       : ( $orderby =~ /^Auth/ )    ? 'Local-Number'
 448       :                              undef;
 449     if ($sort_field) {
 450         my $sort_order = ( $orderby =~ /Asc$/ ) ? 'asc' : 'desc';
 451         %sort = ( $sort_field => $sort_order, );
 452     }
 453     my %search = (
 454         searches     => \@searches,
 455         authtypecode => $authtypecode,
 456     );
 457     $search{sort} = \%sort if %sort;
 458     my $query = $self->build_authorities_query( \%search );
 459     return $query;
 460 }
 461
 462 =head2 _convert_sort_fields
 463
 464     my @sort_params = _convert_sort_fields(@sort_by)
 465
 466 Converts the zebra-style sort index information into elasticsearch-style.
 467
 468 C<@sort_by> is the same as presented to L<build_query_compat>, and it returns
 469 something that can be sent to L<build_query>.
 470
 471 =cut
 472
 473 sub _convert_sort_fields {
 474     my ( $self, @sort_by ) = @_;
 475
 476     # Turn the sorting into something we care about.
 477     my %sort_field_convert = (
 478         acqdate     => 'acqdate',
 479         author      => 'author',
 480         call_number => 'callnum',
 481         popularity  => 'issues',
 482         relevance   => undef,       # default
 483         title       => 'title',
 484         pubdate     => 'pubdate',
 485     );
 486     my %sort_order_convert =
 487       ( qw( dsc desc ), qw( asc asc ), qw( az asc ), qw( za desc ) );
 488
 489     # Convert the fields and orders, drop anything we don't know about.
 490     grep { $_->{field} } map {
 491         my ( $f, $d ) = split /_/;
 492         {
 493             field     => $sort_field_convert{$f},
 494             direction => $sort_order_convert{$d}
 495         }
 496     } @sort_by;
 497 }
 498
 499 =head2 _convert_index_fields
 500
 501     my @index_params = $self->_convert_index_fields(@indexes);
 502
 503 Converts zebra-style search index notation into elasticsearch-style.
 504
 505 C<@indexes> is an array of index names, as presented to L<build_query_compat>,
 506 and it returns something that can be sent to L<build_query>.
 507
 508 B<TODO>: this will pull from the elasticsearch mappings table to figure out
 509 types.
 510
 511 =cut
 512
 513 our %index_field_convert = (
 514     'kw'      => '_all',
 515     'ti'      => 'title',
 516     'au'      => 'author',
 517     'su'      => 'subject',
 518     'nb'      => 'isbn',
 519     'se'      => 'title-series',
 520     'callnum' => 'callnum',
 521     'itype'   => 'itype',
 522     'ln'      => 'ln',
 523     'branch'  => 'homebranch',
 524     'fic'     => 'lf',
 525     'mus'     => 'rtype',
 526     'aud'     => 'ta',
 527     'hi'      => 'Host-Item-Number',
 528 );
 529
 530 sub _convert_index_fields {
 531     my ( $self, @indexes ) = @_;
 532
 533     my %index_type_convert =
 534       ( __default => undef, phr => 'phrase', rtrn => 'right-truncate' );
 535
 536     # Convert according to our table, drop anything that doesn't convert.
 537     # If a field starts with mc- we save it as it's used (and removed) later
 538     # when joining things, to indicate we make it an 'OR' join.
 539     # (Sorry, this got a bit ugly after special cases were found.)
 540     grep { $_->{field} } map {
 541         my ( $f, $t ) = split /,/;
 542         my $mc = '';
 543         if ($f =~ /^mc-/) {
 544             $mc = 'mc-';
 545             $f =~ s/^mc-//;
 546         }
 547         my $r = {
 548             field => $index_field_convert{$f},
 549             type  => $index_type_convert{ $t // '__default' }
 550         };
 551         $r->{field} = ($mc . $r->{field}) if $mc && $r->{field};
 552         $r;
 553     } @indexes;
 554 }
 555
 556 =head2 _convert_index_strings
 557
 558     my @searches = $self->_convert_index_strings(@searches);
 559
 560 Similar to L<_convert_index_fields>, this takes strings of the form
 561 B<field:search term> and rewrites the field from zebra-style to
 562 elasticsearch-style. Anything it doesn't understand is returned verbatim.
 563
 564 =cut
 565
 566 sub _convert_index_strings {
 567     my ( $self, @searches ) = @_;
 568     my @res;
 569     foreach my $s (@searches) {
 570         next if $s eq '';
 571         my ( $field, $term ) = $s =~ /^\s*([\w,-]*?):(.*)/;
 572         unless ( defined($field) && defined($term) ) {
 573             push @res, $s;
 574             next;
 575         }
 576         my ($conv) = $self->_convert_index_fields($field);
 577         unless ( defined($conv) ) {
 578             push @res, $s;
 579             next;
 580         }
 581         push @res, $conv->{field} . ":"
 582           . $self->_modify_string_by_type( %$conv, operand => $term );
 583     }
 584     return @res;
 585 }
 586
 587 =head2 _convert_index_strings_freeform
 588
 589     my $search = $self->_convert_index_strings_freeform($search);
 590
 591 This is similar to L<_convert_index_strings>, however it'll search out the
 592 things to change within the string. So it can handle strings such as
 593 C<(su:foo) AND (su:bar)>, converting the C<su> appropriately.
 594
 595 If there is something of the form "su,complete-subfield" or something, the
 596 second part is stripped off as we can't yet handle that. Making it work
 597 will have to wait for a real query parser.
 598
 599 =cut
 600
 601 sub _convert_index_strings_freeform {
 602     my ( $self, $search ) = @_;
 603     while ( my ( $zeb, $es ) = each %index_field_convert ) {
 604         $search =~ s/\b$zeb(?:,[\w-]*)?:/$es:/g;
 605     }
 606     return $search;
 607 }
 608
 609 =head2 _modify_string_by_type
 610
 611     my $str = $self->_modify_string_by_type(%index_field);
 612
 613 If you have a search term (operand) and a type (phrase, right-truncated), this
 614 will convert the string to have the function in lucene search terms, e.g.
 615 wrapping quotes around it.
 616
 617 =cut
 618
 619 sub _modify_string_by_type {
 620     my ( $self, %idx ) = @_;
 621
 622     my $type = $idx{type} || '';
 623     my $str = $idx{operand};
 624     return $str unless $str;    # Empty or undef, we can't use it.
 625
 626     $str .= '*' if $type eq 'right-truncate';
 627     $str = '"' . $str . '"' if $type eq 'phrase';
 628     return $str;
 629 }
 630
 631 =head2 _join_queries
 632
 633     my $query_str = $self->_join_queries(@query_parts);
 634
 635 This takes a list of query parts, that might be search terms on their own, or
 636 booleaned together, or specifying fields, or whatever, wraps them in
 637 parentheses, and ANDs them all together. Suitable for feeding to the ES
 638 query string query.
 639
 640 Note: doesn't AND them together if they specify an index that starts with "mc"
 641 as that was a special case in the original code for dealing with multiple
 642 choice options (you can't search for something that has an itype of A and
 643 and itype of B otherwise.)
 644
 645 =cut
 646
 647 sub _join_queries {
 648     my ( $self, @parts ) = @_;
 649
 650     my @norm_parts = grep { defined($_) && $_ ne '' && $_ !~ /^mc-/ } @parts;
 651     my @mc_parts =
 652       map { s/^mc-//r } grep { defined($_) && $_ ne '' && $_ =~ /^mc-/ } @parts;
 653     return () unless @norm_parts + @mc_parts;
 654     return ( @norm_parts, @mc_parts )[0] if @norm_parts + @mc_parts == 1;
 655     my $grouped_mc =
 656       @mc_parts ? '(' . ( join ' OR ', map { "($_)" } @mc_parts ) . ')' : ();
 657
 658     # Handy trick: $x || () inside a join means that if $x ends up as an
 659     # empty string, it gets replaced with (), which makes join ignore it.
 660     # (bad effect: this'll also happen to '0', this hopefully doesn't matter
 661     # in this case.)
 662     join( ' AND ',
 663         join( ' AND ', map { "($_)" } @norm_parts ) || (),
 664         $grouped_mc || () );
 665 }
 666
 667 =head2 _make_phrases
 668
 669     my @phrased_queries = $self->_make_phrases(@query_parts);
 670
 671 This takes the supplied queries and forces them to be phrases by wrapping
 672 quotes around them. It understands field prefixes, e.g. 'subject:' and puts
 673 the quotes outside of them if they're there.
 674
 675 =cut
 676
 677 sub _make_phrases {
 678     my ( $self, @parts ) = @_;
 679     map { s/^\s*(\w*?:)(.*)$/$1"$2"/r } @parts;
 680 }
 681
 682 =head2 _create_query_string
 683
 684     my @query_strings = $self->_create_query_string(@queries);
 685
 686 Given a list of hashrefs, it will turn them into a lucene-style query string.
 687 The hash should contain field, type (both for the indexes), operator, and
 688 operand.
 689
 690 =cut
 691
 692 sub _create_query_string {
 693     my ( $self, @queries ) = @_;
 694
 695     map {
 696         my $otor  = $_->{operator} ? $_->{operator} . ' ' : '';
 697         my $field = $_->{field}    ? $_->{field} . ':'    : '';
 698
 699         my $oand = $self->_modify_string_by_type(%$_);
 700         "$otor($field$oand)";
 701     } @queries;
 702 }
 703
 704 =head2 _clean_search_term
 705
 706     my $term = $self->_clean_search_term($term);
 707
 708 This cleans a search term by removing any funny characters that may upset
 709 ES and give us an error. It also calls L<_convert_index_strings_freeform>
 710 to ensure those parts are correct.
 711
 712 =cut
 713
 714 sub _clean_search_term {
 715     my ( $self, $term ) = @_;
 716
 717     # Some hardcoded searches (like with authorities) produce things like
 718     # 'an=123', when it ought to be 'an:123' for our purposes.
 719     $term =~ s/=/:/g;
 720     $term = $self->_convert_index_strings_freeform($term);
 721     $term =~ s/[{}]/"/g;
 722     return $term;
 723 }
 724
 725 =head2 _fix_limit_special_cases
 726
 727     my $limits = $self->_fix_limit_special_cases($limits);
 728
 729 This converts any special cases that the limit specifications have into things
 730 that are more readily processable by the rest of the code.
 731
 732 The argument should be an arrayref, and it'll return an arrayref.
 733
 734 =cut
 735
 736 sub _fix_limit_special_cases {
 737     my ( $self, $limits ) = @_;
 738
 739     my @new_lim;
 740     foreach my $l (@$limits) {
 741
 742         # This is set up by opac-search.pl
 743         if ( $l =~ /^yr,st-numeric,ge=/ ) {
 744             my ( $start, $end ) =
 745               ( $l =~ /^yr,st-numeric,ge=(.*) and yr,st-numeric,le=(.*)$/ );
 746             next unless defined($start) && defined($end);
 747             push @new_lim, "copydate:[$start TO $end]";
 748         }
 749         elsif ( $l =~ /^yr,st-numeric=/ ) {
 750             my ($date) = ( $l =~ /^yr,st-numeric=(.*)$/ );
 751             next unless defined($date);
 752             push @new_lim, "copydate:$date";
 753         }
 754         elsif ( $l =~ /^available$/ ) {
 755             push @new_lim, 'onloan:0';
 756         }
 757         else {
 758             push @new_lim, $l;
 759         }
 760     }
 761     return \@new_lim;
 762 }
 763
 764 =head2 _sort_field
 765
 766     my $field = $self->_sort_field($field);
 767
 768 Given a field name, this works out what the actual name of the version to sort
 769 on should be. Often it's the same, sometimes it involves sticking "__sort" on
 770 the end. Maybe it'll be something else in the future, who knows?
 771
 772 =cut
 773
 774 sub _sort_field {
 775     my ($self, $f) = @_;
 776     if ($self->sort_fields()->{$f}) {
 777         $f .= '__sort';
 778     }
 779     return $f;
 780 }
 781
 782 1;