catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 # limits are used to limit to results to a pre-defined category such as branch or language
 172 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 173 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 174 my %is_nolimit = map { $_ => 1 } @nolimits;
 175 @limits = grep { not $is_nolimit{$_} } @limits;
 176 if  (
 177         !$cgi->param('edit_search') &&
 178         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 179     ) {
 180     $template_name = 'catalogue/results.tt';
 181     $template_type = 'results';
 182 }
 183 else {
 184     $template_name = 'catalogue/advsearch.tt';
 185     $template_type = 'advsearch';
 186 }
 187 # load the template
 188 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 189     template_name => $template_name,
 190     query => $cgi,
 191     type => "intranet",
 192     flagsrequired   => { catalogue => 1 },
 193     }
 194 );
 195
 196 my $lang = C4::Languages::getlanguage($cgi);
 197
 198 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 199     $template->param('UNIMARC' => 1);
 200 }
 201
 202 if($cgi->cookie("holdfor")){
 203     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 204     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 205         $template->param(
 206             holdfor => $cgi->cookie("holdfor"),
 207             holdfor_surname => $holdfor_patron->surname,
 208             holdfor_firstname => $holdfor_patron->firstname,
 209             holdfor_cardnumber => $holdfor_patron->cardnumber,
 210         );
 211     }
 212 }
 213
 214 if($cgi->cookie("holdforclub")){
 215     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 216     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 217         $template->param(
 218             holdforclub => $cgi->cookie("holdforclub"),
 219             holdforclub_name => $holdfor_club->name,
 220         );
 221     }
 222 }
 223
 224 if($cgi->cookie("searchToOrder")){
 225     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 226     $template->param(
 227         searchtoorder_basketno => $basketno,
 228         searchtoorder_vendorid => $vendorid
 229     );
 230 }
 231
 232 # get biblionumbers stored in the cart
 233 my @cart_list;
 234
 235 if($cgi->cookie("intranet_bib_list")){
 236     my $cart_list = $cgi->cookie("intranet_bib_list");
 237     @cart_list = split(/\//, $cart_list);
 238 }
 239
 240 my @search_groups =
 241   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 242 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 243
 244 $template->param(
 245     search_groups    => \@search_groups,
 246 );
 247
 248 # load the Type stuff
 249 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 250 my $advancedsearchesloop = prepare_adv_search_types($types);
 251 $template->param(advancedsearchesloop => $advancedsearchesloop);
 252
 253 $template->param( searchid => scalar $cgi->param('searchid'), );
 254
 255 # The following should only be loaded if we're bringing up the advanced search template
 256 if ( $template_type eq 'advsearch' ) {
 257
 258     my $expanded = $cgi->param('expanded_options');
 259     if( $cgi->param('edit_search') ){
 260         my @operators = $cgi->multi_param('op');
 261         my @indexes   = $cgi->multi_param('idx');
 262         my %limit_hash;
 263         foreach my $limit (@limits){
 264             if ( $limit eq 'available' ){
 265                 $template->param( limit_available => 1 );
 266             } else {
 267                 my ($index,$value) = split(':',$limit);
 268                 $value =~ s/"//g;
 269                 if ( $index =~ /mc-/ ){
 270                     $limit_hash{$index . "_" . $value} = 1;
 271                 } else {
 272                     push @{$limit_hash{$index}}, $value;
 273                 }
 274             }
 275         };
 276         $expanded = 1 if scalar @operators || scalar @limits;
 277         $template->param( operators => \@operators );
 278         $template->param( limits => \%limit_hash );
 279         $template->param(
 280            indexes   => \@indexes,
 281            sort      => $cgi->param('sort_by'),
 282         );
 283     }
 284     # load the servers (used for searching -- to do federated searching, etc.)
 285     my $primary_servers_loop;# = displayPrimaryServers();
 286     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 287
 288     my $secondary_servers_loop;
 289     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 290
 291     # set the default sorting
 292     if (   C4::Context->preference('defaultSortField')
 293         && C4::Context->preference('defaultSortOrder') ) {
 294         my $default_sort_by =
 295             C4::Context->preference('defaultSortField') . '_'
 296           . C4::Context->preference('defaultSortOrder');
 297         $template->param( sort_by => $default_sort_by  );
 298     }
 299
 300     # determine what to display next to the search boxes
 301     my @queries = $cgi->multi_param('q');
 302     while( scalar @queries < 3 ){
 303         push @queries, "";
 304     }
 305     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 306
 307     # load the language limits (for search)
 308     my $languages_limit_loop = getLanguages($lang, 1);
 309     $template->param(search_languages_loop => $languages_limit_loop,);
 310     $template->param(       queries   => \@queries );
 311
 312     # Expanded search options in advanced search:
 313     # use the global setting by default, but let the user override it
 314     {
 315         $expanded = C4::Context->preference("expandedSearchOption") || 0
 316             if !defined($expanded) || $expanded !~ /^0|1$/;
 317         $template->param( expanded_options => $expanded );
 318     }
 319
 320     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 321
 322     output_html_with_http_headers $cgi, $cookie, $template->output;
 323     exit;
 324 }
 325
 326 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 327
 328 # Fetch the paramater list as a hash in scalar context:
 329 #  * returns paramater list as tied hash ref
 330 #  * we can edit the values by changing the key
 331 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 332 my $params = $cgi->Vars;
 333 # Params that can have more than one value
 334 # sort by is used to sort the query
 335 # in theory can have more than one but generally there's just one
 336 my @sort_by;
 337 my $default_sort_by;
 338 if (   C4::Context->preference('defaultSortField')
 339     && C4::Context->preference('defaultSortOrder') ) {
 340     $default_sort_by =
 341         C4::Context->preference('defaultSortField') . '_'
 342       . C4::Context->preference('defaultSortOrder');
 343 }
 344
 345 @sort_by = $cgi->multi_param('sort_by');
 346 $sort_by[0] = $default_sort_by unless $sort_by[0];
 347 foreach my $sort (@sort_by) {
 348     $template->param($sort => 1) if $sort;
 349 }
 350 $template->param('sort_by' => $sort_by[0]);
 351
 352 # Use the servers defined, or just search our local catalog(default)
 353 my @servers = $cgi->multi_param('server');
 354 unless (@servers) {
 355     #FIXME: this should be handled using Context.pm
 356     @servers = ("biblioserver");
 357     # @servers = C4::Context->config("biblioserver");
 358 }
 359 # operators include boolean and proximity operators and are used
 360 # to evaluate multiple operands
 361 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 362
 363 # indexes are query qualifiers, like 'title', 'author', etc. They
 364 # can be single or multiple parameters separated by comma: kw,right-Truncation
 365 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 366
 367 # if a simple index (only one)  display the index used in the top search box
 368 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 369     my $idx = "ms_".$indexes[0];
 370     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 371     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 372     $template->param($idx => 1);
 373 }
 374
 375 # an operand can be a single term, a phrase, or a complete ccl query
 376 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 377
 378 # if a simple search, display the value in the search box
 379 if ($operands[0] && !$operands[1]) {
 380     my $ms_query = $operands[0];
 381     $ms_query =~ s/ #\S+//;
 382     $template->param(ms_value => $ms_query);
 383 }
 384
 385 my $available;
 386 foreach my $limit(@limits) {
 387     if ($limit =~/available/) {
 388         $available = 1;
 389     }
 390 }
 391 $template->param(available => $available);
 392
 393 # append year limits if they exist
 394 my $limit_yr;
 395 my $limit_yr_value;
 396 if ($params->{'limit-yr'}) {
 397     if ($params->{'limit-yr'} =~ /\d{4}/) {
 398         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 399         $limit_yr_value = $params->{'limit-yr'};
 400     }
 401     push @limits,$limit_yr;
 402     #FIXME: Should return a error to the user, incorect date format specified
 403 }
 404
 405 # convert indexes and operands to corresponding parameter names for the z3950 search
 406 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 407 my $z3950par;
 408 my $indexes2z3950 = {
 409     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 410     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 411     ti=>'title', 'ti,phr'=>'title', se=>'title'
 412 };
 413 for (my $ii = 0; $ii < @operands; ++$ii)
 414 {
 415     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 416     if (defined $name && defined $operands[$ii])
 417     {
 418         $z3950par ||= {};
 419         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 420     }
 421 }
 422
 423
 424 # Params that can only have one value
 425 my $scan = $params->{'scan'};
 426 my $count = C4::Context->preference('numSearchResults') || 20;
 427 my $results_per_page = $params->{'count'} || $count;
 428 my $offset = $params->{'offset'} || 0;
 429 my $whole_record = $params->{'whole_record'} || 0;
 430 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 431 $offset = 0 if $offset < 0;
 432 my $page = $cgi->param('page') || 1;
 433 #my $offset = ($page-1)*$results_per_page;
 434
 435 # Define some global variables
 436 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 437
 438 my $builder = Koha::SearchEngine::QueryBuilder->new(
 439     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 440 my $searcher = Koha::SearchEngine::Search->new(
 441     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 442
 443 ## I. BUILD THE QUERY
 444 (
 445     $error,             $query, $simple_query, $query_cgi,
 446     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 447     $query_type
 448   )
 449   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 450     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 451
 452 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 453
 454 ## parse the query_cgi string and put it into a form suitable for <input>s
 455 my @query_inputs;
 456 my $scan_index_to_use;
 457 my $scan_search_term_to_use;
 458
 459 if ($query_cgi) {
 460     for my $this_cgi ( split('&', $query_cgi) ) {
 461         next unless $this_cgi;
 462         $this_cgi =~ m/(.*?)=(.*)/;
 463         my $input_name = $1;
 464         my $input_value = $2;
 465         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 466         if ($input_name eq 'idx') {
 467             # The form contains multiple fields, so take the first value as the scan index
 468             $scan_index_to_use = $input_value unless $scan_index_to_use;
 469         }
 470         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 471             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 472         }
 473     }
 474 }
 475
 476 $template->param ( QUERY_INPUTS => \@query_inputs,
 477                    scan_index_to_use => $scan_index_to_use,
 478                    scan_search_term_to_use => $scan_search_term_to_use );
 479
 480 ## parse the limit_cgi string and put it into a form suitable for <input>s
 481 my @limit_inputs;
 482 if ($limit_cgi) {
 483     for my $this_cgi ( split('&', $limit_cgi) ) {
 484         next unless $this_cgi;
 485         # handle special case limit-yr
 486         if ($this_cgi =~ /yr,st-numeric/) {
 487             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 488             next;
 489         }
 490         $this_cgi =~ m/(.*=)(.*)/;
 491         my $input_name = $1;
 492         my $input_value = $2;
 493         $input_name =~ s/=$//;
 494         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 495     }
 496 }
 497 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 498
 499 ## II. DO THE SEARCH AND GET THE RESULTS
 500 my $total = 0; # the total results for the whole set
 501 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 502 my $results_hashref;
 503
 504 eval {
 505     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 506     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 507         $query,            $simple_query, \@sort_by,       \@servers,
 508         $results_per_page, $offset,       undef,           $itemtypes,
 509         $query_type,       $scan
 510     );
 511 };
 512
 513 if ($@ || $error) {
 514     my $query_error = q{};
 515     $query_error .= $error if $error;
 516     $query_error .= $@ if $@;
 517     $template->param(query_error => $query_error);
 518     output_html_with_http_headers $cgi, $cookie, $template->output;
 519     exit;
 520 }
 521
 522 # At this point, each server has given us a result set
 523 # now we build that set for template display
 524 my @sup_results_array;
 525 for (my $i=0;$i<@servers;$i++) {
 526     my $server = $servers[$i];
 527     if ($server =~/biblioserver/) { # this is the local bibliographic server
 528         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 529         my $page = $cgi->param('page') || 0;
 530         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 531                                        $results_hashref->{$server}->{"RECORDS"});
 532         $total = $total + $hits;
 533
 534         # Search history
 535         if (C4::Context->preference('EnableSearchHistory')) {
 536             unless ( $offset ) {
 537                 my $path_info = $cgi->url(-path_info=>1);
 538                 my $query_cgi_history = $cgi->url(-query=>1);
 539                 $query_cgi_history =~ s/^$path_info\?//;
 540                 $query_cgi_history =~ s/;/&/g;
 541                 my $query_desc_history = $query_desc;
 542                 $query_desc_history .= ", $limit_desc"
 543                     if $limit_desc;
 544
 545                 C4::Search::History::add({
 546                     userid => $borrowernumber,
 547                     sessionid => $cgi->cookie("CGISESSID"),
 548                     query_desc => $query_desc_history,
 549                     query_cgi => $query_cgi_history,
 550                     total => $total,
 551                     type => "biblio",
 552                 });
 553             }
 554             $template->param( EnableSearchHistory => 1 );
 555         }
 556
 557         ## If there's just one result, redirect to the detail page unless doing an index scan
 558         if ($total == 1 && !$scan) {
 559             my $biblionumber = $newresults[0]->{biblionumber};
 560             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 561             my $views = { C4::Search::enabled_staff_search_views };
 562             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 563                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 564             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 565                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 566             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 567                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 568             } else {
 569                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 570             }
 571             exit;
 572         }
 573
 574         # set up parameters if user wishes to re-run the search
 575         # as a Z39.50 search
 576         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 577         $template->param(limit_cgi => $limit_cgi);
 578         $template->param(query_cgi => $query_cgi);
 579         $template->param(query_desc => $query_desc);
 580         $template->param(limit_desc => $limit_desc);
 581         $template->param(offset     => $offset);
 582
 583         if ($hits) {
 584             $template->param(total => $hits);
 585             if ($limit_cgi) {
 586                 my $limit_cgi_not_availablity = $limit_cgi;
 587                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 588                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 589             }
 590             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 591             if ($query_desc || $limit_desc) {
 592                 $template->param(searchdesc => 1);
 593             }
 594             $template->param(results_per_page =>  $results_per_page);
 595             # must define a value for size if not present in DB
 596             # in order to avoid problems generated by the default size value in TT
 597             foreach my $line (@newresults) {
 598                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 599                 # while we're checking each line, see if item is in the cart
 600                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 601                     $line->{'incart'} = 1;
 602                 }
 603             }
 604             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 605                 Koha::SearchEngine::Search->pagination_bar(
 606                     {
 607                         hits              => $hits,
 608                         max_result_window => $searcher->max_result_window,
 609                         results_per_page  => $results_per_page,
 610                         offset            => $offset,
 611                         sort_by           => \@sort_by
 612                     }
 613                 );
 614             $template->param( hits_to_paginate => $hits_to_paginate );
 615             $template->param(SEARCH_RESULTS => \@newresults);
 616             # FIXME: no previous_page_offset when pages < 2
 617             $template->param(   PAGE_NUMBERS => $page_numbers,
 618                                 last_page_offset => $last_page_offset,
 619                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 620             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 621         }
 622
 623
 624         # no hits
 625         else {
 626             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 627         }
 628
 629     } # end of the if local
 630
 631     # asynchronously search the authority server
 632     elsif ($server =~/authorityserver/) { # this is the local authority server
 633         my @inner_sup_results_array;
 634         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 635             my $marc_record_object = C4::Search::new_record_from_zebra(
 636                 'authorityserver',
 637                 $sup_record
 638             );
 639             # warn "Authority Found: ".$marc_record_object->as_formatted();
 640             push @inner_sup_results_array, {
 641                 'title' => $marc_record_object->field(100)->subfield('a'),
 642                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 643             };
 644         }
 645         push @sup_results_array, {  servername => $server,
 646                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 647     }
 648     # FIXME: can add support for other targets as needed here
 649     $template->param(           outer_sup_results_loop => \@sup_results_array);
 650 } #/end of the for loop
 651 #$template->param(FEDERATED_RESULTS => \@results_array);
 652
 653 my $gotonumber = $cgi->param('gotoNumber');
 654 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 655     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 656 }
 657 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 658 my $gotopage = $cgi->param('gotoPage');
 659 $template->{'VARS'}->{'gotoPage'} = $gotopage
 660   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 661
 662 for my $facet ( @$facets ) {
 663     for my $entry ( @{ $facet->{facets} } ) {
 664         my $index = $entry->{type_link_value};
 665         my $value = $entry->{facet_link_value};
 666         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 667     }
 668 }
 669
 670 $template->param(
 671             #classlist => $classlist,
 672             total => $total,
 673             opacfacets => 1,
 674             facets_loop => $facets,
 675             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 676             scan => $scan,
 677             search_error => $error,
 678 );
 679
 680 if ($query_desc || $limit_desc) {
 681     $template->param(searchdesc => 1);
 682 }
 683
 684 # VI. BUILD THE TEMPLATE
 685
 686 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 687     {
 688         borrowernumber => $borrowernumber,
 689         add_allowed    => 1,
 690         public         => 0,
 691     }
 692 );
 693 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 694     {
 695         borrowernumber => $borrowernumber,
 696         add_allowed    => 1,
 697         public         => 1,
 698     }
 699 );
 700
 701
 702 $template->param(
 703     add_to_some_private_shelves => $some_private_shelves,
 704     add_to_some_public_shelves  => $some_public_shelves,
 705 );
 706
 707 output_html_with_http_headers $cgi, $cookie, $template->output;
 708
 709
 710 =head2 prepare_adv_search_types
 711
 712     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 713     my @advanced_search_types = prepare_adv_search_types($type);
 714
 715 Different types can be searched for in the advanced search. This takes the
 716 system preference that defines these types and parses it into an arrayref for
 717 the template.
 718
 719 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 720 It also accounts for the "item-level_itypes" system preference.
 721
 722 =cut
 723
 724 sub prepare_adv_search_types {
 725     my ($types) = @_;
 726
 727     my @advanced_search_types = split( /\|/, $types );
 728
 729     # the index parameter is different for item-level itemtypes
 730     my $itype_or_itemtype =
 731       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 732     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 733
 734     my ( $cnt, @result );
 735     foreach my $advanced_srch_type (@advanced_search_types) {
 736         $advanced_srch_type =~ s/^\s*//;
 737         $advanced_srch_type =~ s/\s*$//;
 738         if ( $advanced_srch_type eq 'itemtypes' ) {
 739
 740        # itemtype is a special case, since it's not defined in authorized values
 741             my @itypesloop;
 742             foreach my $thisitemtype (
 743                 sort {
 744                     $itemtypes->{$a}->{'translated_description'}
 745                       cmp $itemtypes->{$b}->{'translated_description'}
 746                 } keys %$itemtypes
 747               )
 748             {
 749                 my %row = (
 750                     number      => $cnt++,
 751                     ccl         => "$itype_or_itemtype,phr",
 752                     code        => $thisitemtype,
 753                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 754                     imageurl    => getitemtypeimagelocation(
 755                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 756                     ),
 757                 );
 758                 push @itypesloop, \%row;
 759             }
 760             my %search_code = (
 761                 advanced_search_type => $advanced_srch_type,
 762                 code_loop            => \@itypesloop
 763             );
 764             push @result, \%search_code;
 765         }
 766         else {
 767             # covers all the other cases: non-itemtype authorized values
 768             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 769             my @authvalueloop;
 770             for my $thisitemtype (@$advsearchtypes) {
 771                 my %row = (
 772                     number      => $cnt++,
 773                     ccl         => $advanced_srch_type,
 774                     code        => $thisitemtype->{authorised_value},
 775                     description => $thisitemtype->{'lib'},
 776                     imageurl    => getitemtypeimagelocation(
 777                         'intranet', $thisitemtype->{'imageurl'}
 778                     ),
 779                 );
 780                 push @authvalueloop, \%row;
 781             }
 782             my %search_code = (
 783                 advanced_search_type => $advanced_srch_type,
 784                 code_loop            => \@authvalueloop
 785             );
 786             push @result, \%search_code;
 787         }
 788     }
 789     return \@result;
 790 }