catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output qw( output_html_with_http_headers pagination_bar );
 144 use C4::Auth qw( get_template_and_user );
 145 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 146 use C4::Languages qw( getlanguage getLanguages );
 147 use C4::Koha qw( getitemtypeimagelocation GetAuthorisedValues );
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search qw( searchResults enabled_staff_search_views z3950_search_args new_record_from_zebra );
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = CGI->new;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 # limits are used to limit to results to a pre-defined category such as branch or language
 172 my @limits = map uri_unescape($_), $cgi->multi_param("limit");
 173 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 174 my %is_nolimit = map { $_ => 1 } @nolimits;
 175 @limits = grep { not $is_nolimit{$_} } @limits;
 176 if  (
 177         !$cgi->param('edit_search') &&
 178         ( (@limits>=1) || (defined $cgi->param("q") && $cgi->param("q") ne "" ) || ($cgi->param('limit-yr')) )
 179     ) {
 180     $template_name = 'catalogue/results.tt';
 181     $template_type = 'results';
 182 }
 183 else {
 184     $template_name = 'catalogue/advsearch.tt';
 185     $template_type = 'advsearch';
 186 }
 187 # load the template
 188 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 189     template_name => $template_name,
 190     query => $cgi,
 191     type => "intranet",
 192     flagsrequired   => { catalogue => 1 },
 193     }
 194 );
 195
 196 my $lang = C4::Languages::getlanguage($cgi);
 197
 198 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 199     $template->param('UNIMARC' => 1);
 200 }
 201
 202 if($cgi->cookie("holdfor")){
 203     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 204     if ( $holdfor_patron ) { # may have been deleted in the meanwhile
 205         $template->param(
 206             holdfor            => $cgi->cookie("holdfor"),
 207             holdfor_patron     => $holdfor_patron,
 208             holdfor_cardnumber => $holdfor_patron->cardnumber,
 209         );
 210     }
 211 }
 212
 213 if($cgi->cookie("holdforclub")){
 214     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 215     if ( $holdfor_club ) { # May have been deleted in the meanwhile
 216         $template->param(
 217             holdforclub => $cgi->cookie("holdforclub"),
 218             holdforclub_name => $holdfor_club->name,
 219         );
 220     }
 221 }
 222
 223 if($cgi->cookie("searchToOrder")){
 224     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 225     $template->param(
 226         searchtoorder_basketno => $basketno,
 227         searchtoorder_vendorid => $vendorid
 228     );
 229 }
 230
 231 # get biblionumbers stored in the cart
 232 my @cart_list;
 233
 234 if($cgi->cookie("intranet_bib_list")){
 235     my $cart_list = $cgi->cookie("intranet_bib_list");
 236     @cart_list = split(/\//, $cart_list);
 237 }
 238
 239 my @search_groups =
 240   Koha::Library::Groups->get_search_groups( { interface => 'staff' } )->as_list;
 241 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 242
 243 $template->param(
 244     search_groups    => \@search_groups,
 245 );
 246
 247 # load the Type stuff
 248 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 249 my $advancedsearchesloop = prepare_adv_search_types($types);
 250 $template->param(advancedsearchesloop => $advancedsearchesloop);
 251
 252 $template->param( searchid => scalar $cgi->param('searchid'), );
 253
 254 # The following should only be loaded if we're bringing up the advanced search template
 255 if ( $template_type eq 'advsearch' ) {
 256
 257     my $expanded = $cgi->param('expanded_options');
 258     if( $cgi->param('edit_search') ){
 259         my @operators = $cgi->multi_param('op');
 260         my @indexes   = $cgi->multi_param('idx');
 261         my %limit_hash;
 262         foreach my $limit (@limits){
 263             if ( $limit eq 'available' ){
 264                 $template->param( limit_available => 1 );
 265             } else {
 266                 my ($index,$value) = split(':',$limit);
 267                 $value =~ s/"//g;
 268                 if ( $index =~ /mc-/ ){
 269                     $limit_hash{$index . "_" . $value} = 1;
 270                 } else {
 271                     push @{$limit_hash{$index}}, $value;
 272                 }
 273             }
 274         };
 275         $expanded = 1 if scalar @operators || scalar @limits;
 276         $template->param( operators => \@operators );
 277         $template->param( limits => \%limit_hash );
 278         $template->param(
 279            indexes   => \@indexes,
 280            sort      => $cgi->param('sort_by'),
 281         );
 282     }
 283     # load the servers (used for searching -- to do federated searching, etc.)
 284     my $primary_servers_loop;# = displayPrimaryServers();
 285     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 286
 287     my $secondary_servers_loop;
 288     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 289
 290     # set the default sorting
 291     if (   C4::Context->preference('defaultSortField')
 292         && C4::Context->preference('defaultSortOrder') ) {
 293         my $default_sort_by =
 294             C4::Context->preference('defaultSortField') . '_'
 295           . C4::Context->preference('defaultSortOrder');
 296         $template->param( sort_by => $default_sort_by  );
 297     }
 298
 299     # determine what to display next to the search boxes
 300     my @queries = $cgi->multi_param('q');
 301     while( scalar @queries < 3 ){
 302         push @queries, "";
 303     }
 304     $template->param(uc(C4::Context->preference("marcflavour")) =>1 );
 305
 306     # load the language limits (for search)
 307     my $languages_limit_loop = getLanguages($lang, 1);
 308     $template->param(search_languages_loop => $languages_limit_loop,);
 309     $template->param(       queries   => \@queries );
 310
 311     # Expanded search options in advanced search:
 312     # use the global setting by default, but let the user override it
 313     {
 314         $expanded = C4::Context->preference("expandedSearchOption") || 0
 315             if !defined($expanded) || $expanded !~ /^0|1$/;
 316         $template->param( expanded_options => $expanded );
 317     }
 318
 319     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 320
 321     output_html_with_http_headers $cgi, $cookie, $template->output;
 322     exit;
 323 }
 324
 325 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 326
 327 # Fetch the paramater list as a hash in scalar context:
 328 #  * returns paramater list as tied hash ref
 329 #  * we can edit the values by changing the key
 330 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 331 my $params = $cgi->Vars;
 332 # Params that can have more than one value
 333 # sort by is used to sort the query
 334 # in theory can have more than one but generally there's just one
 335 my @sort_by;
 336 my $default_sort_by;
 337 if (   C4::Context->preference('defaultSortField')
 338     && C4::Context->preference('defaultSortOrder') ) {
 339     $default_sort_by =
 340         C4::Context->preference('defaultSortField') . '_'
 341       . C4::Context->preference('defaultSortOrder');
 342 }
 343
 344 @sort_by = $cgi->multi_param('sort_by');
 345 $sort_by[0] = $default_sort_by unless $sort_by[0];
 346 foreach my $sort (@sort_by) {
 347     $template->param($sort => 1) if $sort;
 348 }
 349 $template->param('sort_by' => $sort_by[0]);
 350
 351 # Use the servers defined, or just search our local catalog(default)
 352 my @servers = $cgi->multi_param('server');
 353 unless (@servers) {
 354     #FIXME: this should be handled using Context.pm
 355     @servers = ("biblioserver");
 356     # @servers = C4::Context->config("biblioserver");
 357 }
 358 # operators include boolean and proximity operators and are used
 359 # to evaluate multiple operands
 360 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 361
 362 # indexes are query qualifiers, like 'title', 'author', etc. They
 363 # can be single or multiple parameters separated by comma: kw,right-Truncation
 364 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 365
 366 # if a simple index (only one)  display the index used in the top search box
 367 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 368     my $idx = "ms_".$indexes[0];
 369     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 370     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 371     $template->param($idx => 1);
 372 }
 373
 374 # an operand can be a single term, a phrase, or a complete ccl query
 375 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 376
 377 # if a simple search, display the value in the search box
 378 if ($operands[0] && !$operands[1]) {
 379     my $ms_query = $operands[0];
 380     $ms_query =~ s/ #\S+//;
 381     $template->param(ms_value => $ms_query);
 382 }
 383
 384 my $available;
 385 foreach my $limit(@limits) {
 386     if ($limit =~/available/) {
 387         $available = 1;
 388     }
 389 }
 390 $template->param(available => $available);
 391
 392 # append year limits if they exist
 393 my $limit_yr;
 394 my $limit_yr_value;
 395 if ($params->{'limit-yr'}) {
 396     if ($params->{'limit-yr'} =~ /\d{4}/) {
 397         $limit_yr = "yr,st-numeric:$params->{'limit-yr'}";
 398         $limit_yr_value = $params->{'limit-yr'};
 399     }
 400     push @limits,$limit_yr;
 401     #FIXME: Should return a error to the user, incorect date format specified
 402 }
 403
 404 # convert indexes and operands to corresponding parameter names for the z3950 search
 405 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 406 my $z3950par;
 407 my $indexes2z3950 = {
 408     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 409     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 410     ti=>'title', 'ti,phr'=>'title', se=>'title'
 411 };
 412 for (my $ii = 0; $ii < @operands; ++$ii)
 413 {
 414     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 415     if (defined $name && defined $operands[$ii])
 416     {
 417         $z3950par ||= {};
 418         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 419     }
 420 }
 421
 422
 423 # Params that can only have one value
 424 my $scan = $params->{'scan'};
 425 my $count = C4::Context->preference('numSearchResults') || 20;
 426 my $results_per_page = $params->{'count'} || $count;
 427 my $offset = $params->{'offset'} || 0;
 428 my $whole_record = $params->{'whole_record'} || 0;
 429 my $weight_search = $params->{'advsearch'} ? $params->{'weight_search'} || 0 : 1;
 430 $offset = 0 if $offset < 0;
 431 my $page = $cgi->param('page') || 1;
 432 #my $offset = ($page-1)*$results_per_page;
 433
 434 # Define some global variables
 435 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 436
 437 my $builder = Koha::SearchEngine::QueryBuilder->new(
 438     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 439 my $searcher = Koha::SearchEngine::Search->new(
 440     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 441
 442 ## I. BUILD THE QUERY
 443 (
 444     $error,             $query, $simple_query, $query_cgi,
 445     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 446     $query_type
 447   )
 448   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 449     \@sort_by, $scan, $lang, { weighted_fields => $weight_search, whole_record => $whole_record });
 450
 451 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 452
 453 ## parse the query_cgi string and put it into a form suitable for <input>s
 454 my @query_inputs;
 455 my $scan_index_to_use;
 456 my $scan_search_term_to_use;
 457
 458 if ($query_cgi) {
 459     for my $this_cgi ( split('&', $query_cgi) ) {
 460         next unless $this_cgi;
 461         $this_cgi =~ m/(.*?)=(.*)/;
 462         my $input_name = $1;
 463         my $input_value = $2;
 464         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 465         if ($input_name eq 'idx') {
 466             # The form contains multiple fields, so take the first value as the scan index
 467             $scan_index_to_use = $input_value unless $scan_index_to_use;
 468         }
 469         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 470             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 471         }
 472     }
 473 }
 474
 475 $template->param ( QUERY_INPUTS => \@query_inputs,
 476                    scan_index_to_use => $scan_index_to_use,
 477                    scan_search_term_to_use => $scan_search_term_to_use );
 478
 479 ## parse the limit_cgi string and put it into a form suitable for <input>s
 480 my @limit_inputs;
 481 if ($limit_cgi) {
 482     for my $this_cgi ( split('&', $limit_cgi) ) {
 483         next unless $this_cgi;
 484         # handle special case limit-yr
 485         if ($this_cgi =~ /yr,st-numeric/) {
 486             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 487             next;
 488         }
 489         $this_cgi =~ m/(.*=)(.*)/;
 490         my $input_name = $1;
 491         my $input_value = $2;
 492         $input_name =~ s/=$//;
 493         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 494     }
 495 }
 496 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 497
 498 ## II. DO THE SEARCH AND GET THE RESULTS
 499 my $total = 0; # the total results for the whole set
 500 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 501 my $results_hashref;
 502
 503 eval {
 504     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 505     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 506         $query,            $simple_query, \@sort_by,       \@servers,
 507         $results_per_page, $offset,       undef,           $itemtypes,
 508         $query_type,       $scan
 509     );
 510 };
 511
 512 if ($@ || $error) {
 513     my $query_error = q{};
 514     $query_error .= $error if $error;
 515     $query_error .= $@ if $@;
 516     $template->param(query_error => $query_error);
 517     output_html_with_http_headers $cgi, $cookie, $template->output;
 518     exit;
 519 }
 520
 521 # At this point, each server has given us a result set
 522 # now we build that set for template display
 523 my @sup_results_array;
 524 for (my $i=0;$i<@servers;$i++) {
 525     my $server = $servers[$i];
 526     if ($server =~/biblioserver/) { # this is the local bibliographic server
 527         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 528         my $page = $cgi->param('page') || 0;
 529         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 530                                        $results_hashref->{$server}->{"RECORDS"});
 531         $total = $total + $hits;
 532
 533         # Search history
 534         if (C4::Context->preference('EnableSearchHistory')) {
 535             unless ( $offset ) {
 536                 my $path_info = $cgi->url(-path_info=>1);
 537                 my $query_cgi_history = $cgi->url(-query=>1);
 538                 $query_cgi_history =~ s/^$path_info\?//;
 539                 $query_cgi_history =~ s/;/&/g;
 540                 my $query_desc_history = $query_desc;
 541                 $query_desc_history .= ", $limit_desc"
 542                     if $limit_desc;
 543
 544                 C4::Search::History::add({
 545                     userid => $borrowernumber,
 546                     sessionid => $cgi->cookie("CGISESSID"),
 547                     query_desc => $query_desc_history,
 548                     query_cgi => $query_cgi_history,
 549                     total => $total,
 550                     type => "biblio",
 551                 });
 552             }
 553             $template->param( EnableSearchHistory => 1 );
 554         }
 555
 556         ## If there's just one result, redirect to the detail page unless doing an index scan
 557         if ($total == 1 && !$scan) {
 558             my $biblionumber = $newresults[0]->{biblionumber};
 559             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 560             my $views = { C4::Search::enabled_staff_search_views };
 561             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 562                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&found1=1");
 563             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 564                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&found1=1");
 565             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 566                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&found1=1");
 567             } else {
 568                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&found1=1");
 569             }
 570             exit;
 571         }
 572
 573         # set up parameters if user wishes to re-run the search
 574         # as a Z39.50 search
 575         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 576         $template->param(limit_cgi => $limit_cgi);
 577         $template->param(query_cgi => $query_cgi);
 578         $template->param(query_desc => $query_desc);
 579         $template->param(limit_desc => $limit_desc);
 580         $template->param(offset     => $offset);
 581
 582         if ($hits) {
 583             $template->param(total => $hits);
 584             if ($limit_cgi) {
 585                 my $limit_cgi_not_availablity = $limit_cgi;
 586                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 587                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 588             }
 589             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 590             if ($query_desc || $limit_desc) {
 591                 $template->param(searchdesc => 1);
 592             }
 593             $template->param(results_per_page =>  $results_per_page);
 594             # must define a value for size if not present in DB
 595             # in order to avoid problems generated by the default size value in TT
 596             foreach my $line (@newresults) {
 597                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 598                 # while we're checking each line, see if item is in the cart
 599                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 600                     $line->{'incart'} = 1;
 601                 }
 602             }
 603             my( $page_numbers, $hits_to_paginate, $pages, $current_page_number, $previous_page_offset, $next_page_offset, $last_page_offset ) =
 604                 Koha::SearchEngine::Search->pagination_bar(
 605                     {
 606                         hits              => $hits,
 607                         max_result_window => $searcher->max_result_window,
 608                         results_per_page  => $results_per_page,
 609                         offset            => $offset,
 610                         sort_by           => \@sort_by
 611                     }
 612                 );
 613             $template->param( hits_to_paginate => $hits_to_paginate );
 614             $template->param(SEARCH_RESULTS => \@newresults);
 615             # FIXME: no previous_page_offset when pages < 2
 616             $template->param(   PAGE_NUMBERS => $page_numbers,
 617                                 last_page_offset => $last_page_offset,
 618                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 619             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 620         }
 621
 622
 623         # no hits
 624         else {
 625             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 626         }
 627
 628     } # end of the if local
 629
 630     # asynchronously search the authority server
 631     elsif ($server =~/authorityserver/) { # this is the local authority server
 632         my @inner_sup_results_array;
 633         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 634             my $marc_record_object = C4::Search::new_record_from_zebra(
 635                 'authorityserver',
 636                 $sup_record
 637             );
 638             # warn "Authority Found: ".$marc_record_object->as_formatted();
 639             push @inner_sup_results_array, {
 640                 'title' => $marc_record_object->field(100)->subfield('a'),
 641                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 642             };
 643         }
 644         push @sup_results_array, {  servername => $server,
 645                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 646     }
 647     # FIXME: can add support for other targets as needed here
 648     $template->param(           outer_sup_results_loop => \@sup_results_array);
 649 } #/end of the for loop
 650 #$template->param(FEDERATED_RESULTS => \@results_array);
 651
 652 my $gotonumber = $cgi->param('gotoNumber');
 653 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 654     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 655 }
 656 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 657 my $gotopage = $cgi->param('gotoPage');
 658 $template->{'VARS'}->{'gotoPage'} = $gotopage
 659   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 660
 661 for my $facet ( @$facets ) {
 662     for my $entry ( @{ $facet->{facets} } ) {
 663         my $index = $entry->{type_link_value};
 664         my $value = $entry->{facet_link_value};
 665         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 666     }
 667 }
 668
 669 $template->param(
 670             #classlist => $classlist,
 671             total => $total,
 672             opacfacets => 1,
 673             facets_loop => $facets,
 674             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 675             scan => $scan,
 676             search_error => $error,
 677 );
 678
 679 if ($query_desc || $limit_desc) {
 680     $template->param(searchdesc => 1);
 681 }
 682
 683 # VI. BUILD THE TEMPLATE
 684
 685 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 686     {
 687         borrowernumber => $borrowernumber,
 688         add_allowed    => 1,
 689         public         => 0,
 690     }
 691 );
 692 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 693     {
 694         borrowernumber => $borrowernumber,
 695         add_allowed    => 1,
 696         public         => 1,
 697     }
 698 );
 699
 700
 701 $template->param(
 702     add_to_some_private_shelves => $some_private_shelves,
 703     add_to_some_public_shelves  => $some_public_shelves,
 704 );
 705
 706 output_html_with_http_headers $cgi, $cookie, $template->output;
 707
 708
 709 =head2 prepare_adv_search_types
 710
 711     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 712     my @advanced_search_types = prepare_adv_search_types($type);
 713
 714 Different types can be searched for in the advanced search. This takes the
 715 system preference that defines these types and parses it into an arrayref for
 716 the template.
 717
 718 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 719 It also accounts for the "item-level_itypes" system preference.
 720
 721 =cut
 722
 723 sub prepare_adv_search_types {
 724     my ($types) = @_;
 725
 726     my @advanced_search_types = split( /\|/, $types );
 727
 728     # the index parameter is different for item-level itemtypes
 729     my $itype_or_itemtype =
 730       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 731     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 732
 733     my ( $cnt, @result );
 734     foreach my $advanced_srch_type (@advanced_search_types) {
 735         $advanced_srch_type =~ s/^\s*//;
 736         $advanced_srch_type =~ s/\s*$//;
 737         if ( $advanced_srch_type eq 'itemtypes' ) {
 738
 739        # itemtype is a special case, since it's not defined in authorized values
 740             my @itypesloop;
 741             foreach my $thisitemtype (
 742                 sort {
 743                     $itemtypes->{$a}->{'translated_description'}
 744                       cmp $itemtypes->{$b}->{'translated_description'}
 745                 } keys %$itemtypes
 746               )
 747             {
 748                 my %row = (
 749                     number      => $cnt++,
 750                     ccl         => "$itype_or_itemtype,phr",
 751                     code        => $thisitemtype,
 752                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 753                     imageurl    => getitemtypeimagelocation(
 754                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 755                     ),
 756                 );
 757                 push @itypesloop, \%row;
 758             }
 759             my %search_code = (
 760                 advanced_search_type => $advanced_srch_type,
 761                 code_loop            => \@itypesloop
 762             );
 763             push @result, \%search_code;
 764         }
 765         else {
 766             # covers all the other cases: non-itemtype authorized values
 767             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 768             my @authvalueloop;
 769             for my $thisitemtype (@$advsearchtypes) {
 770                 my %row = (
 771                     number      => $cnt++,
 772                     ccl         => $advanced_srch_type,
 773                     code        => $thisitemtype->{authorised_value},
 774                     description => $thisitemtype->{'lib'},
 775                     imageurl    => getitemtypeimagelocation(
 776                         'intranet', $thisitemtype->{'imageurl'}
 777                     ),
 778                 );
 779                 push @authvalueloop, \%row;
 780             }
 781             my %search_code = (
 782                 advanced_search_type => $advanced_srch_type,
 783                 code_loop            => \@authvalueloop
 784             );
 785             push @result, \%search_code;
 786         }
 787     }
 788     return \@result;
 789 }