admin/restrictions.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2019 PTFS Europe
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Try::Tiny qw( try catch );
  24
  25 use C4::Auth qw( get_template_and_user );
  26 use C4::Output qw( output_html_with_http_headers );
  27 use Koha::Patron::Restriction::Types;
  28
  29 my $input = CGI->new;
  30 my $op    = $input->param('op') // 'list';
  31 my $code  = uc $input->param('code');
  32 my @messages = ();
  33
  34 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  35     {
  36         template_name   => "admin/restrictions.tt",
  37         query           => $input,
  38         type            => "intranet",
  39         flagsrequired   => { parameters => 'manage_patron_restrictions' },
  40         debug           => 1,
  41     }
  42 );
  43
  44 if ( $op eq 'add_form') {
  45     # Get all existing restrictions, so we can do client-side validation
  46     $template->param(
  47         existing => scalar Koha::Patron::Restriction::Types->search()
  48     );
  49     if ($code) {
  50         $template->param(
  51             restriction => scalar Koha::Patron::Restriction::Types->find($code)
  52         );
  53     }
  54 } elsif ( $op eq 'add_validate' ) {
  55
  56     my $display_text = $input->param('display_text');
  57     my $is_a_modif = $input->param("is_a_modif");
  58
  59     if ($is_a_modif) {
  60         # Check whether another restriction already has this display text
  61         my $dupe = Koha::Patron::Restriction::Types->search(
  62             {
  63                 code         => { '!=' => $code },
  64                 display_text => $display_text,
  65             }
  66         );
  67         if ($dupe->count) {
  68             push @messages, {
  69                 type => 'error', code => 'duplicate_display_text'
  70             };
  71         } else {
  72             my $restriction = Koha::Patron::Restriction::Types->find($code);
  73             $restriction->display_text($display_text);
  74             $restriction->store;
  75             push @messages, { type => 'message', code => 'update_success' };
  76         }
  77     } else {
  78         # Check whether another restriction already has this code
  79         my $dupe = Koha::Patron::Restriction::Types->find($code);
  80         if ($dupe) {
  81             push @messages, {
  82                 type => 'error', code => 'duplicate_code'
  83             };
  84         } else {
  85             my $restriction = Koha::Patron::Restriction::Type->new({
  86                 code => $code,
  87                 display_text => $display_text
  88             });
  89             $restriction->store;
  90             push @messages, { type => 'message', code => 'add_success' };
  91         }
  92     }
  93     $op = 'list';
  94 } elsif ( $op eq 'make_default' ) {
  95     my $restriction = Koha::Patron::Restriction::Types->find($code);
  96     $restriction->make_default;
  97     $op = 'list';
  98 } elsif ( $op eq 'delete_confirm' ) {
  99     $template->param(
 100         restriction => scalar Koha::Patron::Restriction::Types->find($code)
 101     );
 102 } elsif ( $op eq 'delete_confirmed' ) {
 103     try {
 104         Koha::Patron::Restriction::Types->find($code)->delete;
 105         push @messages, { type => 'message', code => 'delete_success' };
 106     }
 107     catch {
 108         if ( blessed $_ ) {
 109             if ( $_->isa('Koha::Exceptions::CannotDeleteDefault') ) {
 110                 push @messages, { type => 'error', code => 'delete_default' };
 111             }
 112             elsif ( $_->isa('Koha::Exceptions::CannotDeleteSystem') ) {
 113                 push @messages, { type => 'error', code => 'delete_system' };
 114             }
 115         }
 116     };
 117     $op = 'list';
 118 }
 119
 120 $template->param(
 121     messages => \@messages,
 122     op       => $op
 123 );
 124
 125 if ( $op eq 'list' ) {
 126     my $restrictions = Koha::Patron::Restriction::Types->search();
 127     $template->param(
 128         restrictions => $restrictions,
 129     )
 130 }
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;
 133
 134 exit 0;