cataloguing/addbiblio.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 # Copyright 2004-2010 BibLibre
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI q(-utf8);
  25 use C4::Output;
  26 use C4::Auth;
  27 use C4::Biblio;
  28 use C4::Search;
  29 use C4::AuthoritiesMarc;
  30 use C4::Context;
  31 use MARC::Record;
  32 use C4::Log;
  33 use C4::Koha;
  34 use C4::ClassSource;
  35 use C4::ImportBatch;
  36 use C4::Charset;
  37 use Koha::BiblioFrameworks;
  38 use Koha::DateUtils;
  39
  40 use Koha::ItemTypes;
  41 use Koha::Libraries;
  42
  43 use Koha::BiblioFrameworks;
  44
  45 use Date::Calc qw(Today);
  46 use MARC::File::USMARC;
  47 use MARC::File::XML;
  48 use URI::Escape;
  49
  50 if ( C4::Context->preference('marcflavour') eq 'UNIMARC' ) {
  51     MARC::File::XML->default_record_format('UNIMARC');
  52 }
  53
  54 our($tagslib,$authorised_values_sth,$is_a_modif,$usedTagsLib,$mandatory_z3950);
  55
  56 =head1 FUNCTIONS
  57
  58 =head2 MARCfindbreeding
  59
  60     $record = MARCfindbreeding($breedingid);
  61
  62 Look up the import record repository for the record with
  63 record with id $breedingid.  If found, returns the decoded
  64 MARC::Record; otherwise, -1 is returned (FIXME).
  65 Returns as second parameter the character encoding.
  66
  67 =cut
  68
  69 sub MARCfindbreeding {
  70     my ( $id ) = @_;
  71     my ($marc, $encoding) = GetImportRecordMarc($id);
  72     # remove the - in isbn, koha store isbn without any -
  73     if ($marc) {
  74         my $record = MARC::Record->new_from_usmarc($marc);
  75         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField( 'biblioitems.isbn' );
  76         if ( $record->field($isbnfield) ) {
  77             foreach my $field ( $record->field($isbnfield) ) {
  78                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
  79                     my $newisbn = $field->subfield($isbnsubfield);
  80                     $newisbn =~ s/-//g;
  81                     $field->update( $isbnsubfield => $newisbn );
  82                 }
  83             }
  84         }
  85         # fix the unimarc 100 coded field (with unicode information)
  86         if (C4::Context->preference('marcflavour') eq 'UNIMARC' && $record->subfield(100,'a')) {
  87             my $f100a=$record->subfield(100,'a');
  88             my $f100 = $record->field(100);
  89             my $f100temp = $f100->as_string;
  90             $record->delete_field($f100);
  91             if ( length($f100temp) > 28 ) {
  92                 substr( $f100temp, 26, 2, "50" );
  93                 $f100->update( 'a' => $f100temp );
  94                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
  95                 $record->insert_fields_ordered($f100);
  96             }
  97         }
  98
  99         if ( !defined(ref($record)) ) {
 100             return -1;
 101         }
 102         else {
 103             # normalize author : UNIMARC specific...
 104             if (    C4::Context->preference("z3950NormalizeAuthor")
 105                 and C4::Context->preference("z3950AuthorAuthFields")
 106                 and C4::Context->preference("marcflavour") eq 'UNIMARC' )
 107             {
 108                 my ( $tag, $subfield ) = GetMarcFromKohaField( "biblio.author" );
 109
 110                 my $auth_fields =
 111                   C4::Context->preference("z3950AuthorAuthFields");
 112                 my @auth_fields = split /,/, $auth_fields;
 113                 my $field;
 114
 115                 if ( $record->field($tag) ) {
 116                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 117
 118                         my $subfieldcode  = shift @$tmpfield;
 119                         my $subfieldvalue = shift @$tmpfield;
 120                         if ($field) {
 121                             $field->add_subfields(
 122                                 "$subfieldcode" => $subfieldvalue )
 123                               if ( $subfieldcode ne $subfield );
 124                         }
 125                         else {
 126                             $field =
 127                               MARC::Field->new( $tag, "", "",
 128                                 $subfieldcode => $subfieldvalue )
 129                               if ( $subfieldcode ne $subfield );
 130                         }
 131                     }
 132                 }
 133                 $record->delete_field( $record->field($tag) );
 134                 foreach my $fieldtag (@auth_fields) {
 135                     next unless ( $record->field($fieldtag) );
 136                     my $lastname  = $record->field($fieldtag)->subfield('a');
 137                     my $firstname = $record->field($fieldtag)->subfield('b');
 138                     my $title     = $record->field($fieldtag)->subfield('c');
 139                     my $number    = $record->field($fieldtag)->subfield('d');
 140                     if ($title) {
 141                         $field->add_subfields(
 142                                 "$subfield" => ucfirst($title) . " "
 143                               . ucfirst($firstname) . " "
 144                               . $number );
 145                     }
 146                     else {
 147                         $field->add_subfields(
 148                             "$subfield" => ucfirst($firstname) . ", "
 149                               . ucfirst($lastname) );
 150                     }
 151                 }
 152                 $record->insert_fields_ordered($field);
 153             }
 154             return $record, $encoding;
 155         }
 156     }
 157     return -1;
 158 }
 159
 160 =head2 build_authorized_values_list
 161
 162 =cut
 163
 164 sub build_authorized_values_list {
 165     my ( $tag, $subfield, $value, $dbh, $authorised_values_sth,$index_tag,$index_subfield ) = @_;
 166
 167     my @authorised_values;
 168     my %authorised_lib;
 169
 170     # builds list, depending on authorised value...
 171
 172     #---- branch
 173     if ( $tagslib->{$tag}->{$subfield}->{'authorised_value'} eq "branches" ) {
 174         my $libraries = Koha::Libraries->search_filtered({}, {order_by => ['branchname']});
 175         while ( my $l = $libraries->next ) {
 176             push @authorised_values, $l->branchcode;;
 177             $authorised_lib{$l->branchcode} = $l->branchname;
 178         }
 179     }
 180     elsif ( $tagslib->{$tag}->{$subfield}->{authorised_value} eq "itemtypes" ) {
 181         push @authorised_values, "";
 182
 183         my $itemtype;
 184         my $itemtypes = Koha::ItemTypes->search_with_localization;
 185         while ( $itemtype = $itemtypes->next ) {
 186             push @authorised_values, $itemtype->itemtype;
 187             $authorised_lib{$itemtype->itemtype} = $itemtype->translated_description;
 188         }
 189         $value = $itemtype unless ($value);
 190     }
 191     elsif ( $tagslib->{$tag}->{$subfield}->{authorised_value} eq "cn_source" ) {
 192         push @authorised_values, "";
 193
 194         my $class_sources = GetClassSources();
 195
 196         my $default_source = C4::Context->preference("DefaultClassificationSource");
 197
 198         foreach my $class_source (sort keys %$class_sources) {
 199             next unless $class_sources->{$class_source}->{'used'} or
 200                         ($value and $class_source eq $value) or
 201                         ($class_source eq $default_source);
 202             push @authorised_values, $class_source;
 203             $authorised_lib{$class_source} = $class_sources->{$class_source}->{'description'};
 204         }
 205         $value = $default_source unless $value;
 206     }
 207     else {
 208         my $branch_limit = C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
 209         $authorised_values_sth->execute(
 210             $tagslib->{$tag}->{$subfield}->{authorised_value},
 211             $branch_limit ? $branch_limit : (),
 212         );
 213
 214         push @authorised_values, "";
 215
 216         while ( my ( $value, $lib ) = $authorised_values_sth->fetchrow_array ) {
 217             push @authorised_values, $value;
 218             $authorised_lib{$value} = $lib;
 219         }
 220     }
 221     $authorised_values_sth->finish;
 222     return {
 223         type     => 'select',
 224         id       => "tag_".$tag."_subfield_".$subfield."_".$index_tag."_".$index_subfield,
 225         name     => "tag_".$tag."_subfield_".$subfield."_".$index_tag."_".$index_subfield,
 226         default  => $value,
 227         values   => \@authorised_values,
 228         labels   => \%authorised_lib,
 229     };
 230
 231 }
 232
 233 =head2 CreateKey
 234
 235     Create a random value to set it into the input name
 236
 237 =cut
 238
 239 sub CreateKey {
 240     return int(rand(1000000));
 241 }
 242
 243 =head2 GetMandatoryFieldZ3950
 244
 245     This function returns a hashref which contains all mandatory field
 246     to search with z3950 server.
 247
 248 =cut
 249
 250 sub GetMandatoryFieldZ3950 {
 251     my $frameworkcode = shift;
 252     my @isbn   = GetMarcFromKohaField( 'biblioitems.isbn' );
 253     my @title  = GetMarcFromKohaField( 'biblio.title' );
 254     my @author = GetMarcFromKohaField( 'biblio.author' );
 255     my @issn   = GetMarcFromKohaField( 'biblioitems.issn' );
 256     my @lccn   = GetMarcFromKohaField( 'biblioitems.lccn' );
 257
 258     return {
 259         $isbn[0].$isbn[1]     => 'isbn',
 260         $title[0].$title[1]   => 'title',
 261         $author[0].$author[1] => 'author',
 262         $issn[0].$issn[1]     => 'issn',
 263         $lccn[0].$lccn[1]     => 'lccn',
 264     };
 265 }
 266
 267 =head2 create_input
 268
 269  builds the <input ...> entry for a subfield.
 270
 271 =cut
 272
 273 sub create_input {
 274     my ( $tag, $subfield, $value, $index_tag, $tabloop, $rec, $authorised_values_sth,$cgi ) = @_;
 275
 276     my $index_subfield = CreateKey(); # create a specifique key for each subfield
 277
 278     # if there is no value provided but a default value in parameters, get it
 279     if ( $value eq '' ) {
 280         $value = $tagslib->{$tag}->{$subfield}->{defaultvalue} // q{};
 281
 282         # get today date & replace <<YYYY>>, <<MM>>, <<DD>> if provided in the default value
 283         my $today_dt = dt_from_string;
 284         my $year = $today_dt->strftime('%Y');
 285         my $month = $today_dt->strftime('%m');
 286         my $day = $today_dt->strftime('%d');
 287         $value =~ s/<<YYYY>>/$year/g;
 288         $value =~ s/<<MM>>/$month/g;
 289         $value =~ s/<<DD>>/$day/g;
 290         # And <<USER>> with surname (?)
 291         my $username=(C4::Context->userenv?C4::Context->userenv->{'surname'}:"superlibrarian");
 292         $value=~s/<<USER>>/$username/g;
 293
 294     }
 295     my $dbh = C4::Context->dbh;
 296
 297     # map '@' as "subfield" label for fixed fields
 298     # to something that's allowed in a div id.
 299     my $id_subfield = $subfield;
 300     $id_subfield = "00" if $id_subfield eq "@";
 301
 302     my %subfield_data = (
 303         tag        => $tag,
 304         subfield   => $id_subfield,
 305         marc_lib       => $tagslib->{$tag}->{$subfield}->{lib},
 306         tag_mandatory  => $tagslib->{$tag}->{mandatory},
 307         mandatory      => $tagslib->{$tag}->{$subfield}->{mandatory},
 308         important      => $tagslib->{$tag}->{$subfield}->{important},
 309         repeatable     => $tagslib->{$tag}->{$subfield}->{repeatable},
 310         kohafield      => $tagslib->{$tag}->{$subfield}->{kohafield},
 311         index          => $index_tag,
 312         id             => "tag_".$tag."_subfield_".$id_subfield."_".$index_tag."_".$index_subfield,
 313         value          => $value,
 314         maxlength      => $tagslib->{$tag}->{$subfield}->{maxlength},
 315         random         => CreateKey(),
 316     );
 317
 318     if(exists $mandatory_z3950->{$tag.$subfield}){
 319         $subfield_data{z3950_mandatory} = $mandatory_z3950->{$tag.$subfield};
 320     }
 321     # Subfield is hidden depending of hidden and mandatory flag, and is always
 322     # shown if it contains anything or if its field is mandatory or important.
 323     my $tdef = $tagslib->{$tag};
 324     $subfield_data{visibility} = "display:none;"
 325         if $tdef->{$subfield}->{hidden} % 2 == 1 &&
 326            $value eq '' &&
 327            !$tdef->{$subfield}->{mandatory} &&
 328            !$tdef->{mandatory} &&
 329            !$tdef->{$subfield}->{important} &&
 330            !$tdef->{important};
 331     # expand all subfields of 773 if there is a host item provided in the input
 332     $subfield_data{visibility} ="" if ($tag eq 773 and $cgi->param('hostitemnumber'));
 333
 334
 335     # it's an authorised field
 336     if ( $tagslib->{$tag}->{$subfield}->{authorised_value} ) {
 337         $subfield_data{marc_value} =
 338           build_authorized_values_list( $tag, $subfield, $value, $dbh,
 339             $authorised_values_sth,$index_tag,$index_subfield );
 340
 341     # it's a subfield $9 linking to an authority record - see bug 2206
 342     }
 343     elsif ($subfield eq "9" and
 344            exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 345            defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 346            $tagslib->{$tag}->{'a'}->{authtypecode} ne '') {
 347
 348         $subfield_data{marc_value} = {
 349             type      => 'text',
 350             id        => $subfield_data{id},
 351             name      => $subfield_data{id},
 352             value     => $value,
 353             size      => 5,
 354             maxlength => $subfield_data{maxlength},
 355             readonly  => 1,
 356         };
 357
 358     # it's a thesaurus / authority field
 359     }
 360     elsif ( $tagslib->{$tag}->{$subfield}->{authtypecode} ) {
 361         # when authorities auto-creation is allowed, do not set readonly
 362         my $is_readonly = !C4::Context->preference("BiblioAddsAuthorities");
 363
 364         $subfield_data{marc_value} = {
 365             type      => 'text',
 366             id        => $subfield_data{id},
 367             name      => $subfield_data{id},
 368             value     => $value,
 369             size      => 67,
 370             maxlength => $subfield_data{maxlength},
 371             readonly  => ($is_readonly) ? 1 : 0,
 372             authtype  => $tagslib->{$tag}->{$subfield}->{authtypecode},
 373         };
 374
 375     # it's a plugin field
 376     } elsif ( $tagslib->{$tag}->{$subfield}->{'value_builder'} ) {
 377         require Koha::FrameworkPlugin;
 378         my $plugin = Koha::FrameworkPlugin->new( {
 379             name => $tagslib->{$tag}->{$subfield}->{'value_builder'},
 380         });
 381         my $pars= { dbh => $dbh, record => $rec, tagslib => $tagslib,
 382             id => $subfield_data{id}, tabloop => $tabloop };
 383         $plugin->build( $pars );
 384         if( !$plugin->errstr ) {
 385             $subfield_data{marc_value} = {
 386                 type           => 'text_complex',
 387                 id             => $subfield_data{id},
 388                 name           => $subfield_data{id},
 389                 value          => $value,
 390                 size           => 67,
 391                 maxlength      => $subfield_data{maxlength},
 392                 javascript     => $plugin->javascript,
 393                 noclick        => $plugin->noclick,
 394             };
 395         } else {
 396             warn $plugin->errstr;
 397             # supply default input form
 398             $subfield_data{marc_value} = {
 399                 type      => 'text',
 400                 id        => $subfield_data{id},
 401                 name      => $subfield_data{id},
 402                 value     => $value,
 403                 size      => 67,
 404                 maxlength => $subfield_data{maxlength},
 405                 readonly  => 0,
 406             };
 407         }
 408
 409     # it's an hidden field
 410     } elsif ( $tag eq '' ) {
 411         $subfield_data{marc_value} = {
 412             type      => 'hidden',
 413             id        => $subfield_data{id},
 414             name      => $subfield_data{id},
 415             value     => $value,
 416             size      => 67,
 417             maxlength => $subfield_data{maxlength},
 418         };
 419
 420     }
 421     else {
 422         # it's a standard field
 423         if (
 424             length($value) > 100
 425             or
 426             ( C4::Context->preference("marcflavour") eq "UNIMARC" && $tag >= 300
 427                 and $tag < 400 && $subfield eq 'a' )
 428             or (    $tag >= 500
 429                 and $tag < 600
 430                 && C4::Context->preference("marcflavour") eq "MARC21" )
 431           )
 432         {
 433             $subfield_data{marc_value} = {
 434                 type      => 'textarea',
 435                 id        => $subfield_data{id},
 436                 name      => $subfield_data{id},
 437                 value     => $value,
 438             };
 439
 440         }
 441         else {
 442             $subfield_data{marc_value} = {
 443                 type      => 'text',
 444                 id        => $subfield_data{id},
 445                 name      => $subfield_data{id},
 446                 value     => $value,
 447                 size      => 67,
 448                 maxlength => $subfield_data{maxlength},
 449                 readonly  => 0,
 450             };
 451
 452         }
 453     }
 454     $subfield_data{'index_subfield'} = $index_subfield;
 455     return \%subfield_data;
 456 }
 457
 458
 459 =head2 format_indicator
 460
 461 Translate indicator value for output form - specifically, map
 462 indicator = ' ' to ''.  This is for the convenience of a cataloger
 463 using a mouse to select an indicator input.
 464
 465 =cut
 466
 467 sub format_indicator {
 468     my $ind_value = shift;
 469     return '' if not defined $ind_value;
 470     return '' if $ind_value eq ' ';
 471     return $ind_value;
 472 }
 473
 474 sub build_tabs {
 475     my ( $template, $record, $dbh, $encoding,$input ) = @_;
 476
 477     # fill arrays
 478     my @loop_data = ();
 479     my $tag;
 480
 481     my $branch_limit = C4::Context->userenv ? C4::Context->userenv->{"branch"} : "";
 482     my $query = "SELECT authorised_value, lib
 483                 FROM authorised_values";
 484     $query .= qq{ LEFT JOIN authorised_values_branches ON ( id = av_id )} if $branch_limit;
 485     $query .= " WHERE category = ?";
 486     $query .= " AND ( branchcode = ? OR branchcode IS NULL )" if $branch_limit;
 487     $query .= " GROUP BY authorised_value,lib ORDER BY lib, lib_opac";
 488     my $authorised_values_sth = $dbh->prepare( $query );
 489
 490     # in this array, we will push all the 10 tabs
 491     # to avoid having 10 tabs in the template : they will all be in the same BIG_LOOP
 492     my @BIG_LOOP;
 493     my %seen;
 494     my @tab_data; # all tags to display
 495
 496     my $max_num_tab=-1;
 497     my ( $itemtag, $itemsubfield ) = GetMarcFromKohaField( "items.itemnumber" );
 498     foreach my $used ( @$usedTagsLib ){
 499
 500         push @tab_data,$used->{tagfield} if not $seen{$used->{tagfield}};
 501         $seen{$used->{tagfield}}++;
 502
 503         if (   $used->{tab} > -1
 504             && $used->{tab} >= $max_num_tab
 505             && $used->{tagfield} ne $itemtag )
 506         {
 507             $max_num_tab = $used->{tab};
 508         }
 509     }
 510     if($max_num_tab >= 9){
 511         $max_num_tab = 9;
 512     }
 513     # loop through each tab 0 through 9
 514     for ( my $tabloop = 0 ; $tabloop <= $max_num_tab ; $tabloop++ ) {
 515         my @loop_data = (); #innerloop in the template.
 516         my $i = 0;
 517         foreach my $tag (sort @tab_data) {
 518             $i++;
 519             next if ! $tag;
 520             my ($indicator1, $indicator2);
 521             my $index_tag = CreateKey;
 522
 523             # if MARC::Record is not empty =>use it as master loop, then add missing subfields that should be in the tab.
 524             # if MARC::Record is empty => use tab as master loop.
 525             if ( $record ne -1 && ( $record->field($tag) || $tag eq '000' ) ) {
 526                 my @fields;
 527                 if ( $tag ne '000' ) {
 528                     @fields = $record->field($tag);
 529                 }
 530                 else {
 531                    push @fields, $record->leader(); # if tag == 000
 532                 }
 533                 # loop through each field
 534                 foreach my $field (@fields) {
 535
 536                     my @subfields_data;
 537                     if ( $tag < 10 ) {
 538                         my ( $value, $subfield );
 539                         if ( $tag ne '000' ) {
 540                             $value    = $field->data();
 541                             $subfield = "@";
 542                         }
 543                         else {
 544                             $value    = $field;
 545                             $subfield = '@';
 546                         }
 547                         next if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 548                         next
 549                           if ( $tagslib->{$tag}->{$subfield}->{kohafield} eq
 550                             'biblio.biblionumber' );
 551                         push(
 552                             @subfields_data,
 553                             &create_input(
 554                                 $tag, $subfield, $value, $index_tag, $tabloop, $record,
 555                                 $authorised_values_sth,$input
 556                             )
 557                         );
 558                     }
 559                     else {
 560                         my @subfields = $field->subfields();
 561                         foreach my $subfieldcount ( 0 .. $#subfields ) {
 562                             my $subfield = $subfields[$subfieldcount][0];
 563                             my $value    = $subfields[$subfieldcount][1];
 564                             next if ( length $subfield != 1 );
 565                             next if ( !defined $tagslib->{$tag}->{$subfield} || $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 566                             push(
 567                                 @subfields_data,
 568                                 &create_input(
 569                                     $tag, $subfield, $value, $index_tag, $tabloop,
 570                                     $record, $authorised_values_sth,$input
 571                                 )
 572                             );
 573                         }
 574                     }
 575
 576                     # now, loop again to add parameter subfield that are not in the MARC::Record
 577                     foreach my $subfield ( sort( keys %{ $tagslib->{$tag} } ) )
 578                     {
 579                         next if ( length $subfield != 1 );
 580                         next if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 581                         next if ( $tag < 10 );
 582                         next
 583                           if ( ( $tagslib->{$tag}->{$subfield}->{hidden} <= -4 )
 584                             or ( $tagslib->{$tag}->{$subfield}->{hidden} >= 5 ) )
 585                             and not ( $subfield eq "9" and
 586                                       exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 587                                       defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 588                                       $tagslib->{$tag}->{'a'}->{authtypecode} ne ""
 589                                     )
 590                           ;    #check for visibility flag
 591                                # if subfield is $9 in a field whose $a is authority-controlled,
 592                                # always include in the form regardless of the hidden setting - bug 2206
 593                         next if ( defined( $field->subfield($subfield) ) );
 594                         push(
 595                             @subfields_data,
 596                             &create_input(
 597                                 $tag, $subfield, '', $index_tag, $tabloop, $record,
 598                                 $authorised_values_sth,$input
 599                             )
 600                         );
 601                     }
 602                     if ( $#subfields_data >= 0 ) {
 603                         # build the tag entry.
 604                         # note that the random() field is mandatory. Otherwise, on repeated fields, you'll
 605                         # have twice the same "name" value, and cgi->param() will return only one, making
 606                         # all subfields to be merged in a single field.
 607                         my %tag_data = (
 608                             tag           => $tag,
 609                             index         => $index_tag,
 610                             tag_lib       => $tagslib->{$tag}->{lib},
 611                             repeatable       => $tagslib->{$tag}->{repeatable},
 612                             mandatory       => $tagslib->{$tag}->{mandatory},
 613                             important       => $tagslib->{$tag}->{important},
 614                             subfield_loop => \@subfields_data,
 615                             fixedfield    => $tag < 10?1:0,
 616                             random        => CreateKey,
 617                         );
 618                         if ($tag >= 10){ # no indicator for 00x tags
 619                            $tag_data{indicator1} = format_indicator($field->indicator(1)),
 620                            $tag_data{indicator2} = format_indicator($field->indicator(2)),
 621                         }
 622                         push( @loop_data, \%tag_data );
 623                     }
 624                  } # foreach $field end
 625
 626             # if breeding is empty
 627             }
 628             else {
 629                 my @subfields_data;
 630                 foreach my $subfield ( sort( keys %{ $tagslib->{$tag} } ) ) {
 631                     next if ( length $subfield != 1 );
 632                     next
 633                       if ( ( $tagslib->{$tag}->{$subfield}->{hidden} <= -4 )
 634                         or ( $tagslib->{$tag}->{$subfield}->{hidden} >= 5 ) )
 635                       and not ( $subfield eq "9" and
 636                                 exists($tagslib->{$tag}->{'a'}->{authtypecode}) and
 637                                 defined($tagslib->{$tag}->{'a'}->{authtypecode}) and
 638                                 $tagslib->{$tag}->{'a'}->{authtypecode} ne ""
 639                               )
 640                       ;    #check for visibility flag
 641                            # if subfield is $9 in a field whose $a is authority-controlled,
 642                            # always include in the form regardless of the hidden setting - bug 2206
 643                     next
 644                       if ( $tagslib->{$tag}->{$subfield}->{tab} ne $tabloop );
 645                         push(
 646                         @subfields_data,
 647                         &create_input(
 648                             $tag, $subfield, '', $index_tag, $tabloop, $record,
 649                             $authorised_values_sth,$input
 650                         )
 651                     );
 652                 }
 653                 if ( $#subfields_data >= 0 ) {
 654                     my %tag_data = (
 655                         tag              => $tag,
 656                         index            => $index_tag,
 657                         tag_lib          => $tagslib->{$tag}->{lib},
 658                         repeatable       => $tagslib->{$tag}->{repeatable},
 659                         mandatory       => $tagslib->{$tag}->{mandatory},
 660                         important       => $tagslib->{$tag}->{important},
 661                         indicator1       => ( $indicator1 || $tagslib->{$tag}->{ind1_defaultvalue} ), #if not set, try to load the default value
 662                         indicator2       => ( $indicator2 || $tagslib->{$tag}->{ind2_defaultvalue} ), #use short-circuit operator for efficiency
 663                         subfield_loop    => \@subfields_data,
 664                         tagfirstsubfield => $subfields_data[0],
 665                         fixedfield       => $tag < 10?1:0,
 666                     );
 667
 668                     push @loop_data, \%tag_data ;
 669                 }
 670             }
 671         }
 672         if ( $#loop_data >= 0 ) {
 673             push @BIG_LOOP, {
 674                 number    => $tabloop,
 675                 innerloop => \@loop_data,
 676             };
 677         }
 678     }
 679     $authorised_values_sth->finish;
 680     $template->param( BIG_LOOP => \@BIG_LOOP );
 681 }
 682
 683 # ========================
 684 #          MAIN
 685 #=========================
 686 my $input = new CGI;
 687 my $error = $input->param('error');
 688 my $biblionumber  = $input->param('biblionumber'); # if biblionumber exists, it's a modif, not a new biblio.
 689 my $parentbiblio  = $input->param('parentbiblionumber');
 690 my $breedingid    = $input->param('breedingid');
 691 my $z3950         = $input->param('z3950');
 692 my $op            = $input->param('op') // q{};
 693 my $mode          = $input->param('mode');
 694 my $frameworkcode = $input->param('frameworkcode');
 695 my $redirect      = $input->param('redirect');
 696 my $searchid      = $input->param('searchid');
 697 my $dbh           = C4::Context->dbh;
 698 my $hostbiblionumber = $input->param('hostbiblionumber');
 699 my $hostitemnumber = $input->param('hostitemnumber');
 700 # fast cataloguing datas in transit
 701 my $fa_circborrowernumber = $input->param('circborrowernumber');
 702 my $fa_barcode            = $input->param('barcode');
 703 my $fa_branch             = $input->param('branch');
 704 my $fa_stickyduedate      = $input->param('stickyduedate');
 705 my $fa_duedatespec        = $input->param('duedatespec');
 706
 707 my $userflags = 'edit_catalogue';
 708
 709 my $changed_framework = $input->param('changed_framework') // q{};
 710 $frameworkcode = &GetFrameworkCode($biblionumber)
 711   if ( $biblionumber and not( defined $frameworkcode) and $op ne 'addbiblio' );
 712
 713 if ($frameworkcode eq 'FA'){
 714     $userflags = 'fast_cataloging';
 715 }
 716
 717 $frameworkcode = '' if ( $frameworkcode eq 'Default' );
 718 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 719     {
 720         template_name   => "cataloguing/addbiblio.tt",
 721         query           => $input,
 722         type            => "intranet",
 723         authnotrequired => 0,
 724         flagsrequired   => { editcatalogue => $userflags },
 725     }
 726 );
 727
 728 if ($biblionumber){
 729     my $does_bib_exist = Koha::Biblios->find($biblionumber);
 730     if (!defined $does_bib_exist){
 731         $biblionumber = undef;
 732         $template->param( bib_doesnt_exist => 1 );
 733     }
 734 }
 735
 736 if ($frameworkcode eq 'FA'){
 737     # We need to grab and set some variables in the template for use on the additems screen
 738     $template->param(
 739         'circborrowernumber' => $fa_circborrowernumber,
 740         'barcode'            => $fa_barcode,
 741         'branch'             => $fa_branch,
 742         'stickyduedate'      => $fa_stickyduedate,
 743         'duedatespec'        => $fa_duedatespec,
 744     );
 745 } elsif ( $op ne "delete" &&
 746             C4::Context->preference('EnableAdvancedCatalogingEditor') &&
 747             C4::Auth::haspermission(C4::Context->userenv->{id},{'editcatalogue'=>'advanced_editor'}) &&
 748             $input->cookie( 'catalogue_editor_' . $loggedinuser ) eq 'advanced' &&
 749             !$breedingid ) {
 750     # Only use the advanced editor for non-fast-cataloging.
 751     # breedingid is not handled because those would only come off a Z39.50
 752     # search initiated by the basic editor.
 753     print $input->redirect( '/cgi-bin/koha/cataloguing/editor.pl' . ( $biblionumber ? ( ($op eq 'duplicate'?'#duplicate/':'#catalog/') . $biblionumber ) : '' ) );
 754     exit;
 755 }
 756
 757 my $frameworks = Koha::BiblioFrameworks->search({}, { order_by => ['frameworktext'] });
 758 $template->param(
 759     frameworks => $frameworks,
 760     breedingid => $breedingid,
 761 );
 762
 763 # ++ Global
 764 $tagslib         = &GetMarcStructure( 1, $frameworkcode );
 765 $usedTagsLib     = &GetUsedMarcStructure( $frameworkcode );
 766 $mandatory_z3950 = GetMandatoryFieldZ3950($frameworkcode);
 767 # -- Global
 768
 769 my $record   = -1;
 770 my $encoding = "";
 771 my (
 772         $biblionumbertagfield,
 773         $biblionumbertagsubfield,
 774         $biblioitemnumtagfield,
 775         $biblioitemnumtagsubfield,
 776         $biblioitemnumber
 777 );
 778
 779 if (($biblionumber) && !($breedingid)){
 780     $record = GetMarcBiblio({ biblionumber => $biblionumber });
 781 }
 782 if ($breedingid) {
 783     ( $record, $encoding ) = MARCfindbreeding( $breedingid ) ;
 784 }
 785
 786 #populate hostfield if hostbiblionumber is available
 787 if ($hostbiblionumber) {
 788     my $marcflavour = C4::Context->preference("marcflavour");
 789     $record = MARC::Record->new();
 790     $record->leader('');
 791     my $field =
 792       PrepHostMarcField( $hostbiblionumber, $hostitemnumber, $marcflavour );
 793     $record->append_fields($field);
 794 }
 795
 796 # This is  a child record
 797 if ($parentbiblio) {
 798     my $marcflavour = C4::Context->preference('marcflavour');
 799     $record = MARC::Record->new();
 800     SetMarcUnicodeFlag($record, $marcflavour);
 801     my $hostfield = prepare_host_field($parentbiblio,$marcflavour);
 802     if ($hostfield) {
 803         $record->append_fields($hostfield);
 804     }
 805 }
 806
 807 $is_a_modif = 0;
 808
 809 if ($biblionumber) {
 810     $is_a_modif = 1;
 811     my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 812     $template->param( title => $title );
 813
 814     # if it's a modif, retrieve bibli and biblioitem numbers for the future modification of old-DB.
 815     ( $biblionumbertagfield, $biblionumbertagsubfield ) =
 816         &GetMarcFromKohaField( "biblio.biblionumber" );
 817     ( $biblioitemnumtagfield, $biblioitemnumtagsubfield ) =
 818         &GetMarcFromKohaField( "biblioitems.biblioitemnumber" );
 819
 820     # search biblioitems value
 821     my $sth =  $dbh->prepare("select biblioitemnumber from biblioitems where biblionumber=?");
 822     $sth->execute($biblionumber);
 823     ($biblioitemnumber) = $sth->fetchrow;
 824 }
 825
 826 #-------------------------------------------------------------------------------------
 827 if ( $op eq "addbiblio" ) {
 828 #-------------------------------------------------------------------------------------
 829     $template->param(
 830         biblionumberdata => $biblionumber,
 831     );
 832     # getting html input
 833     my @params = $input->multi_param();
 834     $record = TransformHtmlToMarc( $input, 1 );
 835     # check for a duplicate
 836     my ( $duplicatebiblionumber, $duplicatetitle );
 837     if ( !$is_a_modif ) {
 838         ( $duplicatebiblionumber, $duplicatetitle ) = FindDuplicate($record);
 839     }
 840     my $confirm_not_duplicate = $input->param('confirm_not_duplicate');
 841     # it is not a duplicate (determined either by Koha itself or by user checking it's not a duplicate)
 842     if ( !$duplicatebiblionumber or $confirm_not_duplicate ) {
 843         my $oldbibitemnum;
 844         if ( $is_a_modif ) {
 845             ModBiblio( $record, $biblionumber, $frameworkcode );
 846         }
 847         else {
 848             ( $biblionumber, $oldbibitemnum ) = AddBiblio( $record, $frameworkcode );
 849         }
 850         if ($redirect eq "items" || ($mode ne "popup" && !$is_a_modif && $redirect ne "view" && $redirect ne "just_save")){
 851             if ($frameworkcode eq 'FA'){
 852                 print $input->redirect(
 853             '/cgi-bin/koha/cataloguing/additem.pl?'
 854             .'biblionumber='.$biblionumber
 855             .'&frameworkcode='.$frameworkcode
 856             .'&circborrowernumber='.$fa_circborrowernumber
 857             .'&branch='.$fa_branch
 858             .'&barcode='.uri_escape_utf8($fa_barcode)
 859             .'&stickyduedate='.$fa_stickyduedate
 860             .'&duedatespec='.$fa_duedatespec
 861                 );
 862                 exit;
 863             }
 864             else {
 865                 print $input->redirect(
 866                 "/cgi-bin/koha/cataloguing/additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid"
 867                 );
 868                 exit;
 869             }
 870         }
 871     elsif(($is_a_modif || $redirect eq "view") && $redirect ne "just_save"){
 872             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 873             my $views = { C4::Search::enabled_staff_search_views };
 874             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 875                 print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 876             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 877                 print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 878             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 879                 print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 880             } else {
 881                 print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 882             }
 883             exit;
 884
 885     }
 886     elsif ($redirect eq "just_save"){
 887         my $tab = $input->param('current_tab');
 888         print $input->redirect("/cgi-bin/koha/cataloguing/addbiblio.pl?biblionumber=$biblionumber&framework=$frameworkcode&tab=$tab&searchid=$searchid");
 889     }
 890     else {
 891           $template->param(
 892             biblionumber => $biblionumber,
 893             done         =>1,
 894             popup        =>1
 895           );
 896           if ( $record ne '-1' ) {
 897               my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 898               $template->param( title => $title );
 899           }
 900           $template->param(
 901             popup => $mode,
 902             itemtype => $frameworkcode,
 903           );
 904           output_html_with_http_headers $input, $cookie, $template->output;
 905           exit;
 906         }
 907     } else {
 908     # it may be a duplicate, warn the user and do nothing
 909         build_tabs ($template, $record, $dbh,$encoding,$input);
 910         $template->param(
 911             biblionumber             => $biblionumber,
 912             biblioitemnumber         => $biblioitemnumber,
 913             duplicatebiblionumber    => $duplicatebiblionumber,
 914             duplicatebibid           => $duplicatebiblionumber,
 915             duplicatetitle           => $duplicatetitle,
 916         );
 917     }
 918 }
 919 elsif ( $op eq "delete" ) {
 920
 921     my $error = &DelBiblio($biblionumber);
 922     if ($error) {
 923         warn "ERROR when DELETING BIBLIO $biblionumber : $error";
 924         print "Content-Type: text/html\n\n<html><body><h1>ERROR when DELETING BIBLIO $biblionumber : $error</h1></body></html>";
 925         exit;
 926     }
 927
 928     print $input->redirect('/cgi-bin/koha/catalogue/search.pl');
 929     exit;
 930
 931 } else {
 932    #----------------------------------------------------------------------------
 933    # If we're in a duplication case, we have to set to "" the biblionumber
 934    # as we'll save the biblio as a new one.
 935     $template->param(
 936         biblionumberdata => $biblionumber,
 937         op               => $op,
 938     );
 939     if ( $op eq "duplicate" ) {
 940         $biblionumber = "";
 941     }
 942
 943     if($changed_framework eq "changed"){
 944         $record = TransformHtmlToMarc( $input, 1 );
 945     }
 946     elsif( $record ne -1 ) {
 947 #FIXME: it's kind of silly to go from MARC::Record to MARC::File::XML and then back again just to fix the encoding
 948         eval {
 949             my $uxml = $record->as_xml;
 950             MARC::Record::default_record_format("UNIMARC")
 951             if ( C4::Context->preference("marcflavour") eq "UNIMARC" );
 952             my $urecord = MARC::Record::new_from_xml( $uxml, 'UTF-8' );
 953             $record = $urecord;
 954         };
 955     }
 956     build_tabs( $template, $record, $dbh, $encoding,$input );
 957     $template->param(
 958         biblionumber             => $biblionumber,
 959         biblionumbertagfield        => $biblionumbertagfield,
 960         biblionumbertagsubfield     => $biblionumbertagsubfield,
 961         biblioitemnumtagfield    => $biblioitemnumtagfield,
 962         biblioitemnumtagsubfield => $biblioitemnumtagsubfield,
 963         biblioitemnumber         => $biblioitemnumber,
 964         hostbiblionumber        => $hostbiblionumber,
 965         hostitemnumber          => $hostitemnumber
 966     );
 967 }
 968
 969 if ( $record ne '-1' ) {
 970     my $title = C4::Context->preference('marcflavour') eq "UNIMARC" ? $record->subfield('200', 'a') : $record->title;
 971     $template->param( title => $title );
 972 }
 973 $template->param(
 974     popup => $mode,
 975     frameworkcode => $frameworkcode,
 976     itemtype => $frameworkcode,
 977     borrowernumber => $loggedinuser,
 978     tab => scalar $input->param('tab')
 979 );
 980 $template->{'VARS'}->{'searchid'} = $searchid;
 981
 982 output_html_with_http_headers $input, $cookie, $template->output;