about.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Pat Eyler 2003
   4 # Copyright Biblibre 2006
   5 # Parts Copyright Liblime 2008
   6 # Parts Copyright Chris Nighswonger 2010
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24
  25 use CGI qw ( -utf8 );
  26 use DateTime::TimeZone;
  27 use File::Slurp qw( read_file );
  28 use List::MoreUtils qw( any );
  29 use Module::Load::Conditional qw( can_load );
  30 use Config qw( %Config );
  31 use Search::Elasticsearch;
  32 use Try::Tiny qw( catch try );
  33 use YAML::XS;
  34 use Encode;
  35
  36 use C4::Output qw( output_html_with_http_headers );
  37 use C4::Auth qw( get_template_and_user get_user_subpermissions );
  38 use C4::Context;
  39 use C4::Installer;
  40 use C4::Installer::PerlModules;
  41
  42 use Koha;
  43 use Koha::DateUtils qw( dt_from_string output_pref );
  44 use Koha::Acquisition::Currencies;
  45 use Koha::Authorities;
  46 use Koha::BackgroundJob;
  47 use Koha::BiblioFrameworks;
  48 use Koha::Biblios;
  49 use Koha::Email;
  50 use Koha::Patron::Categories;
  51 use Koha::Patrons;
  52 use Koha::Caches;
  53 use Koha::Config::SysPrefs;
  54 use Koha::Illrequest::Config;
  55 use Koha::SearchEngine::Elasticsearch;
  56 use Koha::Logger;
  57 use Koha::Filter::MARC::ViewPolicy;
  58
  59 use C4::Members::Statistics;
  60
  61 my $query = CGI->new;
  62 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  63     {
  64         template_name   => "about.tt",
  65         query           => $query,
  66         type            => "intranet",
  67         flagsrequired   => { catalogue => 1 },
  68     }
  69 );
  70
  71 my $config_timezone = C4::Context->config('timezone') // '';
  72 my $config_invalid  = !DateTime::TimeZone->is_valid_name( $config_timezone );
  73 my $env_timezone    = $ENV{TZ} // '';
  74 my $env_invalid     = !DateTime::TimeZone->is_valid_name( $env_timezone );
  75 my $actual_bad_tz_fallback = 0;
  76
  77 if ( $config_timezone ne '' &&
  78      $config_invalid ) {
  79     # Bad config
  80     $actual_bad_tz_fallback = 1;
  81 }
  82 elsif ( $config_timezone eq '' &&
  83         $env_timezone    ne '' &&
  84         $env_invalid ) {
  85     # No config, but bad ENV{TZ}
  86     $actual_bad_tz_fallback = 1;
  87 }
  88
  89 my $time_zone = {
  90     actual                 => C4::Context->tz->name,
  91     actual_bad_tz_fallback => $actual_bad_tz_fallback,
  92     config                 => $config_timezone,
  93     config_invalid         => $config_invalid,
  94     environment            => $env_timezone,
  95     environment_invalid    => $env_invalid
  96 };
  97
  98 { # Logger checks
  99     my $log4perl_config = C4::Context->config("log4perl_conf");
 100     my @log4perl_errors;
 101     if ( ! $log4perl_config ) {
 102         push @log4perl_errors, 'missing_config_entry'
 103     }
 104     else {
 105         my @lines = read_file($log4perl_config) or push @log4perl_errors, 'cannot_read_config_file';
 106         for my $line ( @lines ) {
 107             next unless $line =~ m|log4perl.appender.\w+.filename=(.*)|;
 108             push @log4perl_errors, 'logfile_not_writable' unless -w $1;
 109         }
 110     }
 111     eval {Koha::Logger->get};
 112     push @log4perl_errors, 'cannot_init_module' and warn $@ if $@;
 113     $template->param( log4perl_errors => @log4perl_errors );
 114 }
 115
 116 $template->param(
 117     time_zone              => $time_zone,
 118     current_date_and_time  => output_pref({ dt => dt_from_string(), dateformat => 'iso' })
 119 );
 120
 121 my $perl_path = $^X;
 122 if ($^O ne 'VMS') {
 123     $perl_path .= $Config{_exe} unless $perl_path =~ m/$Config{_exe}$/i;
 124 }
 125
 126 my $zebraVersion = `zebraidx -V`;
 127
 128 # Check running PSGI env
 129 if ( C4::Context->psgi_env ) {
 130     $template->param(
 131         is_psgi => 1,
 132         psgi_server => ($ENV{ PLACK_ENV }) ? "Plack ($ENV{PLACK_ENV})" :
 133                        ($ENV{ MOD_PERL })  ? "mod_perl ($ENV{MOD_PERL})" :
 134                                              'Unknown'
 135     );
 136 }
 137
 138 # Memcached configuration
 139 my $memcached_servers   = $ENV{MEMCACHED_SERVERS} || C4::Context->config('memcached_servers');
 140 my $memcached_namespace = $ENV{MEMCACHED_NAMESPACE} || C4::Context->config('memcached_namespace') // 'koha';
 141
 142 my $cache = Koha::Caches->get_instance;
 143 my $effective_caching_method = ref($cache->cache);
 144 # Memcached may have been running when plack has been initialized but could have been stopped since
 145 # FIXME What are the consequences of that??
 146 my $is_memcached_still_active = $cache->set_in_cache('test_for_about_page', "just a simple value");
 147
 148 my $where_is_memcached_config = 'nowhere';
 149 if ( $ENV{MEMCACHED_SERVERS} and C4::Context->config('memcached_servers') ) {
 150     $where_is_memcached_config = 'both';
 151 } elsif ( $ENV{MEMCACHED_SERVERS} and not C4::Context->config('memcached_servers') ) {
 152     $where_is_memcached_config = 'ENV_only';
 153 } elsif ( C4::Context->config('memcached_servers') ) {
 154     $where_is_memcached_config = 'config_only';
 155 }
 156
 157 $template->param(
 158     effective_caching_method => $effective_caching_method,
 159     memcached_servers   => $memcached_servers,
 160     memcached_namespace => $memcached_namespace,
 161     is_memcached_still_active => $is_memcached_still_active,
 162     where_is_memcached_config => $where_is_memcached_config,
 163     memcached_running   => Koha::Caches->get_instance->memcached_cache,
 164 );
 165
 166 # Additional system information for warnings
 167
 168 my $warnStatisticsFieldsError;
 169 my $prefStatisticsFields = C4::Context->preference('StatisticsFields');
 170 if ($prefStatisticsFields) {
 171     $warnStatisticsFieldsError = $prefStatisticsFields
 172         unless ( $prefStatisticsFields eq C4::Members::Statistics->get_fields() );
 173 }
 174
 175 my $prefAutoCreateAuthorities = C4::Context->preference('AutoCreateAuthorities');
 176 my $prefRequireChoosingExistingAuthority = C4::Context->preference('RequireChoosingExistingAuthority');
 177 my $warnPrefRequireChoosingExistingAuthority = ( !$prefAutoCreateAuthorities && ( !$prefRequireChoosingExistingAuthority) );
 178
 179 my $prefEasyAnalyticalRecords  = C4::Context->preference('EasyAnalyticalRecords');
 180 my $prefUseControlNumber  = C4::Context->preference('UseControlNumber');
 181 my $warnPrefEasyAnalyticalRecords  = ( $prefEasyAnalyticalRecords  && $prefUseControlNumber );
 182
 183 my $AnonymousPatron = C4::Context->preference('AnonymousPatron');
 184 my $warnPrefAnonymousPatronOPACPrivacy = (
 185     C4::Context->preference('OPACPrivacy')
 186         and not $AnonymousPatron
 187 );
 188 my $warnPrefAnonymousPatronAnonSuggestions = (
 189     C4::Context->preference('AnonSuggestions')
 190         and not $AnonymousPatron
 191 );
 192
 193 my $anonymous_patron = Koha::Patrons->find( $AnonymousPatron );
 194 my $warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist = ( $AnonymousPatron && C4::Context->preference('AnonSuggestions') && not $anonymous_patron );
 195
 196 my $warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist = ( not $anonymous_patron and Koha::Patrons->search({ privacy => 2 })->count );
 197
 198 my $warnPrefKohaAdminEmailAddress = !Koha::Email->is_valid(C4::Context->preference('KohaAdminEmailAddress'));
 199
 200 my $c = Koha::Items->filter_by_visible_in_opac->count;
 201 my @warnings = C4::Context->dbh->selectrow_array('SHOW WARNINGS');
 202 my $warnPrefOpacHiddenItems = $warnings[2];
 203
 204 my $invalid_yesno = Koha::Config::SysPrefs->search(
 205     {
 206         type  => 'YesNo',
 207         value => { -or => { 'is' => undef, -not_in => [ "1", "0" ] } }
 208     }
 209 );
 210 $template->param( invalid_yesno => $invalid_yesno );
 211
 212 my $errZebraConnection = C4::Context->Zconn("biblioserver",0)->errcode();
 213
 214 my $warnIsRootUser   = (! $loggedinuser);
 215
 216 my $warnNoActiveCurrency = (! defined Koha::Acquisition::Currencies->get_active);
 217
 218 my @xml_config_warnings;
 219
 220 if (    C4::Context->config('zebra_bib_index_mode')
 221     and C4::Context->config('zebra_bib_index_mode') eq 'grs1' )
 222 {
 223     push @xml_config_warnings, { error => 'zebra_bib_index_mode_is_grs1' };
 224 }
 225
 226 if (    C4::Context->config('zebra_auth_index_mode')
 227     and C4::Context->config('zebra_auth_index_mode') eq 'grs1' )
 228 {
 229     push @xml_config_warnings, { error => 'zebra_auth_index_mode_is_grs1' };
 230 }
 231
 232 my $authorityserver = C4::Context->zebraconfig('authorityserver');
 233 if( (   C4::Context->config('zebra_auth_index_mode')
 234     and C4::Context->config('zebra_auth_index_mode') eq 'dom' )
 235     && ( $authorityserver->{config} !~ /zebra-authorities-dom.cfg/ ) )
 236 {
 237     push @xml_config_warnings, {
 238         error => 'zebra_auth_index_mode_mismatch_warn'
 239     };
 240 }
 241
 242 if ( ! defined C4::Context->config('log4perl_conf') ) {
 243     push @xml_config_warnings, {
 244         error => 'log4perl_entry_missing'
 245     }
 246 }
 247
 248 if ( ! defined C4::Context->config('lockdir') ) {
 249     push @xml_config_warnings, {
 250         error => 'lockdir_entry_missing'
 251     }
 252 }
 253 else {
 254     unless ( -w C4::Context->config('lockdir') ) {
 255         push @xml_config_warnings, {
 256             error   => 'lockdir_not_writable',
 257             lockdir => C4::Context->config('lockdir')
 258         }
 259     }
 260 }
 261
 262 if ( ! defined C4::Context->config('upload_path') ) {
 263     if ( Koha::Config::SysPrefs->find('OPACBaseURL')->value ) {
 264         # OPACBaseURL seems to be set
 265         push @xml_config_warnings, {
 266             error => 'uploadpath_entry_missing'
 267         }
 268     } else {
 269         push @xml_config_warnings, {
 270             error => 'uploadpath_and_opacbaseurl_entry_missing'
 271         }
 272     }
 273 }
 274
 275 if ( ! C4::Context->config('tmp_path') ) {
 276     my $temporary_directory = C4::Context::temporary_directory;
 277     push @xml_config_warnings, {
 278         error             => 'tmp_path_missing',
 279         effective_tmp_dir => $temporary_directory,
 280     }
 281 }
 282
 283 my $encryption_key = C4::Context->config('encryption_key');
 284 if ( !$encryption_key || $encryption_key eq '__ENCRYPTION_KEY__') {
 285     push @xml_config_warnings, { error => 'encryption_key_missing' };
 286 }
 287
 288 # Test Zebra facets configuration
 289 if ( !defined C4::Context->config('use_zebra_facets') ) {
 290     push @xml_config_warnings, { error => 'use_zebra_facets_entry_missing' };
 291 }
 292
 293 # ILL module checks
 294 if ( C4::Context->preference('ILLModule') ) {
 295     my $warnILLConfiguration = 0;
 296     my $ill_config_from_file = C4::Context->config("interlibrary_loans");
 297     my $ill_config = Koha::Illrequest::Config->new;
 298
 299     my $available_ill_backends =
 300       ( scalar @{ $ill_config->available_backends } > 0 );
 301
 302     # Check backends
 303     if ( !$available_ill_backends ) {
 304         $template->param( no_ill_backends => 1 );
 305         $warnILLConfiguration = 1;
 306     }
 307
 308     # Check partner_code
 309     if ( !Koha::Patron::Categories->find($ill_config->partner_code) ) {
 310         $template->param( ill_partner_code_doesnt_exist => $ill_config->partner_code );
 311         $warnILLConfiguration = 1;
 312     }
 313
 314     if ( !$ill_config_from_file->{partner_code} ) {
 315         # partner code not defined
 316         $template->param( ill_partner_code_not_defined => 1 );
 317         $warnILLConfiguration = 1;
 318     }
 319
 320
 321     if ( !$ill_config_from_file->{branch} ) {
 322         # branch not defined
 323         $template->param( ill_branch_not_defined => 1 );
 324         $warnILLConfiguration = 1;
 325     }
 326
 327     $template->param( warnILLConfiguration => $warnILLConfiguration );
 328 }
 329
 330 {
 331     # XSLT sysprefs
 332     my @xslt_prefs = qw(
 333         OPACXSLTDetailsDisplay
 334         OPACXSLTListsDisplay
 335         OPACXSLTResultsDisplay
 336         XSLTDetailsDisplay
 337         XSLTListsDisplay
 338         XSLTResultsDisplay
 339     );
 340     my @warnXSLT;
 341     for my $p ( @xslt_prefs ) {
 342         my $xsl_filename = C4::XSLT::get_xsl_filename( $p );
 343         next if -e $xsl_filename;
 344         push @warnXSLT,
 345           {
 346             syspref  => $p,
 347             value    => C4::Context->preference("$p"),
 348             filename => $xsl_filename
 349           };
 350     }
 351
 352     $template->param( warnXSLT => \@warnXSLT ) if @warnXSLT;
 353 }
 354
 355 if ( C4::Context->preference('SearchEngine') eq 'Elasticsearch' ) {
 356     # Check ES configuration health and runtime status
 357
 358     my $es_status;
 359     my $es_config_error;
 360     my $es_running = 1;
 361     my $es_has_missing = 0;
 362
 363     my $es_conf;
 364     try {
 365         $es_conf = Koha::SearchEngine::Elasticsearch::_read_configuration();
 366     }
 367     catch {
 368         if ( ref($_) eq 'Koha::Exceptions::Config::MissingEntry' ) {
 369             $template->param( elasticsearch_fatal_config_error => $_->message );
 370             $es_config_error = 1;
 371         }
 372     };
 373     if ( !$es_config_error ) {
 374
 375         my $biblios_index_name     = $es_conf->{index_name} . "_" . $Koha::SearchEngine::BIBLIOS_INDEX;
 376         my $authorities_index_name = $es_conf->{index_name} . "_" . $Koha::SearchEngine::AUTHORITIES_INDEX;
 377
 378         my @indexes = ($biblios_index_name, $authorities_index_name);
 379         # TODO: When new indexes get added, we could have other ways to
 380         #       fetch the list of available indexes (e.g. plugins, etc)
 381         $es_status->{nodes} = $es_conf->{nodes};
 382         my $es = Search::Elasticsearch->new({ nodes => $es_conf->{nodes} });
 383         my $es_status->{version} = $es->info->{version}->{number};
 384
 385         foreach my $index ( @indexes ) {
 386             my $index_count;
 387             try {
 388                 $index_count = $es->indices->stats( index => $index )
 389                       ->{_all}{primaries}{docs}{count};
 390             }
 391             catch {
 392                 if ( ref($_) eq 'Search::Elasticsearch::Error::Missing' ) {
 393                     push @{ $es_status->{errors} }, "Index not found ($index)";
 394                     $index_count = -1;
 395                 }
 396                 elsif ( ref($_) eq 'Search::Elasticsearch::Error::NoNodes' ) {
 397                     $es_running = 0;
 398                 }
 399                 else {
 400                     # TODO: when time comes, we will cover more use cases
 401                     die $_;
 402                 }
 403             };
 404
 405             my $db_count = -1;
 406             my $missing_count = 0;
 407             if ( $index eq $biblios_index_name ) {
 408                 $db_count = Koha::Biblios->search->count;
 409             } elsif ( $index eq $authorities_index_name ) {
 410                 $db_count = Koha::Authorities->search->count;
 411             }
 412             if ( $db_count != -1 && $index_count != -1 ) {
 413                 $missing_count = $db_count - $index_count;
 414                 $es_has_missing = 1 if $missing_count > 0;
 415             }
 416             push @{ $es_status->{indexes} },
 417               {
 418                 index_name    => $index,
 419                 index_count   => $index_count,
 420                 db_count      => $db_count,
 421                 missing_count => $missing_count,
 422               };
 423         }
 424         $es_status->{running} = $es_running;
 425
 426         $template->param(
 427             elasticsearch_status      => $es_status,
 428             elasticsearch_has_missing => $es_has_missing,
 429         );
 430     }
 431 }
 432
 433 if ( C4::Context->preference('RESTOAuth2ClientCredentials') ) {
 434     # Do we have the required deps?
 435     unless ( can_load( modules => { 'Net::OAuth2::AuthorizationServer' => undef }) ) {
 436         $template->param( oauth2_missing_deps => 1 );
 437     }
 438 }
 439
 440 # Sco Patron should not contain any other perms than circulate => self_checkout
 441 if (  C4::Context->preference('WebBasedSelfCheck')
 442       and C4::Context->preference('AutoSelfCheckAllowed')
 443 ) {
 444     my $userid = C4::Context->preference('AutoSelfCheckID');
 445     my $all_permissions = C4::Auth::get_user_subpermissions( $userid );
 446     my ( $has_self_checkout_perm, $has_other_permissions );
 447     while ( my ( $module, $permissions ) = each %$all_permissions ) {
 448         if ( $module eq 'self_check' ) {
 449             while ( my ( $permission, $flag ) = each %$permissions ) {
 450                 if ( $permission eq 'self_checkout_module' ) {
 451                     $has_self_checkout_perm = 1;
 452                 } else {
 453                     $has_other_permissions = 1;
 454                 }
 455             }
 456         } else {
 457             $has_other_permissions = 1;
 458         }
 459     }
 460     $template->param(
 461         AutoSelfCheckPatronDoesNotHaveSelfCheckPerm => not ( $has_self_checkout_perm ),
 462         AutoSelfCheckPatronHasTooManyPerm => $has_other_permissions,
 463     );
 464 }
 465
 466 # Test YAML system preferences
 467 # FIXME: This is list of current YAML formatted prefs, should by type of preference
 468 my @yaml_prefs = (
 469     "UpdateNotForLoanStatusOnCheckin",
 470     "OpacHiddenItems",
 471     "BibtexExportAdditionalFields",
 472     "RisExportAdditionalFields",
 473     "UpdateItemWhenLostFromHoldList",
 474     "MarcFieldsToOrder",
 475     "MarcItemFieldsToOrder",
 476     "UpdateitemLocationOnCheckin",
 477     "ItemsDeniedRenewal"
 478 );
 479 my @bad_yaml_prefs;
 480 foreach my $syspref (@yaml_prefs) {
 481     my $yaml = C4::Context->preference( $syspref );
 482     if ( $yaml ) {
 483         eval { YAML::XS::Load( Encode::encode_utf8("$yaml\n\n") ); };
 484         if ($@) {
 485             push @bad_yaml_prefs, $syspref;
 486         }
 487     }
 488 }
 489 $template->param( 'bad_yaml_prefs' => \@bad_yaml_prefs ) if @bad_yaml_prefs;
 490
 491 {
 492     my $dbh       = C4::Context->dbh;
 493     my $patrons = $dbh->selectall_arrayref(
 494         q|select b.borrowernumber from borrowers b join deletedborrowers db on b.borrowernumber=db.borrowernumber|,
 495         { Slice => {} }
 496     );
 497     my $biblios = $dbh->selectall_arrayref(
 498         q|select b.biblionumber from biblio b join deletedbiblio db on b.biblionumber=db.biblionumber|,
 499         { Slice => {} }
 500     );
 501     my $biblioitems = $dbh->selectall_arrayref(
 502         q|select bi.biblioitemnumber from biblioitems bi join deletedbiblioitems dbi on bi.biblionumber=dbi.biblionumber|,
 503         { Slice => {} }
 504     );
 505     my $items = $dbh->selectall_arrayref(
 506         q|select i.itemnumber from items i join deleteditems di on i.itemnumber=di.itemnumber|,
 507         { Slice => {} }
 508     );
 509     my $checkouts = $dbh->selectall_arrayref(
 510         q|select i.issue_id from issues i join old_issues oi on i.issue_id=oi.issue_id|,
 511         { Slice => {} }
 512     );
 513     my $holds = $dbh->selectall_arrayref(
 514         q|select r.reserve_id from reserves r join old_reserves o on r.reserve_id=o.reserve_id|,
 515         { Slice => {} }
 516     );
 517     if ( @$patrons or @$biblios or @$biblioitems or @$items or @$checkouts or @$holds ) {
 518         $template->param(
 519             has_ai_issues  => 1,
 520             ai_patrons     => $patrons,
 521             ai_biblios     => $biblios,
 522             ai_biblioitems => $biblioitems,
 523             ai_items       => $items,
 524             ai_checkouts   => $checkouts,
 525             ai_holds       => $holds,
 526         );
 527     }
 528 }
 529
 530 # Circ rule warnings
 531 {
 532     my $dbh   = C4::Context->dbh;
 533     my $units = Koha::CirculationRules->search({ rule_name => 'lengthunit', rule_value => { -not_in => ['days', 'hours'] } });
 534
 535     if ( $units->count ) {
 536         $template->param(
 537             warnIssuingRules => 1,
 538             ir_units         => $units,
 539         );
 540     }
 541 }
 542
 543 # Guarantor relationships warnings
 544 {
 545     my $dbh   = C4::Context->dbh;
 546     my ($bad_relationships_count) = $dbh->selectall_arrayref(q{
 547         SELECT COUNT(*)
 548         FROM (
 549             SELECT relationship FROM borrower_relationships WHERE relationship='_bad_data'
 550             UNION ALL
 551             SELECT relationship FROM borrowers WHERE relationship='_bad_data') a
 552     });
 553
 554     $bad_relationships_count = $bad_relationships_count->[0]->[0];
 555
 556     my $existing_relationships = $dbh->selectall_arrayref(q{
 557           SELECT DISTINCT(relationship)
 558           FROM (
 559               SELECT relationship FROM borrower_relationships WHERE relationship IS NOT NULL
 560               UNION ALL
 561               SELECT relationship FROM borrowers WHERE relationship IS NOT NULL) a
 562     });
 563
 564     my %valid_relationships = map { $_ => 1 } split( /,|\|/, C4::Context->preference('borrowerRelationship') );
 565     $valid_relationships{ _bad_data } = 1; # we handle this case in another way
 566
 567     my $wrong_relationships = [ grep { !$valid_relationships{ $_->[0] } } @{$existing_relationships} ];
 568     if ( @$wrong_relationships or $bad_relationships_count ) {
 569
 570         $template->param(
 571             warnRelationships => 1,
 572         );
 573
 574         if ( $wrong_relationships ) {
 575             $template->param(
 576                 wrong_relationships => $wrong_relationships
 577             );
 578         }
 579         if ($bad_relationships_count) {
 580             $template->param(
 581                 bad_relationships_count => $bad_relationships_count,
 582             );
 583         }
 584     }
 585 }
 586
 587 {
 588     # Test 'bcrypt_settings' config for Pseudonymization
 589     $template->param( config_bcrypt_settings_no_set => 1 )
 590       if C4::Context->preference('Pseudonymization')
 591       and not C4::Context->config('bcrypt_settings');
 592 }
 593
 594 {
 595     my @frameworkcodes = Koha::BiblioFrameworks->search->get_column('frameworkcode');
 596     my @hidden_biblionumbers;
 597     push @frameworkcodes, ""; # it's not in the biblio_frameworks table!
 598     my $no_FA_framework = 1;
 599     for my $frameworkcode ( @frameworkcodes ) {
 600         $no_FA_framework = 0 if $frameworkcode eq 'FA';
 601         my $shouldhidemarc_opac = Koha::Filter::MARC::ViewPolicy->should_hide_marc(
 602             {
 603                 frameworkcode => $frameworkcode,
 604                 interface     => "opac"
 605             }
 606         );
 607         push @hidden_biblionumbers, { frameworkcode => $frameworkcode, interface => 'opac' }
 608           if $shouldhidemarc_opac->{biblionumber};
 609
 610         my $shouldhidemarc_intranet = Koha::Filter::MARC::ViewPolicy->should_hide_marc(
 611             {
 612                 frameworkcode => $frameworkcode,
 613                 interface     => "intranet"
 614             }
 615         );
 616         push @hidden_biblionumbers, { frameworkcode => $frameworkcode, interface => 'intranet' }
 617           if $shouldhidemarc_intranet->{biblionumber};
 618     }
 619     $template->param( warnHiddenBiblionumbers => \@hidden_biblionumbers );
 620     $template->param( warnFastCataloging => $no_FA_framework );
 621 }
 622
 623 {
 624     # BackgroundJob - test connection to message broker
 625     eval {
 626         Koha::BackgroundJob->connect;
 627     };
 628     if ( $@ ) {
 629         warn $@;
 630         $template->param( warnConnectBroker => $@ );
 631     }
 632 }
 633
 634 #BZ 28267: Warn administrators if there are database rows with a format other than 'DYNAMIC'
 635 {
 636     $template->param( warnDbRowFormat => C4::Installer->has_non_dynamic_row_format );
 637 }
 638
 639 my %versions = C4::Context::get_versions();
 640
 641 $template->param(
 642     kohaVersion   => $versions{'kohaVersion'},
 643     osVersion     => $versions{'osVersion'},
 644     perlPath      => $perl_path,
 645     perlVersion   => $versions{'perlVersion'},
 646     perlIncPath   => [ map { perlinc => $_ }, @INC ],
 647     mysqlVersion  => $versions{'mysqlVersion'},
 648     apacheVersion => $versions{'apacheVersion'},
 649     zebraVersion  => $zebraVersion,
 650     prefRequireChoosingExistingAuthority => $prefRequireChoosingExistingAuthority,
 651     prefAutoCreateAuthorities => $prefAutoCreateAuthorities,
 652     warnPrefRequireChoosingExistingAuthority => $warnPrefRequireChoosingExistingAuthority,
 653     warnPrefEasyAnalyticalRecords  => $warnPrefEasyAnalyticalRecords,
 654     warnPrefAnonymousPatronOPACPrivacy        => $warnPrefAnonymousPatronOPACPrivacy,
 655     warnPrefAnonymousPatronAnonSuggestions    => $warnPrefAnonymousPatronAnonSuggestions,
 656     warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist     => $warnPrefAnonymousPatronOPACPrivacy_PatronDoesNotExist,
 657     warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist => $warnPrefAnonymousPatronAnonSuggestions_PatronDoesNotExist,
 658     warnPrefKohaAdminEmailAddress => $warnPrefKohaAdminEmailAddress,
 659     warnPrefOpacHiddenItems => $warnPrefOpacHiddenItems,
 660     errZebraConnection => $errZebraConnection,
 661     warnIsRootUser => $warnIsRootUser,
 662     warnNoActiveCurrency => $warnNoActiveCurrency,
 663     warnNoTemplateCaching => ( C4::Context->config('template_cache_dir') ? 0 : 1 ),
 664     xml_config_warnings => \@xml_config_warnings,
 665     warnStatisticsFieldsError => $warnStatisticsFieldsError,
 666 );
 667
 668 my @components = ();
 669
 670 my $perl_modules = C4::Installer::PerlModules->new;
 671 $perl_modules->versions_info;
 672
 673 my @pm_types = qw(missing_pm upgrade_pm current_pm);
 674
 675 foreach my $pm_type(@pm_types) {
 676     my $modules = $perl_modules->get_attr($pm_type);
 677     foreach (@$modules) {
 678         my ($module, $stats) = each %$_;
 679         push(
 680             @components,
 681             {
 682                 name    => $module,
 683                 version => $stats->{'cur_ver'},
 684                 missing => ($pm_type eq 'missing_pm' ? 1 : 0),
 685                 upgrade => ($pm_type eq 'upgrade_pm' ? 1 : 0),
 686                 current => ($pm_type eq 'current_pm' ? 1 : 0),
 687                 require => $stats->{'required'},
 688                 reqversion => $stats->{'min_ver'},
 689                 maxversion => $stats->{'max_ver'},
 690                 excversion => $stats->{'exc_ver'}
 691             }
 692         );
 693     }
 694 }
 695
 696 @components = sort {$a->{'name'} cmp $b->{'name'}} @components;
 697
 698 my $counter=0;
 699 my $row = [];
 700 my $table = [];
 701 foreach (@components) {
 702     push (@$row, $_);
 703     unless (++$counter % 4) {
 704         push (@$table, {row => $row});
 705         $row = [];
 706     }
 707 }
 708 # Processing the last line (if there are any modules left)
 709 if (scalar(@$row) > 0) {
 710     # Extending $row to the table size
 711     $$row[3] = '';
 712     # Pushing the last line
 713     push (@$table, {row => $row});
 714 }
 715 ## ## $table
 716
 717 $template->param( table => $table );
 718
 719
 720 ## ------------------------------------------
 721 ## Koha contributions
 722 my $docdir;
 723 if ( defined C4::Context->config('docdir') ) {
 724     $docdir = C4::Context->config('docdir');
 725 } else {
 726     # if no <docdir> is defined in koha-conf.xml, use the default location
 727     # this is a work-around to stop breakage on upgraded Kohas, bug 8911
 728     $docdir = C4::Context->config('intranetdir') . '/docs';
 729 }
 730
 731 ## Release teams
 732 my $teams =
 733   -e "$docdir" . "/teams.yaml"
 734   ? YAML::XS::LoadFile( "$docdir" . "/teams.yaml" )
 735   : {};
 736 my $dev_team = (sort {$b <=> $a} (keys %{$teams->{team}}))[0];
 737 my $short_version = substr($versions{'kohaVersion'},0,5);
 738 my $minor = substr($versions{'kohaVersion'},3,2);
 739 my $development_version = ( $minor eq '05' || $minor eq '11' ) ? 0 : 1;
 740 my $codename;
 741 $template->param( short_version => $short_version );
 742 $template->param( development_version => $development_version );
 743
 744 ## Contributors
 745 my $contributors =
 746   -e "$docdir" . "/contributors.yaml"
 747   ? YAML::XS::LoadFile( "$docdir" . "/contributors.yaml" )
 748   : {};
 749 delete $contributors->{_others_};
 750 for my $version ( sort { $a <=> $b } keys %{$teams->{team}} ) {
 751     for my $role ( keys %{ $teams->{team}->{$version} } ) {
 752         my $normalized_role = "$role";
 753         $normalized_role =~ s/s$//;
 754         if ( ref( $teams->{team}->{$version}->{$role} ) eq 'ARRAY' ) {
 755             for my $contributor ( @{ $teams->{team}->{$version}->{$role} } ) {
 756                 my $name = $contributor->{name};
 757                 # Add role to contributors
 758                 push @{ $contributors->{$name}->{roles}->{$normalized_role} },
 759                   $version;
 760                 # Add openhub to teams
 761                 if ( exists( $contributors->{$name}->{openhub} ) ) {
 762                     $contributor->{openhub} = $contributors->{$name}->{openhub};
 763                 }
 764             }
 765         }
 766         elsif ( $role eq 'release_date' ) {
 767             $teams->{team}->{$version}->{$role} = DateTime->from_epoch( epoch => $teams->{team}->{$version}->{$role});
 768         }
 769         elsif ( $role eq 'codename' ) {
 770             if ( $version == $short_version ) {
 771                 $codename = $teams->{team}->{$version}->{$role};
 772             }
 773             next;
 774         }
 775         else {
 776             my $name = $teams->{team}->{$version}->{$role}->{name};
 777             # Add role to contributors
 778             push @{ $contributors->{$name}->{roles}->{$normalized_role} },
 779               $version;
 780             # Add openhub to teams
 781             if ( exists( $contributors->{$name}->{openhub} ) ) {
 782                 $teams->{team}->{$version}->{$role}->{openhub} =
 783                   $contributors->{$name}->{openhub};
 784             }
 785         }
 786     }
 787 }
 788
 789 ## Create last name ordered array of people from contributors
 790 my @people = map {
 791     { name => $_, ( $contributors->{$_} ? %{ $contributors->{$_} } : () ) }
 792 } sort {
 793   my ($alast) = $a =~ /(\S+)$/;
 794   my ($blast) = $b =~ /(\S+)$/;
 795   my $cmp = lc($alast||"") cmp lc($blast||"");
 796   return $cmp if $cmp;
 797
 798   my ($a2last) = $a =~ /(\S+)\s\S+$/;
 799   my ($b2last) = $b =~ /(\S+)\s\S+$/;
 800   lc($a2last||"") cmp lc($b2last||"");
 801 } keys %$contributors;
 802
 803 $template->param( kohaCodename  => $codename);
 804 $template->param( contributors => \@people );
 805 $template->param( maintenance_team => $teams->{team}->{$dev_team} );
 806 $template->param( release_team => $teams->{team}->{$short_version} );
 807
 808 ## Timeline
 809 if ( open( my $file, "<:encoding(UTF-8)", "$docdir" . "/history.txt" ) ) {
 810
 811     my $i = 0;
 812
 813     my @rows2 = ();
 814     my $row2  = [];
 815
 816     my @lines = <$file>;
 817     close($file);
 818
 819     shift @lines; #remove header row
 820
 821     foreach (@lines) {
 822         my ( $epoch, $date, $desc, $tag ) = split(/\t/);
 823         if(!$desc && $date=~ /(?<=\d{4})\s+/) {
 824             ($date, $desc)= ($`, $');
 825         }
 826         push(
 827             @rows2,
 828             {
 829                 date => $date,
 830                 desc => $desc,
 831             }
 832         );
 833     }
 834
 835     my $table2 = [];
 836     #foreach my $row2 (@rows2) {
 837     foreach  (@rows2) {
 838         push (@$row2, $_);
 839         push( @$table2, { row2 => $row2 } );
 840         $row2 = [];
 841     }
 842
 843     $template->param( table2 => $table2 );
 844 } else {
 845     $template->param( timeline_read_error => 1 );
 846 }
 847
 848 output_html_with_http_headers $query, $cookie, $template->output;