cataloguing/additem.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2004-2010 BibLibre
   5 # Parts Copyright Catalyst IT 2011
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use C4::Auth qw( get_template_and_user haspermission );
  26 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  27 use C4::Biblio qw(
  28     GetFrameworkCode
  29     GetMarcBiblio
  30     GetMarcFromKohaField
  31     GetMarcStructure
  32     IsMarcStructureInternal
  33     ModBiblio
  34 );
  35 use C4::Context;
  36 use C4::Circulation qw( barcodedecode LostItem );
  37 use C4::Barcodes;
  38 use C4::Barcodes::ValueBuilder;
  39 use Koha::DateUtils qw( dt_from_string );
  40 use Koha::Items;
  41 use Koha::ItemTypes;
  42 use Koha::Libraries;
  43 use Koha::Patrons;
  44 use Koha::SearchEngine::Indexer;
  45 use C4::Search qw( enabled_staff_search_views );
  46 use Storable qw( freeze thaw );
  47 use URI::Escape qw( uri_escape_utf8 );
  48 use C4::Members;
  49 use Koha::UI::Form::Builder::Item;
  50
  51 use MARC::File::XML;
  52 use URI::Escape qw( uri_escape_utf8 );
  53 use Encode qw( encode_utf8 );
  54 use MIME::Base64 qw( decode_base64url encode_base64url );
  55 use List::Util qw( first );
  56 use List::MoreUtils qw( any uniq );
  57
  58 our $dbh = C4::Context->dbh;
  59
  60 sub get_item_from_cookie {
  61     my ( $input ) = @_;
  62
  63     my $item_from_cookie;
  64     my $lastitemcookie = $input->cookie('LastCreatedItem');
  65     if ($lastitemcookie) {
  66         $lastitemcookie = decode_base64url($lastitemcookie);
  67         eval {
  68             if ( thaw($lastitemcookie) ) {
  69                 $item_from_cookie = thaw($lastitemcookie);
  70             }
  71         };
  72         if ($@) {
  73             $lastitemcookie ||= 'undef';
  74             warn "Storable::thaw failed to thaw LastCreatedItem-cookie. Cookie value '".encode_base64url($lastitemcookie)."'. Caught error follows: '$@'";
  75         }
  76     }
  77     return $item_from_cookie;
  78 }
  79
  80 my $input        = CGI->new;
  81 my $error        = $input->param('error');
  82
  83 my $biblionumber;
  84 my $itemnumber;
  85 if( $input->param('itemnumber') && !$input->param('biblionumber') ){
  86     $itemnumber = $input->param('itemnumber');
  87     my $item = Koha::Items->find( $itemnumber );
  88     $biblionumber = $item->biblionumber;
  89 } else {
  90     $biblionumber = $input->param('biblionumber');
  91     $itemnumber = $input->param('itemnumber');
  92 }
  93
  94 my $biblio = Koha::Biblios->find($biblionumber);
  95
  96 my $op           = $input->param('op') || q{};
  97 my $hostitemnumber = $input->param('hostitemnumber');
  98 my $marcflavour  = C4::Context->preference("marcflavour");
  99 my $searchid     = $input->param('searchid');
 100 # fast cataloguing datas
 101 my $fa_circborrowernumber = $input->param('circborrowernumber');
 102 my $fa_barcode            = $input->param('barcode');
 103 my $fa_branch             = $input->param('branch');
 104 my $fa_stickyduedate      = $input->param('stickyduedate');
 105 my $fa_duedatespec        = $input->param('duedatespec');
 106
 107 our $frameworkcode = &GetFrameworkCode($biblionumber);
 108
 109 # Defining which userflag is needing according to the framework currently used
 110 my $userflags;
 111 if (defined $input->param('frameworkcode')) {
 112     $userflags = ($input->param('frameworkcode') eq 'FA') ? "fast_cataloging" : "edit_items";
 113 }
 114
 115 if (not defined $userflags) {
 116     $userflags = ($frameworkcode eq 'FA') ? "fast_cataloging" : "edit_items";
 117 }
 118
 119 my ($template, $loggedinuser, $cookie)
 120     = get_template_and_user({template_name => "cataloguing/additem.tt",
 121                  query => $input,
 122                  type => "intranet",
 123                  flagsrequired => {editcatalogue => $userflags},
 124                  });
 125
 126
 127 # Does the user have a restricted item editing permission?
 128 my $uid = Koha::Patrons->find( $loggedinuser )->userid;
 129 my $restrictededition = $uid ? haspermission($uid,  {'editcatalogue' => 'edit_items_restricted'}) : undef;
 130 # In case user is a superlibrarian, editing is not restricted
 131 $restrictededition = 0 if ($restrictededition != 0 &&  C4::Context->IsSuperLibrarian());
 132 # In case user has fast cataloging permission (and we're in fast cataloging), editing is not restricted
 133 $restrictededition = 0 if ($restrictededition != 0 && $frameworkcode eq 'FA' && haspermission($uid, {'editcatalogue' => 'fast_cataloging'}));
 134
 135 our $tagslib = &GetMarcStructure(1,$frameworkcode);
 136 my $record = GetMarcBiblio({ biblionumber => $biblionumber });
 137
 138 output_and_exit_if_error( $input, $cookie, $template,
 139     { module => 'cataloguing', record => $record } );
 140
 141 my $current_item;
 142 my $nextop="additem";
 143 my @errors; # store errors found while checking data BEFORE saving item.
 144
 145 # Getting last created item cookie
 146 my $prefillitem = C4::Context->preference('PrefillItem');
 147
 148 #-------------------------------------------------------------------------------
 149 if ($op eq "additem") {
 150
 151     my $add_submit                 = $input->param('add_submit');
 152     my $add_duplicate_submit       = $input->param('add_duplicate_submit');
 153     my $add_multiple_copies_submit = $input->param('add_multiple_copies_submit');
 154     my $number_of_copies           = $input->param('number_of_copies');
 155
 156     my @columns = Koha::Items->columns;
 157     my $item = Koha::Item->new;
 158     $item->biblionumber($biblio->biblionumber);
 159     for my $c ( @columns ) {
 160         if ( $c eq 'more_subfields_xml' ) {
 161             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 162             my @unlinked_item_subfields;
 163             for my $subfield ( @more_subfields_xml ) {
 164                 my $v = $input->param('items.more_subfields_xml_' . $subfield);
 165                 push @unlinked_item_subfields, $subfield, $v;
 166             }
 167             if ( @unlinked_item_subfields ) {
 168                 my $marc = MARC::Record->new();
 169                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 170                 # used in the framework
 171                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 172                 $marc->encoding("UTF-8");
 173                 $item->more_subfields_xml($marc->as_xml("USMARC"));
 174                 next;
 175             }
 176             $item->more_subfields_xml(undef);
 177         } else {
 178             my @v = grep { $_ ne "" }
 179                 uniq $input->multi_param( "items." . $c );
 180
 181             next if !@v
 182                 && $c ne 'permanent_location'; # See 27837
 183
 184             $item->$c(join ' | ', @v);
 185         }
 186     }
 187
 188     # if autoBarcode is set to 'incremental', calculate barcode...
 189     if ( ! defined $item->barcode && C4::Context->preference('autoBarcode') eq 'incremental' ) {
 190         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 191         $item->barcode($barcode);
 192     }
 193
 194     $item->barcode(barcodedecode($item->barcode));
 195
 196     # If we have to add or add & duplicate, we add the item
 197     if ( $add_submit || $add_duplicate_submit || $prefillitem) {
 198
 199         # check for item barcode # being unique
 200         if ( defined $item->barcode
 201             && Koha::Items->search( { barcode => $item->barcode } )->count )
 202         {
 203             # if barcode exists, don't create, but report The problem.
 204             push @errors, "barcode_not_unique";
 205
 206             $current_item = $item->unblessed; # Restore edit form for the same item
 207         }
 208         else {
 209             $item->store->discard_changes;
 210
 211             # This is a bit tricky : if there is a cookie for the last created item and
 212             # we just added an item, the cookie value is not correct yet (it will be updated
 213             # next page). To prevent the form from being filled with outdated values, we
 214             # force the use of "add and duplicate" feature, so the form will be filled with
 215             # correct values.
 216
 217             # Pushing the last created item cookie back
 218             if ( $prefillitem ) {
 219                 my $last_created_item_cookie = $input->cookie(
 220                     -name => 'LastCreatedItem',
 221                     # We encode_base64url the whole freezed structure so we're sure we won't have any encoding problems
 222                     -value   => encode_base64url( freeze( { %{$item->unblessed}, itemnumber => undef } ) ),
 223                     -HttpOnly => 1,
 224                     -expires => ''
 225                 );
 226
 227                 $cookie = [ $cookie, $last_created_item_cookie ];
 228             }
 229
 230         }
 231         $nextop = "additem";
 232
 233     }
 234
 235     # If we have to add & duplicate
 236     if ($prefillitem || $add_duplicate_submit) {
 237
 238         $current_item = $item->unblessed;
 239
 240         if (C4::Context->preference('autoBarcode') eq 'incremental') {
 241             my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 242             $current_item->{barcode} = $barcode;
 243         }
 244         else {
 245             # we have to clear the barcode field in the duplicate item record to make way for the new one generated by the javascript plugin
 246             $current_item->{barcode} = undef; # FIXME or delete?
 247         }
 248
 249         # Don't use the "prefill" feature if we want to generate the form with all the info from this item
 250         # It will remove subfields that are not in SubfieldsToUseWhenPrefill.
 251         $prefillitem = 0 if $add_duplicate_submit;
 252     }
 253
 254     # If we have to add multiple copies
 255     if ($add_multiple_copies_submit) {
 256
 257         $current_item = $item->unblessed;
 258
 259         my $copynumber = $current_item->{copynumber};
 260         my $oldbarcode = $current_item->{barcode};
 261
 262         # If there is a barcode and we can't find their new values, we can't add multiple copies
 263         my $testbarcode;
 264         my $barcodeobj = C4::Barcodes->new;
 265         $testbarcode = $barcodeobj->next_value($oldbarcode) if $barcodeobj;
 266         if ( $oldbarcode && !$testbarcode ) {
 267
 268             push @errors, "no_next_barcode";
 269
 270         }
 271         else {
 272             # We add each item
 273
 274             # For the first iteration
 275             my $barcodevalue = $oldbarcode;
 276             my $exist_itemnumber;
 277
 278             for ( my $i = 0 ; $i < $number_of_copies ; ) {
 279
 280                 # If there is a barcode
 281                 if ($barcodevalue) {
 282
 283 # Getting a new barcode (if it is not the first iteration or the barcode we tried already exists)
 284                     $barcodevalue = $barcodeobj->next_value($oldbarcode)
 285                       if ( $i > 0 || $exist_itemnumber );
 286
 287                     # Putting it into the record
 288                     if ($barcodevalue) {
 289                         if ( C4::Context->preference("autoBarcode") eq
 290                             'hbyymmincr' && $i > 0 )
 291                         { # The first copy already contains the homebranch prefix
 292                              # This is terribly hacky but the easiest way to fix the way hbyymmincr is working
 293                              # Contrary to what one might think, the barcode plugin does not prefix the returned string with the homebranch
 294                              # For a single item, it is handled with some JS code (see cataloguing/value_builder/barcode.pl)
 295                              # But when adding multiple copies we need to prefix it here,
 296                              # so we retrieve the homebranch from the item and prefix the barcode with it.
 297                             my $homebranch = $current_item->{homebranch};
 298                             $barcodevalue = $homebranch . $barcodevalue;
 299                         }
 300                         $current_item->{barcode} = $barcodevalue;
 301                     }
 302
 303                     # Checking if the barcode already exists
 304                     $exist_itemnumber = Koha::Items->search({ barcode => $barcodevalue })->count;
 305                 }
 306
 307                 # Updating record with the new copynumber
 308                 if ($copynumber) {
 309                     $current_item->{copynumber} = $copynumber;
 310                 }
 311
 312                 # Adding the item
 313                 if ( !$exist_itemnumber ) {
 314                     delete $current_item->{itemnumber};
 315                     $current_item = Koha::Item->new($current_item)->store(
 316                         { skip_record_index => 1 } );
 317                     $current_item->discard_changes; # Cannot chain discard_changes
 318                     $current_item = $current_item->unblessed;
 319
 320 # We count the item only if it was really added
 321 # That way, all items are added, even if there was some already existing barcodes
 322 # FIXME : Please note that there is a risk of infinite loop here if we never find a suitable barcode
 323                     $i++;
 324
 325                     # Only increment copynumber if item was really added
 326                     $copynumber++ if ( $copynumber && $copynumber =~ m/^\d+$/ );
 327                 }
 328
 329                 # Preparing the next iteration
 330                 $oldbarcode = $barcodevalue;
 331             }
 332
 333             my $indexer = Koha::SearchEngine::Indexer->new(
 334                 { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 335             $indexer->index_records( $biblionumber, "specialUpdate",
 336                 "biblioserver" );
 337
 338             undef($current_item);
 339         }
 340     }
 341     if ($frameworkcode eq 'FA' && $fa_circborrowernumber){
 342         print $input->redirect(
 343            '/cgi-bin/koha/circ/circulation.pl?'
 344            .'borrowernumber='.$fa_circborrowernumber
 345            .'&barcode='.uri_escape_utf8($fa_barcode)
 346            .'&duedatespec='.$fa_duedatespec
 347            .'&stickyduedate='.$fa_stickyduedate
 348         );
 349         exit;
 350     }
 351
 352
 353 #-------------------------------------------------------------------------------
 354 } elsif ($op eq "edititem") {
 355 #-------------------------------------------------------------------------------
 356 # retrieve item if exist => then, it's a modif
 357     $current_item = Koha::Items->find($itemnumber)->unblessed;
 358     # FIXME Handle non existent item
 359     $nextop = "saveitem";
 360 #-------------------------------------------------------------------------------
 361 } elsif ($op eq "dupeitem") {
 362 #-------------------------------------------------------------------------------
 363 # retrieve item if exist => then, it's a modif
 364     $current_item = Koha::Items->find($itemnumber)->unblessed;
 365     # FIXME Handle non existent item
 366     if (C4::Context->preference('autoBarcode') eq 'incremental') {
 367         my ( $barcode ) = C4::Barcodes::ValueBuilder::incremental::get_barcode;
 368         $current_item->{barcode} = $barcode;
 369     }
 370     else {
 371         $current_item->{barcode} = undef; # Don't save it!
 372     }
 373
 374     $nextop = "additem";
 375 #-------------------------------------------------------------------------------
 376 } elsif ($op eq "delitem") {
 377 #-------------------------------------------------------------------------------
 378     # check that there is no issue on this item before deletion.
 379     my $item = Koha::Items->find($itemnumber);
 380     $error = $item->safe_delete;
 381     if(ref($error) eq 'Koha::Item'){
 382         print $input->redirect("additem.pl?biblionumber=$biblionumber&frameworkcode=$frameworkcode&searchid=$searchid");
 383     }else{
 384         push @errors,$error;
 385         $nextop="additem";
 386     }
 387 #-------------------------------------------------------------------------------
 388 } elsif ($op eq "delallitems") {
 389 #-------------------------------------------------------------------------------
 390     my $items = Koha::Items->search({ biblionumber => $biblionumber });
 391     while ( my $item = $items->next ) {
 392         $error = $item->safe_delete({ skip_record_index => 1 });
 393         next if ref $error eq 'Koha::Item'; # Deleted item is returned if deletion successful
 394         push @errors,$error;
 395     }
 396     my $indexer = Koha::SearchEngine::Indexer->new({ index => $Koha::SearchEngine::BIBLIOS_INDEX });
 397     $indexer->index_records( $biblionumber, "specialUpdate", "biblioserver" );
 398     if ( @errors ) {
 399         $nextop="additem";
 400     } else {
 401         my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 402         my $views = { C4::Search::enabled_staff_search_views };
 403         if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 404             print $input->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 405         } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 406             print $input->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 407         } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 408             print $input->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber&searchid=$searchid");
 409         } else {
 410             print $input->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber&searchid=$searchid");
 411         }
 412         exit;
 413     }
 414 #-------------------------------------------------------------------------------
 415 } elsif ($op eq "saveitem") {
 416 #-------------------------------------------------------------------------------
 417
 418     my $itemnumber = $input->param('itemnumber');
 419     my $item = Koha::Items->find($itemnumber);
 420     # FIXME Handle non existent item
 421     my $olditemlost = $item->itemlost;
 422     my @columns = Koha::Items->columns;
 423     my $new_values = $item->unblessed;
 424     for my $c ( @columns ) {
 425         if ( $c eq 'more_subfields_xml' ) {
 426             my @more_subfields_xml = $input->multi_param("items.more_subfields_xml");
 427             my @unlinked_item_subfields;
 428             for my $subfield ( uniq @more_subfields_xml ) {
 429                 my @v = $input->multi_param('items.more_subfields_xml_' . encode_utf8($subfield));
 430                 push @unlinked_item_subfields, $subfield, $_ for @v;
 431             }
 432             if ( @unlinked_item_subfields ) {
 433                 my $marc = MARC::Record->new();
 434                 # use of tag 999 is arbitrary, and doesn't need to match the item tag
 435                 # used in the framework
 436                 $marc->append_fields(MARC::Field->new('999', ' ', ' ', @unlinked_item_subfields));
 437                 $marc->encoding("UTF-8");
 438                 $new_values->{more_subfields_xml} = $marc->as_xml("USMARC");
 439                 next;
 440             }
 441             $item->more_subfields_xml(undef);
 442         } else {
 443             my @v = map { ( defined $_ && $_ eq '' ) ? undef : $_ } $input->multi_param( "items." . $c );
 444             next unless @v;
 445
 446             if ( scalar(@v) == 1 && not defined $v[0] ) {
 447                 delete $new_values->{$c};
 448             } else {
 449                 $new_values->{$c} = join ' | ', @v;
 450             }
 451         }
 452     }
 453     $item = $item->set_or_blank($new_values);
 454
 455     # check that the barcode don't exist already
 456     if (
 457         defined $item->barcode
 458         && Koha::Items->search(
 459             {
 460                 barcode    => $item->barcode,
 461                 itemnumber => { '!=' => $item->itemnumber }
 462             }
 463         )->count
 464       )
 465     {
 466         # FIXME We shouldn't need that, ->store would explode as there is a unique constraint on items.barcode
 467         push @errors,"barcode_not_unique";
 468         $current_item = $item->unblessed; # Restore edit form for the same item
 469     } else {
 470         my $newitemlost = $item->itemlost;
 471         if ( $newitemlost && $newitemlost ge '1' && !$olditemlost ) {
 472             LostItem( $item->itemnumber, 'additem' );
 473         }
 474         $item->store;
 475     }
 476
 477     $nextop="additem";
 478 } elsif ($op eq "delinkitem"){
 479
 480     my $analyticfield = '773';
 481     if ($marcflavour  eq 'MARC21'){
 482         $analyticfield = '773';
 483     } elsif ($marcflavour eq 'UNIMARC') {
 484         $analyticfield = '461';
 485     }
 486     foreach my $field ($record->field($analyticfield)){
 487         if ($field->subfield('9') eq $hostitemnumber){
 488             $record->delete_field($field);
 489             last;
 490         }
 491     }
 492         my $modbibresult = ModBiblio($record, $biblionumber,'');
 493 }
 494
 495 # update OAI-PMH sets
 496 if ($op) {
 497     if (C4::Context->preference("OAI-PMH:AutoUpdateSets")) {
 498         C4::OAI::Sets::UpdateOAISetsBiblio($biblionumber, $record);
 499     }
 500 }
 501
 502 #
 503 #-------------------------------------------------------------------------------
 504 # build screen with existing items. and "new" one
 505 #-------------------------------------------------------------------------------
 506
 507 # now, build existiing item list
 508
 509 my @items;
 510 for my $item ( $biblio->items->as_list, $biblio->host_items->as_list ) {
 511     push @items, $item->columns_to_str;
 512 }
 513
 514 my @witness_attributes = uniq map {
 515     my $item = $_;
 516     map { defined $item->{$_} && $item->{$_} ne "" ? $_ : () } keys %$item
 517 } @items;
 518
 519 our ( $itemtagfield, $itemtagsubfield ) = GetMarcFromKohaField("items.itemnumber");
 520
 521 my $subfieldcode_attribute_mappings;
 522 for my $subfield_code ( keys %{ $tagslib->{$itemtagfield} } ) {
 523
 524     my $subfield = $tagslib->{$itemtagfield}->{$subfield_code};
 525
 526     next if IsMarcStructureInternal( $subfield );
 527     next unless $subfield->{tab} eq 10; # Is this really needed?
 528
 529     my $attribute;
 530     if ( $subfield->{kohafield} ) {
 531         ( $attribute = $subfield->{kohafield} ) =~ s|^items\.||;
 532     } else {
 533         $attribute = $subfield_code; # It's in more_subfields_xml
 534     }
 535     next unless grep { $attribute eq $_ } @witness_attributes;
 536     $subfieldcode_attribute_mappings->{$subfield_code} = $attribute;
 537 }
 538
 539 my @header_value_loop = map {
 540     {
 541         header_value  => $tagslib->{$itemtagfield}->{$_}->{lib},
 542         attribute     => $subfieldcode_attribute_mappings->{$_},
 543         subfield_code => $_,
 544     }
 545 } sort keys %$subfieldcode_attribute_mappings;
 546
 547 # Using last created item if it exists
 548 if (   $prefillitem
 549     && $op ne "additem"
 550     && $op ne "edititem"
 551     && $op ne "dupeitem" )
 552 {
 553     my $item_from_cookie = get_item_from_cookie($input);
 554     $current_item = $item_from_cookie if $item_from_cookie;
 555 }
 556
 557 if ( $current_item->{more_subfields_xml} ) {
 558     # FIXME Use Maybe MARC::Record::new_from_xml if encoding issues on subfield (??)
 559     $current_item->{marc_more_subfields_xml} = MARC::Record->new_from_xml($current_item->{more_subfields_xml}, 'UTF-8');
 560 }
 561
 562 my $branchcode = $input->param('branch') || C4::Context->userenv->{branch};
 563
 564 # If we are not adding a new item
 565 # OR
 566 # If the subfield must be prefilled with last catalogued item
 567 my @subfields_to_prefill;
 568 if ( $nextop eq 'additem' && $op ne 'dupeitem' && $prefillitem ) {
 569     @subfields_to_prefill = split(' ', C4::Context->preference('SubfieldsToUseWhenPrefill'));
 570     # Setting to 1 element if SubfieldsToUseWhenPrefill is empty to prevent all the subfields to be prefilled
 571     @subfields_to_prefill = ("") unless @subfields_to_prefill;
 572 }
 573
 574 # Getting list of subfields to keep when restricted editing is enabled
 575 my @subfields_to_allow = $restrictededition ? split ' ', C4::Context->preference('SubfieldsToAllowForRestrictedEditing') : ();
 576
 577 my $subfields =
 578   Koha::UI::Form::Builder::Item->new(
 579     { biblionumber => $biblionumber, item => $current_item } )->edit_form(
 580     {
 581         branchcode           => $branchcode,
 582         restricted_editition => $restrictededition,
 583         (
 584             @subfields_to_allow
 585             ? ( subfields_to_allow => \@subfields_to_allow )
 586             : ()
 587         ),
 588         (
 589             @subfields_to_prefill
 590             ? ( subfields_to_prefill => \@subfields_to_prefill )
 591             : ()
 592         ),
 593         prefill_with_default_values => 1,
 594         branch_limit => C4::Context->userenv->{"branch"},
 595     }
 596 );
 597
 598 if (   $frameworkcode eq 'FA' ) {
 599     my ( $barcode_field ) = grep {$_->{kohafield} eq 'items.barcode'} @$subfields;
 600     $barcode_field->{marc_value}->{value} ||= $input->param('barcode');
 601 }
 602
 603 if( my $default_location = C4::Context->preference('NewItemsDefaultLocation') ) {
 604     my ( $location_field ) = grep {$_->{kohafield} eq 'items.location'} @$subfields;
 605     $location_field->{marc_value}->{value} ||= $default_location;
 606 }
 607
 608 # what's the next op ? it's what we are not in : an add if we're editing, otherwise, and edit.
 609 $template->param(
 610     biblio       => $biblio,
 611     items        => \@items,
 612     item_header_loop => \@header_value_loop,
 613     subfields        => $subfields,
 614     itemnumber       => $itemnumber,
 615     barcode          => $current_item->{barcode},
 616     op      => $nextop,
 617     popup => scalar $input->param('popup') ? 1: 0,
 618     C4::Search::enabled_staff_search_views,
 619 );
 620 $template->{'VARS'}->{'searchid'} = $searchid;
 621
 622 if ($frameworkcode eq 'FA'){
 623     # fast cataloguing datas
 624     $template->param(
 625         'circborrowernumber' => $fa_circborrowernumber,
 626         'barcode'            => $fa_barcode,
 627         'branch'             => $fa_branch,
 628         'stickyduedate'      => $fa_stickyduedate,
 629         'duedatespec'        => $fa_duedatespec,
 630     );
 631 }
 632
 633 foreach my $error (@errors) {
 634     $template->param($error => 1);
 635 }
 636 output_html_with_http_headers $input, $cookie, $template->output;