admin/debit_types.pl

   1 #! /usr/bin/perl
   2
   3 # Copyright 2019 Koha Development Team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use Try::Tiny;
  23
  24 use C4::Context;
  25 use C4::Auth;
  26 use C4::Output;
  27
  28 use Koha::Account::DebitType;
  29 use Koha::Account::DebitTypes;
  30
  31 my $input = new CGI;
  32 my $code  = $input->param('code');
  33 my $op    = $input->param('op') || 'list';
  34 my @messages;
  35
  36 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  37     {
  38         template_name   => "admin/debit_types.tt",
  39         query           => $input,
  40         type            => "intranet",
  41         flagsrequired   => { parameters => 'parameters_remaining_permissions' },
  42         debug           => 1,
  43     }
  44 );
  45
  46 my $debit_type;
  47 if ($code) {
  48     $debit_type = Koha::Account::DebitTypes->find($code);
  49 }
  50
  51 if ( $op eq 'add_form' ) {
  52
  53     my $selected_branches =
  54       $debit_type ? $debit_type->get_library_limits : undef;
  55     my $branches =
  56       Koha::Libraries->search( {}, { order_by => ['branchname'] } )->unblessed;
  57     my @branches_loop;
  58     foreach my $branch (@$branches) {
  59         my $selected =
  60           ( $selected_branches
  61               && grep { $_->branchcode eq $branch->{branchcode} }
  62               @{ $selected_branches->as_list } ) ? 1 : 0;
  63         push @branches_loop,
  64           {
  65             branchcode => $branch->{branchcode},
  66             branchname => $branch->{branchname},
  67             selected   => $selected,
  68           };
  69     }
  70
  71     $template->param(
  72         debit_type    => $debit_type,
  73         branches_loop => \@branches_loop
  74     );
  75 }
  76 elsif ( $op eq 'add_validate' ) {
  77     my $description           = $input->param('description');
  78     my $can_be_added_manually = $input->param('can_be_added_manually') || 0;
  79     my $default_amount        = $input->param('default_amount') || undef;
  80     my @branches = grep { $_ ne q{} } $input->multi_param('branches');
  81
  82     if ( not defined $debit_type ) {
  83         $debit_type = Koha::Account::DebitType->new( { code => $code } );
  84     }
  85     $debit_type->description($description);
  86     $debit_type->can_be_added_manually($can_be_added_manually);
  87     $debit_type->default_amount($default_amount);
  88
  89     try {
  90         $debit_type->store;
  91         $debit_type->replace_library_limits( \@branches );
  92         push @messages, { type => 'message', code => 'success_on_saving' };
  93     }
  94     catch {
  95         push @messages, { type => 'error', code => 'error_on_saving' };
  96     };
  97     $op = 'list';
  98 }
  99 elsif ( $op eq 'archive' ) {
 100     try {
 101         $debit_type->archived(1)->store();
 102         push @messages, { code => 'success_on_archive', type => 'message' };
 103     }
 104     catch {
 105         push @messages, { code => 'error_on_archive', type => 'alert' };
 106
 107     };
 108     $op = 'list';
 109 }
 110 elsif ( $op eq 'unarchive' ) {
 111     try {
 112         $debit_type->archived(0)->store();
 113         push @messages, { code => 'success_on_restore', type => 'message' };
 114     }
 115     catch {
 116         push @messages, { code => 'error_on_restore', type => 'alert' };
 117     };
 118     $op = 'list';
 119 }
 120
 121 if ( $op eq 'list' ) {
 122     my $debit_types = Koha::Account::DebitTypes->search();
 123     $template->param( debit_types => $debit_types, );
 124 }
 125
 126 $template->param(
 127     code     => $code,
 128     messages => \@messages,
 129     op       => $op,
 130 );
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;