circ/reserveratios.pl

   1 #!/usr/bin/perl
   2
   3
   4 # Copyright 2000-2002 Katipo Communications
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw ( -utf8 );
  24 use POSIX qw( ceil );
  25
  26 use C4::Context;
  27 use C4::Output qw( output_html_with_http_headers );
  28 use C4::Auth qw( get_template_and_user );
  29 use C4::Acquisition qw/GetOrdersByBiblionumber/;
  30 use Koha::DateUtils qw( dt_from_string );
  31 use Koha::Acquisition::Baskets;
  32
  33 my $input = CGI->new;
  34 my $startdate       = $input->param('from');
  35 my $enddate         = $input->param('to');
  36 my $ratio           = $input->param('ratio');
  37 my $include_ordered = $input->param('include_ordered');
  38 my $include_suspended = $input->param('include_suspended');
  39
  40 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  41     {
  42         template_name   => "circ/reserveratios.tt",
  43         query           => $input,
  44         type            => "intranet",
  45         flagsrequired   => { circulate => "circulate_remaining_permissions" },
  46     }
  47 );
  48
  49 my $booksellerid = $input->param('booksellerid') // '';
  50 my $basketno = $input->param('basketno') // '';
  51 if ($booksellerid && $basketno) {
  52      $template->param( booksellerid => $booksellerid, basketno => $basketno );
  53 }
  54
  55 my $effective_create_items = q{};
  56 if ( $basketno ){
  57     my $basket = Koha::Acquisition::Baskets->find( $basketno );
  58     if ($basket){
  59         $effective_create_items = $basket->effective_create_items;
  60     } else {
  61         $effective_create_items = C4::Context->preference('AcqCreateItem');
  62     }
  63 }
  64
  65 my $todaysdate = dt_from_string;
  66
  67 #    A default of the prior years's holds is a reasonable way to pull holds
  68 $enddate = $todaysdate unless $enddate;
  69 $startdate = $todaysdate->clone->subtract( years => 1 ) unless $startdate;
  70
  71 if (!defined($ratio)) {
  72     $ratio = 3;
  73 }
  74 # Force to be a number
  75 $ratio += 0;
  76 if ($ratio <= 0) {
  77     $ratio = 1; # prevent division by zero
  78 }
  79
  80 my $dbh    = C4::Context->dbh;
  81 my $sqldatewhere = "";
  82 my @query_params = ();
  83
  84 $sqldatewhere .= " AND reservedate >= ?";
  85 push @query_params, $startdate;
  86 $sqldatewhere .= " AND reservedate <= ?";
  87 push @query_params, $enddate;
  88
  89 my $include_aqorders_qty =
  90   $effective_create_items eq 'receiving'
  91   ? '+ COALESCE(aqorders.quantity, 0) - COALESCE(aqorders.quantityreceived, 0)'
  92   : q{};
  93
  94 my $include_aqorders_qty_join =
  95   $effective_create_items eq 'receiving'
  96   ? 'LEFT JOIN aqorders ON reserves.biblionumber=aqorders.biblionumber'
  97   : q{};
  98
  99 my $nfl_comparison = $include_ordered ? '<=' : '=';
 100 my $sus_comparison = $include_suspended ? '<=' : '<';
 101 my $strsth =
 102 "SELECT reservedate,
 103         reserves.borrowernumber as borrowernumber,
 104         reserves.biblionumber,
 105         reserves.branchcode as branch,
 106         items.holdingbranch,
 107         items.itemcallnumber,
 108         items.itemnumber,
 109         GROUP_CONCAT(DISTINCT items.itemcallnumber
 110             ORDER BY items.itemnumber SEPARATOR '|') as listcall,
 111         GROUP_CONCAT(DISTINCT homebranch
 112             ORDER BY items.itemnumber SEPARATOR '|') as homebranch_list,
 113         GROUP_CONCAT(DISTINCT holdingbranch
 114             ORDER BY items.itemnumber SEPARATOR '|') as holdingbranch_list,
 115         GROUP_CONCAT(DISTINCT items.location
 116             ORDER BY items.itemnumber SEPARATOR '|') as l_location,
 117         GROUP_CONCAT(DISTINCT items.itype
 118             ORDER BY items.itemnumber SEPARATOR '|') as l_itype,
 119
 120         reserves.found,
 121         biblio.title,
 122         biblio.subtitle,
 123         biblio.medium,
 124         biblio.part_number,
 125         biblio.part_name,
 126         biblio.author,
 127         count(DISTINCT reserves.borrowernumber) as reservecount,
 128         count(DISTINCT items.itemnumber) $include_aqorders_qty as itemcount
 129  FROM  reserves
 130  LEFT JOIN items ON items.biblionumber=reserves.biblionumber
 131  LEFT JOIN biblio ON reserves.biblionumber=biblio.biblionumber
 132  $include_aqorders_qty_join
 133  WHERE
 134  notforloan $nfl_comparison 0 AND damaged = 0 AND itemlost = 0 AND withdrawn = 0
 135  AND suspend $sus_comparison 1
 136  $sqldatewhere
 137 ";
 138
 139 if (C4::Context->preference('IndependentBranches')){
 140     $strsth .= " AND items.holdingbranch=? ";
 141     push @query_params, C4::Context->userenv->{'branch'};
 142 }
 143
 144 $strsth .= " GROUP BY reserves.biblionumber ORDER BY reservecount DESC";
 145
 146 $template->param(sql => $strsth);
 147 my $sth = $dbh->prepare($strsth);
 148 $sth->execute(@query_params);
 149
 150 my @reservedata;
 151 while ( my $data = $sth->fetchrow_hashref ) {
 152     my $thisratio = $data->{reservecount} / $data->{itemcount};
 153     my $copies_to_buy = ceil($data->{reservecount}/$ratio - $data->{itemcount});
 154     $thisratio >= $ratio or next;  # TODO: tighter targeting -- get ratio limit into SQL using HAVING clause
 155     push(
 156         @reservedata,
 157         {
 158             reservedate        => $data->{reservedate},
 159             priority           => $data->{priority},
 160             name               => $data->{borrower},
 161             title              => $data->{title},
 162             subtitle           => $data->{subtitle},
 163             medium             => $data->{medium},
 164             part_number        => $data->{part_number},
 165             part_name          => $data->{part_name},
 166             author             => $data->{author},
 167             itemnum            => $data->{itemnumber},
 168             biblionumber       => $data->{biblionumber},
 169             holdingbranch      => $data->{holdingbranch},
 170             homebranch_list    => [split('\|', $data->{homebranch_list})],
 171             holdingbranch_list => [split('\|', $data->{holdingbranch_list})],
 172             branch             => $data->{branch},
 173             itemcallnumber     => $data->{itemcallnumber},
 174             location           => [split('\|', $data->{l_location})],
 175             itype              => [split('\|', $data->{l_itype})],
 176             reservecount       => $data->{reservecount},
 177             itemcount          => $data->{itemcount},
 178             copies_to_buy      => sprintf( "%d", $copies_to_buy ),
 179             thisratio => sprintf( "%.2f", $thisratio ),
 180             thisratio_atleast1 => ( $thisratio >= 1 ) ? 1 : 0,
 181             listcall           => [split('\|', $data->{listcall})]
 182         }
 183     );
 184 }
 185
 186 for my $rd ( @reservedata ) {
 187     next unless $rd->{biblionumber};
 188     $rd->{pendingorders} = CountPendingOrdersByBiblionumber( $rd->{biblionumber} );
 189 }
 190
 191 $template->param(
 192     todaysdate      => $todaysdate,
 193     from            => $startdate,
 194     to              => $enddate,
 195     ratio           => $ratio,
 196     include_ordered => $include_ordered,
 197     include_suspended => $include_suspended,
 198     reserveloop     => \@reservedata,
 199 );
 200
 201 output_html_with_http_headers $input, $cookie, $template->output;
 202
 203 sub CountPendingOrdersByBiblionumber {
 204     my $biblionumber = shift;
 205     my @orders = GetOrdersByBiblionumber( $biblionumber );
 206     my $cnt = 0;
 207     if (scalar(@orders)) {
 208         for my $order ( @orders ) {
 209             next if $order->{datecancellationprinted};
 210             my $onum = $order->{quantity} // 0;
 211             my $rnum = $order->{quantityreceived} // 0;
 212             next if $rnum >= $onum;
 213             $cnt += ($onum - $rnum);
 214         }
 215     }
 216     return $cnt;
 217 }