admin/itemtypes.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2002 Paul Poulain
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 =head1 admin/itemtypes.pl
  22
  23 =cut
  24
  25 use Modern::Perl;
  26 use CGI qw ( -utf8 );
  27
  28 use File::Spec;
  29
  30 use C4::Koha;
  31 use C4::Context;
  32 use C4::Auth;
  33 use C4::Output;
  34 use Koha::ItemTypes;
  35 use Koha::ItemType;
  36 use Koha::Localizations;
  37
  38 my $input         = new CGI;
  39 my $searchfield   = $input->param('description');
  40 my $itemtype_code = $input->param('itemtype');
  41 my $op            = $input->param('op') // 'list';
  42 my @messages;
  43 $searchfield =~ s/\,//g if $searchfield;
  44 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  45     {   template_name   => "admin/itemtypes.tt",
  46         query           => $input,
  47         type            => "intranet",
  48         flagsrequired   => { parameters => 'manage_itemtypes' },
  49         debug           => 1,
  50     }
  51 );
  52
  53 my $dbh = C4::Context->dbh;
  54
  55 my $sip_media_type = $input->param('sip_media_type');
  56 undef($sip_media_type) if defined($sip_media_type) and $sip_media_type =~ /^\s*$/;
  57
  58 if ( $op eq 'add_form' ) {
  59     my $itemtype = Koha::ItemTypes->find($itemtype_code);
  60
  61     my $selected_branches = $itemtype ? $itemtype->get_library_limits : undef;
  62     my $branches = Koha::Libraries->search( {}, { order_by => ['branchname'] } )->unblessed;
  63     my @branches_loop;
  64     foreach my $branch ( @$branches ) {
  65         my $selected = ($selected_branches && grep {$_->branchcode eq $branch->{branchcode}} @{ $selected_branches->as_list } ) ? 1 : 0;
  66         push @branches_loop, {
  67             branchcode => $branch->{branchcode},
  68             branchname => $branch->{branchname},
  69             selected   => $selected,
  70         };
  71     }
  72
  73     my $imagesets = C4::Koha::getImageSets( checked => ( $itemtype ? $itemtype->imageurl : undef ) );
  74     my $searchcategory = GetAuthorisedValues("ITEMTYPECAT");
  75     my $translated_languages = C4::Languages::getTranslatedLanguages( undef , C4::Context->preference('template') );
  76     $template->param(
  77         itemtype  => $itemtype,
  78         imagesets => $imagesets,
  79         searchcategory => $searchcategory,
  80         can_be_translated => ( scalar(@$translated_languages) > 1 ? 1 : 0 ),
  81         branches_loop    => \@branches_loop,
  82     );
  83 } elsif ( $op eq 'add_validate' ) {
  84     my $is_a_modif   = $input->param('is_a_modif');
  85     my $itemtype     = Koha::ItemTypes->find($itemtype_code);
  86     my $description  = $input->param('description');
  87     my $rentalcharge = $input->param('rentalcharge');
  88     my $rentalcharge_daily = $input->param('rentalcharge_daily');
  89     my $rentalcharge_hourly = $input->param('rentalcharge_hourly');
  90     my $defaultreplacecost = $input->param('defaultreplacecost');
  91     my $processfee = $input->param('processfee');
  92     my $image = $input->param('image') || q||;
  93     my @branches = grep { $_ ne q{} } $input->multi_param('branches');
  94
  95     my $notforloan = $input->param('notforloan') ? 1 : 0;
  96     my $imageurl =
  97       $image eq 'removeImage' ? ''
  98       : (
  99           $image eq 'remoteImage' ? $input->param('remoteImage')
 100         : $image
 101       );
 102     my $summary        = $input->param('summary');
 103     my $checkinmsg     = $input->param('checkinmsg');
 104     my $checkinmsgtype = $input->param('checkinmsgtype');
 105     my $hideinopac     = $input->param('hideinopac') // 0;
 106     my $searchcategory = $input->param('searchcategory');
 107
 108     if ( $itemtype and $is_a_modif ) {    # it's a modification
 109         $itemtype->description($description);
 110         $itemtype->rentalcharge($rentalcharge);
 111         $itemtype->rentalcharge_daily($rentalcharge_daily);
 112         $itemtype->rentalcharge_hourly($rentalcharge_hourly);
 113         $itemtype->defaultreplacecost($defaultreplacecost);
 114         $itemtype->processfee($processfee);
 115         $itemtype->notforloan($notforloan);
 116         $itemtype->imageurl($imageurl);
 117         $itemtype->summary($summary);
 118         $itemtype->checkinmsg($checkinmsg);
 119         $itemtype->checkinmsgtype($checkinmsgtype);
 120         $itemtype->sip_media_type($sip_media_type);
 121         $itemtype->hideinopac($hideinopac);
 122         $itemtype->searchcategory($searchcategory);
 123
 124         eval {
 125           $itemtype->store;
 126           $itemtype->replace_library_limits( \@branches );
 127         };
 128
 129         if ($@) {
 130             push @messages, { type => 'alert', code => 'error_on_update' };
 131         } else {
 132             push @messages, { type => 'message', code => 'success_on_update' };
 133         }
 134     } elsif ( not $itemtype and not $is_a_modif ) {
 135         my $itemtype = Koha::ItemType->new(
 136             {
 137                 itemtype            => $itemtype_code,
 138                 description         => $description,
 139                 rentalcharge        => $rentalcharge,
 140                 rentalcharge_daily  => $rentalcharge_daily,
 141                 rentalcharge_hourly => $rentalcharge_hourly,
 142                 defaultreplacecost  => $defaultreplacecost,
 143                 processfee          => $processfee,
 144                 notforloan          => $notforloan,
 145                 imageurl            => $imageurl,
 146                 summary             => $summary,
 147                 checkinmsg          => $checkinmsg,
 148                 checkinmsgtype      => $checkinmsgtype,
 149                 sip_media_type      => $sip_media_type,
 150                 hideinopac          => $hideinopac,
 151                 searchcategory      => $searchcategory,
 152             }
 153         );
 154         eval {
 155           $itemtype->store;
 156           $itemtype->replace_library_limits( \@branches );
 157         };
 158
 159         if ($@) {
 160             push @messages, { type => 'alert', code => 'error_on_insert' };
 161         } else {
 162             push @messages, { type => 'message', code => 'success_on_insert' };
 163         }
 164     } else {
 165         push @messages,
 166           { type => 'alert',
 167             code => 'already_exists',
 168           };
 169     }
 170
 171     $searchfield = '';
 172     $op          = 'list';
 173
 174  } elsif ( $op eq 'delete_confirm' ) {
 175     my $itemtype = Koha::ItemTypes->find($itemtype_code);
 176     my $can_be_deleted = $itemtype->can_be_deleted();
 177     if ($can_be_deleted == 0) {
 178         push @messages, { type => 'alert', code => 'cannot_be_deleted'};
 179         $op = 'list';
 180     } else {
 181         $template->param( itemtype => $itemtype, );
 182     }
 183
 184 } elsif ( $op eq 'delete_confirmed' ) {
 185
 186     my $itemtype = Koha::ItemTypes->find($itemtype_code);
 187     my $deleted = eval { $itemtype->delete };
 188     if ( $@ or not $deleted ) {
 189         push @messages, { type => 'alert', code => 'error_on_delete' };
 190     } else {
 191         push @messages, { type => 'message', code => 'success_on_delete' };
 192     }
 193
 194     $op = 'list';
 195 }
 196
 197 if ( $op eq 'list' ) {
 198     my @itemtypes = Koha::ItemTypes->search->as_list;
 199     $template->param(
 200         itemtypes => \@itemtypes,
 201         messages  => \@messages,
 202     );
 203 }
 204
 205 $template->param( op => $op );
 206
 207 output_html_with_http_headers $input, $cookie, $template->output;