acqui/neworderempty.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4 #written by chris@katipo.co.nz 24/2/2000
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 =head1 NAME
  25
  26 neworderempty.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script allows to create a new record to order it. This record shouldn't exist
  31 on database.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38 the bookseller the librarian has to buy a new book.
  39
  40 =item title
  41 the title of this new record.
  42
  43 =item author
  44 the author of this new record.
  45
  46 =item publication year
  47 the publication year of this new record.
  48
  49 =item ordernumber
  50 the number of this order.
  51
  52 =item biblio
  53
  54 =item basketno
  55 the basket number for this new order.
  56
  57 =item suggestionid
  58 if this order comes from a suggestion.
  59
  60 =item breedingid
  61 the item's id in the breeding reservoir
  62
  63 =item close
  64
  65 =back
  66
  67 =cut
  68
  69 use Modern::Perl;
  70 use CGI qw ( -utf8 );
  71 use C4::Context;
  72
  73 use C4::Auth;
  74 use C4::Budgets;
  75
  76 use C4::Acquisition;
  77 use C4::Contract;
  78 use C4::Suggestions;    # GetSuggestion
  79 use C4::Biblio;                 # GetBiblioData GetMarcPrice
  80 use C4::Items; #PrepareItemRecord
  81 use C4::Output;
  82 use C4::Koha;
  83 use C4::Members;
  84 use C4::Search qw/FindDuplicate/;
  85
  86 #needed for z3950 import:
  87 use C4::ImportBatch qw/GetImportRecordMarc SetImportRecordStatus/;
  88
  89 use Koha::Acquisition::Booksellers;
  90 use Koha::Acquisition::Currencies;
  91 use Koha::BiblioFrameworks;
  92 use Koha::DateUtils qw( dt_from_string );
  93 use Koha::MarcSubfieldStructures;
  94 use Koha::ItemTypes;
  95 use Koha::Patrons;
  96 use Koha::RecordProcessor;
  97 use Koha::Subscriptions;
  98
  99 our $input           = new CGI;
 100 my $booksellerid    = $input->param('booksellerid');    # FIXME: else ERROR!
 101 my $budget_id       = $input->param('budget_id') || 0;
 102 my $title           = $input->param('title');
 103 my $author          = $input->param('author');
 104 my $publicationyear = $input->param('publicationyear');
 105 my $ordernumber          = $input->param('ordernumber') || '';
 106 our $biblionumber    = $input->param('biblionumber');
 107 our $basketno        = $input->param('basketno');
 108 my $suggestionid    = $input->param('suggestionid');
 109 my $close           = $input->param('close');
 110 my $uncertainprice  = $input->param('uncertainprice');
 111 my $import_batch_id = $input->param('import_batch_id'); # if this is filled, we come from a staged file, and we will return here after saving the order !
 112 my $from_subscriptionid  = $input->param('from_subscriptionid');
 113 my $data;
 114 my $new = 'no';
 115
 116 my $budget_name;
 117
 118 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
 119     {
 120         template_name   => "acqui/neworderempty.tt",
 121         query           => $input,
 122         type            => "intranet",
 123         authnotrequired => 0,
 124         flagsrequired   => { acquisition => 'order_manage' },
 125         debug           => 1,
 126     }
 127 );
 128
 129 our $marcflavour = C4::Context->preference('marcflavour');
 130
 131 if(!$basketno) {
 132     my $order = GetOrder($ordernumber);
 133     $basketno = $order->{'basketno'};
 134 }
 135
 136 our $basket = GetBasket($basketno);
 137 my $basketobj = Koha::Acquisition::Baskets->find( $basketno );
 138 $booksellerid = $basket->{booksellerid} unless $booksellerid;
 139 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 140
 141 output_and_exit( $input, $cookie, $template, 'unknown_basket') unless $basketobj;
 142 output_and_exit( $input, $cookie, $template, 'unknown_vendor') unless $bookseller;
 143
 144 my $contract = GetContract({
 145     contractnumber => $basket->{contractnumber}
 146 });
 147
 148 #simple parameters reading (all in one :-)
 149 our $params = $input->Vars;
 150 my $listprice=0; # the price, that can be in MARC record if we have one
 151 if ( $ordernumber eq '' and defined $params->{'breedingid'}){
 152 #we want to import from the breeding reservoir (from a z3950 search)
 153     my ($marcrecord, $encoding) = MARCfindbreeding($params->{'breedingid'});
 154     die("Could not find the selected record in the reservoir, bailing") unless $marcrecord;
 155
 156     # Remove all the items (952) from the imported record
 157     foreach my $item ($marcrecord->field('952')) {
 158         $marcrecord->delete_field($item);
 159     }
 160
 161     my $duplicatetitle;
 162 #look for duplicates
 163     ($biblionumber,$duplicatetitle) = FindDuplicate($marcrecord);
 164     if($biblionumber && !$input->param('use_external_source')) {
 165         #if duplicate record found and user did not decide yet, first warn user
 166         #and let them choose between using a new record or an existing record
 167         Load_Duplicate($duplicatetitle);
 168         exit;
 169     }
 170     #from this point: add a new record
 171         my $bibitemnum;
 172         $params->{'frameworkcode'} or $params->{'frameworkcode'} = "";
 173         ( $biblionumber, $bibitemnum ) = AddBiblio( $marcrecord, $params->{'frameworkcode'} );
 174         # get the price if there is one.
 175         $listprice = GetMarcPrice($marcrecord, $marcflavour);
 176         SetImportRecordStatus($params->{'breedingid'}, 'imported');
 177 }
 178
 179
 180
 181 my ( @order_user_ids, @order_users, @catalog_details );
 182 our $tagslib = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 183 my ( $itemnumber_tag, $itemnumber_subtag ) = GetMarcFromKohaField( 'items.itemnumber' );
 184 if ( not $ordernumber ) {    # create order
 185     $new = 'yes';
 186
 187     if ( $biblionumber ) {
 188         $data = GetBiblioData($biblionumber);
 189     }
 190     # get suggestion fields if applicable. If it's a subscription renewal, then the biblio already exists
 191     # otherwise, retrieve suggestion information.
 192     elsif ($suggestionid) {
 193         $data = GetSuggestion($suggestionid);
 194         $budget_id ||= $data->{'budgetid'} // 0;
 195     }
 196
 197     if ( not $biblionumber and Koha::BiblioFrameworks->find('ACQ') ) {
 198         #my $acq_mss = Koha::MarcSubfieldStructures->search({ frameworkcode => 'ACQ', tagfield => { '!=' => $itemnumber_tag } });
 199         foreach my $tag ( sort keys %{$tagslib} ) {
 200             next if $tag eq '';
 201             next if $tag eq $itemnumber_tag;    # skip items fields
 202             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 203                 my $mss = $tagslib->{$tag}{$subfield};
 204                 next if IsMarcStructureInternal($mss);
 205                 next if $mss->{tab} == -1;
 206                 my $value = $mss->{defaultvalue};
 207
 208                 if ($suggestionid and $mss->{kohafield}) {
 209                     # Reading suggestion info if ordering from a suggestion
 210                     if ( $mss->{kohafield} eq 'biblio.title' ) {
 211                         $value = $data->{title};
 212                     }
 213                     elsif ( $mss->{kohafield} eq 'biblio.author' ) {
 214                         $value = $data->{author};
 215                     }
 216                     elsif ( $mss->{kohafield} eq 'biblioitems.publishercode' ) {
 217                         $value = $data->{publishercode};
 218                     }
 219                     elsif ( $mss->{kohafield} eq 'biblioitems.editionstatement' ) {
 220                         $value = $data->{editionstatement};
 221                     }
 222                     elsif ( $mss->{kohafield} eq 'biblioitems.publicationyear' ) {
 223                         $value = $data->{publicationyear};
 224                     }
 225                     elsif ( $mss->{kohafield} eq 'biblioitems.isbn' ) {
 226                         $value = $data->{isbn};
 227                     }
 228                     elsif ( $mss->{kohafield} eq 'biblio.seriestitle' ) {
 229                         $value = $data->{seriestitle};
 230                     }
 231                 }
 232
 233                 if ( $value eq '' ) {
 234
 235                     # get today date & replace <<YYYY>>, <<MM>>, <<DD>> if provided in the default value
 236                     my $today_dt = dt_from_string;
 237                     my $year     = $today_dt->strftime('%Y');
 238                     my $month    = $today_dt->strftime('%m');
 239                     my $day      = $today_dt->strftime('%d');
 240                     $value =~ s/<<YYYY>>/$year/g;
 241                     $value =~ s/<<MM>>/$month/g;
 242                     $value =~ s/<<DD>>/$day/g;
 243
 244                     # And <<USER>> with surname (?)
 245                     my $username =
 246                       (   C4::Context->userenv
 247                         ? C4::Context->userenv->{'surname'}
 248                         : "superlibrarian" );
 249                     $value =~ s/<<USER>>/$username/g;
 250                 }
 251                 push @catalog_details, {
 252                     tag      => $tag,
 253                     subfield => $subfield,
 254                     %$mss,    # Do we need plugins support (?)
 255                     value => $value,
 256                 };
 257             }
 258         }
 259     }
 260 }
 261 else {    #modify order
 262     $data   = GetOrder($ordernumber);
 263     $biblionumber = $data->{'biblionumber'};
 264     $budget_id = $data->{'budget_id'};
 265
 266     $template->param(
 267         subscriptionid => $data->{subscriptionid},
 268     );
 269
 270     $basket   = GetBasket( $data->{'basketno'} );
 271     $basketno = $basket->{'basketno'};
 272
 273     @order_user_ids = GetOrderUsers($ordernumber);
 274     foreach my $order_user_id (@order_user_ids) {
 275         # FIXME Could be improved with search -in
 276         my $order_patron = Koha::Patrons->find( $order_user_id );
 277         push @order_users, $order_patron if $order_patron;
 278     }
 279 }
 280
 281 # We can have:
 282 # - no ordernumber but a biblionumber: from a subscription, from an existing record
 283 # - no ordernumber, no biblionumber: from a suggestion, from a new order
 284 if ( not $ordernumber or $biblionumber ) {
 285     if ( C4::Context->preference('UseACQFrameworkForBiblioRecords') ) {
 286         my $record = $biblionumber ? GetMarcBiblio({ biblionumber => $biblionumber }) : undef;
 287         foreach my $tag ( sort keys %{$tagslib} ) {
 288             next if $tag eq '';
 289             next if $tag eq $itemnumber_tag; # skip items fields
 290             my @fields = $biblionumber ? $record->field($tag) : ();
 291             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 292                 my $mss = $tagslib->{$tag}{$subfield};
 293                 next if IsMarcStructureInternal($mss);
 294                 next if $mss->{tab} == -1;
 295                 # We only need to display the values
 296                 my $value = join '; ', map { $tag < 10 ? $_->data : $_->subfield( $subfield ) } @fields;
 297                 if ( $value ) {
 298                     push @catalog_details, {
 299                         tag => $tag,
 300                         subfield => $subfield,
 301                         %$mss,
 302                         value => $value,
 303                     };
 304                 }
 305             }
 306         }
 307     }
 308 }
 309
 310 $template->param( catalog_details => \@catalog_details, );
 311
 312 my $suggestion;
 313 $suggestion = GetSuggestionInfo($suggestionid) if $suggestionid;
 314
 315 my @currencies = Koha::Acquisition::Currencies->search;
 316 my $active_currency = Koha::Acquisition::Currencies->get_active;
 317
 318 # build bookfund list
 319 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 320
 321 my $budget =  GetBudget($budget_id);
 322 # build budget list
 323 my $budget_loop = [];
 324 my $budgets = GetBudgetHierarchy;
 325 foreach my $r (@{$budgets}) {
 326     next unless (CanUserUseBudget($patron, $r, $userflags));
 327     if (!defined $r->{budget_amount} || $r->{budget_amount} <0) {
 328         next;
 329     }
 330     push @{$budget_loop}, {
 331         b_id  => $r->{budget_id},
 332         b_txt => $r->{budget_name},
 333         b_sort1_authcat => $r->{'sort1_authcat'},
 334         b_sort2_authcat => $r->{'sort2_authcat'},
 335         b_active => $r->{budget_period_active},
 336         b_sel => ( $r->{budget_id} == $budget_id ) ? 1 : 0,
 337         b_level => $r->{budget_level},
 338     };
 339 }
 340
 341 if ($close) {
 342     $budget_id      =  $data->{'budget_id'};
 343     $budget_name    =   $budget->{'budget_name'};
 344
 345 }
 346
 347 $template->param( sort1 => $data->{'sort1'} );
 348 $template->param( sort2 => $data->{'sort2'} );
 349
 350 if ($basketobj->effective_create_items eq 'ordering' && !$ordernumber) {
 351     # Check if ACQ framework exists
 352     my $marc = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 353     unless($marc) {
 354         $template->param('NoACQframework' => 1);
 355     }
 356     $template->param(
 357         AcqCreateItemOrdering => 1,
 358         UniqueItemFields => C4::Context->preference('UniqueItemFields'),
 359     );
 360 }
 361
 362 # Get the item types list, but only if item_level_itype is YES. Otherwise, it will be in the item, no need to display it in the biblio
 363 my @itemtypes;
 364 @itemtypes = Koha::ItemTypes->search unless C4::Context->preference('item-level_itypes');
 365
 366 if ( defined $from_subscriptionid ) {
 367     my $lastOrderReceived = GetLastOrderReceivedFromSubscriptionid $from_subscriptionid;
 368     if ( defined $lastOrderReceived ) {
 369         $budget_id              = $lastOrderReceived->{budgetid};
 370         $data->{listprice}      = $lastOrderReceived->{listprice};
 371         $data->{uncertainprice} = $lastOrderReceived->{uncertainprice};
 372         $data->{tax_rate}       = $lastOrderReceived->{tax_rate_on_ordering};
 373         $data->{discount}       = $lastOrderReceived->{discount};
 374         $data->{rrp}            = $lastOrderReceived->{rrp};
 375         $data->{replacementprice} = $lastOrderReceived->{replacementprice};
 376         $data->{ecost}          = $lastOrderReceived->{ecost};
 377         $data->{quantity}       = $lastOrderReceived->{quantity};
 378         $data->{order_internalnote} = $lastOrderReceived->{order_internalnote};
 379         $data->{order_vendornote}   = $lastOrderReceived->{order_vendornote};
 380         $data->{sort1}          = $lastOrderReceived->{sort1};
 381         $data->{sort2}          = $lastOrderReceived->{sort2};
 382
 383         $basket = GetBasket( $input->param('basketno') );
 384     }
 385
 386     my $subscription = Koha::Subscriptions->find($from_subscriptionid);
 387     $template->param(
 388         subscriptionid => $from_subscriptionid,
 389         subscription   => $subscription,
 390     );
 391 }
 392
 393 # Find the items.barcode subfield for barcode validations
 394 my (undef, $barcode_subfield) = GetMarcFromKohaField( 'items.barcode' );
 395
 396 # fill template
 397 $template->param(
 398     close        => $close,
 399     budget_id    => $budget_id,
 400     budget_name  => $budget_name
 401 ) if ($close);
 402
 403 # get option values for gist syspref
 404 my @gst_values = map {
 405     option => $_ + 0.0
 406 }, split( '\|', C4::Context->preference("gist") );
 407
 408 my $quantity = $input->param('rr_quantity_to_order') ?
 409       $input->param('rr_quantity_to_order') :
 410       $data->{'quantity'};
 411 $quantity //= 0;
 412
 413 $template->param(
 414     existing         => $biblionumber,
 415     ordernumber           => $ordernumber,
 416     # basket informations
 417     basketno             => $basketno,
 418     basket               => $basket,
 419     basketname           => $basket->{'basketname'},
 420     basketnote           => $basket->{'note'},
 421     booksellerid         => $basket->{'booksellerid'},
 422     basketbooksellernote => $basket->{booksellernote},
 423     basketcontractno     => $basket->{contractnumber},
 424     basketcontractname   => $contract->{contractname},
 425     creationdate         => $basket->{creationdate},
 426     authorisedby         => $basket->{'authorisedby'},
 427     authorisedbyname     => $basket->{'authorisedbyname'},
 428     closedate            => $basket->{'closedate'},
 429     # order details
 430     suggestionid         => $suggestion->{suggestionid},
 431     surnamesuggestedby   => $suggestion->{surnamesuggestedby},
 432     firstnamesuggestedby => $suggestion->{firstnamesuggestedby},
 433     biblionumber         => $biblionumber,
 434     uncertainprice       => $data->{'uncertainprice'},
 435     discount_2dp         => sprintf( "%.2f",  $bookseller->discount ) ,   # for display
 436     discount             => $bookseller->discount,
 437     orderdiscount_2dp    => sprintf( "%.2f", $data->{'discount'} || 0 ),
 438     orderdiscount        => $data->{'discount'},
 439     order_internalnote   => $data->{'order_internalnote'},
 440     order_vendornote     => $data->{'order_vendornote'},
 441     listincgst       => $bookseller->listincgst,
 442     invoiceincgst    => $bookseller->invoiceincgst,
 443     name             => $bookseller->name,
 444     cur_active_sym   => $active_currency->symbol,
 445     cur_active       => $active_currency->currency,
 446     currencies       => \@currencies,
 447     currency         => $data->{currency},
 448     vendor_currency  => $bookseller->listprice,
 449     orderexists      => ( $new eq 'yes' ) ? 0 : 1,
 450     title            => $data->{'title'},
 451     author           => $data->{'author'},
 452     publicationyear  => $data->{'publicationyear'} ? $data->{'publicationyear'} : $data->{'copyrightdate'},
 453     editionstatement => $data->{'editionstatement'},
 454     budget_loop      => $budget_loop,
 455     isbn             => $data->{'isbn'},
 456     ean              => $data->{'ean'},
 457     seriestitle      => $data->{'seriestitle'},
 458     itemtypeloop     => \@itemtypes,
 459     quantity         => $quantity,
 460     quantityrec      => $quantity,
 461     rrp              => $data->{'rrp'},
 462     replacementprice => $data->{'replacementprice'},
 463     gst_values       => \@gst_values,
 464     tax_rate         => $data->{tax_rate_on_ordering} ? $data->{tax_rate_on_ordering}+0.0 : $bookseller->tax_rate ? $bookseller->tax_rate+0.0 : 0,
 465     listprice        => sprintf( "%.2f", $data->{listprice} || $data->{price} || $listprice),
 466     total            => sprintf( "%.2f", ($data->{ecost} || 0) * ($data->{'quantity'} || 0) ),
 467     ecost            => sprintf( "%.2f", $data->{ecost} || 0),
 468     publishercode    => $data->{'publishercode'},
 469     barcode_subfield => $barcode_subfield,
 470     import_batch_id  => $import_batch_id,
 471     acqcreate        => $basketobj->effective_create_items eq "ordering" ? 1 : "",
 472     users_ids        => join(':', @order_user_ids),
 473     users            => \@order_users,
 474     (uc(C4::Context->preference("marcflavour"))) => 1
 475 );
 476
 477 output_html_with_http_headers $input, $cookie, $template->output;
 478
 479
 480 =head2 MARCfindbreeding
 481
 482   $record = MARCfindbreeding($breedingid);
 483
 484 Look up the import record repository for the record with
 485 record with id $breedingid.  If found, returns the decoded
 486 MARC::Record; otherwise, -1 is returned (FIXME).
 487 Returns as second parameter the character encoding.
 488
 489 =cut
 490
 491 sub MARCfindbreeding {
 492     my ( $id ) = @_;
 493     my ($marc, $encoding) = GetImportRecordMarc($id);
 494     # remove the - in isbn, koha store isbn without any -
 495     if ($marc) {
 496         my $record = MARC::Record->new_from_usmarc($marc);
 497         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField( 'biblioitems.isbn' );
 498         if ( $record->field($isbnfield) ) {
 499             foreach my $field ( $record->field($isbnfield) ) {
 500                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
 501                     my $newisbn = $field->subfield($isbnsubfield);
 502                     $newisbn =~ s/-//g;
 503                     $field->update( $isbnsubfield => $newisbn );
 504                 }
 505             }
 506         }
 507         # fix the unimarc 100 coded field (with unicode information)
 508         if ($marcflavour eq 'UNIMARC' && $record->subfield(100,'a')) {
 509             my $f100a=$record->subfield(100,'a');
 510             my $f100 = $record->field(100);
 511             my $f100temp = $f100->as_string;
 512             $record->delete_field($f100);
 513             if ( length($f100temp) > 28 ) {
 514                 substr( $f100temp, 26, 2, "50" );
 515                 $f100->update( 'a' => $f100temp );
 516                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
 517                 $record->insert_fields_ordered($f100);
 518             }
 519         }
 520
 521         if ( !defined(ref($record)) ) {
 522             return -1;
 523         }
 524         else {
 525             # normalize author : probably UNIMARC specific...
 526             if (    C4::Context->preference("z3950NormalizeAuthor")
 527                 and C4::Context->preference("z3950AuthorAuthFields") )
 528             {
 529                 my ( $tag, $subfield ) = GetMarcFromKohaField( "biblio.author" );
 530
 531                 my $auth_fields =
 532                 C4::Context->preference("z3950AuthorAuthFields");
 533                 my @auth_fields = split /,/, $auth_fields;
 534                 my $field;
 535
 536                 if ( $record->field($tag) ) {
 537                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 538
 539                         my $subfieldcode  = shift @$tmpfield;
 540                         my $subfieldvalue = shift @$tmpfield;
 541                         if ($field) {
 542                             $field->add_subfields(
 543                                 "$subfieldcode" => $subfieldvalue )
 544                             if ( $subfieldcode ne $subfield );
 545                         }
 546                         else {
 547                             $field =
 548                             MARC::Field->new( $tag, "", "",
 549                                 $subfieldcode => $subfieldvalue )
 550                             if ( $subfieldcode ne $subfield );
 551                         }
 552                     }
 553                 }
 554                 $record->delete_field( $record->field($tag) );
 555                 foreach my $fieldtag (@auth_fields) {
 556                     next unless ( $record->field($fieldtag) );
 557                     my $lastname  = $record->field($fieldtag)->subfield('a');
 558                     my $firstname = $record->field($fieldtag)->subfield('b');
 559                     my $title     = $record->field($fieldtag)->subfield('c');
 560                     my $number    = $record->field($fieldtag)->subfield('d');
 561                     if ($title) {
 562                         $field->add_subfields(
 563                                 "$subfield" => ucfirst($title) . " "
 564                             . ucfirst($firstname) . " "
 565                             . $number );
 566                     }
 567                     else {
 568                         $field->add_subfields(
 569                             "$subfield" => ucfirst($firstname) . ", "
 570                             . ucfirst($lastname) );
 571                     }
 572                 }
 573                 $record->insert_fields_ordered($field);
 574             }
 575             return $record, $encoding;
 576         }
 577     }
 578     return -1;
 579 }
 580
 581 sub Load_Duplicate {
 582   my ($duplicatetitle)= @_;
 583   ($template, $loggedinuser, $cookie) = get_template_and_user(
 584     {
 585         template_name   => "acqui/neworderempty_duplicate.tt",
 586         query           => $input,
 587         type            => "intranet",
 588         authnotrequired => 0,
 589         flagsrequired   => { acquisition => 'order_manage' },
 590 #        debug           => 1,
 591     }
 592   );
 593
 594   $template->param(
 595     biblionumber        => $biblionumber,
 596     basketno            => $basketno,
 597     booksellerid        => $basket->{'booksellerid'},
 598     breedingid          => $params->{'breedingid'},
 599     duplicatetitle      => $duplicatetitle,
 600     (uc(C4::Context->preference("marcflavour"))) => 1
 601   );
 602
 603   output_html_with_http_headers $input, $cookie, $template->output;
 604 }