catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = new CGI;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     authnotrequired => 0,
 186     flagsrequired   => { catalogue => 1 },
 187     }
 188 );
 189
 190 my $lang = C4::Languages::getlanguage($cgi);
 191
 192 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 193     $template->param('UNIMARC' => 1);
 194 }
 195
 196 if($cgi->cookie("holdfor")){
 197     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 198     $template->param(
 199         holdfor => $cgi->cookie("holdfor"),
 200         holdfor_surname => $holdfor_patron->surname,
 201         holdfor_firstname => $holdfor_patron->firstname,
 202         holdfor_cardnumber => $holdfor_patron->cardnumber,
 203     );
 204 }
 205
 206 if($cgi->cookie("holdforclub")){
 207     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 208     $template->param(
 209         holdforclub => $cgi->cookie("holdforclub"),
 210         holdforclub_name => $holdfor_club->name,
 211     );
 212 }
 213
 214 if($cgi->cookie("searchToOrder")){
 215     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 216     $template->param(
 217         searchtoorder_basketno => $basketno,
 218         searchtoorder_vendorid => $vendorid
 219     );
 220 }
 221
 222 # get biblionumbers stored in the cart
 223 my @cart_list;
 224
 225 if($cgi->cookie("intranet_bib_list")){
 226     my $cart_list = $cgi->cookie("intranet_bib_list");
 227     @cart_list = split(/\//, $cart_list);
 228 }
 229
 230 my @search_groups =
 231   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 232 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 233
 234 $template->param(
 235     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 236     search_groups    => \@search_groups,
 237 );
 238
 239 # load the Type stuff
 240 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 241 # the index parameter is different for item-level itemtypes
 242 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 243 my @advancedsearchesloop;
 244 my $cnt;
 245 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 246 my @advanced_search_types = split(/\|/, $advanced_search_types);
 247
 248 foreach my $advanced_srch_type (@advanced_search_types) {
 249     $advanced_srch_type =~ s/^\s*//;
 250     $advanced_srch_type =~ s/\s*$//;
 251    if ($advanced_srch_type eq 'itemtypes') {
 252    # itemtype is a special case, since it's not defined in authorized values
 253         my @itypesloop;
 254         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 255             my %row =(  number=>$cnt++,
 256                 ccl => "$itype_or_itemtype,phr",
 257                 code => $thisitemtype,
 258                 description => $itemtypes->{$thisitemtype}->{translated_description},
 259                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 260             );
 261             push @itypesloop, \%row;
 262         }
 263         my %search_code = (  advanced_search_type => $advanced_srch_type,
 264                              code_loop => \@itypesloop );
 265         push @advancedsearchesloop, \%search_code;
 266     } else {
 267     # covers all the other cases: non-itemtype authorized values
 268        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 269         my @authvalueloop;
 270         for my $thisitemtype (@$advsearchtypes) {
 271                 my %row =(
 272                                 number=>$cnt++,
 273                                 ccl => $advanced_srch_type,
 274                 code => $thisitemtype->{authorised_value},
 275                 description => $thisitemtype->{'lib'},
 276                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 277                 );
 278                 push @authvalueloop, \%row;
 279         }
 280         my %search_code = (  advanced_search_type => $advanced_srch_type,
 281                              code_loop => \@authvalueloop );
 282         push @advancedsearchesloop, \%search_code;
 283     }
 284 }
 285 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 286 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 287 my $advancedsearchesloop = prepare_adv_search_types($types);
 288 $template->param(advancedsearchesloop => $advancedsearchesloop);
 289
 290 # The following should only be loaded if we're bringing up the advanced search template
 291 if ( $template_type eq 'advsearch' ) {
 292
 293     # load the servers (used for searching -- to do federated searching, etc.)
 294     my $primary_servers_loop;# = displayPrimaryServers();
 295     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 296
 297     my $secondary_servers_loop;
 298     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 299
 300     # set the default sorting
 301     if (   C4::Context->preference('defaultSortField')
 302         && C4::Context->preference('defaultSortOrder') ) {
 303         my $default_sort_by =
 304             C4::Context->preference('defaultSortField') . '_'
 305           . C4::Context->preference('defaultSortOrder');
 306         $template->param( sort_by => $default_sort_by  );
 307     }
 308
 309     # determine what to display next to the search boxes (ie, boolean option
 310     # shouldn't appear on the first one, scan indexes should, adding a new
 311     # box should only appear on the last, etc.
 312     my @search_boxes_array;
 313     my $search_boxes_count = 3; # begin with 3 boxes
 314     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 315     for (my $i=1;$i<=$search_boxes_count;$i++) {
 316         # if it's the first one, don't display boolean option, but show scan indexes
 317         if ($i==1) {
 318             push @search_boxes_array, {scan_index => 1};
 319         }
 320         # if it's the last one, show the 'add field' box
 321         elsif ($i==$search_boxes_count) {
 322             push @search_boxes_array,
 323                 {
 324                 boolean => 1,
 325                 add_field => 1,
 326                 };
 327         }
 328         else {
 329             push @search_boxes_array,
 330                 {
 331                 boolean => 1,
 332                 };
 333         }
 334
 335     }
 336     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 337                       search_boxes_loop => \@search_boxes_array);
 338
 339     # load the language limits (for search)
 340     my $languages_limit_loop = getLanguages($lang, 1);
 341     $template->param(search_languages_loop => $languages_limit_loop,);
 342
 343     # Expanded search options in advanced search:
 344     # use the global setting by default, but let the user override it
 345     {
 346         my $expanded = $cgi->param('expanded_options');
 347         $expanded = C4::Context->preference("expandedSearchOption") || 0
 348             if !defined($expanded) || $expanded !~ /^0|1$/;
 349         $template->param( expanded_options => $expanded );
 350     }
 351
 352     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 353
 354     output_html_with_http_headers $cgi, $cookie, $template->output;
 355     exit;
 356 }
 357
 358 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 359
 360 # Fetch the paramater list as a hash in scalar context:
 361 #  * returns paramater list as tied hash ref
 362 #  * we can edit the values by changing the key
 363 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 364 my $params = $cgi->Vars;
 365 # Params that can have more than one value
 366 # sort by is used to sort the query
 367 # in theory can have more than one but generally there's just one
 368 my @sort_by;
 369 my $default_sort_by;
 370 if (   C4::Context->preference('defaultSortField')
 371     && C4::Context->preference('defaultSortOrder') ) {
 372     $default_sort_by =
 373         C4::Context->preference('defaultSortField') . '_'
 374       . C4::Context->preference('defaultSortOrder');
 375 }
 376
 377 @sort_by = $cgi->multi_param('sort_by');
 378 $sort_by[0] = $default_sort_by unless $sort_by[0];
 379 foreach my $sort (@sort_by) {
 380     $template->param($sort => 1) if $sort;
 381 }
 382 $template->param('sort_by' => $sort_by[0]);
 383
 384 # Use the servers defined, or just search our local catalog(default)
 385 my @servers = $cgi->multi_param('server');
 386 unless (@servers) {
 387     #FIXME: this should be handled using Context.pm
 388     @servers = ("biblioserver");
 389     # @servers = C4::Context->config("biblioserver");
 390 }
 391 # operators include boolean and proximity operators and are used
 392 # to evaluate multiple operands
 393 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 394
 395 # indexes are query qualifiers, like 'title', 'author', etc. They
 396 # can be single or multiple parameters separated by comma: kw,right-Truncation
 397 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 398
 399 # if a simple index (only one)  display the index used in the top search box
 400 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 401     my $idx = "ms_".$indexes[0];
 402     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 403     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 404     $template->param($idx => 1);
 405 }
 406
 407 # an operand can be a single term, a phrase, or a complete ccl query
 408 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 409
 410 # if a simple search, display the value in the search box
 411 if ($operands[0] && !$operands[1]) {
 412     my $ms_query = $operands[0];
 413     $ms_query =~ s/ #\S+//;
 414     $template->param(ms_value => $ms_query);
 415 }
 416
 417 # limits are use to limit to results to a pre-defined category such as branch or language
 418 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 419 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 420 my %is_nolimit = map { $_ => 1 } @nolimits;
 421 @limits = grep { not $is_nolimit{$_} } @limits;
 422
 423 if($params->{'multibranchlimit'}) {
 424     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 425     my @libraries = $search_group->all_libraries;
 426     my $multibranch = '('.join( " OR ", map { '(homebranch: ' . $_->branchcode .')' } @libraries ) .')';
 427     push @limits, $multibranch if ($multibranch ne  '()');
 428 }
 429
 430 my $available;
 431 foreach my $limit(@limits) {
 432     if ($limit =~/available/) {
 433         $available = 1;
 434     }
 435 }
 436 $template->param(available => $available);
 437
 438 # append year limits if they exist
 439 my $limit_yr;
 440 my $limit_yr_value;
 441 if ($params->{'limit-yr'}) {
 442     if ($params->{'limit-yr'} =~ /\d{4}/) {
 443         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 444         $limit_yr_value = $params->{'limit-yr'};
 445     }
 446     push @limits,$limit_yr;
 447     #FIXME: Should return a error to the user, incorect date format specified
 448 }
 449
 450 # convert indexes and operands to corresponding parameter names for the z3950 search
 451 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 452 my $z3950par;
 453 my $indexes2z3950 = {
 454     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 455     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 456     ti=>'title', 'ti,phr'=>'title', se=>'title'
 457 };
 458 for (my $ii = 0; $ii < @operands; ++$ii)
 459 {
 460     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 461     if (defined $name && defined $operands[$ii])
 462     {
 463         $z3950par ||= {};
 464         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 465     }
 466 }
 467
 468
 469 # Params that can only have one value
 470 my $scan = $params->{'scan'};
 471 my $count = C4::Context->preference('numSearchResults') || 20;
 472 my $results_per_page = $params->{'count'} || $count;
 473 my $offset = $params->{'offset'} || 0;
 474 my $whole_record = $params->{'whole_record'} || 0;
 475 $offset = 0 if $offset < 0;
 476 my $page = $cgi->param('page') || 1;
 477 #my $offset = ($page-1)*$results_per_page;
 478
 479 # Define some global variables
 480 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 481
 482 my $builder = Koha::SearchEngine::QueryBuilder->new(
 483     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 484 my $searcher = Koha::SearchEngine::Search->new(
 485     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 486
 487 ## I. BUILD THE QUERY
 488 (
 489     $error,             $query, $simple_query, $query_cgi,
 490     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 491     $query_type
 492   )
 493   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 494     \@sort_by, $scan, $lang, { weighted_fields => !$cgi->param('advsearch'), whole_record => $whole_record });
 495
 496 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 497
 498 ## parse the query_cgi string and put it into a form suitable for <input>s
 499 my @query_inputs;
 500 my $scan_index_to_use;
 501 my $scan_search_term_to_use;
 502
 503 if ($query_cgi) {
 504     for my $this_cgi ( split('&', $query_cgi) ) {
 505         next unless $this_cgi;
 506         $this_cgi =~ m/(.*?)=(.*)/;
 507         my $input_name = $1;
 508         my $input_value = $2;
 509         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 510         if ($input_name eq 'idx') {
 511             # The form contains multiple fields, so take the first value as the scan index
 512             $scan_index_to_use = $input_value unless $scan_index_to_use;
 513         }
 514         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 515             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 516         }
 517     }
 518 }
 519
 520 $template->param ( QUERY_INPUTS => \@query_inputs,
 521                    scan_index_to_use => $scan_index_to_use,
 522                    scan_search_term_to_use => $scan_search_term_to_use );
 523
 524 ## parse the limit_cgi string and put it into a form suitable for <input>s
 525 my @limit_inputs;
 526 if ($limit_cgi) {
 527     for my $this_cgi ( split('&', $limit_cgi) ) {
 528         next unless $this_cgi;
 529         # handle special case limit-yr
 530         if ($this_cgi =~ /yr,st-numeric/) {
 531             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 532             next;
 533         }
 534         $this_cgi =~ m/(.*=)(.*)/;
 535         my $input_name = $1;
 536         my $input_value = $2;
 537         $input_name =~ s/=$//;
 538         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 539     }
 540 }
 541 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 542
 543 ## II. DO THE SEARCH AND GET THE RESULTS
 544 my $total = 0; # the total results for the whole set
 545 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 546 my $results_hashref;
 547
 548 eval {
 549     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 550     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 551         $query,            $simple_query, \@sort_by,       \@servers,
 552         $results_per_page, $offset,       undef,           $itemtypes,
 553         $query_type,       $scan
 554     );
 555 };
 556
 557 if ($@ || $error) {
 558     $template->param(query_error => $error.$@);
 559     output_html_with_http_headers $cgi, $cookie, $template->output;
 560     exit;
 561 }
 562
 563 # At this point, each server has given us a result set
 564 # now we build that set for template display
 565 my @sup_results_array;
 566 for (my $i=0;$i<@servers;$i++) {
 567     my $server = $servers[$i];
 568     if ($server =~/biblioserver/) { # this is the local bibliographic server
 569         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 570         my $page = $cgi->param('page') || 0;
 571         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 572                                        $results_hashref->{$server}->{"RECORDS"});
 573         $total = $total + $hits;
 574
 575         # Search history
 576         if (C4::Context->preference('EnableSearchHistory')) {
 577             unless ( $offset ) {
 578                 my $path_info = $cgi->url(-path_info=>1);
 579                 my $query_cgi_history = $cgi->url(-query=>1);
 580                 $query_cgi_history =~ s/^$path_info\?//;
 581                 $query_cgi_history =~ s/;/&/g;
 582                 my $query_desc_history = $query_desc;
 583                 $query_desc_history .= ", $limit_desc"
 584                     if $limit_desc;
 585
 586                 C4::Search::History::add({
 587                     userid => $borrowernumber,
 588                     sessionid => $cgi->cookie("CGISESSID"),
 589                     query_desc => $query_desc_history,
 590                     query_cgi => $query_cgi_history,
 591                     total => $total,
 592                     type => "biblio",
 593                 });
 594             }
 595             $template->param( EnableSearchHistory => 1 );
 596         }
 597
 598         ## If there's just one result, redirect to the detail page unless doing an index scan
 599         if ($total == 1 && !$scan) {
 600             my $biblionumber = $newresults[0]->{biblionumber};
 601             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 602             my $views = { C4::Search::enabled_staff_search_views };
 603             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 604                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 605             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 606                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 607             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 608                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 609             } else {
 610                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 611             }
 612             exit;
 613         }
 614
 615         # set up parameters if user wishes to re-run the search
 616         # as a Z39.50 search
 617         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 618
 619         if ($hits) {
 620             $template->param(total => $hits);
 621             if ($limit_cgi) {
 622                 my $limit_cgi_not_availablity = $limit_cgi;
 623                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 624                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 625             }
 626             $template->param(limit_cgi => $limit_cgi);
 627             $template->param(query_cgi => $query_cgi);
 628             $template->param(query_desc => $query_desc);
 629             $template->param(limit_desc => $limit_desc);
 630             $template->param(offset     => $offset);
 631             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 632             if ($query_desc || $limit_desc) {
 633                 $template->param(searchdesc => 1);
 634             }
 635             $template->param(results_per_page =>  $results_per_page);
 636             # must define a value for size if not present in DB
 637             # in order to avoid problems generated by the default size value in TT
 638             foreach my $line (@newresults) {
 639                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 640                 # while we're checking each line, see if item is in the cart
 641                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 642                     $line->{'incart'} = 1;
 643                 }
 644             }
 645             $template->param(SEARCH_RESULTS => \@newresults);
 646             ## FIXME: add a global function for this, it's better than the current global one
 647             ## Build the page numbers on the bottom of the page
 648             my @page_numbers;
 649             my $max_result_window = $searcher->max_result_window;
 650             my $hits_to_paginate = ($max_result_window && $max_result_window < $hits) ? $max_result_window : $hits;
 651             $template->param( hits_to_paginate => $hits_to_paginate );
 652             # total number of pages there will be
 653             my $pages = ceil($hits_to_paginate / $results_per_page);
 654             my $last_page_offset = ( $pages -1 ) * $results_per_page;
 655             # default page number
 656             my $current_page_number = 1;
 657             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 658             my $previous_page_offset;
 659             if ( $offset >= $results_per_page ) {
 660                 $previous_page_offset = $offset - $results_per_page;
 661             }
 662             my $next_page_offset = $offset + $results_per_page;
 663             # If we're within the first 10 pages, keep it simple
 664             #warn "current page:".$current_page_number;
 665             if ($current_page_number < 10) {
 666                 # just show the first 10 pages
 667                 # Loop through the pages
 668                 my $pages_to_show = 10;
 669                 $pages_to_show = $pages if $pages<10;
 670                 for (my $i=1; $i<=$pages_to_show;$i++) {
 671                     # the offset for this page
 672                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 673                     # the page number for this page
 674                     my $this_page_number = $i;
 675                     # put it in the array
 676                     push @page_numbers,
 677                       { offset    => $this_offset,
 678                         pg        => $this_page_number,
 679                         # it should only be highlighted if it's the current page
 680                         highlight => $this_page_number == $current_page_number,
 681                         sort_by   => join ' ', @sort_by
 682                       };
 683
 684                 }
 685
 686             }
 687
 688             # now, show twenty pages, with the current one smack in the middle
 689             else {
 690                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 691                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 692                     my $this_page_number = $i-9;
 693                     if ( $this_page_number <= $pages ) {
 694                         push @page_numbers,
 695                           { offset    => $this_offset,
 696                             pg        => $this_page_number,
 697                             highlight => $this_page_number == $current_page_number,
 698                             sort_by   => join ' ', @sort_by
 699                           };
 700                     }
 701                 }
 702             }
 703             # FIXME: no previous_page_offset when pages < 2
 704             $template->param(   PAGE_NUMBERS => \@page_numbers,
 705                                 last_page_offset => $last_page_offset,
 706                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 707             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 708         }
 709
 710
 711         # no hits
 712         else {
 713             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 714         }
 715
 716     } # end of the if local
 717
 718     # asynchronously search the authority server
 719     elsif ($server =~/authorityserver/) { # this is the local authority server
 720         my @inner_sup_results_array;
 721         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 722             my $marc_record_object = C4::Search::new_record_from_zebra(
 723                 'authorityserver',
 724                 $sup_record
 725             );
 726             # warn "Authority Found: ".$marc_record_object->as_formatted();
 727             push @inner_sup_results_array, {
 728                 'title' => $marc_record_object->field(100)->subfield('a'),
 729                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 730             };
 731         }
 732         push @sup_results_array, {  servername => $server,
 733                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 734     }
 735     # FIXME: can add support for other targets as needed here
 736     $template->param(           outer_sup_results_loop => \@sup_results_array);
 737 } #/end of the for loop
 738 #$template->param(FEDERATED_RESULTS => \@results_array);
 739
 740 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 741
 742 my $gotonumber = $cgi->param('gotoNumber');
 743 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 744     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 745 }
 746 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 747 my $gotopage = $cgi->param('gotoPage');
 748 $template->{'VARS'}->{'gotoPage'} = $gotopage
 749   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 750
 751 for my $facet ( @$facets ) {
 752     for my $entry ( @{ $facet->{facets} } ) {
 753         my $index = $entry->{type_link_value};
 754         my $value = $entry->{facet_link_value};
 755         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 756     }
 757 }
 758
 759 $template->param(
 760             #classlist => $classlist,
 761             total => $total,
 762             opacfacets => 1,
 763             facets_loop => $facets,
 764             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 765             scan => $scan,
 766             search_error => $error,
 767 );
 768
 769 if ($query_desc || $limit_desc) {
 770     $template->param(searchdesc => 1);
 771 }
 772
 773 # VI. BUILD THE TEMPLATE
 774
 775 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 776     {
 777         borrowernumber => $borrowernumber,
 778         add_allowed    => 1,
 779         category       => 1,
 780     }
 781 );
 782 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 783     {
 784         borrowernumber => $borrowernumber,
 785         add_allowed    => 1,
 786         category       => 2,
 787     }
 788 );
 789
 790
 791 $template->param(
 792     add_to_some_private_shelves => $some_private_shelves,
 793     add_to_some_public_shelves  => $some_public_shelves,
 794 );
 795
 796 output_html_with_http_headers $cgi, $cookie, $template->output;
 797
 798
 799 =head2 prepare_adv_search_types
 800
 801     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 802     my @advanced_search_types = prepare_adv_search_types($type);
 803
 804 Different types can be searched for in the advanced search. This takes the
 805 system preference that defines these types and parses it into an arrayref for
 806 the template.
 807
 808 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 809 It also accounts for the "item-level_itypes" system preference.
 810
 811 =cut
 812
 813 sub prepare_adv_search_types {
 814     my ($types) = @_;
 815
 816     my @advanced_search_types = split( /\|/, $types );
 817
 818     # the index parameter is different for item-level itemtypes
 819     my $itype_or_itemtype =
 820       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 821     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 822
 823     my ( $cnt, @result );
 824     foreach my $advanced_srch_type (@advanced_search_types) {
 825         $advanced_srch_type =~ s/^\s*//;
 826         $advanced_srch_type =~ s/\s*$//;
 827         if ( $advanced_srch_type eq 'itemtypes' ) {
 828
 829        # itemtype is a special case, since it's not defined in authorized values
 830             my @itypesloop;
 831             foreach my $thisitemtype (
 832                 sort {
 833                     $itemtypes->{$a}->{'translated_description'}
 834                       cmp $itemtypes->{$b}->{'translated_description'}
 835                 } keys %$itemtypes
 836               )
 837             {
 838                 my %row = (
 839                     number      => $cnt++,
 840                     ccl         => "$itype_or_itemtype,phr",
 841                     code        => $thisitemtype,
 842                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 843                     imageurl    => getitemtypeimagelocation(
 844                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 845                     ),
 846                 );
 847                 push @itypesloop, \%row;
 848             }
 849             my %search_code = (
 850                 advanced_search_type => $advanced_srch_type,
 851                 code_loop            => \@itypesloop
 852             );
 853             push @result, \%search_code;
 854         }
 855         else {
 856             # covers all the other cases: non-itemtype authorized values
 857             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 858             my @authvalueloop;
 859             for my $thisitemtype (@$advsearchtypes) {
 860                 my %row = (
 861                     number      => $cnt++,
 862                     ccl         => $advanced_srch_type,
 863                     code        => $thisitemtype->{authorised_value},
 864                     description => $thisitemtype->{'lib'},
 865                     imageurl    => getitemtypeimagelocation(
 866                         'intranet', $thisitemtype->{'imageurl'}
 867                     ),
 868                 );
 869                 push @authvalueloop, \%row;
 870             }
 871             my %search_code = (
 872                 advanced_search_type => $advanced_srch_type,
 873                 code_loop            => \@authvalueloop
 874             );
 875             push @result, \%search_code;
 876         }
 877     }
 878     return \@result;
 879 }