acqui/orderreceive.pl

   1 #!/usr/bin/perl
   2
   3
   4 #script to receive orders
   5 #written by chris@katipo.co.nz 24/2/2000
   6
   7 # Copyright 2000-2002 Katipo Communications
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 NAME
  25
  26 orderreceive.pl
  27
  28 =head1 DESCRIPTION
  29
  30 This script shows all order already receive and all pendings orders.
  31 It permit to write a new order as 'received'.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38
  39 to know on what supplier this script has to display receive order.
  40
  41 =item invoiceid
  42
  43 the id of this invoice.
  44
  45 =item freight
  46
  47 =item biblio
  48
  49 The biblionumber of this order.
  50
  51 =item datereceived
  52
  53 =item catview
  54
  55 =item gst
  56
  57 =back
  58
  59 =cut
  60
  61 use Modern::Perl;
  62
  63 use CGI qw ( -utf8 );
  64 use C4::Context;
  65 use C4::Acquisition;
  66 use C4::Auth;
  67 use C4::Output;
  68 use C4::Budgets qw/ GetBudget GetBudgetHierarchy CanUserUseBudget GetBudgetPeriods /;
  69 use C4::Members;
  70 use C4::Items;
  71 use C4::Biblio;
  72 use C4::Suggestions;
  73 use C4::Koha;
  74
  75 use Koha::Acquisition::Booksellers;
  76 use Koha::Acquisition::Currencies;
  77 use Koha::Acquisition::Orders;
  78 use Koha::DateUtils qw( dt_from_string );
  79 use Koha::ItemTypes;
  80 use Koha::Patrons;
  81
  82 my $input      = new CGI;
  83
  84 my $dbh          = C4::Context->dbh;
  85 my $invoiceid    = $input->param('invoiceid');
  86 my $invoice      = GetInvoice($invoiceid);
  87 my $booksellerid   = $invoice->{booksellerid};
  88 my $freight      = $invoice->{shipmentcost};
  89 my $ordernumber  = $input->param('ordernumber');
  90
  91 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
  92 my $order = Koha::Acquisition::Orders->find( $ordernumber );
  93
  94 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  95     {
  96         template_name   => "acqui/orderreceive.tt",
  97         query           => $input,
  98         type            => "intranet",
  99         authnotrequired => 0,
 100         flagsrequired   => {acquisition => 'order_receive'},
 101         debug           => 1,
 102     }
 103 );
 104
 105 unless ( $order ) {
 106     output_html_with_http_headers $input, $cookie, $template->output;
 107     exit;
 108 }
 109
 110 # prepare the form for receiving
 111 my $basket = $order->basket;
 112 my $currencies = Koha::Acquisition::Currencies->search;
 113 my $active_currency = $currencies->get_active;
 114
 115 # Check if ACQ framework exists
 116 my $acq_fw = GetMarcStructure( 1, 'ACQ', { unsafe => 1 } );
 117 unless($acq_fw) {
 118     $template->param('NoACQframework' => 1);
 119 }
 120
 121
 122 my $creator = Koha::Patrons->find( $order->created_by );
 123
 124 my $budget = GetBudget( $order->budget_id );
 125
 126 my $datereceived = $order->datereceived ? dt_from_string( $order->datereceived ) : dt_from_string;
 127
 128 # get option values for gist syspref
 129 my @gst_values = map {
 130     option => $_ + 0.0
 131 }, split( '\|', C4::Context->preference("gist") );
 132
 133 my $order_internalnote = $order->order_internalnote;
 134 my $order_vendornote   = $order->order_vendornote;
 135 if ( $order->subscriptionid ) {
 136     # Order from a subscription, we will display an history of what has been received
 137     my $orders = Koha::Acquisition::Orders->search(
 138         {
 139             subscriptionid     => $order->subscriptionid,
 140             parent_ordernumber => $order->ordernumber,
 141             ordernumber        => { '!=' => $order->ordernumber }
 142         }
 143     );
 144     if ( $order->parent_ordernumber != $order->ordernumber ) {
 145         my $parent_order = Koha::Acquisition::Orders->find($order->parent_ordernumber);
 146         $order_internalnote = $parent_order->order_internalnote;
 147         $order_vendornote   = $parent_order->order_vendornote;
 148     }
 149     $template->param(
 150         orders => $orders,
 151     );
 152 }
 153
 154 $template->param(
 155     order                 => $order,
 156     freight               => $freight,
 157     name                  => $bookseller->name,
 158     active_currency       => $active_currency,
 159     currencies            => scalar $currencies->search({ rate => { '!=' => 1 } }),
 160     invoiceincgst         => $bookseller->invoiceincgst,
 161     bookfund              => $budget->{budget_name},
 162     creator               => $creator,
 163     invoiceid             => $invoice->{invoiceid},
 164     invoice               => $invoice->{invoicenumber},
 165     datereceived          => $datereceived,
 166     order_internalnote    => $order_internalnote,
 167     order_vendornote      => $order_vendornote,
 168     gst_values            => \@gst_values,
 169 );
 170
 171 my $suggestion = GetSuggestionInfoFromBiblionumber($order->{biblionumber});
 172 if ( $suggestion ) {
 173     $template->param( suggestion => $suggestion );
 174 }
 175
 176 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 177 my @budget_loop;
 178 my $periods = GetBudgetPeriods( );
 179 foreach my $period (@$periods) {
 180     if ($period->{'budget_period_id'} == $budget->{'budget_period_id'}) {
 181         $template->{'VARS'}->{'budget_period_description'} = $period->{'budget_period_description'};
 182     }
 183     next if $period->{'budget_period_locked'} || !$period->{'budget_period_description'};
 184     my $budget_hierarchy = GetBudgetHierarchy( $period->{'budget_period_id'} );
 185     my @funds;
 186     foreach my $r ( @{$budget_hierarchy} ) {
 187         next unless ( CanUserUseBudget( $patron, $r, $userflags ) );
 188         if ( !defined $r->{budget_amount} || $r->{budget_amount} == 0 ) {
 189             next;
 190         }
 191         push @funds,
 192           {
 193             b_id  => $r->{budget_id},
 194             b_txt => $r->{budget_name},
 195             b_sel => ( $r->{budget_id} == $order->{budget_id} ) ? 1 : 0,
 196           };
 197     }
 198
 199     @funds = sort { uc( $a->{b_txt} ) cmp uc( $b->{b_txt} ) } @funds;
 200
 201     push @budget_loop,
 202       {
 203         'id'          => $period->{'budget_period_id'},
 204         'description' => $period->{'budget_period_description'},
 205         'funds'       => \@funds
 206       };
 207 }
 208
 209 $template->{'VARS'}->{'budget_loop'} = \@budget_loop;
 210
 211 my $op = $input->param('op');
 212 if ($op and $op eq 'edit'){
 213     $template->param(edit   =>   1);
 214 }
 215 output_html_with_http_headers $input, $cookie, $template->output;