catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to acomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use strict;            # always use
 136 #use warnings; FIXME - Bug 2505
 137
 138 ## STEP 1. Load things that are used in both search page and
 139 # results page and decide which template to load, operations
 140 # to perform, etc.
 141
 142 ## load Koha modules
 143 use C4::Context;
 144 use C4::Output;
 145 use C4::Auth qw(:DEFAULT get_session);
 146 use C4::Search;
 147 use C4::Languages qw(getLanguages);
 148 use C4::Koha;
 149 use C4::Members qw(GetMember);
 150 use C4::VirtualShelves;
 151 use URI::Escape;
 152 use POSIX qw(ceil floor);
 153 use C4::Branch; # GetBranches
 154 use C4::Search::History;
 155
 156 use Koha::Virtualshelves;
 157
 158 use URI::Escape;
 159
 160 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 161 # create a new CGI object
 162 # FIXME: no_undef_params needs to be tested
 163 use CGI qw('-no_undef_params' -utf8 );
 164 my $cgi = new CGI;
 165
 166 my ($template,$borrowernumber,$cookie);
 167 # decide which template to use
 168 my $template_name;
 169 my $template_type;
 170 my @params = $cgi->param("limit");
 171 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 172     $template_name = 'catalogue/results.tt';
 173 }
 174 else {
 175     $template_name = 'catalogue/advsearch.tt';
 176     $template_type = 'advsearch';
 177 }
 178 # load the template
 179 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 180     template_name => $template_name,
 181     query => $cgi,
 182     type => "intranet",
 183     authnotrequired => 0,
 184     flagsrequired   => { catalogue => 1 },
 185     }
 186 );
 187
 188 my $lang = C4::Languages::getlanguage($cgi);
 189
 190 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 191     $template->param('UNIMARC' => 1);
 192 }
 193 if (C4::Context->preference("IntranetNumbersPreferPhrase")) {
 194     $template->param('numbersphr' => 1);
 195 }
 196
 197 if($cgi->cookie("holdfor")){
 198     my $holdfor_patron = GetMember('borrowernumber' => $cgi->cookie("holdfor"));
 199     $template->param(
 200         holdfor => $cgi->cookie("holdfor"),
 201         holdfor_surname => $holdfor_patron->{'surname'},
 202         holdfor_firstname => $holdfor_patron->{'firstname'},
 203         holdfor_cardnumber => $holdfor_patron->{'cardnumber'},
 204     );
 205 }
 206
 207 ## URI Re-Writing
 208 # Deprecated, but preserved because it's interesting :-)
 209 # The same thing can be accomplished with mod_rewrite in
 210 # a more elegant way
 211 #
 212 #my $rewrite_flag;
 213 #my $uri = $cgi->url(-base => 1);
 214 #my $relative_url = $cgi->url(-relative=>1);
 215 #$uri.="/".$relative_url."?";
 216 #warn "URI:$uri";
 217 #my @cgi_params_list = $cgi->param();
 218 #my $url_params = $cgi->Vars;
 219 #
 220 #for my $each_param_set (@cgi_params_list) {
 221 #    $uri.= join "",  map "\&$each_param_set=".$_, split("\0",$url_params->{$each_param_set}) if $url_params->{$each_param_set};
 222 #}
 223 #warn "New URI:$uri";
 224 # Only re-write a URI if there are params or if it already hasn't been re-written
 225 #unless (($cgi->param('r')) || (!$cgi->param()) ) {
 226 #    print $cgi->redirect(     -uri=>$uri."&r=1",
 227 #                            -cookie => $cookie);
 228 #    exit;
 229 #}
 230
 231 # load the branches
 232 my $branches = GetBranches();
 233
 234 # Populate branch_loop with all branches sorted by their name.  If
 235 # IndependentBranches is activated, set the default branch to the borrower
 236 # branch, except for superlibrarian who need to search all libraries.
 237 my $user = C4::Context->userenv;
 238 my @branch_loop = map {
 239      {
 240         value      => $_,
 241         branchname => $branches->{$_}->{branchname},
 242         selected   => $user->{branch} eq $_ && C4::Branch::onlymine(),
 243      }
 244 } sort {
 245     $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname}
 246 } keys %$branches;
 247
 248 my $categories = GetBranchCategories('searchdomain');
 249
 250 $template->param(branchloop => \@branch_loop, searchdomainloop => $categories);
 251
 252 # load the Type stuff
 253 my $itemtypes = GetItemTypes;
 254 # the index parameter is different for item-level itemtypes
 255 my $itype_or_itemtype = (C4::Context->preference("item-level_itypes"))?'itype':'itemtype';
 256 my @advancedsearchesloop;
 257 my $cnt;
 258 my $advanced_search_types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 259 my @advanced_search_types = split(/\|/, $advanced_search_types);
 260
 261 foreach my $advanced_srch_type (@advanced_search_types) {
 262     $advanced_srch_type =~ s/^\s*//;
 263     $advanced_srch_type =~ s/\s*$//;
 264    if ($advanced_srch_type eq 'itemtypes') {
 265    # itemtype is a special case, since it's not defined in authorized values
 266         my @itypesloop;
 267         foreach my $thisitemtype ( sort {$itemtypes->{$a}->{translated_description} cmp $itemtypes->{$b}->{translated_description} } keys %$itemtypes ) {
 268             my %row =(  number=>$cnt++,
 269                 ccl => "$itype_or_itemtype,phr",
 270                 code => $thisitemtype,
 271                 description => $itemtypes->{$thisitemtype}->{translated_description},
 272                 imageurl=> getitemtypeimagelocation( 'intranet', $itemtypes->{$thisitemtype}->{'imageurl'} ),
 273             );
 274             push @itypesloop, \%row;
 275         }
 276         my %search_code = (  advanced_search_type => $advanced_srch_type,
 277                              code_loop => \@itypesloop );
 278         push @advancedsearchesloop, \%search_code;
 279     } else {
 280     # covers all the other cases: non-itemtype authorized values
 281        my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 282         my @authvalueloop;
 283         for my $thisitemtype (@$advsearchtypes) {
 284                 my %row =(
 285                                 number=>$cnt++,
 286                                 ccl => $advanced_srch_type,
 287                 code => $thisitemtype->{authorised_value},
 288                 description => $thisitemtype->{'lib'},
 289                 imageurl => getitemtypeimagelocation( 'intranet', $thisitemtype->{'imageurl'} ),
 290                 );
 291                 push @authvalueloop, \%row;
 292         }
 293         my %search_code = (  advanced_search_type => $advanced_srch_type,
 294                              code_loop => \@authvalueloop );
 295         push @advancedsearchesloop, \%search_code;
 296     }
 297 }
 298 $template->param(advancedsearchesloop => \@advancedsearchesloop);
 299
 300 # The following should only be loaded if we're bringing up the advanced search template
 301 if ( $template_type eq 'advsearch' ) {
 302
 303     # load the servers (used for searching -- to do federated searching, etc.)
 304     my $primary_servers_loop;# = displayPrimaryServers();
 305     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 306
 307     my $secondary_servers_loop;
 308     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 309
 310     # set the default sorting
 311     if (   C4::Context->preference('OPACdefaultSortField')
 312         && C4::Context->preference('OPACdefaultSortOrder') ) {
 313         my $default_sort_by =
 314             C4::Context->preference('defaultSortField') . '_'
 315           . C4::Context->preference('defaultSortOrder');
 316         $template->param( sort_by => $default_sort_by  );
 317     }
 318
 319     # determine what to display next to the search boxes (ie, boolean option
 320     # shouldn't appear on the first one, scan indexes should, adding a new
 321     # box should only appear on the last, etc.
 322     my @search_boxes_array;
 323     my $search_boxes_count = 3; # begin whith 3 boxes
 324     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 325     for (my $i=1;$i<=$search_boxes_count;$i++) {
 326         # if it's the first one, don't display boolean option, but show scan indexes
 327         if ($i==1) {
 328             push @search_boxes_array, {scan_index => 1};
 329         }
 330         # if it's the last one, show the 'add field' box
 331         elsif ($i==$search_boxes_count) {
 332             push @search_boxes_array,
 333                 {
 334                 boolean => 1,
 335                 add_field => 1,
 336                 };
 337         }
 338         else {
 339             push @search_boxes_array,
 340                 {
 341                 boolean => 1,
 342                 };
 343         }
 344
 345     }
 346     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 347                       search_boxes_loop => \@search_boxes_array);
 348
 349     # load the language limits (for search)
 350     my $languages_limit_loop = getLanguages($lang, 1);
 351     $template->param(search_languages_loop => $languages_limit_loop,);
 352
 353     # Expanded search options in advanced search:
 354     # use the global setting by default, but let the user override it
 355     {
 356         my $expanded = $cgi->param('expanded_options');
 357         $expanded = C4::Context->preference("expandedSearchOption") || 0
 358             if !defined($expanded) || $expanded !~ /^0|1$/;
 359         $template->param( expanded_options => $expanded );
 360     }
 361
 362     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 363
 364     output_html_with_http_headers $cgi, $cookie, $template->output;
 365     exit;
 366 }
 367
 368 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 369
 370 # Fetch the paramater list as a hash in scalar context:
 371 #  * returns paramater list as tied hash ref
 372 #  * we can edit the values by changing the key
 373 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 374 my $params = $cgi->Vars;
 375
 376 # Params that can have more than one value
 377 # sort by is used to sort the query
 378 # in theory can have more than one but generally there's just one
 379 my @sort_by;
 380 my $default_sort_by;
 381 if (   C4::Context->preference('defaultSortField')
 382     && C4::Context->preference('defaultSortOrder') ) {
 383     $default_sort_by =
 384         C4::Context->preference('defaultSortField') . '_'
 385       . C4::Context->preference('defaultSortOrder');
 386 }
 387
 388 @sort_by = $cgi->param('sort_by');
 389 $sort_by[0] = $default_sort_by unless $sort_by[0];
 390 foreach my $sort (@sort_by) {
 391     $template->param($sort => 1) if $sort;
 392 }
 393 $template->param('sort_by' => $sort_by[0]);
 394
 395 # Use the servers defined, or just search our local catalog(default)
 396 my @servers = $cgi->param('server');
 397 unless (@servers) {
 398     #FIXME: this should be handled using Context.pm
 399     @servers = ("biblioserver");
 400     # @servers = C4::Context->config("biblioserver");
 401 }
 402 # operators include boolean and proximity operators and are used
 403 # to evaluate multiple operands
 404 my @operators = map uri_unescape($_), $cgi->param('op');
 405
 406 # indexes are query qualifiers, like 'title', 'author', etc. They
 407 # can be single or multiple parameters separated by comma: kw,right-Truncation
 408 my @indexes = map uri_unescape($_), $cgi->param('idx');
 409
 410 # if a simple index (only one)  display the index used in the top search box
 411 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 412     my $idx = "ms_".$indexes[0];
 413     $idx =~ s/\,/comma/g;  # template toolkit doesnt like variables with a , in it
 414     $template->param($idx => 1);
 415 }
 416
 417 # an operand can be a single term, a phrase, or a complete ccl query
 418 my @operands = map uri_unescape($_), $cgi->param('q');
 419
 420 # limits are use to limit to results to a pre-defined category such as branch or language
 421 my @limits = map uri_unescape($_), $cgi->param('limit');
 422 my @nolimits = map uri_unescape($_), $cgi->param('nolimit');
 423 my %is_nolimit = map { $_ => 1 } @nolimits;
 424 @limits = grep { not $is_nolimit{$_} } @limits;
 425
 426 if($params->{'multibranchlimit'}) {
 427     my $multibranch = '('.join( " or ", map { "branch: $_ " } @{ GetBranchesInCategory( $params->{'multibranchlimit'} ) } ).')';
 428     push @limits, $multibranch if ($multibranch ne  '()');
 429 }
 430
 431 my $available;
 432 foreach my $limit(@limits) {
 433     if ($limit =~/available/) {
 434         $available = 1;
 435     }
 436 }
 437 $template->param(available => $available);
 438
 439 # append year limits if they exist
 440 my $limit_yr;
 441 my $limit_yr_value;
 442 if ($params->{'limit-yr'}) {
 443     if ($params->{'limit-yr'} =~ /\d{4}-\d{4}/) {
 444         my ($yr1,$yr2) = split(/-/, $params->{'limit-yr'});
 445         $limit_yr = "yr,st-numeric,ge=$yr1 and yr,st-numeric,le=$yr2";
 446         $limit_yr_value = "$yr1-$yr2";
 447     }
 448     elsif ($params->{'limit-yr'} =~ /\d{4}/) {
 449         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 450         $limit_yr_value = $params->{'limit-yr'};
 451     }
 452     push @limits,$limit_yr;
 453     #FIXME: Should return a error to the user, incorect date format specified
 454 }
 455
 456 # convert indexes and operands to corresponding parameter names for the z3950 search
 457 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 458 my $z3950par;
 459 my $indexes2z3950 = {
 460     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 461     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 462     ti=>'title', 'ti,phr'=>'title', se=>'title'
 463 };
 464 for (my $ii = 0; $ii < @operands; ++$ii)
 465 {
 466     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 467     if (defined $name && defined $operands[$ii])
 468     {
 469         $z3950par ||= {};
 470         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 471     }
 472 }
 473
 474
 475 # Params that can only have one value
 476 my $scan = $params->{'scan'};
 477 my $count = C4::Context->preference('numSearchResults') || 20;
 478 my $results_per_page = $params->{'count'} || $count;
 479 my $offset = $params->{'offset'} || 0;
 480 my $page = $cgi->param('page') || 1;
 481 #my $offset = ($page-1)*$results_per_page;
 482 my $hits;
 483 my $expanded_facet = $params->{'expand'};
 484
 485 # Define some global variables
 486 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type);
 487
 488 my @results;
 489
 490 ## I. BUILD THE QUERY
 491 ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$stopwords_removed,$query_type) = buildQuery(\@operators,\@operands,\@indexes,\@limits,\@sort_by,$scan,$lang);
 492
 493 ## parse the query_cgi string and put it into a form suitable for <input>s
 494 my @query_inputs;
 495 my $scan_index_to_use;
 496
 497 for my $this_cgi ( split('&',$query_cgi) ) {
 498     next unless $this_cgi;
 499     $this_cgi =~ m/(.*?)=(.*)/;
 500     my $input_name = $1;
 501     my $input_value = $2;
 502     push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 503     if ($input_name eq 'idx') {
 504         $scan_index_to_use = $input_value; # unless $scan_index_to_use;
 505     }
 506 }
 507 $template->param ( QUERY_INPUTS => \@query_inputs,
 508                    scan_index_to_use => $scan_index_to_use );
 509
 510 ## parse the limit_cgi string and put it into a form suitable for <input>s
 511 my @limit_inputs;
 512 for my $this_cgi ( split('&',$limit_cgi) ) {
 513     next unless $this_cgi;
 514     # handle special case limit-yr
 515     if ($this_cgi =~ /yr,st-numeric/) {
 516         push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 517         next;
 518     }
 519     $this_cgi =~ m/(.*=)(.*)/;
 520     my $input_name = $1;
 521     my $input_value = $2;
 522     $input_name =~ s/=$//;
 523     push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 524 }
 525 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 526
 527 ## II. DO THE SEARCH AND GET THE RESULTS
 528 my $total; # the total results for the whole set
 529 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 530 my @results_array;
 531 my $results_hashref;
 532
 533 eval {
 534     ($error, $results_hashref, $facets) = getRecords($query,$simple_query,\@sort_by,\@servers,$results_per_page,$offset,$expanded_facet,$branches,$itemtypes,$query_type,$scan);
 535 };
 536
 537 # This sorts the facets into alphabetical order
 538 if ($facets) {
 539     foreach my $f (@$facets) {
 540         $f->{facets} = [ sort { uc($a->{facet_label_value}) cmp uc($b->{facet_label_value}) } @{ $f->{facets} } ];
 541     }
 542 }
 543 if ($@ || $error) {
 544     $template->param(query_error => $error.$@);
 545     output_html_with_http_headers $cgi, $cookie, $template->output;
 546     exit;
 547 }
 548
 549 # At this point, each server has given us a result set
 550 # now we build that set for template display
 551 my @sup_results_array;
 552 for (my $i=0;$i<@servers;$i++) {
 553     my $server = $servers[$i];
 554     if ($server =~/biblioserver/) { # this is the local bibliographic server
 555         $hits = $results_hashref->{$server}->{"hits"};
 556         my $page = $cgi->param('page') || 0;
 557         my @newresults = searchResults('intranet', $query_desc, $hits, $results_per_page, $offset, $scan,
 558                                        $results_hashref->{$server}->{"RECORDS"});
 559         $total = $total + $results_hashref->{$server}->{"hits"};
 560
 561         # Search history
 562         if (C4::Context->preference('EnableSearchHistory')) {
 563             unless ( $offset ) {
 564                 my $path_info = $cgi->url(-path_info=>1);
 565                 my $query_cgi_history = $cgi->url(-query=>1);
 566                 $query_cgi_history =~ s/^$path_info\?//;
 567                 $query_cgi_history =~ s/;/&/g;
 568                 my $query_desc_history = $query_desc;
 569                 $query_desc_history .= ", $limit_desc"
 570                     if $limit_desc;
 571
 572                 C4::Search::History::add({
 573                     userid => $borrowernumber,
 574                     sessionid => $cgi->cookie("CGISESSID"),
 575                     query_desc => $query_desc_history,
 576                     query_cgi => $query_cgi_history,
 577                     total => $total,
 578                     type => "biblio",
 579                 });
 580             }
 581             $template->param( EnableSearchHistory => 1 );
 582         }
 583
 584         ## If there's just one result, redirect to the detail page
 585         if ($total == 1) {
 586             my $biblionumber = $newresults[0]->{biblionumber};
 587             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 588             my $views = { C4::Search::enabled_staff_search_views };
 589             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 590                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 591             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 592                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 593             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 594                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 595             } else {
 596                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 597             }
 598             exit;
 599         }
 600
 601         # set up parameters if user wishes to re-run the search
 602         # as a Z39.50 search
 603         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 604
 605         if ($hits) {
 606             $template->param(total => $hits);
 607             my $limit_cgi_not_availablity = $limit_cgi;
 608             $limit_cgi_not_availablity =~ s/&limit=available//g;
 609             $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 610             $template->param(limit_cgi => $limit_cgi);
 611             $template->param(query_cgi => $query_cgi);
 612             $template->param(query_desc => $query_desc);
 613             $template->param(limit_desc => $limit_desc);
 614             $template->param(offset     => $offset);
 615             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 616             if ($query_desc || $limit_desc) {
 617                 $template->param(searchdesc => 1);
 618             }
 619             $template->param(stopwords_removed => "@$stopwords_removed") if $stopwords_removed;
 620             $template->param(results_per_page =>  $results_per_page);
 621             # must define a value for size if not present in DB
 622             # in order to avoid problems generated by the default size value in TT
 623             foreach my $line (@newresults) {
 624                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 625             }
 626             $template->param(SEARCH_RESULTS => \@newresults);
 627             ## FIXME: add a global function for this, it's better than the current global one
 628             ## Build the page numbers on the bottom of the page
 629             my @page_numbers;
 630             # total number of pages there will be
 631             my $pages = ceil($hits / $results_per_page);
 632             # default page number
 633             my $current_page_number = 1;
 634             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 635             my $previous_page_offset;
 636             if ( $offset >= $results_per_page ) {
 637                 $previous_page_offset = $offset - $results_per_page;
 638             }
 639             my $next_page_offset = $offset + $results_per_page;
 640             # If we're within the first 10 pages, keep it simple
 641             #warn "current page:".$current_page_number;
 642             if ($current_page_number < 10) {
 643                 # just show the first 10 pages
 644                 # Loop through the pages
 645                 my $pages_to_show = 10;
 646                 $pages_to_show = $pages if $pages<10;
 647                 for (my $i=1; $i<=$pages_to_show;$i++) {
 648                     # the offset for this page
 649                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 650                     # the page number for this page
 651                     my $this_page_number = $i;
 652                     # put it in the array
 653                     push @page_numbers,
 654                       { offset    => $this_offset,
 655                         pg        => $this_page_number,
 656                         # it should only be highlighted if it's the current page
 657                         highlight => $this_page_number == $current_page_number,
 658                         sort_by   => join ' ', @sort_by
 659                       };
 660
 661                 }
 662
 663             }
 664
 665             # now, show twenty pages, with the current one smack in the middle
 666             else {
 667                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 668                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 669                     my $this_page_number = $i-9;
 670                     if ( $this_page_number <= $pages ) {
 671                         push @page_numbers,
 672                           { offset    => $this_offset,
 673                             pg        => $this_page_number,
 674                             highlight => $this_page_number == $current_page_number,
 675                             sort_by   => join ' ', @sort_by
 676                           };
 677                     }
 678                 }
 679             }
 680             # FIXME: no previous_page_offset when pages < 2
 681             $template->param(   PAGE_NUMBERS => \@page_numbers,
 682                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 683             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 684         }
 685
 686
 687         # no hits
 688         else {
 689             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 690         }
 691
 692     } # end of the if local
 693
 694     # asynchronously search the authority server
 695     elsif ($server =~/authorityserver/) { # this is the local authority server
 696         my @inner_sup_results_array;
 697         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 698             my $marc_record_object = C4::Search::new_record_from_zebra(
 699                 'authorityserver',
 700                 $sup_record
 701             );
 702             # warn "Authority Found: ".$marc_record_object->as_formatted();
 703             push @inner_sup_results_array, {
 704                 'title' => $marc_record_object->field(100)->subfield('a'),
 705                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 706             };
 707         }
 708         push @sup_results_array, {  servername => $server,
 709                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 710     }
 711     # FIXME: can add support for other targets as needed here
 712     $template->param(           outer_sup_results_loop => \@sup_results_array);
 713 } #/end of the for loop
 714 #$template->param(FEDERATED_RESULTS => \@results_array);
 715
 716 $template->{'VARS'}->{'searchid'} = $cgi->param('searchid');
 717
 718 my $gotonumber = $cgi->param('gotoNumber');
 719 if ($gotonumber eq 'last' || $gotonumber eq 'first') {
 720     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 721 }
 722 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 723 my $gotopage = $cgi->param('gotoPage');
 724 $template->{'VARS'}->{'gotoPage'} = $gotopage
 725   if $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 726
 727 for my $facet ( @$facets ) {
 728     for my $entry ( @{ $facet->{facets} } ) {
 729         my $index = $entry->{type_link_value};
 730         my $value = $entry->{facet_link_value};
 731         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 732     }
 733 }
 734
 735 $template->param(
 736             #classlist => $classlist,
 737             total => $total,
 738             opacfacets => 1,
 739             facets_loop => $facets,
 740             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 741             scan => $scan,
 742             search_error => $error,
 743 );
 744
 745 if ($query_desc || $limit_desc) {
 746     $template->param(searchdesc => 1);
 747 }
 748
 749 # VI. BUILD THE TEMPLATE
 750
 751 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 752     {
 753         borrowernumber => $borrowernumber,
 754         add_allowed    => 1,
 755         category       => 1,
 756     }
 757 );
 758 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 759     {
 760         borrowernumber => $borrowernumber,
 761         add_allowed    => 1,
 762         category       => 2,
 763     }
 764 );
 765
 766
 767 $template->param(
 768     add_to_some_private_shelves => $some_private_shelves,
 769     add_to_some_public_shelves  => $some_public_shelves,
 770 );
 771
 772 output_html_with_http_headers $cgi, $cookie, $template->output;