admin/aqbudgets.pl

   1 #!/usr/bin/perl
   2
   3 #script to administer the aqbudget table
   4
   5 # Copyright 2008-2009 BibLibre SARL
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it under the
  10 # terms of the GNU General Public License as published by the Free Software
  11 # Foundation; either version 2 of the License, or (at your option) any later
  12 # version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  15 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  16 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License along
  19 # with Koha; if not, write to the Free Software Foundation, Inc.,
  20 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  21
  22 use Modern::Perl;
  23
  24 use CGI;
  25 use List::Util qw/min/;
  26 use Number::Format qw(format_price);
  27
  28 use Koha::Database;
  29 use C4::Auth qw/get_user_subpermissions/;
  30 use C4::Branch; # GetBranches
  31 use C4::Dates qw/format_date format_date_in_iso/;
  32 use C4::Auth;
  33 use C4::Acquisition;
  34 use C4::Budgets;
  35 use C4::Members;  # calls GetSortDetails()
  36 use C4::Context;
  37 use C4::Output;
  38 use C4::Koha;
  39 use C4::Debug;
  40
  41 my $input = new CGI;
  42 my $dbh     = C4::Context->dbh;
  43
  44 my ($template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  45     {   template_name   => "admin/aqbudgets.tt",
  46         query           => $input,
  47         type            => "intranet",
  48         authnotrequired => 0,
  49         flagsrequired   => { acquisition => 'budget_manage' },
  50         debug           => 0,
  51     }
  52 );
  53
  54 my $cur = GetCurrency();
  55 $template->param( symbol => $cur->{symbol},
  56                   currency => $cur->{currency}
  57                );
  58
  59 my $op = $input->param('op') || 'list';
  60
  61 # see if the user want to see all budgets or only owned ones by default
  62 my $show_mine = $input->param('show_mine') // 0;
  63
  64 # IF USER DOESNT HAVE PERM FOR AN 'ADD', THEN REDIRECT TO THE DEFAULT VIEW...
  65 if (not defined $template->{VARS}->{'CAN_user_acquisition_budget_add_del'}
  66     and $op eq 'add_form')
  67 {
  68     $op = 'list';
  69 }
  70
  71 # get only the columns of aqbudgets in budget_hash
  72 my @columns = Koha::Database->new()->schema->source('Aqbudget')->columns;
  73 my $budget_hash = { map { join(' ',@columns) =~ /$_/ ? ( $_ => $input->param($_) )  : () } keys( %{$input->Vars()}) } ;
  74
  75 my $budget_id                 = $input->param('budget_id');
  76 my $budget_period_id          = $input->param('budget_period_id');
  77 my $budget_permission         = $input->param('budget_permission');
  78 my $budget_users_ids          = $input->param('budget_users_ids');
  79 my $filter_budgetbranch       = $input->param('filter_budgetbranch') // '';
  80 my $filter_budgetname         = $input->param('filter_budgetname');
  81
  82
  83 # ' ------- get periods stuff ------------------'
  84 # IF PERIODID IS DEFINED,  GET THE PERIOD - ELSE JUST GET THE ACTIVE PERIOD BY DEFAULT
  85 my $period;
  86 if ( $budget_period_id ) {
  87     $period = GetBudgetPeriod( $budget_period_id );
  88 }
  89
  90 # ------- get periods stuff ------------------
  91
  92 # USED FOR PERMISSION COMPARISON LATER
  93 my $borrower_id         = $template->{VARS}->{'USER_INFO'}[0]->{'borrowernumber'};
  94 my $user                = GetMemberDetails($borrower_id);
  95 my $user_branchcode     = $user->{'branchcode'};
  96
  97 $template->param(
  98     show_mine   => $show_mine,
  99     op  => $op,
 100 );
 101
 102 my $budget;
 103
 104 my $branches = GetBranches($show_mine);
 105 my @branchloop2;
 106 foreach my $thisbranch (keys %$branches) {
 107     my %row = (
 108         value      => $thisbranch,
 109         branchname => $branches->{$thisbranch}->{'branchname'},
 110     );
 111     $row{selected} = 1 if $thisbranch eq $filter_budgetbranch;
 112     push @branchloop2, \%row;
 113 }
 114
 115 $template->param(auth_cats_loop => GetBudgetAuthCats( $budget_period_id ))
 116     if $budget_period_id;
 117
 118 # Used to create form to add or  modify a record
 119 if ($op eq 'add_form') {
 120 #### ------------------- ADD_FORM -------------------------
 121     # if no buget_id is passed then its an add
 122     #  pass the period_id to build the dropbox - because we only want to show  budgets from this period
 123     my $dropbox_disabled;
 124     if (defined $budget_id ) {    ### MOD
 125         $budget = GetBudget($budget_id);
 126         if (!CanUserModifyBudget($borrowernumber, $budget, $staffflags)) {
 127             $template->param(error_not_authorised_to_modify => 1);
 128             output_html_with_http_headers $input, $cookie, $template->output;
 129             exit;
 130         }
 131         $dropbox_disabled = BudgetHasChildren($budget_id);
 132         my $borrower = &GetMember( borrowernumber=>$budget->{budget_owner_id} );
 133         $budget->{budget_owner_name} = ( $borrower ? $borrower->{'firstname'} . ' ' . $borrower->{'surname'} : '' );
 134         $$budget{$_}= sprintf("%.2f", $budget->{$_}) for grep{ /amount|encumb|expend/ } keys %$budget;
 135     }
 136
 137     # build budget hierarchy
 138     my %labels;
 139     my @values;
 140     my $hier = GetBudgetHierarchy($$period{budget_period_id});
 141     foreach my $r (@$hier) {
 142         $labels{"$r->{budget_id}"} = $r->{budget_code};
 143         push @values, $r->{budget_id};
 144     }
 145     push @values, '';
 146     # if no buget_id is passed then its an add
 147     my $budget_parent;
 148     my $budget_parent_id;
 149     if ($budget){
 150         $budget_parent_id = $budget->{'budget_parent_id'} ;
 151     }else{
 152         $budget_parent_id = $input->param('budget_parent_id');
 153     }
 154     $budget_parent = GetBudget($budget_parent_id);
 155
 156     # build branches select
 157     my $branches = GetBranches;
 158     my @branchloop_select;
 159     foreach my $thisbranch ( sort keys %$branches ) {
 160         my %row = (
 161             value      => $thisbranch,
 162             branchname => $branches->{$thisbranch}->{'branchname'},
 163         );
 164         $row{selected} = 1 if $budget and $thisbranch eq $budget->{'budget_branchcode'};
 165         push @branchloop_select, \%row;
 166     }
 167
 168     # populates the YUI planning button
 169     my $categories = GetAuthorisedValueCategories();
 170     my @auth_cats_loop1 = ();
 171     foreach my $category (@$categories) {
 172         my $entry = { category => $category,
 173                         selected => ( $budget and $budget->{sort1_authcat} eq $category ? 1 : 0 ),
 174                     };
 175         push @auth_cats_loop1, $entry;
 176     }
 177     my @auth_cats_loop2 = ();
 178     foreach my $category (@$categories) {
 179         my $entry = { category => $category,
 180                         selected => ( $budget and $budget->{sort2_authcat} eq $category ? 1 : 0 ),
 181                     };
 182         push @auth_cats_loop2, $entry;
 183     }
 184     $template->param(authorised_value_categories1 => \@auth_cats_loop1);
 185     $template->param(authorised_value_categories2 => \@auth_cats_loop2);
 186
 187     if($budget->{'budget_permission'}){
 188         my $budget_permission = "budget_perm_".$budget->{'budget_permission'};
 189         $template->param($budget_permission => 1);
 190     }
 191
 192     if ($budget) {
 193         my @budgetusers = GetBudgetUsers($budget->{budget_id});
 194         my @budgetusers_loop;
 195         foreach my $borrowernumber (@budgetusers) {
 196             my $member = C4::Members::GetMember(
 197                 borrowernumber => $borrowernumber);
 198             push @budgetusers_loop, {
 199                 firstname => $member->{firstname},
 200                 surname => $member->{surname},
 201                 borrowernumber => $borrowernumber
 202             };
 203         }
 204         $template->param(
 205             budget_users => \@budgetusers_loop,
 206             budget_users_ids => join ':', @budgetusers
 207         );
 208     }
 209
 210     # if no buget_id is passed then its an add
 211     $template->param(
 212         budget_has_children => BudgetHasChildren( $budget->{budget_id} ),
 213         budget_parent_id                  => $budget_parent->{'budget_id'},
 214         budget_parent_name                => $budget_parent->{'budget_name'},
 215         branchloop_select         => \@branchloop_select,
 216                 %$period,
 217                 %$budget,
 218     );
 219                                                     # END $OP eq ADD_FORM
 220 #---------------------- DEFAULT DISPLAY BELOW ---------------------
 221
 222 # called by default form, used to confirm deletion of data in DB
 223 } elsif ($op eq 'delete_confirm') {
 224
 225     my $budget = GetBudget($budget_id);
 226     $template->param(
 227         budget_id     => $budget->{'budget_id'},
 228         budget_code   => $budget->{'budget_code'},
 229         budget_name   => $budget->{'budget_name'},
 230         budget_amount => $budget->{'budget_amount'},
 231     );
 232                                                     # END $OP eq DELETE_CONFIRM
 233 # called by delete_confirm, used to effectively confirm deletion of data in DB
 234 } elsif ( $op eq 'delete_confirmed' ) {
 235     my $rc = DelBudget($budget_id);
 236     $op = 'list';
 237 } elsif( $op eq 'add_validate' ) {
 238     my @budgetusersid;
 239     if (defined $budget_users_ids){
 240         @budgetusersid = split(':', $budget_users_ids);
 241     }
 242
 243     my $budget_modified = 0;
 244     if (defined $budget_id) {
 245         if (CanUserModifyBudget($borrowernumber, $budget_hash->{budget_id},
 246             $staffflags)
 247         ) {
 248             ModBudget( $budget_hash );
 249             ModBudgetUsers($budget_hash->{budget_id}, @budgetusersid);
 250             $budget_modified = 1;
 251         }
 252         else {
 253             $template->param(error_not_authorised_to_modify => 1);
 254         }
 255     } else {
 256         $budget_hash->{budget_id} = AddBudget( $budget_hash );
 257         ModBudgetUsers($budget_hash->{budget_id}, @budgetusersid);
 258         $budget_modified = 1;
 259     }
 260
 261     my $set_owner_to_children = $input->param('set_owner_to_children');
 262     if ( $set_owner_to_children and $budget_modified ) {
 263         C4::Budgets::SetOwnerToFundHierarchy( $budget_hash->{budget_id}, $budget_hash->{budget_owner_id} );
 264     }
 265     $op = 'list';
 266 }
 267
 268 if ( $op eq 'list' ) {
 269     my $branches = GetBranches();
 270     $template->param(
 271         budget_id => $budget_id,
 272         %$period,
 273     );
 274
 275     my @budgets = @{
 276         GetBudgetHierarchy($$period{budget_period_id},
 277             C4::Context->userenv->{branchcode}, $show_mine ? $borrower_id : '')
 278     };
 279
 280     my $period_total = 0;
 281     my ($period_alloc_total, $spent_total, $ordered_total, $available_total) = (0,0,0,0);
 282
 283         #This Looks WEIRD to me : should budgets be filtered in such a way ppl who donot own it would not see the amount spent on the budget by others ?
 284
 285     foreach my $budget (@budgets) {
 286         # PERMISSIONS
 287         unless(CanUserModifyBudget($borrowernumber, $budget, $staffflags)) {
 288             $budget->{'budget_lock'} = 1;
 289         }
 290
 291         # if a budget search doesnt match, next
 292         if ($filter_budgetname) {
 293             next
 294               unless $budget->{budget_code} =~ m/$filter_budgetname/i
 295                   || $budget->{budget_name} =~ m/$filter_budgetname/i;
 296         }
 297         if ($filter_budgetbranch ) {
 298             next unless  $budget->{budget_branchcode} eq $filter_budgetbranch;
 299         }
 300
 301 ## TOTALS
 302         $budget->{'budget_remaining'} = $budget->{'budget_amount'} - $budget->{'budget_spent'} - $budget->{budget_ordered};
 303         $budget->{'total_remaining'} = $budget->{'budget_amount'} - $budget->{'total_spent'} - $budget->{total_ordered};
 304         # adds to total  - only if budget is a 'top-level' budget
 305         unless ( defined $budget->{budget_parent_id} ) {
 306             $period_alloc_total += $budget->{'budget_amount'};
 307             $spent_total += $budget->{total_spent};
 308             $ordered_total += $budget->{total_ordered};
 309             $available_total += $budget->{total_remaining};
 310         }
 311
 312 # if amount == 0 dont display...
 313         delete $budget->{'budget_unalloc_sublevel'}
 314             if (!defined $budget->{'budget_unalloc_sublevel'}
 315             or $budget->{'budget_unalloc_sublevel'} == 0);
 316
 317         # Value of budget_spent equals 0 instead of undefined value
 318         $budget->{budget_spent} = 0 unless defined($budget->{budget_spent});
 319         $budget->{budget_ordered} = 0 unless defined($budget->{budget_ordered});
 320
 321         #Make a list of parents of the bugdet
 322         my @budget_hierarchy;
 323         push  @budget_hierarchy, { element_name => $budget->{"budget_name"}, element_id => $budget->{"budget_id"} };
 324         my $parent_id = $budget->{"budget_parent_id"};
 325         while ($parent_id) {
 326             my $parent = GetBudget($parent_id);
 327             push @budget_hierarchy, { element_name => $parent->{"budget_name"}, element_id => $parent->{"budget_id"} };
 328             $parent_id = $parent->{"budget_parent_id"};
 329         }
 330         push  @budget_hierarchy, { element_name => $period->{"budget_period_description"} };
 331         @budget_hierarchy = reverse(@budget_hierarchy);
 332
 333         $budget->{budget_hierarchy} = \@budget_hierarchy;
 334     }
 335
 336     my $budget_period_total = $period->{budget_period_total};
 337
 338     my $periods = GetBudgetPeriods();
 339
 340     $template->param(
 341         op                     => 'list',
 342         budgets                => \@budgets,
 343         periods                => $periods,
 344         budget_period_total    => $budget_period_total,
 345         period_alloc_total     => $period_alloc_total,
 346         spent_total            => $spent_total,
 347         ordered_total          => $ordered_total,
 348         available_total        => $available_total,
 349         branchloop             => \@branchloop2,
 350     );
 351
 352 } #---- END list
 353
 354 output_html_with_http_headers $input, $cookie, $template->output;