catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 # limits are used to limit to results to a pre-defined category such as branch or language
 172 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 173 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 174 my %is_nolimit = map { $_ => 1 } @nolimits;
 175 @limits = grep { not $is_nolimit{$_} } @limits;
 176 if  (
 177         !$cgi->param('edit_search') &&
 178         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 179     ) {
 180     $template_name = 'catalogue/results.tt';
 181     $template_type = 'results';
 182 }
 183 else {
 184     $template_name = 'catalogue/advsearch.tt';
 185     $template_type = 'advsearch';
 186 }
 187 # load the template
 188 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 189     template_name => $template_name,
 190     query => $cgi,
 191     type => "intranet",
 192     flagsrequired   => { catalogue => 1 },
 193     }
 194 );
 195
 196 my $lang = C4::Languages::getlanguage($cgi);
 197
 198 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 199     $template->param('UNIMARC' => 1);
 200 }
 201
 202 if($cgi->cookie("holdfor")){
 203     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 204     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 205         $template->param(
 206             holdfor        => $cgi->cookie("holdfor"),
 207             holdfor_patron => $holdfor_patron,
 208         );
 209     }
 210 }
 211
 212 if($cgi->cookie("holdforclub")){
 213     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 214     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 215         $template->param(
 216             holdforclub => $cgi->cookie("holdforclub"),
 217             holdforclub_name => $holdfor_club->name,
 218         );
 219     }
 220 }
 221
 222 if($cgi->cookie("searchToOrder")){
 223     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 224     $template->param(
 225         searchtoorder_basketno => $basketno,
 226         searchtoorder_vendorid => $vendorid
 227     );
 228 }
 229
 230 # get biblionumbers stored in the cart
 231 my @cart_list;
 232
 233 if($cgi->cookie("intranet_bib_list")){
 234     my $cart_list = $cgi->cookie("intranet_bib_list");
 235     @cart_list = split(/\//, $cart_list);
 236 }
 237
 238 my @search_groups =
 239   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 240 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 241
 242 $template->param(
 243     search_groups    => \@search_groups,
 244 );
 245
 246 # load the Type stuff
 247 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 248 my $advancedsearchesloop = prepare_adv_search_types($types);
 249 $template->param(advancedsearchesloop => $advancedsearchesloop);
 250
 251 $template->param( searchid => scalar $cgi->param('searchid'), );
 252
 253 # The following should only be loaded if we're bringing up the advanced search template
 254 if ( $template_type eq 'advsearch' ) {
 255
 256     my $expanded = $cgi->param('expanded_options');
 257     if( $cgi->param('edit_search') ){
 258         my @operators = $cgi->multi_param('op');
 259         my @indexes   = $cgi->multi_param('idx');
 260         my %limit_hash;
 261         foreach my $limit (@limits){
 262             if ( $limit eq 'available' ){
 263                 $template->param( limit_available => 1 );
 264             } else {
 265                 my ($index,$value) = split(':',$limit);
 266                 $value =~ s/"//g;
 267                 if ( $index =~ /mc-/ ){
 268                     $limit_hash{$index . "_" . $value} = 1;
 269                 } else {
 270                     push @{$limit_hash{$index}}, $value;
 271                 }
 272             }
 273         };
 274         $expanded = 1 if scalar @operators || scalar @limits;
 275         $template->param( operators => \@operators );
 276         $template->param( limits => \%limit_hash );
 277         $template->param(
 278            indexes   => \@indexes,
 279            sort      => $cgi->param('sort_by'),
 280         );
 281     }
 282     # load the servers (used for searching -- to do federated searching, etc.)
 283     my $primary_servers_loop;# = displayPrimaryServers();
 284     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 285
 286     my $secondary_servers_loop;
 287     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 288
 289     # set the default sorting
 290     if (   C4::Context->preference('defaultSortField')
 291         && C4::Context->preference('defaultSortOrder') ) {
 292         my $default_sort_by =
 293             C4::Context->preference('defaultSortField') . '_'
 294           . C4::Context->preference('defaultSortOrder');
 295         $template->param( sort_by => $default_sort_by  );
 296     }
 297
 298     # determine what to display next to the search boxes
 299     my @queries = $cgi->multi_param('q');
 300     while( scalar @queries < 3 ){
 301         push @queries, "";
 302     }
 303     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 304
 305     # load the language limits (for search)
 306     my $languages_limit_loop = getLanguages($lang, 1);
 307     $template->param(search_languages_loop => $languages_limit_loop,);
 308     $template->param(       queries   => \@queries );
 309
 310     # Expanded search options in advanced search:
 311     # use the global setting by default, but let the user override it
 312     {
 313         $expanded = C4::Context->preference("expandedSearchOption") || 0
 314             if !defined($expanded) || $expanded !~ /^0|1$/;
 315         $template->param( expanded_options => $expanded );
 316     }
 317
 318     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 319
 320     output_html_with_http_headers $cgi, $cookie, $template->output;
 321     exit;
 322 }
 323
 324 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 325
 326 # Fetch the paramater list as a hash in scalar context:
 327 #  * returns paramater list as tied hash ref
 328 #  * we can edit the values by changing the key
 329 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 330 my $params = $cgi->Vars;
 331 # Params that can have more than one value
 332 # sort by is used to sort the query
 333 # in theory can have more than one but generally there's just one
 334 my @sort_by;
 335 my $default_sort_by;
 336 if (   C4::Context->preference('defaultSortField')
 337     && C4::Context->preference('defaultSortOrder') ) {
 338     $default_sort_by =
 339         C4::Context->preference('defaultSortField') . '_'
 340       . C4::Context->preference('defaultSortOrder');
 341 }
 342
 343 @sort_by = $cgi->multi_param('sort_by');
 344 $sort_by[0] = $default_sort_by unless $sort_by[0];
 345 foreach my $sort (@sort_by) {
 346     $template->param($sort => 1) if $sort;
 347 }
 348 $template->param('sort_by' => $sort_by[0]);
 349
 350 # Use the servers defined, or just search our local catalog(default)
 351 my @servers = $cgi->multi_param('server');
 352 unless (@servers) {
 353     #FIXME: this should be handled using Context.pm
 354     @servers = ("biblioserver");
 355     # @servers = C4::Context->config("biblioserver");
 356 }
 357 # operators include boolean and proximity operators and are used
 358 # to evaluate multiple operands
 359 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 360
 361 # indexes are query qualifiers, like 'title', 'author', etc. They
 362 # can be single or multiple parameters separated by comma: kw,right-Truncation
 363 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 364
 365 # if a simple index (only one)  display the index used in the top search box
 366 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 367     my $idx = "ms_".$indexes[0];
 368     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 369     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 370     $template->param($idx => 1);
 371 }
 372
 373 # an operand can be a single term, a phrase, or a complete ccl query
 374 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 375
 376 # if a simple search, display the value in the search box
 377 if ($operands[0] && !$operands[1]) {
 378     my $ms_query = $operands[0];
 379     $ms_query =~ s/ #\S+//;
 380     $template->param(ms_value => $ms_query);
 381 }
 382
 383 my $available;
 384 foreach my $limit(@limits) {
 385     if ($limit =~/available/) {
 386         $available = 1;
 387     }
 388 }
 389 $template->param(available => $available);
 390
 391 # append year limits if they exist
 392 my $limit_yr;
 393 my $limit_yr_value;
 394 if ($params->{'limit-yr'}) {
 395     if ($params->{'limit-yr'} =~ /\d{4}/) {
 396         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 397         $limit_yr_value = $params->{'limit-yr'};
 398     }
 399     push @limits,$limit_yr;
 400     #FIXME: Should return a error to the user, incorect date format specified
 401 }
 402
 403 # convert indexes and operands to corresponding parameter names for the z3950 search
 404 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 405 my $z3950par;
 406 my $indexes2z3950 = {
 407     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 408     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 409     ti=>'title', 'ti,phr'=>'title', se=>'title'
 410 };
 411 for (my $ii = 0; $ii < @operands; ++$ii)
 412 {
 413     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 414     if (defined $name && defined $operands[$ii])
 415     {
 416         $z3950par ||= {};
 417         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 418     }
 419 }
 420
 421
 422 # Params that can only have one value
 423 my $scan = $params->{'scan'};
 424 my $count = C4::Context->preference('numSearchResults') || 20;
 425 my $results_per_page = $params->{'count'} || $count;
 426 my $offset = $params->{'offset'} || 0;
 427 my $whole_record = $params->{'whole_record'} || 0;
 428 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 429 $offset = 0 if $offset < 0;
 430 my $page = $cgi->param('page') || 1;
 431 #my $offset = ($page-1)*$results_per_page;
 432
 433 # Define some global variables
 434 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 435
 436 my $builder = Koha::SearchEngine::QueryBuilder->new(
 437     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 438 my $searcher = Koha::SearchEngine::Search->new(
 439     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 440
 441 ## I. BUILD THE QUERY
 442 (
 443     $error,             $query, $simple_query, $query_cgi,
 444     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 445     $query_type
 446   )
 447   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 448     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 449
 450 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 451
 452 ## parse the query_cgi string and put it into a form suitable for <input>s
 453 my @query_inputs;
 454 my $scan_index_to_use;
 455 my $scan_search_term_to_use;
 456
 457 if ($query_cgi) {
 458     for my $this_cgi ( split('&', $query_cgi) ) {
 459         next unless $this_cgi;
 460         $this_cgi =~ m/(.*?)=(.*)/;
 461         my $input_name = $1;
 462         my $input_value = $2;
 463         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 464         if ($input_name eq 'idx') {
 465             # The form contains multiple fields, so take the first value as the scan index
 466             $scan_index_to_use = $input_value unless $scan_index_to_use;
 467         }
 468         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 469             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 470         }
 471     }
 472 }
 473
 474 $template->param ( QUERY_INPUTS => \@query_inputs,
 475                    scan_index_to_use => $scan_index_to_use,
 476                    scan_search_term_to_use => $scan_search_term_to_use );
 477
 478 ## parse the limit_cgi string and put it into a form suitable for <input>s
 479 my @limit_inputs;
 480 if ($limit_cgi) {
 481     for my $this_cgi ( split('&', $limit_cgi) ) {
 482         next unless $this_cgi;
 483         # handle special case limit-yr
 484         if ($this_cgi =~ /yr,st-numeric/) {
 485             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 486             next;
 487         }
 488         $this_cgi =~ m/(.*=)(.*)/;
 489         my $input_name = $1;
 490         my $input_value = $2;
 491         $input_name =~ s/=$//;
 492         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 493     }
 494 }
 495 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 496
 497 ## II. DO THE SEARCH AND GET THE RESULTS
 498 my $total = 0; # the total results for the whole set
 499 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 500 my $results_hashref;
 501
 502 eval {
 503     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 504     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 505         $query,            $simple_query, \@sort_by,       \@servers,
 506         $results_per_page, $offset,       undef,           $itemtypes,
 507         $query_type,       $scan
 508     );
 509 };
 510
 511 if ($@ || $error) {
 512     my $query_error = q{};
 513     $query_error .= $error if $error;
 514     $query_error .= $@ if $@;
 515     $template->param(query_error => $query_error);
 516     output_html_with_http_headers $cgi, $cookie, $template->output;
 517     exit;
 518 }
 519
 520 # At this point, each server has given us a result set
 521 # now we build that set for template display
 522 my @sup_results_array;
 523 for (my $i=0;$i<@servers;$i++) {
 524     my $server = $servers[$i];
 525     if ($server =~/biblioserver/) { # this is the local bibliographic server
 526         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 527         my $page = $cgi->param('page') || 0;
 528         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 529                                        $results_hashref->{$server}->{"RECORDS"});
 530         $total = $total + $hits;
 531
 532         # Search history
 533         if (C4::Context->preference('EnableSearchHistory')) {
 534             unless ( $offset ) {
 535                 my $path_info = $cgi->url(-path_info=>1);
 536                 my $query_cgi_history = $cgi->url(-query=>1);
 537                 $query_cgi_history =~ s/^$path_info\?//;
 538                 $query_cgi_history =~ s/;/&/g;
 539                 my $query_desc_history = $query_desc;
 540                 $query_desc_history .= ", $limit_desc"
 541                     if $limit_desc;
 542
 543                 C4::Search::History::add({
 544                     userid => $borrowernumber,
 545                     sessionid => $cgi->cookie("CGISESSID"),
 546                     query_desc => $query_desc_history,
 547                     query_cgi => $query_cgi_history,
 548                     total => $total,
 549                     type => "biblio",
 550                 });
 551             }
 552             $template->param( EnableSearchHistory => 1 );
 553         }
 554
 555         ## If there's just one result, redirect to the detail page unless doing an index scan
 556         if ($total == 1 && !$scan) {
 557             my $biblionumber = $newresults[0]->{biblionumber};
 558             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 559             my $views = { C4::Search::enabled_staff_search_views };
 560             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 561                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 562             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 563                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 564             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 565                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 566             } else {
 567                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 568             }
 569             exit;
 570         }
 571
 572         # set up parameters if user wishes to re-run the search
 573         # as a Z39.50 search
 574         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 575         $template->param(limit_cgi => $limit_cgi);
 576         $template->param(query_cgi => $query_cgi);
 577         $template->param(query_desc => $query_desc);
 578         $template->param(limit_desc => $limit_desc);
 579         $template->param(offset     => $offset);
 580
 581         if ($hits) {
 582             $template->param(total => $hits);
 583             if ($limit_cgi) {
 584                 my $limit_cgi_not_availablity = $limit_cgi;
 585                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 586                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 587             }
 588             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 589             if ($query_desc || $limit_desc) {
 590                 $template->param(searchdesc => 1);
 591             }
 592             $template->param(results_per_page =>  $results_per_page);
 593             # must define a value for size if not present in DB
 594             # in order to avoid problems generated by the default size value in TT
 595             foreach my $line (@newresults) {
 596                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 597                 # while we're checking each line, see if item is in the cart
 598                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 599                     $line->{'incart'} = 1;
 600                 }
 601             }
 602             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 603                 Koha::SearchEngine::Search->pagination_bar(
 604                     {
 605                         hits              => $hits,
 606                         max_result_window => $searcher->max_result_window,
 607                         results_per_page  => $results_per_page,
 608                         offset            => $offset,
 609                         sort_by           => \@sort_by
 610                     }
 611                 );
 612             $template->param( hits_to_paginate => $hits_to_paginate );
 613             $template->param(SEARCH_RESULTS => \@newresults);
 614             # FIXME: no previous_page_offset when pages < 2
 615             $template->param(   PAGE_NUMBERS => $page_numbers,
 616                                 last_page_offset => $last_page_offset,
 617                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 618             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 619         }
 620
 621
 622         # no hits
 623         else {
 624             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 625         }
 626
 627     } # end of the if local
 628
 629     # asynchronously search the authority server
 630     elsif ($server =~/authorityserver/) { # this is the local authority server
 631         my @inner_sup_results_array;
 632         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 633             my $marc_record_object = C4::Search::new_record_from_zebra(
 634                 'authorityserver',
 635                 $sup_record
 636             );
 637             # warn "Authority Found: ".$marc_record_object->as_formatted();
 638             push @inner_sup_results_array, {
 639                 'title' => $marc_record_object->field(100)->subfield('a'),
 640                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 641             };
 642         }
 643         push @sup_results_array, {  servername => $server,
 644                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 645     }
 646     # FIXME: can add support for other targets as needed here
 647     $template->param(           outer_sup_results_loop => \@sup_results_array);
 648 } #/end of the for loop
 649 #$template->param(FEDERATED_RESULTS => \@results_array);
 650
 651 my $gotonumber = $cgi->param('gotoNumber');
 652 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 653     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 654 }
 655 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 656 my $gotopage = $cgi->param('gotoPage');
 657 $template->{'VARS'}->{'gotoPage'} = $gotopage
 658   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 659
 660 for my $facet ( @$facets ) {
 661     for my $entry ( @{ $facet->{facets} } ) {
 662         my $index = $entry->{type_link_value};
 663         my $value = $entry->{facet_link_value};
 664         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 665     }
 666 }
 667
 668 $template->param(
 669             #classlist => $classlist,
 670             total => $total,
 671             opacfacets => 1,
 672             facets_loop => $facets,
 673             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 674             scan => $scan,
 675             search_error => $error,
 676 );
 677
 678 if ($query_desc || $limit_desc) {
 679     $template->param(searchdesc => 1);
 680 }
 681
 682 # VI. BUILD THE TEMPLATE
 683
 684 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 685     {
 686         borrowernumber => $borrowernumber,
 687         add_allowed    => 1,
 688         public         => 0,
 689     }
 690 );
 691 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 692     {
 693         borrowernumber => $borrowernumber,
 694         add_allowed    => 1,
 695         public         => 1,
 696     }
 697 );
 698
 699
 700 $template->param(
 701     add_to_some_private_shelves => $some_private_shelves,
 702     add_to_some_public_shelves  => $some_public_shelves,
 703 );
 704
 705 output_html_with_http_headers $cgi, $cookie, $template->output;
 706
 707
 708 =head2 prepare_adv_search_types
 709
 710     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 711     my @advanced_search_types = prepare_adv_search_types($type);
 712
 713 Different types can be searched for in the advanced search. This takes the
 714 system preference that defines these types and parses it into an arrayref for
 715 the template.
 716
 717 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 718 It also accounts for the "item-level_itypes" system preference.
 719
 720 =cut
 721
 722 sub prepare_adv_search_types {
 723     my ($types) = @_;
 724
 725     my @advanced_search_types = split( /\|/, $types );
 726
 727     # the index parameter is different for item-level itemtypes
 728     my $itype_or_itemtype =
 729       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 730     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 731
 732     my ( $cnt, @result );
 733     foreach my $advanced_srch_type (@advanced_search_types) {
 734         $advanced_srch_type =~ s/^\s*//;
 735         $advanced_srch_type =~ s/\s*$//;
 736         if ( $advanced_srch_type eq 'itemtypes' ) {
 737
 738        # itemtype is a special case, since it's not defined in authorized values
 739             my @itypesloop;
 740             foreach my $thisitemtype (
 741                 sort {
 742                     $itemtypes->{$a}->{'translated_description'}
 743                       cmp $itemtypes->{$b}->{'translated_description'}
 744                 } keys %$itemtypes
 745               )
 746             {
 747                 my %row = (
 748                     number      => $cnt++,
 749                     ccl         => "$itype_or_itemtype,phr",
 750                     code        => $thisitemtype,
 751                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 752                     imageurl    => getitemtypeimagelocation(
 753                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 754                     ),
 755                 );
 756                 push @itypesloop, \%row;
 757             }
 758             my %search_code = (
 759                 advanced_search_type => $advanced_srch_type,
 760                 code_loop            => \@itypesloop
 761             );
 762             push @result, \%search_code;
 763         }
 764         else {
 765             # covers all the other cases: non-itemtype authorized values
 766             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 767             my @authvalueloop;
 768             for my $thisitemtype (@$advsearchtypes) {
 769                 my %row = (
 770                     number      => $cnt++,
 771                     ccl         => $advanced_srch_type,
 772                     code        => $thisitemtype->{authorised_value},
 773                     description => $thisitemtype->{'lib'},
 774                     imageurl    => getitemtypeimagelocation(
 775                         'intranet', $thisitemtype->{'imageurl'}
 776                     ),
 777                 );
 778                 push @authvalueloop, \%row;
 779             }
 780             my %search_code = (
 781                 advanced_search_type => $advanced_srch_type,
 782                 code_loop            => \@authvalueloop
 783             );
 784             push @result, \%search_code;
 785         }
 786     }
 787     return \@result;
 788 }