cataloguing/value_builder/upload.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2011-2012 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21 use CGI qw/-utf8/;
  22 use File::Basename;
  23
  24 use C4::Auth;
  25 use C4::Context;
  26 use C4::Output;
  27 use C4::UploadedFiles;
  28
  29 my $upload_path = C4::Context->preference('uploadPath');
  30
  31 sub plugin_parameters {
  32     my ( $dbh, $record, $tagslib, $i, $tabloop ) = @_;
  33     return "";
  34 }
  35
  36 sub plugin_javascript {
  37     my ( $dbh, $record, $tagslib, $field_number, $tabloop ) = @_;
  38     my $function_name = $field_number;
  39     my $res           = "
  40     <script type=\"text/javascript\">
  41         function Focus$function_name(subfield_managed) {
  42             return 1;
  43         }
  44
  45         function Blur$function_name(subfield_managed) {
  46             return 1;
  47         }
  48
  49         function Clic$function_name(index) {
  50             var id = document.getElementById(index).value;
  51             if(id.match(/id=([0-9a-f]+)/)){
  52                 id = RegExp.\$1;
  53             }
  54             window.open(\"../cataloguing/plugin_launcher.pl?plugin_name=upload.pl&index=\"+index+\"&id=\"+id, 'upload', 'width=600,height=400,toolbar=false,scrollbars=no');
  55
  56         }
  57     </script>
  58 ";
  59
  60     return ( $function_name, $res );
  61 }
  62
  63 sub plugin {
  64     my ($input) = @_;
  65     my $index = $input->param('index');
  66     my $id = $input->param('id');
  67     my $delete = $input->param('delete');
  68     my $uploaded_file = $input->param('uploaded_file');
  69
  70     my $template_name = ($id || $delete)
  71                     ? "upload_delete_file.tt"
  72                     : "upload.tt";
  73
  74     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  75         {   template_name   => "cataloguing/value_builder/$template_name",
  76             query           => $input,
  77             type            => "intranet",
  78             authnotrequired => 0,
  79             flagsrequired   => { editcatalogue => '*' },
  80             debug           => 1,
  81         }
  82     );
  83
  84     # Dealing with the uploaded file
  85     if ($uploaded_file) {
  86         my $fh = $input->upload('uploaded_file');
  87         my $dir = $input->param('dir');
  88
  89         $id = C4::UploadedFiles::UploadFile($uploaded_file, $dir, $fh->handle);
  90         if($id) {
  91             my $OPACBaseURL = C4::Context->preference('OPACBaseURL');
  92             $OPACBaseURL =~ s#/$##;
  93             my $return = "$OPACBaseURL/cgi-bin/koha/opac-retrieve-file.pl?id=$id";
  94             $template->param(
  95                 success => 1,
  96                 return => $return,
  97                 uploaded_file => $uploaded_file,
  98             );
  99         } else {
 100             $template->param(error => 1);
 101         }
 102     } elsif ($delete || $id) {
 103         # If there's already a file uploaded for this field,
 104         # We handle its deletion
 105         if ($delete) {
 106             if(C4::UploadedFiles::DelUploadedFile($id)) {;
 107                 $template->param(success => 1);
 108             } else {
 109                 $template->param(error => 1);
 110             }
 111         }
 112     } else {
 113         my $filefield = CGI::filefield(
 114             -name => 'uploaded_file',
 115             -size => 50,
 116         );
 117
 118         my $dirs_tree = [ {
 119             name => '/',
 120             value => '/',
 121             dirs => finddirs($upload_path)
 122         } ];
 123
 124         $template->param(
 125             dirs_tree => $dirs_tree,
 126             filefield => $filefield
 127         );
 128     }
 129
 130     $template->param(
 131         index => $index,
 132         id => $id
 133     );
 134
 135     output_html_with_http_headers $input, $cookie, $template->output;
 136 }
 137
 138 # Build a hierarchy of directories
 139 sub finddirs {
 140     my $base = shift || $upload_path;
 141     my $found = 0;
 142     my @dirs;
 143     my @files = glob("$base/*");
 144     foreach (@files) {
 145         if (-d $_ and -w $_) {
 146             my $lastdirname = basename($_);
 147             my $dirname =  $_;
 148             $dirname =~ s/^$upload_path//g;
 149             push @dirs, {
 150                 value => $dirname,
 151                 name => $lastdirname,
 152                 dirs => finddirs($_)
 153             };
 154             $found = 1;
 155         };
 156     }
 157     return \@dirs;
 158 }
 159
 160 1;
 161
 162
 163 __END__
 164
 165 =head1 upload.pl
 166
 167 This plugin allow to upload files on the server and reference it in a marc
 168 field.
 169
 170 Two system preference are used:
 171
 172 =over 4
 173
 174 =item * uploadPath: the real absolute path where files will be stored
 175
 176 =item * OPACBaseURL: for building URLs to be stored in MARC
 177
 178 =back