admin/cities.pl

   1 #! /usr/bin/perl
   2
   3 # Copyright 2006 SAN OUEST-PROVENCE et Paul POULAIN
   4 # Copyright 2015 Koha Development Team
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22 use CGI qw ( -utf8 );
  23 use C4::Context;
  24 use C4::Auth qw( get_template_and_user );
  25 use C4::Output qw( output_html_with_http_headers );
  26
  27 use Koha::Cities;
  28
  29 my $input       = CGI->new;
  30 my $city_name_filter = $input->param('city_name_filter') // q||;
  31 my $cityid      = $input->param('cityid');
  32 my $op          = $input->param('op') || 'list';
  33 my @messages;
  34
  35 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  36     {   template_name   => "admin/cities.tt",
  37         query           => $input,
  38         type            => "intranet",
  39         flagsrequired   => { parameters => 'manage_cities' },
  40     }
  41 );
  42
  43 my $dbh = C4::Context->dbh;
  44 if ( $op eq 'add_form' ) {
  45     my $city;
  46     if ($cityid) {
  47         $city = Koha::Cities->find($cityid);
  48     }
  49
  50     $template->param( city => $city, );
  51 } elsif ( $op eq 'add_validate' ) {
  52     my $city_name    = $input->param('city_name');
  53     my $city_state   = $input->param('city_state');
  54     my $city_zipcode = $input->param('city_zipcode');
  55     my $city_country = $input->param('city_country');
  56
  57     if ($cityid) {
  58         my $city = Koha::Cities->find($cityid);
  59         $city->city_name($city_name);
  60         $city->city_state($city_state);
  61         $city->city_zipcode($city_zipcode);
  62         $city->city_country($city_country);
  63         eval { $city->store; };
  64         if ($@) {
  65             push @messages, { type => 'error', code => 'error_on_update' };
  66         } else {
  67             push @messages, { type => 'message', code => 'success_on_update' };
  68         }
  69     } else {
  70         my $city = Koha::City->new(
  71             {   city_name    => $city_name,
  72                 city_state   => $city_state,
  73                 city_zipcode => $city_zipcode,
  74                 city_country => $city_country,
  75             }
  76         );
  77         eval { $city->store; };
  78         if ($@) {
  79             push @messages, { type => 'error', code => 'error_on_insert' };
  80         } else {
  81             push @messages, { type => 'message', code => 'success_on_insert' };
  82         }
  83     }
  84     $city_name = q||;
  85     $op        = 'list';
  86 } elsif ( $op eq 'delete_confirm' ) {
  87     my $city = Koha::Cities->find($cityid);
  88     $template->param( city => $city, );
  89 } elsif ( $op eq 'delete_confirmed' ) {
  90     my $city = Koha::Cities->find($cityid);
  91     my $deleted = eval { $city->delete; };
  92
  93     if ( $@ or not $deleted ) {
  94         push @messages, { type => 'error', code => 'error_on_delete' };
  95     } else {
  96         push @messages, { type => 'message', code => 'success_on_delete' };
  97     }
  98     $op = 'list';
  99 }
 100
 101 if ( $op eq 'list' ) {
 102     $template->param( cities_count => Koha::Cities->search->count );
 103 }
 104
 105 $template->param(
 106     cityid      => $cityid,
 107     city_name_filter => $city_name_filter,
 108     messages    => \@messages,
 109     op          => $op,
 110 );
 111
 112 output_html_with_http_headers $input, $cookie, $template->output;