Koha/Template/Plugin/Branches.pm

   1 package Koha::Template::Plugin::Branches;
   2
   3 # Copyright ByWater Solutions 2012
   4 # Copyright BibLibre 2014
   5
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use Template::Plugin;
  24 use base qw( Template::Plugin );
  25
  26 use C4::Koha;
  27 use C4::Context;
  28 use Koha::Libraries;
  29
  30 sub GetName {
  31     my ( $self, $branchcode ) = @_;
  32
  33     my $l = Koha::Libraries->find($branchcode);
  34     return $l ? $l->branchname : q{};
  35 }
  36
  37 sub GetLoggedInBranchcode {
  38     my ($self) = @_;
  39
  40     return C4::Context::mybranch;
  41 }
  42
  43 sub GetLoggedInBranchname {
  44     my ($self) = @_;
  45
  46     return C4::Context->userenv ? C4::Context->userenv->{'branchname'} : q{};
  47 }
  48
  49 sub GetURL {
  50     my ( $self, $branchcode ) = @_;
  51
  52     my $query = "SELECT branchurl FROM branches WHERE branchcode = ?";
  53     my $sth   = C4::Context->dbh->prepare($query);
  54     $sth->execute($branchcode);
  55     my $b = $sth->fetchrow_hashref();
  56     return $b->{branchurl};
  57 }
  58
  59 sub all {
  60     my ( $self, $params ) = @_;
  61     my $selected = $params->{selected};
  62     my $selecteds = $params->{selecteds};
  63     my $unfiltered = $params->{unfiltered} || 0;
  64     my $search_params = $params->{search_params} || {};
  65     my $do_not_select_my_library = $params->{do_not_select_my_library} || 0; # By default we select the library of the logged in user if no selected passed
  66
  67     if ( !$unfiltered ) {
  68         $search_params->{only_from_group} = $params->{only_from_group} || 0;
  69     }
  70
  71     my @selected =
  72       ref $selected eq 'Koha::Libraries'
  73       ? $selected->get_column('branchcode')
  74       : $selected;
  75
  76     my $libraries = $unfiltered
  77       ? Koha::Libraries->search( $search_params, { order_by => ['branchname'] } )->unblessed
  78       : Koha::Libraries->search_filtered( $search_params, { order_by => ['branchname'] } )->unblessed;
  79
  80     if (defined $selecteds) {
  81         # For a select multiple, must be a Koha::Libraries
  82         my @selected_branchcodes = $selecteds ? $selecteds->get_column( ['branchcode'] ) : ();
  83         $libraries = [ map {
  84             my $l = $_;
  85             $l->{selected} = 1
  86               if grep { $_ eq $l->{branchcode} } @selected_branchcodes;
  87             $l;
  88         } @$libraries ];
  89     }
  90     else {
  91         for my $l ( @$libraries ) {
  92             if (       defined $selected and $l->{branchcode} eq $selected
  93                 or not defined $selected and C4::Context->userenv and $l->{branchcode} eq ( C4::Context->userenv->{branch} // q{} )
  94             ) {
  95                 $l->{selected} = 1;
  96             }
  97         }
  98     }
  99
 100     return $libraries;
 101 }
 102
 103 sub InIndependentBranchesMode {
 104     my ( $self ) = @_;
 105     return ( not C4::Context->preference("IndependentBranches") or C4::Context::IsSuperLibrarian );
 106 }
 107
 108 sub pickup_locations {
 109     my ( $self, $params ) = @_;
 110     my $search_params = $params->{search_params} || {};
 111     my $selected      = $params->{selected};
 112     my @libraries;
 113
 114     if(defined $search_params->{item} || defined $search_params->{biblio}) {
 115         my $item = $search_params->{'item'};
 116         my $biblio = $search_params->{'biblio'};
 117         my $patron = $search_params->{'patron'};
 118
 119         unless (! defined $patron || ref($patron) eq 'Koha::Patron') {
 120             $patron = Koha::Patrons->find($patron);
 121         }
 122
 123         if ($item) {
 124             $item = Koha::Items->find($item)
 125               unless ref($item) eq 'Koha::Item';
 126             @libraries = $item->pickup_locations( { patron => $patron } )
 127               if defined $item;
 128         }
 129         elsif ($biblio) {
 130             $biblio = Koha::Biblios->find($biblio)
 131               unless ref($biblio) eq 'Koha::Biblio';
 132             @libraries = $biblio->pickup_locations( { patron => $patron } )
 133               if defined $biblio;
 134         }
 135     }
 136
 137     @libraries = Koha::Libraries->search( { pickup_location => 1 },
 138         { order_by => ['branchname'] } )
 139       unless @libraries;
 140
 141     @libraries = map { $_->unblessed } @libraries;
 142
 143     for my $l (@libraries) {
 144         if ( defined $selected and $l->{branchcode} eq $selected
 145             or not defined $selected
 146             and C4::Context->userenv
 147             and $l->{branchcode} eq C4::Context->userenv->{branch} )
 148         {
 149             $l->{selected} = 1;
 150         }
 151     }
 152
 153     return \@libraries;
 154 }
 155
 156 1;