catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     flagsrequired   => { catalogue => 1 },
 186     }
 187 );
 188
 189 my $lang = C4::Languages::getlanguage($cgi);
 190
 191 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 192     $template->param('UNIMARC' => 1);
 193 }
 194
 195 if($cgi->cookie("holdfor")){
 196     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 197     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 198         $template->param(
 199             holdfor => $cgi->cookie("holdfor"),
 200             holdfor_surname => $holdfor_patron->surname,
 201             holdfor_firstname => $holdfor_patron->firstname,
 202             holdfor_cardnumber => $holdfor_patron->cardnumber,
 203         );
 204     }
 205 }
 206
 207 if($cgi->cookie("holdforclub")){
 208     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 209     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 210         $template->param(
 211             holdforclub => $cgi->cookie("holdforclub"),
 212             holdforclub_name => $holdfor_club->name,
 213         );
 214     }
 215 }
 216
 217 if($cgi->cookie("searchToOrder")){
 218     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 219     $template->param(
 220         searchtoorder_basketno => $basketno,
 221         searchtoorder_vendorid => $vendorid
 222     );
 223 }
 224
 225 # get biblionumbers stored in the cart
 226 my @cart_list;
 227
 228 if($cgi->cookie("intranet_bib_list")){
 229     my $cart_list = $cgi->cookie("intranet_bib_list");
 230     @cart_list = split(/\//, $cart_list);
 231 }
 232
 233 my @search_groups =
 234   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 235 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 236
 237 $template->param(
 238     search_groups    => \@search_groups,
 239 );
 240
 241 # load the Type stuff
 242 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 243 my $advancedsearchesloop = prepare_adv_search_types($types);
 244 $template->param(advancedsearchesloop => $advancedsearchesloop);
 245
 246 $template->param( searchid => scalar $cgi->param('searchid'), );
 247
 248 # The following should only be loaded if we're bringing up the advanced search template
 249 if ( $template_type eq 'advsearch' ) {
 250
 251     # load the servers (used for searching -- to do federated searching, etc.)
 252     my $primary_servers_loop;# = displayPrimaryServers();
 253     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 254
 255     my $secondary_servers_loop;
 256     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 257
 258     # set the default sorting
 259     if (   C4::Context->preference('defaultSortField')
 260         && C4::Context->preference('defaultSortOrder') ) {
 261         my $default_sort_by =
 262             C4::Context->preference('defaultSortField') . '_'
 263           . C4::Context->preference('defaultSortOrder');
 264         $template->param( sort_by => $default_sort_by  );
 265     }
 266
 267     # determine what to display next to the search boxes (ie, boolean option
 268     # shouldn't appear on the first one, scan indexes should, adding a new
 269     # box should only appear on the last, etc.
 270     my @search_boxes_array;
 271     my $search_boxes_count = 3; # begin with 3 boxes
 272     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 273     for (my $i=1;$i<=$search_boxes_count;$i++) {
 274         # if it's the first one, don't display boolean option, but show scan indexes
 275         if ($i==1) {
 276             push @search_boxes_array, {scan_index => 1};
 277         }
 278         # if it's the last one, show the 'add field' box
 279         elsif ($i==$search_boxes_count) {
 280             push @search_boxes_array,
 281                 {
 282                 boolean => 1,
 283                 add_field => 1,
 284                 };
 285         }
 286         else {
 287             push @search_boxes_array,
 288                 {
 289                 boolean => 1,
 290                 };
 291         }
 292
 293     }
 294     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 295                       search_boxes_loop => \@search_boxes_array);
 296
 297     # load the language limits (for search)
 298     my $languages_limit_loop = getLanguages($lang, 1);
 299     $template->param(search_languages_loop => $languages_limit_loop,);
 300
 301     # Expanded search options in advanced search:
 302     # use the global setting by default, but let the user override it
 303     {
 304         my $expanded = $cgi->param('expanded_options');
 305         $expanded = C4::Context->preference("expandedSearchOption") || 0
 306             if !defined($expanded) || $expanded !~ /^0|1$/;
 307         $template->param( expanded_options => $expanded );
 308     }
 309
 310     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 311
 312     output_html_with_http_headers $cgi, $cookie, $template->output;
 313     exit;
 314 }
 315
 316 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 317
 318 # Fetch the paramater list as a hash in scalar context:
 319 #  * returns paramater list as tied hash ref
 320 #  * we can edit the values by changing the key
 321 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 322 my $params = $cgi->Vars;
 323 # Params that can have more than one value
 324 # sort by is used to sort the query
 325 # in theory can have more than one but generally there's just one
 326 my @sort_by;
 327 my $default_sort_by;
 328 if (   C4::Context->preference('defaultSortField')
 329     && C4::Context->preference('defaultSortOrder') ) {
 330     $default_sort_by =
 331         C4::Context->preference('defaultSortField') . '_'
 332       . C4::Context->preference('defaultSortOrder');
 333 }
 334
 335 @sort_by = $cgi->multi_param('sort_by');
 336 $sort_by[0] = $default_sort_by unless $sort_by[0];
 337 foreach my $sort (@sort_by) {
 338     $template->param($sort => 1) if $sort;
 339 }
 340 $template->param('sort_by' => $sort_by[0]);
 341
 342 # Use the servers defined, or just search our local catalog(default)
 343 my @servers = $cgi->multi_param('server');
 344 unless (@servers) {
 345     #FIXME: this should be handled using Context.pm
 346     @servers = ("biblioserver");
 347     # @servers = C4::Context->config("biblioserver");
 348 }
 349 # operators include boolean and proximity operators and are used
 350 # to evaluate multiple operands
 351 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 352
 353 # indexes are query qualifiers, like 'title', 'author', etc. They
 354 # can be single or multiple parameters separated by comma: kw,right-Truncation
 355 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 356
 357 # if a simple index (only one)  display the index used in the top search box
 358 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 359     my $idx = "ms_".$indexes[0];
 360     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 361     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 362     $template->param($idx => 1);
 363 }
 364
 365 # an operand can be a single term, a phrase, or a complete ccl query
 366 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 367
 368 # if a simple search, display the value in the search box
 369 if ($operands[0] && !$operands[1]) {
 370     my $ms_query = $operands[0];
 371     $ms_query =~ s/ #\S+//;
 372     $template->param(ms_value => $ms_query);
 373 }
 374
 375 # limits are use to limit to results to a pre-defined category such as branch or language
 376 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 377 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 378 my %is_nolimit = map { $_ => 1 } @nolimits;
 379 @limits = grep { not $is_nolimit{$_} } @limits;
 380
 381 if ( $params->{'multibranchlimit'} ) {
 382     my $branchfield  = C4::Context->preference('SearchLimitLibrary');
 383     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 384     my @branchcodes  = map { $_->branchcode } $search_group->all_libraries;
 385
 386     if (@branchcodes) {
 387         if ( $branchfield eq "homebranch" ) {
 388             push @limits, sprintf "(%s)", join " or ", map { 'homebranch: ' . $_ } @branchcodes;
 389         }
 390         elsif ( $branchfield eq "holdingbranch" ) {
 391             push @limits, sprintf "(%s)", join " or ", map { 'holdingbranch: ' . $_ } @branchcodes;
 392         }
 393         else {
 394             push @limits, sprintf "(%s or %s)",
 395               join( " or ", map { 'homebranch: ' . $_ } @branchcodes ),
 396               join( " or ", map { 'holdingbranch: ' . $_ } @branchcodes );
 397         }
 398     }
 399 }
 400
 401 for ( my $i=0; $i<@limits; $i++ ) {
 402     if ( $limits[$i] =~ /^branch:/ ) {
 403         my $branchfield  = C4::Context->preference('SearchLimitLibrary');
 404         if ( $branchfield eq "homebranch" ) {
 405             $limits[$i] =~ s/branch/homebranch/;
 406         }
 407         elsif ( $branchfield eq "holdingbranch" ) {
 408             $limits[$i] =~ s/branch/holdingbranch/;
 409         }
 410         else {
 411             my $homebranchlimit = $limits[$i];
 412             my $holdingbranchlimit = $limits[$i];
 413             $homebranchlimit =~ s/branch/homebranch/;
 414             $holdingbranchlimit =~ s/branch/holdingbranch/;
 415             $limits[$i] = "($homebranchlimit or $holdingbranchlimit)";
 416         }
 417     }
 418 }
 419
 420 my $available;
 421 foreach my $limit(@limits) {
 422     if ($limit =~/available/) {
 423         $available = 1;
 424     }
 425 }
 426 $template->param(available => $available);
 427
 428 # append year limits if they exist
 429 my $limit_yr;
 430 my $limit_yr_value;
 431 if ($params->{'limit-yr'}) {
 432     if ($params->{'limit-yr'} =~ /\d{4}/) {
 433         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 434         $limit_yr_value = $params->{'limit-yr'};
 435     }
 436     push @limits,$limit_yr;
 437     #FIXME: Should return a error to the user, incorect date format specified
 438 }
 439
 440 # convert indexes and operands to corresponding parameter names for the z3950 search
 441 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 442 my $z3950par;
 443 my $indexes2z3950 = {
 444     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 445     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 446     ti=>'title', 'ti,phr'=>'title', se=>'title'
 447 };
 448 for (my $ii = 0; $ii < @operands; ++$ii)
 449 {
 450     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 451     if (defined $name && defined $operands[$ii])
 452     {
 453         $z3950par ||= {};
 454         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 455     }
 456 }
 457
 458
 459 # Params that can only have one value
 460 my $scan = $params->{'scan'};
 461 my $count = C4::Context->preference('numSearchResults') || 20;
 462 my $results_per_page = $params->{'count'} || $count;
 463 my $offset = $params->{'offset'} || 0;
 464 my $whole_record = $params->{'whole_record'} || 0;
 465 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 466 $offset = 0 if $offset < 0;
 467 my $page = $cgi->param('page') || 1;
 468 #my $offset = ($page-1)*$results_per_page;
 469
 470 # Define some global variables
 471 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 472
 473 my $builder = Koha::SearchEngine::QueryBuilder->new(
 474     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 475 my $searcher = Koha::SearchEngine::Search->new(
 476     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 477
 478 ## I. BUILD THE QUERY
 479 (
 480     $error,             $query, $simple_query, $query_cgi,
 481     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 482     $query_type
 483   )
 484   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 485     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 486
 487 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 488
 489 ## parse the query_cgi string and put it into a form suitable for <input>s
 490 my @query_inputs;
 491 my $scan_index_to_use;
 492 my $scan_search_term_to_use;
 493
 494 if ($query_cgi) {
 495     for my $this_cgi ( split('&', $query_cgi) ) {
 496         next unless $this_cgi;
 497         $this_cgi =~ m/(.*?)=(.*)/;
 498         my $input_name = $1;
 499         my $input_value = $2;
 500         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 501         if ($input_name eq 'idx') {
 502             # The form contains multiple fields, so take the first value as the scan index
 503             $scan_index_to_use = $input_value unless $scan_index_to_use;
 504         }
 505         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 506             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 507         }
 508     }
 509 }
 510
 511 $template->param ( QUERY_INPUTS => \@query_inputs,
 512                    scan_index_to_use => $scan_index_to_use,
 513                    scan_search_term_to_use => $scan_search_term_to_use );
 514
 515 ## parse the limit_cgi string and put it into a form suitable for <input>s
 516 my @limit_inputs;
 517 if ($limit_cgi) {
 518     for my $this_cgi ( split('&', $limit_cgi) ) {
 519         next unless $this_cgi;
 520         # handle special case limit-yr
 521         if ($this_cgi =~ /yr,st-numeric/) {
 522             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 523             next;
 524         }
 525         $this_cgi =~ m/(.*=)(.*)/;
 526         my $input_name = $1;
 527         my $input_value = $2;
 528         $input_name =~ s/=$//;
 529         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 530     }
 531 }
 532 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 533
 534 ## II. DO THE SEARCH AND GET THE RESULTS
 535 my $total = 0; # the total results for the whole set
 536 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 537 my $results_hashref;
 538
 539 eval {
 540     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 541     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 542         $query,            $simple_query, \@sort_by,       \@servers,
 543         $results_per_page, $offset,       undef,           $itemtypes,
 544         $query_type,       $scan
 545     );
 546 };
 547
 548 if ($@ || $error) {
 549     $template->param(query_error => $error.$@);
 550     output_html_with_http_headers $cgi, $cookie, $template->output;
 551     exit;
 552 }
 553
 554 # At this point, each server has given us a result set
 555 # now we build that set for template display
 556 my @sup_results_array;
 557 for (my $i=0;$i<@servers;$i++) {
 558     my $server = $servers[$i];
 559     if ($server =~/biblioserver/) { # this is the local bibliographic server
 560         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 561         my $page = $cgi->param('page') || 0;
 562         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 563                                        $results_hashref->{$server}->{"RECORDS"});
 564         $total = $total + $hits;
 565
 566         # Search history
 567         if (C4::Context->preference('EnableSearchHistory')) {
 568             unless ( $offset ) {
 569                 my $path_info = $cgi->url(-path_info=>1);
 570                 my $query_cgi_history = $cgi->url(-query=>1);
 571                 $query_cgi_history =~ s/^$path_info\?//;
 572                 $query_cgi_history =~ s/;/&/g;
 573                 my $query_desc_history = $query_desc;
 574                 $query_desc_history .= ", $limit_desc"
 575                     if $limit_desc;
 576
 577                 C4::Search::History::add({
 578                     userid => $borrowernumber,
 579                     sessionid => $cgi->cookie("CGISESSID"),
 580                     query_desc => $query_desc_history,
 581                     query_cgi => $query_cgi_history,
 582                     total => $total,
 583                     type => "biblio",
 584                 });
 585             }
 586             $template->param( EnableSearchHistory => 1 );
 587         }
 588
 589         ## If there's just one result, redirect to the detail page unless doing an index scan
 590         if ($total == 1 && !$scan) {
 591             my $biblionumber = $newresults[0]->{biblionumber};
 592             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 593             my $views = { C4::Search::enabled_staff_search_views };
 594             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 595                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 596             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 597                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 598             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 599                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 600             } else {
 601                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 602             }
 603             exit;
 604         }
 605
 606         # set up parameters if user wishes to re-run the search
 607         # as a Z39.50 search
 608         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 609
 610         if ($hits) {
 611             $template->param(total => $hits);
 612             if ($limit_cgi) {
 613                 my $limit_cgi_not_availablity = $limit_cgi;
 614                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 615                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 616             }
 617             $template->param(limit_cgi => $limit_cgi);
 618             $template->param(query_cgi => $query_cgi);
 619             $template->param(query_desc => $query_desc);
 620             $template->param(limit_desc => $limit_desc);
 621             $template->param(offset     => $offset);
 622             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 623             if ($query_desc || $limit_desc) {
 624                 $template->param(searchdesc => 1);
 625             }
 626             $template->param(results_per_page =>  $results_per_page);
 627             # must define a value for size if not present in DB
 628             # in order to avoid problems generated by the default size value in TT
 629             foreach my $line (@newresults) {
 630                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 631                 # while we're checking each line, see if item is in the cart
 632                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 633                     $line->{'incart'} = 1;
 634                 }
 635             }
 636             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 637                 Koha::SearchEngine::Search->pagination_bar(
 638                     {
 639                         hits              => $hits,
 640                         max_result_window => $searcher->max_result_window,
 641                         results_per_page  => $results_per_page,
 642                         offset            => $offset,
 643                         sort_by           => \@sort_by
 644                     }
 645                 );
 646             $template->param( hits_to_paginate => $hits_to_paginate );
 647             $template->param(SEARCH_RESULTS => \@newresults);
 648             # FIXME: no previous_page_offset when pages < 2
 649             $template->param(   PAGE_NUMBERS => $page_numbers,
 650                                 last_page_offset => $last_page_offset,
 651                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 652             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 653         }
 654
 655
 656         # no hits
 657         else {
 658             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 659         }
 660
 661     } # end of the if local
 662
 663     # asynchronously search the authority server
 664     elsif ($server =~/authorityserver/) { # this is the local authority server
 665         my @inner_sup_results_array;
 666         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 667             my $marc_record_object = C4::Search::new_record_from_zebra(
 668                 'authorityserver',
 669                 $sup_record
 670             );
 671             # warn "Authority Found: ".$marc_record_object->as_formatted();
 672             push @inner_sup_results_array, {
 673                 'title' => $marc_record_object->field(100)->subfield('a'),
 674                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 675             };
 676         }
 677         push @sup_results_array, {  servername => $server,
 678                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 679     }
 680     # FIXME: can add support for other targets as needed here
 681     $template->param(           outer_sup_results_loop => \@sup_results_array);
 682 } #/end of the for loop
 683 #$template->param(FEDERATED_RESULTS => \@results_array);
 684
 685 my $gotonumber = $cgi->param('gotoNumber');
 686 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 687     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 688 }
 689 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 690 my $gotopage = $cgi->param('gotoPage');
 691 $template->{'VARS'}->{'gotoPage'} = $gotopage
 692   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 693
 694 for my $facet ( @$facets ) {
 695     for my $entry ( @{ $facet->{facets} } ) {
 696         my $index = $entry->{type_link_value};
 697         my $value = $entry->{facet_link_value};
 698         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 699     }
 700 }
 701
 702 $template->param(
 703             #classlist => $classlist,
 704             total => $total,
 705             opacfacets => 1,
 706             facets_loop => $facets,
 707             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 708             scan => $scan,
 709             search_error => $error,
 710 );
 711
 712 if ($query_desc || $limit_desc) {
 713     $template->param(searchdesc => 1);
 714 }
 715
 716 # VI. BUILD THE TEMPLATE
 717
 718 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 719     {
 720         borrowernumber => $borrowernumber,
 721         add_allowed    => 1,
 722         category       => 1,
 723     }
 724 );
 725 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 726     {
 727         borrowernumber => $borrowernumber,
 728         add_allowed    => 1,
 729         category       => 2,
 730     }
 731 );
 732
 733
 734 $template->param(
 735     add_to_some_private_shelves => $some_private_shelves,
 736     add_to_some_public_shelves  => $some_public_shelves,
 737 );
 738
 739 output_html_with_http_headers $cgi, $cookie, $template->output;
 740
 741
 742 =head2 prepare_adv_search_types
 743
 744     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 745     my @advanced_search_types = prepare_adv_search_types($type);
 746
 747 Different types can be searched for in the advanced search. This takes the
 748 system preference that defines these types and parses it into an arrayref for
 749 the template.
 750
 751 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 752 It also accounts for the "item-level_itypes" system preference.
 753
 754 =cut
 755
 756 sub prepare_adv_search_types {
 757     my ($types) = @_;
 758
 759     my @advanced_search_types = split( /\|/, $types );
 760
 761     # the index parameter is different for item-level itemtypes
 762     my $itype_or_itemtype =
 763       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 764     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 765
 766     my ( $cnt, @result );
 767     foreach my $advanced_srch_type (@advanced_search_types) {
 768         $advanced_srch_type =~ s/^\s*//;
 769         $advanced_srch_type =~ s/\s*$//;
 770         if ( $advanced_srch_type eq 'itemtypes' ) {
 771
 772        # itemtype is a special case, since it's not defined in authorized values
 773             my @itypesloop;
 774             foreach my $thisitemtype (
 775                 sort {
 776                     $itemtypes->{$a}->{'translated_description'}
 777                       cmp $itemtypes->{$b}->{'translated_description'}
 778                 } keys %$itemtypes
 779               )
 780             {
 781                 my %row = (
 782                     number      => $cnt++,
 783                     ccl         => "$itype_or_itemtype,phr",
 784                     code        => $thisitemtype,
 785                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 786                     imageurl    => getitemtypeimagelocation(
 787                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 788                     ),
 789                 );
 790                 push @itypesloop, \%row;
 791             }
 792             my %search_code = (
 793                 advanced_search_type => $advanced_srch_type,
 794                 code_loop            => \@itypesloop
 795             );
 796             push @result, \%search_code;
 797         }
 798         else {
 799             # covers all the other cases: non-itemtype authorized values
 800             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 801             my @authvalueloop;
 802             for my $thisitemtype (@$advsearchtypes) {
 803                 my %row = (
 804                     number      => $cnt++,
 805                     ccl         => $advanced_srch_type,
 806                     code        => $thisitemtype->{authorised_value},
 807                     description => $thisitemtype->{'lib'},
 808                     imageurl    => getitemtypeimagelocation(
 809                         'intranet', $thisitemtype->{'imageurl'}
 810                     ),
 811                 );
 812                 push @authvalueloop, \%row;
 813             }
 814             my %search_code = (
 815                 advanced_search_type => $advanced_srch_type,
 816                 code_loop            => \@authvalueloop
 817             );
 818             push @result, \%search_code;
 819         }
 820     }
 821     return \@result;
 822 }