acqui/finishreceive.pl

   1 #!/usr/bin/perl
   2
   3 #script to add a new item and to mark orders as received
   4 #written 1/3/00 by chris@katipo.co.nz
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24 use CGI qw ( -utf8 );
  25 use C4::Auth;
  26 use C4::Output;
  27 use C4::Context;
  28 use C4::Acquisition;
  29 use C4::Biblio;
  30 use C4::Items;
  31 use C4::Search;
  32
  33 use Koha::Number::Price;
  34 use Koha::Acquisition::Booksellers;
  35 use Koha::Acquisition::Orders;
  36
  37 use List::MoreUtils qw/any/;
  38
  39 my $input=new CGI;
  40 my $flagsrequired = {acquisition => 'order_receive'};
  41
  42 checkauth($input, 0, $flagsrequired, 'intranet');
  43
  44 my $user             = $input->remote_user;
  45 my $biblionumber     = $input->param('biblionumber');
  46 my $ordernumber      = $input->param('ordernumber');
  47 my $origquantityrec  = $input->param('origquantityrec');
  48 my $quantityrec      = $input->param('quantityrec');
  49 my $quantity         = $input->param('quantity');
  50 my $unitprice        = $input->param('unitprice');
  51 my $datereceived     = $input->param('datereceived'),
  52 my $invoiceid        = $input->param('invoiceid');
  53 my $invoice          = GetInvoice($invoiceid);
  54 my $invoiceno        = $invoice->{invoicenumber};
  55 my $booksellerid     = $input->param('booksellerid');
  56 my $cnt              = 0;
  57 my $bookfund         = $input->param("bookfund");
  58 my $order            = GetOrder($ordernumber);
  59 my $new_ordernumber  = $ordernumber;
  60
  61 #bug18723 regression fix
  62 if (C4::Context->preference("CurrencyFormat") eq 'FR') {
  63     if (rindex($unitprice, '.') ge 0) {
  64         substr($unitprice, rindex($unitprice, '.'), 1, ',');
  65     }
  66 }
  67
  68 $unitprice = Koha::Number::Price->new( $unitprice )->unformat();
  69 my $basket = Koha::Acquisition::Orders->find( $ordernumber )->basket;
  70
  71 #need old receivedate if we update the order, parcel.pl only shows the right parcel this way FIXME
  72 if ($quantityrec > $origquantityrec ) {
  73     my @received_items = ();
  74     if ($basket->effective_create_items eq 'ordering') {
  75         @received_items = $input->param('items_to_receive');
  76         my @affects = split q{\|}, C4::Context->preference("AcqItemSetSubfieldsWhenReceived");
  77         if ( @affects ) {
  78             my $frameworkcode = GetFrameworkCode($biblionumber);
  79             my ( $itemfield ) = GetMarcFromKohaField( 'items.itemnumber', $frameworkcode );
  80             for my $in ( @received_items ) {
  81                 my $item = C4::Items::GetMarcItem( $biblionumber, $in );
  82                 for my $affect ( @affects ) {
  83                     my ( $sf, $v ) = split q{=}, $affect, 2;
  84                     foreach ( $item->field($itemfield) ) {
  85                         $_->update( $sf => $v );
  86                     }
  87                 }
  88                 C4::Items::ModItemFromMarc( $item, $biblionumber, $in );
  89             }
  90         }
  91     }
  92
  93     $order->{order_internalnote} = $input->param("order_internalnote");
  94     $order->{tax_rate_on_receiving} = $input->param("tax_rate");
  95     $order->{unitprice} = $unitprice;
  96
  97     $order = C4::Acquisition::populate_order_with_prices(
  98         {
  99             order => $order,
 100             booksellerid => $booksellerid,
 101             receiving => 1
 102         }
 103     );
 104
 105     # save the quantity received.
 106     if ( $quantityrec > 0 ) {
 107         ( $datereceived, $new_ordernumber ) = ModReceiveOrder(
 108             {
 109                 biblionumber     => $biblionumber,
 110                 order            => $order,
 111                 quantityreceived => $quantityrec,
 112                 user             => $user,
 113                 invoice          => $invoice,
 114                 budget_id        => $bookfund,
 115                 received_items   => \@received_items,
 116             }
 117         );
 118     }
 119
 120     # now, add items if applicable
 121     if ($basket->effective_create_items eq 'receiving') {
 122
 123         my @tags         = $input->multi_param('tag');
 124         my @subfields    = $input->multi_param('subfield');
 125         my @field_values = $input->multi_param('field_value');
 126         my @serials      = $input->multi_param('serial');
 127         my @itemid       = $input->multi_param('itemid');
 128         my @ind_tag      = $input->multi_param('ind_tag');
 129         my @indicator    = $input->multi_param('indicator');
 130         #Rebuilding ALL the data for items into a hash
 131         # parting them on $itemid.
 132         my %itemhash;
 133         my $countdistinct;
 134         my $range=scalar(@itemid);
 135         for (my $i=0; $i<$range; $i++){
 136             unless ($itemhash{$itemid[$i]}){
 137             $countdistinct++;
 138             }
 139             push @{$itemhash{$itemid[$i]}->{'tags'}},$tags[$i];
 140             push @{$itemhash{$itemid[$i]}->{'subfields'}},$subfields[$i];
 141             push @{$itemhash{$itemid[$i]}->{'field_values'}},$field_values[$i];
 142             push @{$itemhash{$itemid[$i]}->{'ind_tag'}},$ind_tag[$i];
 143             push @{$itemhash{$itemid[$i]}->{'indicator'}},$indicator[$i];
 144         }
 145         my $new_order = Koha::Acquisition::Orders->find( $new_ordernumber );
 146         foreach my $item (keys %itemhash){
 147             my $xml = TransformHtmlToXml( $itemhash{$item}->{'tags'},
 148                                           $itemhash{$item}->{'subfields'},
 149                                           $itemhash{$item}->{'field_values'},
 150                                           $itemhash{$item}->{'indicator'},
 151                                           $itemhash{$item}->{'ind_tag'},
 152                                           'ITEM' );
 153             my $record=MARC::Record::new_from_xml($xml, 'UTF-8');
 154             my (undef,$bibitemnum,$itemnumber) = AddItemFromMarc($record,$biblionumber);
 155             $new_order->add_item( $itemnumber );
 156         }
 157     }
 158 }
 159
 160 ModItem(
 161     {
 162         booksellerid         => $booksellerid,
 163         dateaccessioned      => $datereceived,
 164         datelastseen         => $datereceived,
 165         price                => $unitprice,
 166         replacementprice     => $order->{rrp},
 167         replacementpricedate => $datereceived,
 168     },
 169     $biblionumber,
 170     $_
 171 ) foreach GetItemnumbersFromOrder($new_ordernumber);
 172
 173 print $input->redirect("/cgi-bin/koha/acqui/parcel.pl?invoiceid=$invoiceid&sticky_filters=1");