catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 # limits are used to limit to results to a pre-defined category such as branch or language
 172 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 173 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 174 my %is_nolimit = map { $_ => 1 } @nolimits;
 175 @limits = grep { not $is_nolimit{$_} } @limits;
 176 if  (
 177         !$cgi->param('edit_search') &&
 178         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 179     ) {
 180     $template_name = 'catalogue/results.tt';
 181     $template_type = 'results';
 182 }
 183 else {
 184     $template_name = 'catalogue/advsearch.tt';
 185     $template_type = 'advsearch';
 186 }
 187 # load the template
 188 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 189     template_name => $template_name,
 190     query => $cgi,
 191     type => "intranet",
 192     flagsrequired   => { catalogue => 1 },
 193     }
 194 );
 195
 196 my $lang = C4::Languages::getlanguage($cgi);
 197
 198 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 199     $template->param('UNIMARC' => 1);
 200 }
 201
 202 if($cgi->cookie("holdfor")){
 203     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 204     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 205         $template->param(
 206             holdfor        => $cgi->cookie("holdfor"),
 207             holdfor_patron => $holdfor_patron,
 208         );
 209     }
 210 }
 211
 212 if($cgi->cookie("holdforclub")){
 213     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 214     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 215         $template->param(
 216             holdforclub => $cgi->cookie("holdforclub"),
 217             holdforclub_name => $holdfor_club->name,
 218         );
 219     }
 220 }
 221
 222 if($cgi->cookie("searchToOrder")){
 223     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 224     $template->param(
 225         searchtoorder_basketno => $basketno,
 226         searchtoorder_vendorid => $vendorid
 227     );
 228 }
 229
 230 # get biblionumbers stored in the cart
 231 my @cart_list;
 232
 233 if($cgi->cookie("intranet_bib_list")){
 234     my $cart_list = $cgi->cookie("intranet_bib_list");
 235     @cart_list = split(/\//, $cart_list);
 236 }
 237
 238 my @search_groups =
 239   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 240
 241 my $branch_limit = '';
 242 if ( scalar $cgi->param('limit') =~ /branch:([\w-]+)/ ) {
 243     $branch_limit = $1;
 244 }
 245
 246 $template->param(
 247     search_groups    => \@search_groups,
 248     branch_limit     => $branch_limit
 249 );
 250
 251 # load the Type stuff
 252 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 253 my $advancedsearchesloop = prepare_adv_search_types($types);
 254 $template->param(advancedsearchesloop => $advancedsearchesloop);
 255
 256 $template->param( searchid => scalar $cgi->param('searchid'), );
 257
 258 # The following should only be loaded if we're bringing up the advanced search template
 259 if ( $template_type eq 'advsearch' ) {
 260
 261     my $expanded = $cgi->param('expanded_options');
 262     if( $cgi->param('edit_search') ){
 263         my @operators = $cgi->multi_param('op');
 264         my @indexes   = $cgi->multi_param('idx');
 265         my %limit_hash;
 266         foreach my $limit (@limits){
 267             if ( $limit eq 'available' ){
 268                 $template->param( limit_available => 1 );
 269             } else {
 270                 my ($index,$value) = split(':',$limit);
 271                 $value =~ s/"//g;
 272                 if ( $index =~ /mc-/ ){
 273                     $limit_hash{$index . "_" . $value} = 1;
 274                 } else {
 275                     push @{$limit_hash{$index}}, $value;
 276                 }
 277             }
 278         };
 279         $expanded = 1 if scalar @operators || scalar @limits;
 280         $template->param( operators => \@operators );
 281         $template->param( limits => \%limit_hash );
 282         $template->param(
 283            indexes   => \@indexes,
 284            sort      => $cgi->param('sort_by'),
 285         );
 286     }
 287     # load the servers (used for searching -- to do federated searching, etc.)
 288     my $primary_servers_loop;# = displayPrimaryServers();
 289     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 290
 291     my $secondary_servers_loop;
 292     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 293
 294     # set the default sorting
 295     if (   C4::Context->preference('defaultSortField')
 296         && C4::Context->preference('defaultSortOrder') ) {
 297         my $default_sort_by =
 298             C4::Context->preference('defaultSortField') . '_'
 299           . C4::Context->preference('defaultSortOrder');
 300         $template->param( sort_by => $default_sort_by  );
 301     }
 302
 303     # determine what to display next to the search boxes
 304     my @queries = $cgi->multi_param('q');
 305     while( scalar @queries < 3 ){
 306         push @queries, "";
 307     }
 308     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 309
 310     # load the language limits (for search)
 311     my $languages_limit_loop = getLanguages($lang, 1);
 312     $template->param(search_languages_loop => $languages_limit_loop,);
 313     $template->param(       queries   => \@queries );
 314
 315     # Expanded search options in advanced search:
 316     # use the global setting by default, but let the user override it
 317     {
 318         $expanded = C4::Context->preference("expandedSearchOption") || 0
 319             if !defined($expanded) || $expanded !~ /^0|1$/;
 320         $template->param( expanded_options => $expanded );
 321     }
 322
 323     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 324
 325     output_html_with_http_headers $cgi, $cookie, $template->output;
 326     exit;
 327 }
 328
 329 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 330
 331 # Fetch the paramater list as a hash in scalar context:
 332 #  * returns paramater list as tied hash ref
 333 #  * we can edit the values by changing the key
 334 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 335 my $params = $cgi->Vars;
 336 # Params that can have more than one value
 337 # sort by is used to sort the query
 338 # in theory can have more than one but generally there's just one
 339 my @sort_by;
 340 my $default_sort_by;
 341 if (   C4::Context->preference('defaultSortField')
 342     && C4::Context->preference('defaultSortOrder') ) {
 343     $default_sort_by =
 344         C4::Context->preference('defaultSortField') . '_'
 345       . C4::Context->preference('defaultSortOrder');
 346 }
 347
 348 @sort_by = $cgi->multi_param('sort_by');
 349 $sort_by[0] = $default_sort_by unless $sort_by[0];
 350 foreach my $sort (@sort_by) {
 351     $template->param($sort => 1) if $sort;
 352 }
 353 $template->param('sort_by' => $sort_by[0]);
 354
 355 # Use the servers defined, or just search our local catalog(default)
 356 my @servers = $cgi->multi_param('server');
 357 unless (@servers) {
 358     #FIXME: this should be handled using Context.pm
 359     @servers = ("biblioserver");
 360     # @servers = C4::Context->config("biblioserver");
 361 }
 362 # operators include boolean and proximity operators and are used
 363 # to evaluate multiple operands
 364 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 365
 366 # indexes are query qualifiers, like 'title', 'author', etc. They
 367 # can be single or multiple parameters separated by comma: kw,right-Truncation
 368 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 369
 370 # if a simple index (only one)  display the index used in the top search box
 371 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 372     my $idx = "ms_".$indexes[0];
 373     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 374     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 375     $template->param(header_pulldown => $idx);
 376 }
 377
 378 # an operand can be a single term, a phrase, or a complete ccl query
 379 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 380
 381 # if a simple search, display the value in the search box
 382 my $basic_search = 0;
 383 if ($operands[0] && !$operands[1]) {
 384     my $ms_query = $operands[0];
 385     $ms_query =~ s/ #\S+//;
 386     $template->param(ms_value => $ms_query);
 387     $basic_search=1;
 388 }
 389
 390 my $available;
 391 foreach my $limit(@limits) {
 392     if ($limit =~/available/) {
 393         $available = 1;
 394     }
 395 }
 396 $template->param(available => $available);
 397
 398 # append year limits if they exist
 399 my $limit_yr;
 400 my $limit_yr_value;
 401 if ($params->{'limit-yr'}) {
 402     if ($params->{'limit-yr'} =~ /\d{4}/) {
 403         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 404         $limit_yr_value = $params->{'limit-yr'};
 405     }
 406     push @limits,$limit_yr;
 407     #FIXME: Should return a error to the user, incorect date format specified
 408 }
 409
 410 # convert indexes and operands to corresponding parameter names for the z3950 search
 411 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 412 my $z3950par;
 413 my $indexes2z3950 = {
 414     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 415     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 416     ti=>'title', 'ti,phr'=>'title', se=>'title'
 417 };
 418 for (my $ii = 0; $ii < @operands; ++$ii)
 419 {
 420     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 421     if (defined $name && defined $operands[$ii])
 422     {
 423         $z3950par ||= {};
 424         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 425     }
 426 }
 427
 428
 429 # Params that can only have one value
 430 my $scan = $params->{'scan'};
 431 my $count = C4::Context->preference('numSearchResults') || 20;
 432 my $results_per_page = $params->{'count'} || $count;
 433 my $offset = $params->{'offset'} || 0;
 434 my $whole_record = $params->{'whole_record'} || 0;
 435 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 436 $offset = 0 if $offset < 0;
 437 my $page = $cgi->param('page') || 1;
 438 #my $offset = ($page-1)*$results_per_page;
 439
 440 # Define some global variables
 441 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 442
 443 my $builder = Koha::SearchEngine::QueryBuilder->new(
 444     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 445 my $searcher = Koha::SearchEngine::Search->new(
 446     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 447
 448 ## I. BUILD THE QUERY
 449 (
 450     $error,             $query, $simple_query, $query_cgi,
 451     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 452     $query_type
 453   )
 454   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 455     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 456
 457 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 458
 459 ## parse the query_cgi string and put it into a form suitable for <input>s
 460 my @query_inputs;
 461 my $scan_index_to_use;
 462 my $scan_search_term_to_use;
 463
 464 if ($query_cgi) {
 465     for my $this_cgi ( split('&', $query_cgi) ) {
 466         next unless $this_cgi;
 467         $this_cgi =~ m/(.*?)=(.*)/;
 468         my $input_name = $1;
 469         my $input_value = $2;
 470         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 471         if ($input_name eq 'idx') {
 472             # The form contains multiple fields, so take the first value as the scan index
 473             $scan_index_to_use = $input_value unless $scan_index_to_use;
 474         }
 475         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 476             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 477         }
 478     }
 479 }
 480
 481 $template->param ( QUERY_INPUTS => \@query_inputs,
 482                    scan_index_to_use => $scan_index_to_use,
 483                    scan_search_term_to_use => $scan_search_term_to_use );
 484
 485 ## parse the limit_cgi string and put it into a form suitable for <input>s
 486 my @limit_inputs;
 487 if ($limit_cgi) {
 488     for my $this_cgi ( split('&', $limit_cgi) ) {
 489         next unless $this_cgi;
 490         # handle special case limit-yr
 491         if ($this_cgi =~ /yr,st-numeric/) {
 492             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 493             next;
 494         }
 495         $this_cgi =~ m/(.*=)(.*)/;
 496         my $input_name = $1;
 497         my $input_value = $2;
 498         $input_name =~ s/=$//;
 499         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 500     }
 501 }
 502 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 503
 504 ## II. DO THE SEARCH AND GET THE RESULTS
 505 my $total = 0; # the total results for the whole set
 506 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 507 my $results_hashref;
 508
 509 eval {
 510     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 511     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 512         $query,            $simple_query, \@sort_by,       \@servers,
 513         $results_per_page, $offset,       undef,           $itemtypes,
 514         $query_type,       $scan
 515     );
 516 };
 517
 518 if ($@ || $error) {
 519     my $query_error = q{};
 520     $query_error .= $error if $error;
 521     $query_error .= $@ if $@;
 522     $template->param(query_error => $query_error);
 523     output_html_with_http_headers $cgi, $cookie, $template->output;
 524     exit;
 525 }
 526
 527 # At this point, each server has given us a result set
 528 # now we build that set for template display
 529 my @sup_results_array;
 530 for (my $i=0;$i<@servers;$i++) {
 531     my $server = $servers[$i];
 532     if ($server =~/biblioserver/) { # this is the local bibliographic server
 533         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 534         if ( $hits == 0 && $basic_search ){
 535             $operands[0] = '"'.$operands[0].'"'; #quote it
 536             ## I. BUILD THE QUERY
 537             (
 538                 $error,             $query, $simple_query, $query_cgi,
 539                 $query_desc,        $limit, $limit_cgi,    $limit_desc,
 540                 $query_type
 541               )
 542               = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 543                 \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 544             my $quoted_results_hashref;
 545             eval {
 546                 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 547                 ( $error, $quoted_results_hashref, $facets ) = $searcher->search_compat(
 548                     $query,            $simple_query, \@sort_by,       ['biblioserver'],
 549                     $results_per_page, $offset,       undef,           $itemtypes,
 550                     $query_type,       $scan
 551                 );
 552             };
 553             my $quoted_hits = $quoted_results_hashref->{$server}->{"hits"} // 0;
 554             if ( $quoted_hits ){
 555                 $results_hashref->{'biblioserver'} = $quoted_results_hashref->{'biblioserver'};
 556                 $hits = $quoted_hits;
 557             }
 558         }
 559         my $page = $cgi->param('page') || 0;
 560         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 561                                        $results_hashref->{$server}->{"RECORDS"});
 562         $total = $total + $hits;
 563
 564         # Search history
 565         if (C4::Context->preference('EnableSearchHistory')) {
 566             unless ( $offset ) {
 567                 my $path_info = $cgi->url(-path_info=>1);
 568                 my $query_cgi_history = $cgi->url(-query=>1);
 569                 $query_cgi_history =~ s/^$path_info\?//;
 570                 $query_cgi_history =~ s/;/&/g;
 571                 my $query_desc_history = $query_desc;
 572                 $query_desc_history .= ", $limit_desc"
 573                     if $limit_desc;
 574
 575                 C4::Search::History::add({
 576                     userid => $borrowernumber,
 577                     sessionid => $cgi->cookie("CGISESSID"),
 578                     query_desc => $query_desc_history,
 579                     query_cgi => $query_cgi_history,
 580                     total => $total,
 581                     type => "biblio",
 582                 });
 583             }
 584             $template->param( EnableSearchHistory => 1 );
 585         }
 586
 587         ## If there's just one result, redirect to the detail page unless doing an index scan
 588         if ($total == 1 && !$scan) {
 589             my $biblionumber = $newresults[0]->{biblionumber};
 590             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 591             my $views = { C4::Search::enabled_staff_search_views };
 592             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 593                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 594             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 595                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 596             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 597                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 598             } else {
 599                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 600             }
 601             exit;
 602         }
 603
 604         # set up parameters if user wishes to re-run the search
 605         # as a Z39.50 search
 606         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 607         $template->param(limit_cgi => $limit_cgi);
 608         $template->param(query_cgi => $query_cgi);
 609         $template->param(query_desc => $query_desc);
 610         $template->param(limit_desc => $limit_desc);
 611         $template->param(offset     => $offset);
 612
 613         if ($hits) {
 614             $template->param(total => $hits);
 615             if ($limit_cgi) {
 616                 my $limit_cgi_not_availablity = $limit_cgi;
 617                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 618                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 619             }
 620             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 621             if ($query_desc || $limit_desc) {
 622                 $template->param(searchdesc => 1);
 623             }
 624             $template->param(results_per_page =>  $results_per_page);
 625             # must define a value for size if not present in DB
 626             # in order to avoid problems generated by the default size value in TT
 627             foreach my $line (@newresults) {
 628                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 629                 # while we're checking each line, see if item is in the cart
 630                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 631                     $line->{'incart'} = 1;
 632                 }
 633             }
 634             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 635                 Koha::SearchEngine::Search->pagination_bar(
 636                     {
 637                         hits              => $hits,
 638                         max_result_window => $searcher->max_result_window,
 639                         results_per_page  => $results_per_page,
 640                         offset            => $offset,
 641                         sort_by           => \@sort_by
 642                     }
 643                 );
 644             $template->param( hits_to_paginate => $hits_to_paginate );
 645             $template->param(SEARCH_RESULTS => \@newresults);
 646             # FIXME: no previous_page_offset when pages < 2
 647             $template->param(   PAGE_NUMBERS => $page_numbers,
 648                                 last_page_offset => $last_page_offset,
 649                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 650             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 651         }
 652
 653
 654         # no hits
 655         else {
 656             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 657         }
 658
 659     } # end of the if local
 660
 661     # asynchronously search the authority server
 662     elsif ($server =~/authorityserver/) { # this is the local authority server
 663         my @inner_sup_results_array;
 664         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 665             my $marc_record_object = C4::Search::new_record_from_zebra(
 666                 'authorityserver',
 667                 $sup_record
 668             );
 669             # warn "Authority Found: ".$marc_record_object->as_formatted();
 670             push @inner_sup_results_array, {
 671                 'title' => $marc_record_object->field(100)->subfield('a'),
 672                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 673             };
 674         }
 675         push @sup_results_array, {  servername => $server,
 676                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 677     }
 678     # FIXME: can add support for other targets as needed here
 679     $template->param(           outer_sup_results_loop => \@sup_results_array);
 680 } #/end of the for loop
 681 #$template->param(FEDERATED_RESULTS => \@results_array);
 682
 683 my $gotonumber = $cgi->param('gotoNumber');
 684 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 685     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 686 }
 687 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 688 my $gotopage = $cgi->param('gotoPage');
 689 $template->{'VARS'}->{'gotoPage'} = $gotopage
 690   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 691
 692 for my $facet ( @$facets ) {
 693     for my $entry ( @{ $facet->{facets} } ) {
 694         my $index = $entry->{type_link_value};
 695         my $value = $entry->{facet_link_value};
 696         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 697     }
 698 }
 699
 700 $template->param(
 701             #classlist => $classlist,
 702             total => $total,
 703             opacfacets => 1,
 704             facets_loop => $facets,
 705             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 706             scan => $scan,
 707             search_error => $error,
 708 );
 709
 710 if ($query_desc || $limit_desc) {
 711     $template->param(searchdesc => 1);
 712 }
 713
 714 # VI. BUILD THE TEMPLATE
 715
 716 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 717     {
 718         borrowernumber => $borrowernumber,
 719         add_allowed    => 1,
 720         public         => 0,
 721     }
 722 );
 723 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 724     {
 725         borrowernumber => $borrowernumber,
 726         add_allowed    => 1,
 727         public         => 1,
 728     }
 729 );
 730
 731
 732 $template->param(
 733     add_to_some_private_shelves => $some_private_shelves,
 734     add_to_some_public_shelves  => $some_public_shelves,
 735 );
 736
 737 output_html_with_http_headers $cgi, $cookie, $template->output;
 738
 739
 740 =head2 prepare_adv_search_types
 741
 742     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 743     my @advanced_search_types = prepare_adv_search_types($type);
 744
 745 Different types can be searched for in the advanced search. This takes the
 746 system preference that defines these types and parses it into an arrayref for
 747 the template.
 748
 749 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 750 It also accounts for the "item-level_itypes" system preference.
 751
 752 =cut
 753
 754 sub prepare_adv_search_types {
 755     my ($types) = @_;
 756
 757     my @advanced_search_types = split( /\|/, $types );
 758
 759     # the index parameter is different for item-level itemtypes
 760     my $itype_or_itemtype =
 761       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 762     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 763
 764     my ( $cnt, @result );
 765     foreach my $advanced_srch_type (@advanced_search_types) {
 766         $advanced_srch_type =~ s/^\s*//;
 767         $advanced_srch_type =~ s/\s*$//;
 768         if ( $advanced_srch_type eq 'itemtypes' ) {
 769
 770        # itemtype is a special case, since it's not defined in authorized values
 771             my @itypesloop;
 772             foreach my $thisitemtype (
 773                 sort {
 774                     $itemtypes->{$a}->{'translated_description'}
 775                       cmp $itemtypes->{$b}->{'translated_description'}
 776                 } keys %$itemtypes
 777               )
 778             {
 779                 my %row = (
 780                     number      => $cnt++,
 781                     ccl         => "$itype_or_itemtype,phr",
 782                     code        => $thisitemtype,
 783                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 784                     imageurl    => getitemtypeimagelocation(
 785                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 786                     ),
 787                 );
 788                 push @itypesloop, \%row;
 789             }
 790             my %search_code = (
 791                 advanced_search_type => $advanced_srch_type,
 792                 code_loop            => \@itypesloop
 793             );
 794             push @result, \%search_code;
 795         }
 796         else {
 797             # covers all the other cases: non-itemtype authorized values
 798             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 799             my @authvalueloop;
 800             for my $thisitemtype (@$advsearchtypes) {
 801                 my %row = (
 802                     number      => $cnt++,
 803                     ccl         => $advanced_srch_type,
 804                     code        => $thisitemtype->{authorised_value},
 805                     description => $thisitemtype->{'lib'},
 806                     imageurl    => getitemtypeimagelocation(
 807                         'intranet', $thisitemtype->{'imageurl'}
 808                     ),
 809                 );
 810                 push @authvalueloop, \%row;
 811             }
 812             my %search_code = (
 813                 advanced_search_type => $advanced_srch_type,
 814                 code_loop            => \@authvalueloop
 815             );
 816             push @result, \%search_code;
 817         }
 818     }
 819     return \@result;
 820 }