Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 # Copyright 2016 PTFS Europe
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18 #
  19 # Current maintainer MJR http://mjr.towers.org.uk/
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27 use Getopt::Long qw/HelpMessage/;
  28 use FindBin; # we need to enforce which C4::Installer::PerlModule is used in case more than one is installed
  29
  30 use lib $FindBin::Bin;
  31
  32 use C4::Installer::PerlModules;
  33
  34 my $koha_pm = C4::Installer::PerlModules->new;
  35
  36 my $DEBUG = 0;
  37 die "perl 5.10 or later required" unless ($] >= 5.010000);
  38
  39 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  40
  41 my $dirtree = hashdir('.');
  42 my %result = ();
  43
  44 =head1 NAME
  45
  46 Makefile.PL - Koha packager and installer
  47
  48 =head1 SYNOPSIS
  49
  50 =head2 BASIC INSTALLATION
  51
  52     perl Makefile.PL
  53     make
  54     make test
  55     sudo make install
  56
  57 =head2 UPGRADE INSTALLATION
  58
  59     NOTE: This option is only available if koha-install-log exists.
  60
  61     perl Makefile.PL --prev-install-log /path/to/koha-install-log
  62
  63     make
  64     make test
  65     sudo make upgrade
  66
  67 =head2 PACKAGING RELEASE TARBALLS
  68
  69     make manifest tardist
  70     make manifest zipdist
  71
  72 =head2 CLEANING UP
  73
  74         make clean
  75
  76 =head2 CLI PARAMETERS
  77
  78     --prev-install-log           Read configuration from previous installation
  79     --install_mode               Installation mode (dev, standard, single)
  80     --db_type                    Database (mysql, Pg)
  81     --db_host                    Database host (e.g. localhost)
  82     --db_port                    Database port (e.g. 3306)
  83     --db_name                    Database name (e.g. koha)
  84     --db_user                    Database user (e.g. kohaadmin)
  85     --db_pass                    Database password (e.g. katikoan)
  86     --zebra_marc_format          Zebra MARC format (marc21, unimarc)
  87     --zebra_language             Zebra language (e.g. en)
  88     --zebra_tokenizer            Zebra tokenizer (chr, icu)
  89     --zebra_user                 Zebra user (e.g. kohauser)
  90     --zebra_pass                 Zebra password (e.g. zebrastripes)
  91     --zebra_sru_host             Zebra SRU servername (e.g. localhost)
  92     --zebra_sru_biblios_port     Zebra SRU biblios port (e.g. 9998)
  93     --zebra_sru_authorities_port Zebra SRU biblios port (e.g. 9999)
  94     --koha_user                  Koha Unix user (e.g. koha)
  95     --koha_group                 Koha Unix group (e.g. koha)
  96     --install_sru                Install the SRU server (yes, no)
  97     --use_memcached              Use Memcached (yes, no)
  98     --font_dir                   Location of fonts (e.g. /usr/share/fonts/truetype/dejavu)
  99     --run_database_tests         Run database dependent tests (yes, no)
 100     --install_base               Base directory of installation (e.g. /usr/share/koha)
 101     --template-cache-dir         Specify a template cache directory (e.g. /var/cache/koha)
 102     --help                       Display this help message
 103
 104 =head1 DESCRIPTION
 105
 106 This is a packager and installer that uses
 107 ExtUtils::MakeMaker, which is fairly common
 108 on perl systems.
 109 As well as building tar or zip files
 110 and installing with the above commands,
 111 it allows us to check pre-requisites
 112 and generate configuration files.
 113
 114 =head1 VARIABLES
 115
 116 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
 117
 118 Basic metadata about this software.
 119
 120 =head2 NO_META
 121
 122 Suppress generation of META.yml file.
 123
 124 =head2 PREREQ_PM
 125
 126 Hash of perl modules and versions required.
 127
 128 =head2 PM
 129
 130 Hash of file mappings
 131
 132 =head2 PL_FILES
 133
 134 This is a hash of PL scripts to run after installation and
 135 the files to ask them to generate.
 136 Maybe use the values from CONFIGURE
 137 to generate initial configuration files in future.
 138
 139 =cut
 140
 141 =head2 target_map
 142
 143 This is a hash mapping directories and files in the
 144 source tree to installation target directories.  The rules
 145 for this mapping are:
 146
 147 =over 4
 148
 149 =item If a directory or file is specified, it and its
 150 contents will be copied to the installation target directory.
 151
 152 =item If a subdirectory of a mapped directory is specified,
 153 its target overrides the parent's target for that subdirectory.
 154
 155 =item The value of each map entry may either be a scalar containing
 156 one target or a reference to a hash containing 'target' and 'trimdir'
 157 keys.
 158
 159 =item Any files at the top level of the source tree that are
 160 not included in the map will not be installed.
 161
 162 =item Any directories at the top level of the source tree
 163 that are not included in the map will be installed in
 164 INTRANET_CGI_DIR.  This is a sensible default given the
 165 current organization of the source tree, but (FIXME) it
 166 would be better to reorganize the source tree to better
 167 match the installation system, to allow adding new directories
 168 without having to adjust Makefile.PL each time.  The idea
 169 is to make the C<$target_map> hash as minimal as possible.
 170
 171 =back
 172
 173 The permitted installation targets are:
 174
 175 =over 4
 176
 177 =item INTRANET_CGI_DIR
 178
 179 CGI scripts for intranet (staff) interface.
 180
 181 =item INTRANET_TMPL_DIR
 182
 183 HTML templates for the intranet interface.
 184
 185 =item INTRANET_WWW_DIR
 186
 187 HTML files, images, etc. for DocumentRoot for the intranet interface.
 188
 189 =item OPAC_CGI_DIR
 190
 191 CGI scripts for OPAC (public) interface.
 192
 193 =item OPAC_TMPL_DIR
 194
 195 HTML templates for the OPAC interface.
 196
 197 =item OPAC_WWW_DIR
 198
 199 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 200
 201 =item PERL_MODULE_DIR
 202
 203 Perl modules (at present just the C4 modules) that are intimately
 204 tied to Koha.  Depending on the installation options, these
 205 may or may not be installed one of the standard directories
 206 in Perl's default @LIB.
 207
 208 =item KOHA_CONF_DIR
 209
 210 Directory for Koha configuration files.
 211
 212 =item ZEBRA_CONF_DIR
 213
 214 Directory for Zebra configuration files.
 215
 216 =item ZEBRA_LOCK_DIR
 217
 218 Directory for Zebra's lock files.  This includes subdirs for authorities,
 219 biblios, and the zebra rebuild function.  Any activity to reindex
 220 zebra from koha should interlock here with rebuild_zebra.pl.
 221
 222 =item ZEBRA_DATA_DIR
 223
 224 Directory for Zebra's data files.
 225
 226 =item ZEBRA_RUN_DIR
 227
 228 Directory for Zebra's UNIX-domain sockets.
 229
 230 =item ELASTICSEARCH_SERVERS
 231
 232 Server:port of the Elasticsearch server to use, as a comma separated list:
 233 eg. 192.168.0.100:9200, localhost:9200
 234
 235 =item ELASTICSEARCH_INDEX
 236
 237 Unique index in Elasticsearch, for this Koha-instance
 238 eg. koha-mykoha  or just  koha
 239
 240 =item MISC_DIR
 241
 242 Directory for for miscellaenous scripts, among other
 243 things the translation toolkit and RSS feed tools.
 244
 245 =item SCRIPT_DIR
 246
 247 Directory for command-line scripts and daemons to
 248 be set up all for installation modes.
 249
 250 =item SCRIPT_NONDEV_DIR
 251
 252 Directory for command-line scripts that should
 253 be installed in the same directory as the
 254 SCRIPT_DIR target except 'dev' installs.
 255
 256 =item MAN_DIR
 257
 258 Directory for man pages created from POD -- will mostly
 259 contain information of interest to Koha developers.
 260
 261 =item DOC_DIR
 262
 263 Directory for Koha documentation accessed from the
 264 command-line, e.g., READMEs.
 265
 266 =item LOCK_DIR
 267
 268 Directory for Koha scripts to put their locks.
 269
 270 =item LOG_DIR
 271
 272 Directory for Apache and Zebra logs produced by Koha.
 273
 274 =item BACKUP_DIR
 275
 276 Directory for backup files produced by Koha.
 277
 278 =item PLUGINS_DIR
 279
 280 Directory for external Koha plugins.
 281
 282 =item FONT_DIR
 283
 284 Directory where DejaVu fonts are installed.
 285
 286 =item NONE
 287
 288 This is a dummy target used to explicitly state
 289 that a given file or directory is not to be installed.
 290 This is used either for parts of the installer itself
 291 or for development tools that are not applicable to a
 292 production installation.
 293
 294 =back
 295
 296 =cut
 297
 298 my $target_map = {
 299   './about.pl'                  => 'INTRANET_CGI_DIR',
 300   './acqui'                     => 'INTRANET_CGI_DIR',
 301   './admin'                     => 'INTRANET_CGI_DIR',
 302   './api'                       => { target => 'API_CGI_DIR', trimdir => -1 },
 303   './app.psgi'                  => 'SCRIPT_DIR',
 304   './authorities'               => 'INTRANET_CGI_DIR',
 305   './basket'                    => 'INTRANET_CGI_DIR',
 306   './bin'                       => { target => 'SCRIPT_DIR', trimdir => -1 },
 307   './C4'                        => 'PERL_MODULE_DIR',
 308   './C4/SIP/t'                  => 'NONE',
 309   './C4/SIP/koha_test'          => 'NONE',
 310   './C4/tests'                  => 'NONE',
 311   './catalogue'                 => 'INTRANET_CGI_DIR',
 312   './cataloguing'               => 'INTRANET_CGI_DIR',
 313   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 314   './check_sysprefs.pl'         => 'NONE',
 315   './circ'                      => 'INTRANET_CGI_DIR',
 316   './clubs'                     => 'INTRANET_CGI_DIR',
 317   './course_reserves'           => 'INTRANET_CGI_DIR',
 318   './cpanfile'                  => 'PERL_MODULE_DIR',
 319   './docs/history.txt'          => { target => 'DOC_DIR', trimdir => -1 },
 320   './docs/contributors.yaml'    => { target => 'DOC_DIR', trimdir => -1 },
 321   './docs/teams.yaml'           => { target => 'DOC_DIR', trimdir => -1 },
 322   './offline_circ'              => 'INTRANET_CGI_DIR',
 323   './erm'                       => 'INTRANET_CGI_DIR',
 324   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 325   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 326   './etc/z3950'                 => { target => 'Z3950_CONF_DIR', trimdir => -1 },
 327   './help.pl'                   => 'INTRANET_CGI_DIR',
 328   './ill'                       => 'INTRANET_CGI_DIR',
 329   './installer-CPAN.pl'         => 'NONE',
 330   './installer'                 => 'INTRANET_CGI_DIR',
 331   './errors'                    => {target => 'INTRANET_CGI_DIR'},
 332   './Koha'                      => 'PERL_MODULE_DIR',
 333   './Koha.pm'                   => 'PERL_MODULE_DIR',
 334   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 335   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 336   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 337   './labels'                    => 'INTRANET_CGI_DIR',
 338   './lib'                       => {target => 'PERL_MODULE_LIB_DIR', trimdir => -1},
 339   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 340   './Makefile.PL'               => 'NONE',
 341   './MANIFEST.SKIP'             => 'NONE',
 342   './members'                   => 'INTRANET_CGI_DIR',
 343   './misc'                      => { target => 'SCRIPT_NONDEV_DIR', trimdir => -1 },
 344   './misc/bin'                  => { target => 'SCRIPT_DIR', trimdir => -1 },
 345   './misc/release_notes'        => { target => 'DOC_DIR', trimdir => 2 },
 346   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 347   './misc/koha-install-log'     => { target => 'MISC_DIR', trimdir => -1 },
 348   './misc/installer_devel_notes' => 'NONE',
 349   './opac'                      => 'OPAC_CGI_DIR',
 350   './OpenILS'                   => 'PERL_MODULE_DIR',
 351   './README.txt'                => 'NONE',
 352   './patroncards'               => 'INTRANET_CGI_DIR',
 353   './patron_lists'              => 'INTRANET_CGI_DIR',
 354   './plugins'                   => 'INTRANET_CGI_DIR',
 355   './pos'                       => 'INTRANET_CGI_DIR',
 356   './recalls'                   => 'INTRANET_CGI_DIR',
 357   './reports'                   => 'INTRANET_CGI_DIR',
 358   './reserve'                   => 'INTRANET_CGI_DIR',
 359   './reviews'                   => 'INTRANET_CGI_DIR',
 360   './rewrite-config.PL'         => 'NONE',
 361   './reviews'                   => 'INTRANET_CGI_DIR',
 362   './rotating_collections'      => 'INTRANET_CGI_DIR',
 363   './serials'                   => 'INTRANET_CGI_DIR',
 364   './services'                  => 'INTRANET_CGI_DIR',
 365   './skel'                      => 'NONE',
 366   './skel/var/lock/koha'        => { target => 'LOCK_DIR', trimdir => -1 },
 367   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 368   './skel/var/spool/koha'       => { target => 'BACKUP_DIR', trimdir => -1 },
 369   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 370   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 371   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 372   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 373   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 374   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 375   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 376   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 377   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 378   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 379   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 380   './skel/var/lock/koha/zebradb/rebuild' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 381   './skel/var/lib/koha/plugins' => { target => 'PLUGINS_DIR', trimdir => 6 },
 382   './sms'                       => 'INTRANET_CGI_DIR',
 383   './suggestion'                => 'INTRANET_CGI_DIR',
 384   './svc'                       => 'INTRANET_CGI_DIR',
 385   './t'                         => 'NONE',
 386   './xt'                        => 'NONE',
 387   './tags'                      => 'INTRANET_CGI_DIR',
 388   './tmp'                       => 'NONE', # FIXME need to determine whether
 389                                            # Koha generates any persistent temp files
 390                                            # that should go in /var/tmp/koha
 391   './tools'                     => 'INTRANET_CGI_DIR',
 392   './virtualshelves'            => 'INTRANET_CGI_DIR',
 393   # ignore files and directories created by the install itself
 394   './pm_to_blib'                => 'NONE',
 395   './blib'                      => 'NONE',
 396   '.sass-lint.yml'              => 'NONE',
 397   '.scss-lint.yml'              => 'NONE',
 398   '.eslintrc.json'              => 'NONE',
 399   'gulpfile.js'                 => 'NONE',
 400   'package.json'                => 'NONE',
 401   'yarn.lock'                   => 'NONE',
 402   'cypress.json'                => 'NONE',
 403   'tsconfig.json'               => 'NONE',
 404   'webpack.config.js'           => 'NONE',
 405 };
 406
 407 =head1 CONFIGURATION OPTIONS
 408
 409 The following configuration options are used by the installer.
 410
 411 =over 4
 412
 413 =item INSTALL_MODE
 414
 415 Specifies whether installation will be FHS-compliant (default,
 416 assumes user has root), put everything under
 417 a single directory (for users installing on a web host
 418 that allows CGI scripts and a MySQL database but not root
 419 access), or development (for a developer who wants to run
 420 Koha from a git clone with no fuss).
 421
 422 =item INSTALL_BASE
 423
 424 Directory under which most components will go.  Default
 425 value will vary depending on INSTALL_MODE.
 426
 427 =item DB_TYPE
 428
 429 Type of DBMS (e.g., mysql or Pg).
 430
 431 =item DB_HOST
 432
 433 Name of DBMS server.
 434
 435 =item DB_PORT
 436
 437 Port that DBMS server is listening on.
 438
 439 =item DB_NAME
 440
 441 Name of the DBMS database for Koha.
 442
 443 =item DB_USER
 444
 445 Name of DBMS user account for Koha's database.
 446
 447 =item DB_PASS
 448
 449 Pasword of DMBS user account for Koha's database.
 450
 451 =item ZEBRA_MARC_FORMAT
 452
 453 Specifies format of MARC records to be indexed by Zebra.
 454
 455 =item ZEBRA_LANGUAGE
 456
 457 Specifies primary language of records that will be
 458 indexed by Zebra.
 459
 460 =item ZEBRA_USER
 461
 462 Internal Zebra user account for the index.
 463
 464 =item ZEBRA_PASS
 465
 466 Internal Zebra user account's password.
 467
 468 =item KOHA_USER
 469
 470 System user account that will own Koha's files.
 471
 472 =item KOHA_GROUP
 473
 474 System group that will own Koha's files.
 475
 476 =item SMTP_HOST
 477
 478 SMTP server host name (default: localhost)
 479
 480 =item SMTP_PORT
 481
 482 SMTP server port (default: 25)
 483
 484 =item SMTP_TIMEOUT
 485
 486 Connection timeour in seconds (default: 120)
 487
 488 =item SMTP_SSL_MODE
 489
 490 SSL mode. Options are 'disabled' (default), 'ssl' and 'starttls'
 491
 492 =item SMTP_USER_NAME
 493
 494 SMTP authentication user name
 495
 496 =item SMTP_PASSWORD
 497
 498 SMTP authentication password
 499
 500 =item SMTP_DEBUG
 501
 502 Enable debug mode for SMTP (default: no)
 503
 504 =back
 505
 506 =cut
 507
 508 # default configuration options
 509 my %config_defaults = (
 510   'DB_TYPE'           => 'mysql',
 511   'DB_HOST'           => 'localhost',
 512   'DB_NAME'           => 'koha',
 513   'DB_USER'           => 'kohaadmin',
 514   'DB_PASS'           => 'katikoan',
 515   'DB_USE_TLS'        => 'no',
 516   'DB_TLS_CA_CERTIFICATE'  => '/etc/mysql-ssl/server-ca.pem',
 517   'DB_TLS_CLIENT_CERTIFICATE'  => '/etc/mysql-ssl/client-cert.pem',
 518   'DB_TLS_CLIENT_KEY' => '/etc/mysql-ssl/client-key.pem',
 519   'INSTALL_SRU'       => 'yes',
 520   'ZEBRA_MARC_FORMAT' => 'marc21',
 521   'ZEBRA_LANGUAGE'    => 'en',
 522   'ZEBRA_TOKENIZER'   => 'chr',
 523   'ZEBRA_USER'        => 'kohauser',
 524   'ZEBRA_PASS'        => 'zebrastripes',
 525   'ZEBRA_SRU_HOST'    => 'localhost',
 526   'ZEBRA_SRU_BIBLIOS_PORT'    => '9998',
 527   'ZEBRA_SRU_AUTHORITIES_PORT'    => '9999',
 528   'KOHA_USER'         => 'koha',
 529   'KOHA_GROUP'        => 'koha',
 530   'MERGE_SERVER_HOST' => 'localhost',
 531   'MERGE_SERVER_PORT' => '11001',
 532   'RUN_DATABASE_TESTS' => 'no',
 533   'PATH_TO_ZEBRA' => '',
 534   'USE_MEMCACHED'     => 'yes',
 535   'MEMCACHED_SERVERS' => '127.0.0.1:11211',
 536   'MEMCACHED_NAMESPACE' => 'KOHA',
 537   'TEMPLATE_CACHE_DIR' => '/tmp/koha',
 538   'USE_ELASTICSEARCH'     => 'no',
 539   'ELASTICSEARCH_SERVERS' => 'localhost:9200',
 540   'ELASTICSEARCH_INDEX'  => 'koha',
 541   'FONT_DIR'          => '/usr/share/fonts/truetype/dejavu',
 542   'SMTP_HOST'      => 'localhost',
 543   'SMTP_PORT'      => '25',
 544   'SMTP_TIMEOUT'   => '120',
 545   'SMTP_SSL_MODE'  => 'disabled',
 546   'SMTP_USER_NAME' => '',
 547   'SMTP_PASSWORD'  => '',
 548   'SMTP_DEBUG'     => 'no',
 549 );
 550
 551 # set some default configuration options based on OS
 552 # more conditions need to be added for other OS's
 553
 554 warn "Your platform appears to be $^O.\n" if $DEBUG;
 555
 556 if ( $^O eq 'cygwin' ) {
 557         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 558         # this could be changed to put some files (ie. libraries) into system32, etc.
 559         $config_defaults{'INSTALL_MODE'} = 'single';
 560         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 561 }
 562 else {
 563         $config_defaults{'INSTALL_MODE'} = 'standard';
 564         $config_defaults{'INSTALL_BASE'} = '/usr/share/koha';
 565 }
 566
 567 # valid values for certain configuration options
 568 my %valid_config_values = (
 569   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 570   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 571   'DB_USE_TLS' => {'yes', 'no'},
 572   'INSTALL_SRU' => { 'yes' => 1, 'no' => 1 },
 573   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 574   'ZEBRA_LANGUAGE'    => { 'cs' => 1, 'el' => 1, 'en' => 1, 'es' => 1, 'fr' => 1, 'nb' => 1, 'ru' => 1, 'uk' => 1 }, # FIXME should generate from contents of distribution
 575   'ZEBRA_TOKENIZER' => { chr => 1, icu => 1 },
 576   'RUN_DATABASE_TESTS' => { 'yes' => 1, 'no' => 1 },
 577   'USE_MEMCACHED'      => { 'yes' => 1, 'no' => 1 },
 578   'USE_ELASTICSEARCH'  => { 'yes' => 1, 'no' => 1 },
 579   'SMTP_SSL_MODE'      => { 'disabled' => 1, 'ssl' => 1, 'starttls' => 1 },
 580   'SMTP_DEBUG'         => { 'yes' => 1, 'no' => 1 },
 581 );
 582
 583 # get settings from command-line
 584 my $koha_install_log = "";
 585 my $cli_koha_install_mode = "";
 586 my $cli_koha_db_type = "";
 587 my $cli_koha_db_host = "";
 588 my $cli_koha_db_port = "";
 589 my $cli_koha_db_name = "";
 590 my $cli_koha_db_user = "";
 591 my $cli_koha_db_pass = "";
 592 my $cli_zebra_marc_format = "";
 593 my $cli_zebra_language = "",
 594 my $cli_zebra_tokenizer = "";
 595 my $cli_zebra_user = "";
 596 my $cli_zebra_pass = "";
 597 my $cli_zebra_sru_host = "";
 598 my $cli_zebra_sru_bib_port = "";
 599 my $cli_zebra_sru_auth_port = "";
 600 my $cli_koha_user = "";
 601 my $cli_koha_group = "";
 602 my $cli_koha_install_sru = "";
 603 my $cli_koha_use_memcached = "";
 604 my $cli_koha_font_dir = "";
 605 my $cli_koha_run_database_tests = "";
 606 my $cli_koha_install_base = "";
 607 my $cli_koha_template_cache_dir = "";
 608 my $cli_smtp_host      = "";
 609 my $cli_smtp_port      = "";
 610 my $cli_smtp_timeout   = "";
 611 my $cli_smtp_ssl_mode  = "";
 612 my $cli_smtp_user_name = "";
 613 my $cli_smtp_password  = "";
 614 my $cli_smtp_debug     = "";
 615
 616 Getopt::Long::Configure('pass_through');
 617 my $results = GetOptions(
 618     "prev-install-log=s"           => \$koha_install_log,
 619     "install_mode=s"               => \$cli_koha_install_mode,
 620     "db_type=s"                    => \$cli_koha_db_type,
 621     "db_host=s"                    => \$cli_koha_db_host,
 622     "db_port=s"                    => \$cli_koha_db_port,
 623     "db_name=s"                    => \$cli_koha_db_name,
 624     "db_user=s"                    => \$cli_koha_db_user,
 625     "db_pass=s"                    => \$cli_koha_db_pass,
 626     "zebra_marc_format=s"          => \$cli_zebra_marc_format,
 627     "zebra_language=s"             => \$cli_zebra_language,
 628     "zebra_tokenizer=s"            => \$cli_zebra_tokenizer,
 629     "zebra_user=s"                 => \$cli_zebra_user,
 630     "zebra_pass=s"                 => \$cli_zebra_pass,
 631     "zebra_sru_host=s"             => \$cli_zebra_sru_host,
 632     "zebra_sru_biblios_port=s"     => \$cli_zebra_sru_bib_port,
 633     "zebra_sru_authorities_port=s" => \$cli_zebra_sru_auth_port,
 634     "koha_user=s"                  => \$cli_koha_user,
 635     "koha_group=s"                 => \$cli_koha_group,
 636     "install_sru=s"                => \$cli_koha_install_sru,
 637     "use_memcached=s"              => \$cli_koha_use_memcached,
 638     "font_dir=s"                   => \$cli_koha_font_dir,
 639     "run_database_tests=s"         => \$cli_koha_run_database_tests,
 640     "install_base=s"               => \$cli_koha_install_base,
 641     "template-cache-dir=s"         => \$cli_koha_template_cache_dir,
 642     "smtp-host=s"                  => \$cli_smtp_host,
 643     "smtp-port=s"                  => \$cli_smtp_port,
 644     "smtp-timeout=s"               => \$cli_smtp_timeout,
 645     "smtp-ssl-mode=s"              => \$cli_smtp_ssl_mode,
 646     "smtp-user-name=s"             => \$cli_smtp_user_name,
 647     "smtp-password=s"              => \$cli_smtp_password,
 648     "smtp-debug"                   => \$cli_smtp_debug,
 649     "help"                         => sub { HelpMessage(0) },
 650 ) or HelpMessage(1);
 651
 652 my %install_log_values = ();
 653 if ($koha_install_log ne "") {
 654     get_install_log_values($koha_install_log, \%install_log_values);
 655 } else {
 656     # Try to set install_log_values for provided values;
 657     get_cli_values(\%install_log_values);
 658 }
 659
 660 my %config = get_configuration(\%config_defaults, \%valid_config_values, \%install_log_values);
 661 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 662 display_configuration(\%config, $target_directories);
 663 my $file_map = {};
 664 get_file_map($target_map, $dirtree, $file_map);
 665
 666 #NOTE: List files generated by build-resources.PL, so that they're copied into blib for installation
 667 #INTRANET_TMPL_DIR
 668 $file_map->{'koha-tmpl/intranet-tmpl/prog/css/calendar.css'} = 'blib/INTRANET_TMPL_DIR/prog/css/calendar.css';
 669 $file_map->{'koha-tmpl/intranet-tmpl/prog/css/holds.css'} = 'blib/INTRANET_TMPL_DIR/prog/css/holds.css';
 670 $file_map->{'koha-tmpl/intranet-tmpl/prog/css/installer.css'} = 'blib/INTRANET_TMPL_DIR/prog/css/installer.css';
 671 $file_map->{'koha-tmpl/intranet-tmpl/prog/css/mainpage.css'} = 'blib/INTRANET_TMPL_DIR/prog/css/mainpage.css';
 672 $file_map->{'koha-tmpl/intranet-tmpl/prog/css/staff-global.css'} = 'blib/INTRANET_TMPL_DIR/prog/css/staff-global.css';
 673 $file_map->{'koha-tmpl/intranet-tmpl/prog/js/vue/dist/main.js'} = 'blib/INTRANET_TMPL_DIR/prog/js/vue/dist/main.js';
 674 $file_map->{'koha-tmpl/intranet-tmpl/prog/js/vue/dist/main.js.LICENSE.txt'} = 'blib/INTRANET_TMPL_DIR/prog/js/vue/dist/main.js.LICENSE.txt';
 675 #OPAC_TMPL_DIR
 676 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/opac.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/opac.css';
 677 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/opac-rtl.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/opac-rtl.css';
 678 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/print.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/print.css';
 679 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/print-rtl.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/print-rtl.css';
 680 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/sco.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/sco.css';
 681 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/sco-rtl.css'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/sco-rtl.css';
 682 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/maps/opac-rtl.css.map'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/maps/opac-rtl.css.map';
 683 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/maps/print-rtl.css.map'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/maps/print-rtl.css.map';
 684 $file_map->{'koha-tmpl/opac-tmpl/bootstrap/css/maps/sco-rtl.css.map'} = 'blib/OPAC_TMPL_DIR/bootstrap/css/maps/sco-rtl.css.map';
 685
 686 my $pl_files = {
 687       'rewrite-config.PL' => [
 688          'blib/KOHA_CONF_DIR/koha-conf.xml',
 689          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 690          'blib/KOHA_CONF_DIR/log4perl.conf',
 691          'blib/KOHA_CONF_DIR/koha-worker.service',
 692          'blib/ZEBRA_CONF_DIR/etc/default.idx',
 693          'blib/MISC_DIR/koha-install-log'
 694          ],
 695           'fix-perl-path.PL' => [       # this script ensures the correct shebang line for the platform installed on...
 696                  'blib'
 697                  ],
 698 };
 699
 700 push @{ $pl_files->{'rewrite-config.PL'} }, (
 701     'blib/ZEBRA_CONF_DIR/etc/passwd',
 702     'blib/ZEBRA_CONF_DIR/zebra-biblios-dom.cfg',
 703     'blib/ZEBRA_CONF_DIR/zebra-authorities-dom.cfg',
 704     'blib/ZEBRA_CONF_DIR/explain-authorities.xml',
 705     'blib/ZEBRA_CONF_DIR/explain-biblios.xml',
 706     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-dom.xml',
 707     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-dom.xml',
 708 );
 709 push @{ $pl_files->{'rewrite-config.PL'} }, (
 710     'blib/SCRIPT_DIR/koha-zebra-ctl.sh',
 711     'blib/SCRIPT_DIR/koha-index-daemon-ctl.sh',
 712 );
 713 $config{'ZEBRA_AUTH_CFG'} = 'zebra-authorities-dom.cfg';
 714 $config{'ZEBRA_BIB_CFG'}  = 'zebra-biblios-dom.cfg';
 715 $config{'AUTH_RETRIEVAL_CFG'} = 'retrieval-info-auth-dom.xml';
 716 $config{'BIB_RETRIEVAL_CFG'}  = 'retrieval-info-bib-dom.xml';
 717
 718 if ($config{'INSTALL_MODE'} ne "dev") {
 719     push @{ $pl_files->{'rewrite-config.PL'} }, (
 720         'blib/PERL_MODULE_DIR/C4/Context.pm',
 721     );
 722 }
 723
 724 $config{ZEBRA_TOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 725     ? 'icuchain words-icu.xml'
 726     : 'charmap word-phrase-utf.chr';
 727
 728 $config{ZEBRA_PTOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 729     ? 'icuchain phrases-icu.xml'
 730     : 'charmap word-phrase-utf.chr';
 731
 732 my %test_suite_override_dirs = (
 733     KOHA_CONF_DIR  => ['etc'],
 734     ZEBRA_CONF_DIR => ['etc', 'zebradb'],
 735     Z3950_CONF_DIR => ['etc', 'z3950'],
 736     LOCK_DIR       => ['var', 'lock'],
 737     LOG_DIR        => ['var', 'log'],
 738     BACKUP_DIR     => ['var', 'spool'],
 739     SCRIPT_DIR     => ['bin'],
 740     ZEBRA_LOCK_DIR => ['var', 'lock', 'zebradb'],
 741     ZEBRA_DATA_DIR => ['var', 'lib', 'zebradb'],
 742     ZEBRA_RUN_DIR  => ['var', 'run', 'zebradb'],
 743 );
 744
 745 WriteMakefile(
 746               NAME         => 'koha',
 747               #VERSION     => strftime('2.9.%Y%m%d%H',gmtime),
 748               VERSION_FROM => 'kohaversion.pl',
 749               ABSTRACT     => 'Award-winning integrated library system (ILS) and Web OPAC',
 750               AUTHOR       => 'Koha Contributors <https://koha-community.org/>',
 751               NO_META      => 1,
 752               PREREQ_PM    => $koha_pm->prereq_pm,
 753
 754               # File tree mapping
 755               PM => $file_map,
 756
 757               # Man pages generated from POD
 758               # ExtUtils::MakeMaker already manage $(DESTDIR)
 759               INSTALLMAN1DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man1'),
 760               INSTALLMAN3DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man3'),
 761
 762               PL_FILES => $pl_files,
 763 );
 764
 765 =head1 FUNCTIONS
 766
 767 =head2 hashdir
 768
 769 This function recurses through the directory structure and builds
 770 a hash of hashes containing the structure with arrays holding filenames.
 771 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 772
 773 =cut
 774
 775 sub hashdir{
 776     my $dir = shift;
 777     opendir my $dh, $dir or die $!;
 778     my $tree = {}->{$dir} = {};
 779     while( my $file = readdir($dh) ) {
 780         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 781         my $path = $dir .'/' . $file;
 782         $tree->{$file} = hashdir($path), next if -d $path;
 783         push @{$tree->{'.'}}, $file;
 784     }
 785     return $tree;
 786 }
 787
 788 =head2 get_file_map
 789
 790 This function combines the target_map and file hash to
 791 map each source file to its destination relative to
 792 the set of installation targets.
 793
 794 Output will be a hash mapping from each source file
 795 to its destination value, like this:
 796
 797 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 798
 799 =cut
 800
 801 sub get_file_map {
 802     my $target_map = shift;
 803     my $dirtree = shift;
 804     my $file_map = shift;
 805     my $curr_path = @_ ? shift : ['.'];
 806
 807     # Traverse the directory tree.
 808     # For each file or directory, identify the
 809     # most specific match in the target_map
 810     foreach my $dir (sort keys %{ $dirtree }) {
 811         if ($dir eq '.') {
 812             # deal with files in directory
 813             foreach my $file (sort @{ $dirtree->{$dir} }) {
 814                 my $targetdir = undef;
 815                 my $matchlevel = undef;
 816                 # first, see if there is a match on this specific
 817                 # file in the target map
 818                 my $filepath = join("/", @$curr_path, $file);
 819                 if (exists $target_map->{$filepath}) {
 820                     $targetdir = $target_map->{$filepath};
 821                     $matchlevel = scalar(@$curr_path) + 1;
 822                 } else {
 823                     # no match on the specific file; look for
 824                     # a directory match
 825                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 826                         my $dirpath = join("/", @$curr_path[0..$i]);
 827                         if (exists $target_map->{$dirpath}) {
 828                             $targetdir = $target_map->{$dirpath};
 829                             $matchlevel = $i + 1;
 830                             last;
 831                         }
 832                     }
 833                 }
 834                 if (defined $targetdir) {
 835                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel);
 836                 } else {
 837                     my $path = join("/", @$curr_path);
 838                     print "failed to map: $path/$file\n" if $DEBUG;
 839                 }
 840             }
 841         } else {
 842             # dealing with subdirectory
 843             push @$curr_path, $dir;
 844             get_file_map($target_map, $dirtree->{$dir}, $file_map, $curr_path);
 845             pop @$curr_path;
 846         }
 847     }
 848 }
 849
 850 sub _add_to_file_map {
 851     my $file_map = shift;
 852     my $targetdir = shift;
 853     my $curr_path = shift;
 854     my $file = shift;
 855     my $matchlevel = shift;
 856     my $dest_path = @_ ? shift : $curr_path;
 857
 858     # The target can be one of the following:
 859     # 1. scalar representing target symbol
 860     # 2. hash ref containing target and trimdir keys
 861     #
 862     # Consequently, this routine traverses this structure,
 863     # calling itself recursively, until it deals with
 864     # all of the scalar target symbols.
 865     if (ref $targetdir eq 'HASH') {
 866         my $subtarget = $targetdir->{target};
 867         if (exists $targetdir->{trimdir}) {
 868             # if we get here, we've specified that
 869             # rather than installing the file to
 870             # $(TARGET)/matching/dirs/subdirs/file,
 871             # we want to install it to
 872             # $(TARGET)/subdirs/file
 873             #
 874             # Note that this the only place where
 875             # $matchlevel is used.
 876             my @new_dest_path = @$dest_path;
 877             if ($targetdir->{trimdir} == -1)  {
 878                 splice @new_dest_path, 0, $matchlevel;
 879             } else {
 880                 splice @new_dest_path, 0, $targetdir->{trimdir};
 881             }
 882             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, \@new_dest_path);
 883         } else {
 884             # actually getting here means that the
 885             # target was unnecessarily listed
 886             # as a hash, but we'll forgive that
 887             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel);
 888         }
 889     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 890         my $source = File::Spec->catfile(@$curr_path, $file);
 891         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 892         #print "$source => $destination\n"; # DEBUG
 893         # quote spaces in file names
 894         # FIXME: this is of questionable portability and
 895         # probably depends on user's make recognizing this
 896         # quoting syntax -- probably better to remove
 897         # spaces and shell metacharacters from all file names
 898         $source =~ s/ /\\ /g;
 899         $destination =~ s/ /\\ /g;
 900
 901         $file_map->{$source} = $destination;
 902     }
 903 }
 904
 905 =head2 get_cli_values
 906
 907 Reads values provided on cli for configuration values
 908
 909 =cut
 910
 911 sub get_cli_values {
 912     my $values = shift;
 913     my $map = {
 914         INSTALL_MODE               => $cli_koha_install_mode,
 915         DB_TYPE                    => $cli_koha_db_type,
 916         DB_HOST                    => $cli_koha_db_host,
 917         DB_PORT                    => $cli_koha_db_port,
 918         DB_NAME                    => $cli_koha_db_name,
 919         DB_USER                    => $cli_koha_db_user,
 920         DB_PASS                    => $cli_koha_db_pass,
 921         ZEBRA_MARC_FORMAT          => $cli_zebra_marc_format,
 922         ZEBRA_LANGUAGE             => $cli_zebra_language,
 923         ZEBRA_TOKENIZER            => $cli_zebra_tokenizer,
 924         ZEBRA_USER                 => $cli_zebra_user,
 925         ZEBRA_PASS                 => $cli_zebra_pass,
 926         ZEBRA_SRU_HOST             => $cli_zebra_sru_host,
 927         ZEBRA_SRU_BIBLIOS_PORT     => $cli_zebra_sru_bib_port,
 928         ZEBRA_SRU_AUTHORITIES_PORT => $cli_zebra_sru_auth_port,
 929         KOHA_USER                  => $cli_koha_user,
 930         KOHA_GROUP                 => $cli_koha_group,
 931         INSTALL_SRU                => $cli_koha_install_sru,
 932         USE_MEMCACHED              => $cli_koha_use_memcached,
 933         FONT_DIR                   => $cli_koha_font_dir,
 934         RUN_DATABASE_TESTS         => $cli_koha_run_database_tests,
 935         INSTALL_BASE               => $cli_koha_install_base,
 936         TEMPLATE_CACHE_DIR         => $cli_koha_template_cache_dir,
 937         SMTP_HOST                  => $cli_smtp_host,
 938         SMTP_PORT                  => $cli_smtp_port,
 939         SMTP_TIMEOUT               => $cli_smtp_timeout,
 940         SMTP_SSL_MODE              => $cli_smtp_ssl_mode,
 941         SMTP_USER_NAME             => $cli_smtp_user_name,
 942         SMTP_PASSWORD              => $cli_smtp_password,
 943         SMTP_DEBUG                 => (defined $cli_smtp_debug) ? ( $cli_smtp_debug ? 'yes' : 'no' ) : $values->{SMTP_DEBUG},
 944     };
 945     foreach my $key (keys %{$map}) {
 946         $values->{$key} = $map->{$key} if ($map->{$key});
 947     }
 948 }
 949
 950 =head2 get_install_log_values
 951
 952 Reads value from the Koha install log specified by
 953 --prev-install-log
 954
 955 =cut
 956
 957 sub get_install_log_values {
 958     my $install_log = shift;
 959     my $values = shift;
 960
 961     open my $log, '<', $install_log or die "Cannot open install log $install_log: $!\n";
 962     while (<$log>) {
 963         chomp;
 964         next if /^#/ or /^\s*$/;
 965         next if /^=/;
 966         next unless m/=/;
 967         s/\s+$//g;
 968         my ($key, $value) = split /=/, $_, 2;
 969         $values->{$key} = $value;
 970     }
 971     close $log;
 972
 973     print <<_EXPLAIN_INSTALL_LOG_;
 974 Reading values from install log $install_log.  You
 975 will be prompted only for settings that have been
 976 added since the last time you installed Koha.  To
 977 be prompted for all settings, run 'perl Makefile.PL'
 978 without the --prev-install-log option.
 979 _EXPLAIN_INSTALL_LOG_
 980 }
 981
 982 =head2 get_configuration
 983
 984 This prompts the user for various configuration options.
 985
 986 =cut
 987
 988 sub get_configuration {
 989   my $defaults = shift;
 990   my $valid_values = shift;
 991   my $install_log_values = shift;
 992   my %config = ();
 993
 994   my $msg = q(
 995 By default, Koha can be installed in one of three ways:
 996
 997 standard: Install files in conformance with the Filesystem
 998           Hierarchy Standard (FHS).  This is the default mode
 999           and should be used when installing a production
1000           Koha system.  On Unix systems, root access is
1001           needed to complete a standard installation.
1002
1003 single:   Install files under a single directory.  This option
1004           is useful for installing Koha without root access, e.g.,
1005           on a web host that allows CGI scripts and MySQL databases
1006           but requires the user to keep all files under the user's
1007           HOME directory.
1008
1009 dev:      Create a set of symbolic links and configuration files to
1010           allow Koha to run directly from the source distribution.
1011           This mode is useful for developers who want to run
1012           Koha from a git clone.
1013
1014 Installation mode);
1015     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
1016     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values, $install_log_values);
1017
1018     # set message and default value for INSTALL_BASE
1019     # depending on value of INSTALL_MODE
1020     my $install_base_default = $defaults->{'INSTALL_BASE'};
1021     if ($config{'INSTALL_MODE'} eq 'dev') {
1022         $msg = q(
1023 Please specify the directory in which to install Koha's
1024 active configuration files and (if applicable) the
1025 Zebra database.  Koha's CGI scripts and templates will
1026 be run from the current directory.
1027
1028 Configuration directory:);
1029         # FIXME - home directory portability consideration apply
1030         $install_base_default =
1031             $ENV{DESTDIR}
1032             || ( exists $ENV{HOME} ? "$ENV{HOME}/koha-dev" : "$defaults->{'INSTALL_BASE'}-dev" )
1033         ;
1034     } elsif ($config{'INSTALL_MODE'} eq 'single') {
1035         $msg = "\nPlease specify the directory in which to install Koha";
1036         # FIXME -- we're assuming under a 'single' mode install
1037         # that user will likely want to install under the home
1038         # directory.  This is OK in and of itself, but we should
1039         # use File::HomeDir to locate the home directory portably.
1040         # This is deferred for now because File::HomeDir is not yet
1041         # core.
1042                 # --we must also keep this portable to the major OS's -fbcit
1043         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : $defaults->{'INSTALL_BASE'};
1044     } else {
1045         # must be standard
1046         $msg = q(
1047 Please specify the directory under which most Koha files
1048 will be installed.
1049
1050 Note that if you are planning in installing more than
1051 one instance of Koha, you may want to modify the last
1052 component of the directory path, which will be used
1053 as the package name in the FHS layout.
1054
1055 Base installation directory);
1056     }
1057     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values, $install_log_values);
1058
1059     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
1060         print "INSTALL_BASE=$config{'INSTALL_BASE'}\r\n" if $DEBUG;
1061     if ($config{'INSTALL_MODE'} eq "standard") {
1062         $msg = q(
1063 Since you are using the 'standard' install
1064 mode, you should run 'make install' as root.
1065 However, it is recommended that a non-root
1066 user (on Unix and Linux platforms) have
1067 ownership of Koha's files, including the
1068 Zebra indexes if applicable.
1069
1070 Please specify a user account.  This
1071 user account does not need to exist
1072 right now, but it needs to exist
1073 before you run 'make install'.  Please
1074 note that for security reasons, this
1075 user should not be the same as the user
1076 account Apache runs under.
1077
1078 User account);
1079         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values, $install_log_values);
1080
1081         $msg = q(
1082 Please specify the group that should own
1083 Koha's files.  As above, this group need
1084 not exist right now, but should be created
1085 before you run 'make install'.
1086
1087 Group);
1088         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values, $install_log_values);
1089     }
1090
1091     $msg = q(
1092 Please specify which database engine you will use
1093 to store data in Koha.  The choices are MySQL and
1094 PostgreSQL; please note that at the moment
1095 PostgreSQL support is highly experimental.
1096
1097 DBMS to use);
1098     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
1099     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values, $install_log_values);
1100
1101     $msg = q(
1102 Please specify the name or address of your
1103 database server.  Note that the database
1104 does not have to exist at this point, it
1105 can be created after running 'make install'
1106 and before you try using Koha for the first time.
1107
1108 Database server);
1109     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values, $install_log_values);
1110
1111     $msg = q(
1112 Please specify the port used to connect to the
1113 DMBS);
1114     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
1115     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values, $install_log_values);
1116
1117     $msg = q(
1118 Please specify the name of the database to be
1119 used by Koha);
1120     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values, $install_log_values);
1121     if ($config{'DB_TYPE'} eq 'mysql'){
1122         $msg = q(
1123 Please specify whether the connection to MySQL will use TLS
1124         );
1125         $config{'DB_USE_TLS'} = _get_value('DB_USE_TLS', $msg, $defaults->{'DB_USE_TLS'}, $valid_values, $install_log_values);
1126     }
1127     if ($config{'DB_USE_TLS'} eq 'yes'){
1128         $msg = q(
1129 Please enter the path to the CA certificate for TLS
1130         );
1131         $config{'DB_TLS_CA_CERTIFICATE'} = _get_value('DB_TLS_CA_CERTIFICATE', $msg, $defaults->{'DB_TLS_CA_CERTIFICATE'}, $valid_values, $install_log_values);
1132
1133         $msg = q(
1134 Please enter the path to the client certificate for TLS
1135         );
1136         $config{'DB_TLS_CLIENT_CERTIFICATE'} = _get_value('DB_TLS_CLIENT_CERTIFICATE', $msg, $defaults->{'DB_TLS_CLIENT_CERTIFICATE'}, $valid_values, $install_log_values);
1137         $msg = q(
1138 Please enter the path to the client key for TLS
1139         );
1140         $config{'DB_TLS_CLIENT_KEY'} = _get_value('DB_TLS_CLIENT_KEY', $msg, $defaults->{'DB_TLS_CLIENT_KEY'}, $valid_values, $install_log_values);
1141     }
1142
1143     $msg = q(
1144 Please specify the user that owns the database to be
1145 used by Koha);
1146     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values, $install_log_values);
1147
1148     $msg = q(
1149 Please specify the password of the user that owns the
1150 database to be used by Koha);
1151     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values, $install_log_values);
1152
1153     print q(
1154 Koha uses the Zebra search engine for high-performance
1155 searching of bibliographic and authority records.  Checking
1156 to see if you have installed the Zebra software...
1157 );
1158
1159     if (defined(my $zebra_path = find_zebra())) {
1160         $config{'PATH_TO_ZEBRA'} = $zebra_path;
1161         print qq(
1162 Found 'zebrasrv' and 'zebraidx' in $zebra_path.
1163 );
1164     } else {
1165         print q(
1166 Unable to find the Zebra programs 'zebrasrv' and 'zebraidx'
1167 in your PATH or in some of the usual places.  If you haven't
1168 installed Zebra yet, please do so and run Makefile.PL again.
1169
1170 );
1171     }
1172
1173     $msg = q(
1174 You must specify the primary MARC format of the
1175 records to be indexed by Zebra.
1176
1177 Koha provides Zebra configuration files for MARC21,
1178 and UNIMARC.
1179
1180 MARC format for Zebra indexing);
1181     $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
1182     $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values, $install_log_values);
1183     $msg = q(
1184 Koha supplies Zebra configuration files tuned for
1185 searching either English (en) or French (fr) MARC
1186 records.
1187
1188 Primary language for Zebra indexing);
1189     $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
1190     $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values, $install_log_values);
1191
1192     $msg = q(
1193 Zebra has two methods to perform records tokenization
1194 and characters normalization: CHR and ICU. ICU is
1195 recommended for catalogs containing non-Latin
1196 characters.);
1197
1198     $msg .= _add_valid_values_disp('ZEBRA_TOKENIZER', $valid_values);
1199     $config{'ZEBRA_TOKENIZER'} = _get_value('ZEBRA_TOKENIZER', $msg, $defaults->{'ZEBRA_TOKENIZER'}, $valid_values, $install_log_values);
1200
1201     $msg = q(
1202 Please specify Zebra database user);
1203     $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values, $install_log_values);
1204
1205     $msg = q(
1206 Please specify the Zebra database password);
1207     $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values, $install_log_values);
1208
1209     $msg = q(
1210 Since you've chosen to use Zebra, you can enable the SRU/
1211 Z39.50 Server if you so choose, but you must specify a
1212 few configuration options for it.
1213
1214 Please note that if you choose *NOT* to configure SRU,
1215 koha-conf.xml will still contain some references to SRU
1216 settings.  Those references will be ignored by Koha.
1217
1218 Install the SRU configuration files?);
1219     $msg .= _add_valid_values_disp('INSTALL_SRU', $valid_values);
1220     $config{'INSTALL_SRU'} = _get_value('INSTALL_SRU', $msg, $defaults->{'INSTALL_SRU'}, $valid_values, $install_log_values);
1221
1222     if ($config{'INSTALL_SRU'} eq 'yes') {
1223         $msg = q(
1224 Since you've chosen to configure SRU, you must
1225 specify the host and port(s) that the SRU
1226 Servers (bibliographic and authority) should run on.
1227 );
1228         $msg = q(
1229 SRU Database host?);
1230         $config{'ZEBRA_SRU_HOST'} = _get_value('ZEBRA_SRU_HOST', $msg, $defaults->{'ZEBRA_SRU_HOST'}, $valid_values, $install_log_values);
1231
1232         $msg = q(
1233 SRU port for bibliographic data?);
1234         $config{'ZEBRA_SRU_BIBLIOS_PORT'} = _get_value('ZEBRA_SRU_BIBLIOS_PORT', $msg, $defaults->{'ZEBRA_SRU_BIBLIOS_PORT'}, $valid_values, $install_log_values);
1235
1236         $msg = q(
1237 SRU port for authority data?);
1238         $config{'ZEBRA_SRU_AUTHORITIES_PORT'} = _get_value('ZEBRA_SRU_AUTHORITIES_PORT', $msg, $defaults->{'ZEBRA_SRU_AUTHORITIES_PORT'}, $valid_values, $install_log_values);
1239
1240     }
1241
1242   $msg = q(
1243 Use memcached to cache the results of some function calls?
1244 This provides a significant performance improvement.
1245 You will need a Memcached server running.);
1246   $msg .= _add_valid_values_disp('USE_MEMCACHED', $valid_values);
1247   $config{'USE_MEMCACHED'} = _get_value('USE_MEMCACHED', $msg, $defaults->{'USE_MEMCACHED'}, $valid_values, $install_log_values);
1248   if ($config{'USE_MEMCACHED'} eq 'yes'){
1249       $msg = q(
1250 Since you've chosen to use caching, you must specify the memcached servers and the namespace to use:
1251 );
1252       $msg = q(
1253 Memcached server address?);
1254       $config{'MEMCACHED_SERVERS'} = _get_value('MEMCACHED_SERVERS', $msg, $defaults->{'MEMCACHED_SERVERS'}, $valid_values, $install_log_values);
1255
1256       $msg = q(
1257 Memcached namespace?);
1258       $config{'MEMCACHED_NAMESPACE'} = _get_value('MEMCACHED_NAMESPACE', $msg, $defaults->{'MEMCACHED_NAMESPACE'}, $valid_values, $install_log_values);
1259   }
1260
1261
1262   $msg = q(
1263 Use Elasticsearch to serve search results?
1264 You will need a Elasticsearch server running.);
1265   $msg .= _add_valid_values_disp('USE_ELASTICSEARCH', $valid_values);
1266   $config{'USE_ELASTICSEARCH'} = _get_value('USE_ELASTICSEARCH', $msg, $defaults->{'USE_ELASTICSEARCH'}, $valid_values, $install_log_values);
1267   if ($config{'USE_ELASTICSEARCH'} eq 'yes'){
1268       $msg = q(
1269 Define the ELASTICSEARCH_SERVERS with a comma-separated list. Eg
1270 localhost:9200, 192.168.0.100:9200
1271 );
1272       $msg = q(
1273 Elasticsearch server addresses?);
1274       $config{'ELASTICSEARCH_SERVERS'} = _get_value('ELASTICSEARCH_SERVERS', $msg, $defaults->{'ELASTICSEARCH_SERVERS'}, $valid_values, $install_log_values);
1275
1276       $msg = q(
1277 What index name to use for this Koha-instance? It must be unique for each Koha
1278 sharing the same Elasticsearch-cluster
1279
1280 Elasticsearch index?);
1281       $config{'ELASTICSEARCH_INDEX'} = _get_value('ELASTICSEARCH_INDEX', $msg, $defaults->{'ELASTICSEARCH_INDEX'}, $valid_values, $install_log_values);
1282   }
1283
1284   $msg = q(
1285 Template cache directory?);
1286   $config{'TEMPLATE_CACHE_DIR'} = _get_value('TEMPLATE_CACHE_DIR', $msg, $defaults->{'TEMPLATE_CACHE_DIR'}, $valid_values, $install_log_values);
1287
1288   $msg = q(
1289 Path to DejaVu fonts?);
1290   $config{'FONT_DIR'} = _get_value('FONT_DIR', $msg, $defaults->{'FONT_DIR'}, $valid_values, $install_log_values);
1291
1292   $msg = q(
1293 SMTP settings
1294 You will be able to set your default SMTP configuration.);
1295   $msg .= q{
1296 SMTP host name?};
1297   $config{'SMTP_HOST'} = _get_value('SMTP_HOST', $msg, $defaults->{'SMTP_HOST'}, $valid_values, $install_log_values);
1298
1299   $msg = q{
1300 SMTP port?};
1301   $config{'SMTP_PORT'} = _get_value('SMTP_PORT', $msg, $defaults->{'SMTP_PORT'}, $valid_values, $install_log_values);
1302
1303   $msg = q{
1304 SMTP timeout (in seconds)?};
1305   $config{'SMTP_TIMEOUT'} = _get_value('SMTP_TIMEOUT', $msg, $defaults->{'SMTP_TIMEOUT'}, $valid_values, $install_log_values);
1306
1307   $msg = q{
1308 SMTP SSL mode?};
1309   $msg .= _add_valid_values_disp('SMTP_SSL_MODE', $valid_values);
1310   $config{'SMTP_SSL_MODE'} = _get_value('SMTP_SSL_MODE', $msg, $defaults->{'SMTP_SSL_MODE'}, $valid_values, $install_log_values);
1311
1312   $msg = q{
1313 SMTP user name?};
1314   $config{'SMTP_USER_NAME'} = _get_value('SMTP_USER_NAME', $msg, $defaults->{'SMTP_USER_NAME'}, $valid_values, $install_log_values);
1315
1316   $msg = q{
1317 SMTP password?};
1318   $config{'SMTP_PASSWORD'} = _get_value('SMTP_PASSWORD', $msg, $defaults->{'SMTP_PASSWORD'}, $valid_values, $install_log_values);
1319
1320   $msg = q{
1321 SMTP debug mode?};
1322   $msg .= _add_valid_values_disp('SMTP_DEBUG', $valid_values);
1323   $config{'SMTP_DEBUG'} = _get_value('SMTP_DEBUG', $msg, $defaults->{'SMTP_DEBUG'}, $valid_values, $install_log_values);
1324
1325   $config{'SMTP_DEBUG'} = ( $config{'SMTP_DEBUG'} eq 'yes' ) ? 1 : 0;
1326
1327   $msg = q(
1328 Would you like to run the database-dependent test suite?);
1329   $msg .= _add_valid_values_disp( 'RUN_DATABASE_TESTS', $valid_values );
1330     $config{'RUN_DATABASE_TESTS'} = _get_value( 'RUN_DATABASE_TESTS', $msg, $defaults->{'RUN_DATABASE_TESTS'}, $valid_values, $install_log_values );
1331
1332   if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1333       $config{'TEST_DB_TYPE'} = $config{'DB_TYPE'};
1334       $config{'TEST_DB_HOST'} = $config{'DB_HOST'};
1335       $msg = q(TEST DATABASE
1336
1337 THE DATA IN THIS DATABASE WILL BE DESTROYED during the process of
1338 testing. Please don't do this on your production database. It is not
1339 reversible.
1340
1341 YOU WILL SUFFER DATA LOSS if you run this test suite on your test
1342 database. You are better off not running this optional test suite than
1343 doing it in a database that you don't want to lose.
1344
1345 Please specify the name of the test database to be
1346 used by Koha);
1347
1348       $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1349       while ( $config{'TEST_DB_NAME'} eq $config{'DB_NAME'} ) {
1350           $msg = q(Please do not use the same database for testing as you do for production. You run the severe risk of data loss.);
1351           $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1352       }
1353
1354       $msg = q(
1355 Please specify the user that owns the database to be
1356 used by Koha);
1357     $config{'TEST_DB_USER'} = _get_value('TEST_DB_USER', $msg, $defaults->{'TEST_DB_USER'}, $valid_values, $install_log_values);
1358
1359       $msg = q(
1360 Please specify the password of the user that owns the
1361 database to be used by Koha);
1362       $config{'TEST_DB_PASS'} = _get_value('TEST_DB_PASS', $msg, $defaults->{'TEST_DB_PASS'}, $valid_values, $install_log_values);
1363   }
1364
1365     print "\n\n";
1366
1367     # add version number
1368     my $version = "no_version_found";
1369     eval {
1370         require 'kohaversion.pl';
1371         $version = kohaversion();
1372     };
1373     $config{'KOHA_INSTALLED_VERSION'} = $version;
1374
1375     return %config;
1376 }
1377
1378 sub _add_valid_values_disp {
1379     my $key = shift;
1380     my $valid_values = shift;
1381
1382     my $disp = "";
1383     if (exists $valid_values->{$key}) {
1384         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
1385     }
1386     return $disp;
1387 }
1388
1389 sub _get_value {
1390     my $key = shift;
1391     my $msg = shift;
1392     my $default = shift;
1393     my $valid_values = shift;
1394     my $install_log_values = shift;
1395
1396     # take value from install log if present
1397     if (exists $install_log_values{$key}) {
1398         $install_log_values{$key} =~ s/\$/\$\$/g;
1399         return $install_log_values{$key};
1400     }
1401
1402     # override default value from environment
1403     if (exists $ENV{$key}) {
1404         $default = $ENV{$key};
1405         $msg .= " (default from environment)";
1406     }
1407
1408     my $val = prompt($msg, $default);
1409
1410     while (exists $valid_values->{$key} and
1411            $val ne $default and
1412            not exists $valid_values->{$key}->{$val}) {
1413         my $retry_msg = "Value '$val' is not a valid option.\n";
1414         $retry_msg .= "Please enter a value";
1415         $retry_msg .= _add_valid_values_disp($key, $valid_values);
1416         $val = prompt($retry_msg, $default);
1417     }
1418     $val =~ s/\$/\$\$/g;
1419     return $val;
1420 }
1421
1422 =head2 get_target_directories
1423
1424 Creates a hash mapping from symbols for installation target
1425 directories to actual directory paths.
1426
1427 Also returns a hash indicating targets for which
1428 files need not be copied -- this is used for the 'dev'
1429 mode installation, where some files are installed in place.
1430
1431 =cut
1432
1433 sub get_target_directories {
1434     my $config = shift;
1435
1436     my $base = $config->{'INSTALL_BASE'};
1437     my $mode = $config->{'INSTALL_MODE'};
1438
1439     # get last component of install base directory
1440     # to treat as package name
1441     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
1442
1443     my @basedir = File::Spec->splitdir($directories);
1444
1445     if ( $^O eq 'cygwin' ) { shift @basedir; unshift @basedir, 'c:'; }   # in a cygwin environment, $volume is returned empty
1446
1447     my $package = pop @basedir;
1448
1449
1450     my %dirmap = ();
1451     my %skipdirs = ();
1452     if ($mode eq 'single') {
1453         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1454         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1455         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1456         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1457         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1458         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1459         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1460         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1461         $dirmap{'PERL_MODULE_LIB_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1462         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1463         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1464         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'z3950');
1465         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1466         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1467         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1468         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1469         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1470         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1471         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lock');
1472         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1473         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1474         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'koha', 'plugins');
1475         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1476         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1477     } elsif ($mode eq 'dev') {
1478         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
1479         $dirmap{'API_CGI_DIR'} = File::Spec->catdir($curdir, 'api');
1480         $skipdirs{'API_CGI_DIR'} = 1;
1481         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
1482         $skipdirs{'INTRANET_CGI_DIR'} = 1;
1483         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
1484         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
1485         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1486         $skipdirs{'INTRANET_WWW_DIR'} = 1;
1487         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir);
1488         $skipdirs{'OPAC_CGI_DIR'} = 1;
1489         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
1490         $skipdirs{'OPAC_TMPL_DIR'} = 1;
1491         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1492         $skipdirs{'OPAC_WWW_DIR'} = 1;
1493         #NOTE: We're hacking the dirmap here, so that PERL_MODULE_DIR tokens get rewritten correctly for git installs
1494         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
1495         $skipdirs{'PERL_MODULE_DIR'} = 1;
1496         $dirmap{'PERL_MODULE_LIB_DIR'} = File::Spec->catdir($curdir,'lib');
1497         $skipdirs{'PERL_MODULE_LIB_DIR'} = 1;
1498         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1499         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1500         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'z3950');
1501         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1502         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1503         #For dev install, point NONDEV_DIR to misc in current dir (not base)
1504         #Used by supportdir in koha-conf.xml (BZ 12031)
1505         $dirmap{'SCRIPT_NONDEV_DIR'} = File::Spec->catdir($curdir, 'misc');
1506         $skipdirs{'SCRIPT_NONDEV_DIR'} = 1;
1507         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1508         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1509         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1510         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lock');
1511         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1512         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1513         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'plugins');
1514         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1515         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1516     } else {
1517         # mode is standard, i.e., 'fhs'
1518         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1519         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1520         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1521         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1522         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1523         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1524         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1525         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1526         $dirmap{'PERL_MODULE_LIB_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1527         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
1528         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
1529         $dirmap{'Z3950_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'z3950');
1530         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1531         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1532         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1533         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1534         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1535         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
1536         $dirmap{'LOCK_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package);
1537         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
1538         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'spool', $package);
1539         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'plugins');
1540         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
1541         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
1542     }
1543
1544     _get_env_overrides(\%dirmap);
1545     _get_argv_overrides(\%dirmap);
1546     _add_destdir(\%dirmap);
1547
1548     return \%dirmap, \%skipdirs;
1549 }
1550
1551 =head2 get_test_dir
1552
1553 Map a directory target to the corresponding path for
1554 the test suite.
1555
1556 =cut
1557
1558 sub get_test_dir {
1559     my ($dirname) = @_;
1560
1561     my @basedir = (File::Spec->rel2abs(File::Spec->curdir()), 't', 'run');
1562     if (exists $test_suite_override_dirs{$dirname}) {
1563         return File::Spec->catdir(@basedir, @{ $test_suite_override_dirs{$dirname} });
1564     } else {
1565         return;
1566     }
1567
1568 }
1569
1570 sub _get_env_overrides {
1571     my $dirmap = shift;
1572
1573     foreach my $key (keys %$dirmap) {
1574         if (exists $ENV{$key}) {
1575             $dirmap->{$key} = $ENV{$key};
1576             print "Setting $key from environment\n";
1577         }
1578     }
1579 }
1580
1581 sub _get_argv_overrides {
1582     my $dirmap = shift;
1583
1584     my @new_argv = ();
1585     for (my $i = 0; $i <= $#ARGV; $i++) {
1586         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
1587             $dirmap->{$1} = $2;
1588         } else {
1589             push @new_argv, $ARGV[$i];
1590         }
1591     }
1592     @ARGV = @new_argv;
1593 }
1594
1595 sub _strip_destdir {
1596     my $dir = shift;
1597     $dir =~ s/^\$\(DESTDIR\)//;
1598     return $dir;
1599 }
1600
1601 sub _add_destdir {
1602     my $dirmap = shift;
1603
1604     foreach my $key (keys %$dirmap) {
1605         $dirmap->{$key} = '$(DESTDIR)'.$dirmap->{$key};
1606     }
1607 }
1608
1609 sub display_configuration {
1610     my $config = shift;
1611     my $dirmap = shift;
1612     my @version = grep /\/usr\/share\/perl\//, @INC;
1613     push @version, ('/usr/share/perl/5.10') if !$version[0];
1614     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1615     foreach my $key (sort keys %$config) {
1616         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1617     }
1618
1619     print "\nand in the following directories:\n\n";
1620     foreach my $key (sort keys %$dirmap) {
1621         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1622     }
1623     print "\n\nTo change any configuration setting, please run\n";
1624     print "perl Makefile.PL again.  To override one of the target\n";
1625     print "directories, you can do so on the command line like this:\n";
1626     print "\nperl Makefile.PL PERL_MODULE_DIR=$version[0]\n\n";
1627     print "You can also set different default values for parameters\n";
1628     print "or override directory locations by using environment variables.\n";
1629     print "\nFor example:\n\n";
1630     print "export DB_USER=my_koha\n";
1631     print "perl Makefile.PL\n";
1632     print "\nor\n\n";
1633     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1634 }
1635
1636 =head2 find_zebra
1637
1638 Attempt to find Zebra - check user's PATH and
1639 a few other directories for zebrasrv and zebraidx.
1640
1641 =cut
1642
1643 sub find_zebra {
1644     my @search_dirs = map {
1645                             my $abs = File::Spec->rel2abs($_);
1646                             my ($toss, $directories);
1647                             ($toss, $directories, $toss) = File::Spec->splitpath($abs, 1);
1648                             $directories;
1649                         }  split /:/, $ENV{PATH};
1650     push @search_dirs, qw(/usr/local/bin /opt/local/bin /usr/bin);
1651     my @zebrasrv_dirs = grep { -x File::Spec->catpath('', $_, 'zebrasrv') } @search_dirs;
1652     return unless @zebrasrv_dirs;
1653     # verify that directory that contains zebrasrv also contains zebraidx
1654     foreach my $dir (@zebrasrv_dirs) {
1655         return $dir if -x File::Spec->catpath('', $dir, 'zebraidx');
1656     }
1657     return;
1658 }
1659
1660 package MY;
1661
1662 sub test {
1663     my $self = shift;
1664     my $test = $self->SUPER::test(@_);
1665     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1666
1667     # set KOHA_CONF
1668     $test =~ s!\$\(FULLPERLRUN\)!KOHA_CONF=blib/KOHA_CONF_DIR/koha-conf.xml \$(FULLPERLRUN)!g;
1669     return $test;
1670 }
1671
1672 sub install {
1673     my $self = shift;
1674     my $install = "";
1675     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1676     # This means that we're completely overriding EU::MM's default
1677     # installation and uninstallation targets.
1678
1679     my $perl5lib_dirs = _build_perl5lib_string({ target_dirs => $target_directories });
1680
1681 # If installation is on Win32, we need to do permissions different from *nix
1682     if ( $^O =~ /darwin|linux|cygwin|freebsd|solaris/ ) { # this value needs to be verified for each platform and modified accordingly
1683             foreach my $key (sort keys %$target_directories) {
1684                     $install .= qq(
1685 KOHA_INST_$key = blib/$key
1686 KOHA_DEST_$key = $target_directories->{$key}
1687 ) unless exists $skip_directories->{$key};
1688                 }
1689                 $install .= qq(
1690 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1691 \t\$(NOECHO) \$(NOOP)
1692 );
1693                         $install .= "install_koha ::\n";
1694                         $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1695                         foreach my $key (sort keys %$target_directories) {
1696                                 $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1697           unless exists $skip_directories->{$key};
1698                         }
1699                         $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1700                         $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1701
1702                         $install .= "\n";
1703                         $install .= "set_koha_ownership ::\n";
1704 # Do not try to change ownership if DESTDIR is set
1705                         if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1706                                 foreach my $key (sort keys %$target_directories) {
1707             $install .= "\t\$(NOECHO) if test -z \"\$(DESTDIR)\"; then chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key); fi\n"
1708             unless exists $skip_directories->{$key};
1709                                 }
1710                         } else {
1711                                 $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1712                         }
1713
1714                         $install .= "\n";
1715                         $install .= "set_koha_permissions ::\n";
1716                         # This is necessary because EU::MM installs files
1717                         # as either 0444 or 0555, and we want the owner
1718                         # of Koha's files to have write permission by default.
1719                         foreach my $key (sort keys %$target_directories) {
1720                                 $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1721           unless exists $skip_directories->{$key};
1722                         }
1723         }
1724
1725         $install .= "\n";
1726
1727     $install .= "warn_koha_env_vars ::\n";
1728     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1729     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1730     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1731     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1732     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1733     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1734     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1735     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$perl5lib_dirs\n";
1736     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1737     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1738     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1739
1740     $install .= _update_zebra_conf_target();
1741
1742     $install .= upgrade();
1743
1744     return $install;
1745 }
1746
1747 =head2 _update_zebra_conf_target
1748
1749 Add an installation target for updating
1750 Zebra's configuration files.
1751
1752 =cut
1753
1754 sub _update_zebra_conf_target {
1755
1756     my $target = "\nupdate_zebra_conf ::\n";
1757     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1758     $target .= "\t\t\$(KOHA_INST_ZEBRA_CONF_DIR) \$(KOHA_DEST_ZEBRA_CONF_DIR) \n";
1759     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_ZEBRA_CONF_DIR)\n";
1760     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1761
1762     return $target;
1763 }
1764
1765 sub upgrade {
1766     my $upgrade = "";
1767
1768     my $backup_suffix;
1769     if (exists $install_log_values{'KOHA_INSTALLED_VERSION'}) {
1770         my $version = $install_log_values{'KOHA_INSTALLED_VERSION'};
1771         $version =~ s/\./_/g;
1772         $backup_suffix = "_koha_$version";
1773     } else {
1774         $backup_suffix = "_upgrade_backup";
1775     }
1776
1777     $upgrade .= qq/
1778 MOD_BACKUP = \$(ABSPERLRUN) -MC4::Installer::UpgradeBackup -e 'backup_changed_files({\@ARGV}, '$backup_suffix', '\''\$(VERBINST)'\'', '\''\$(UNINST)'\'');' --
1779
1780 upgrade :: make_upgrade_backup install
1781 \t\$(NOECHO) \$(NOOP)
1782 make_upgrade_backup ::
1783 \t\$(NOECHO) umask 022; \$(MOD_BACKUP) \\
1784 /;
1785     foreach my $key (qw/KOHA_CONF_DIR INTRANET_TMPL_DIR INTRANET_WWW_DIR OPAC_TMPL_DIR OPAC_WWW_DIR
1786                      ZEBRA_CONF_DIR PLUGINS_DIR/) {
1787         $upgrade .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1788             unless exists $skip_directories->{$key} or
1789                    not exists $target_directories->{$key};
1790     }
1791     $upgrade =~ s/\\\n$/\n/;
1792
1793     return $upgrade;
1794 }
1795 sub postamble {
1796     # put directory mappings into Makefile
1797     # so that Make will export as environment
1798     # variables -- this is for the use of
1799     # rewrite-confg.PL
1800
1801     my $env;
1802
1803     #NOTE: Build __PERL5LIB_DIRS__ for rewrite-config.PL
1804     my $perl5lib_dirs = _build_perl5lib_string({ target_dirs => $target_directories });
1805     if ($perl5lib_dirs){
1806         $env .= "export __PERL5LIB_DIRS__ := $perl5lib_dirs\n"
1807     }
1808
1809         # Hereagain, we must alter syntax per platform...
1810         {
1811                 $env .= join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1812                 $env .= "\n\n";
1813                 $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1814         }
1815
1816     return "$env\n";
1817 }
1818
1819 sub top_targets {
1820     my $inherited = shift->SUPER::top_targets(@_);
1821     my $compile_step;
1822     $compile_step .= "all :: compile_css_js\n";
1823     $compile_step .= "\t" . '$(NOECHO) $(NOOP)' . "\n";
1824     $compile_step .= "\n";
1825     $compile_step .= "compile_css_js:\n";
1826     $compile_step .= "\t" . '$(PERLRUN) build-resources.PL' . "\n";
1827     my $top_targets = $compile_step . "\n" . $inherited;
1828     return $top_targets;
1829 }
1830
1831 sub _build_perl5lib_string {
1832     my ($args) = @_;
1833     my %unique_map = ();
1834     my $perl5lib_str;
1835     my $target_dirs = $args->{target_dirs};
1836     my @dir_codes = ("PERL_MODULE_DIR","PERL_MODULE_LIB_DIR");
1837     if ($target_dirs){
1838         foreach my $code (@dir_codes){
1839             my $path = $target_dirs->{ $code };
1840             if ($path){
1841                 $unique_map{$path} = 1 unless $unique_map{$path};
1842             }
1843         }
1844         my @paths = sort keys %unique_map;
1845         if (@paths){
1846             $perl5lib_str = join(':',@paths);
1847         }
1848     }
1849     return $perl5lib_str;
1850 }
1851
1852 __END__
1853
1854
1855 =head1 SEE ALSO
1856
1857 ExtUtils::MakeMaker(3)
1858
1859 =head1 AUTHORS
1860
1861 MJ Ray mjr at phonecoop.coop
1862 Galen Charlton galen.charlton at liblime.com
1863
1864 =cut
1865
1866 FIXME: deal with .htaccess