course_reserves/batch_add_items.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # Copyright 2018 Bywater Solutions
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use Modern::Perl;
  22
  23 use CGI qw( -utf8 );
  24 use List::MoreUtils qw( uniq );
  25
  26 use C4::Auth;
  27 use C4::Output;
  28 use C4::CourseReserves qw(ModCourseItem ModCourseReserve GetCourse);
  29
  30 use Koha::Items;
  31
  32 my $cgi = new CGI;
  33
  34 my $action    = $cgi->param('action')    || q{};
  35 my $course_id = $cgi->param('course_id') || q{};
  36 my $barcodes  = $cgi->param('barcodes')  || q{};
  37
  38 my $itype         = $cgi->param('itype');
  39 my $ccode         = $cgi->param('ccode');
  40 my $holdingbranch = $cgi->param('holdingbranch');
  41 my $location      = $cgi->param('location');
  42 my $staff_note    = $cgi->param('staff_note');
  43 my $public_note   = $cgi->param('public_note');
  44
  45 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  46     {
  47         template_name   => "course_reserves/batch_add_items.tt",
  48         query           => $cgi,
  49         type            => "intranet",
  50         flagsrequired   => { coursereserves => 'add_reserves' },
  51     }
  52 );
  53
  54 my $course = GetCourse($course_id);
  55
  56 if ( $course_id && $course ) {
  57     $template->param( course => $course );
  58
  59     if ( !$action ) {
  60         $template->param( action => 'display_form' );
  61     }
  62     elsif ( $action eq 'add' ) {
  63         my @barcodes = uniq( split( /\s\n/, $barcodes ) );
  64
  65         my @items;
  66         my @invalid_barcodes;
  67         for my $b (@barcodes) {
  68             my $item = Koha::Items->find( { barcode => $b } );
  69
  70             if ($item) {
  71                 push( @items, $item );
  72             }
  73             else {
  74                 push( @invalid_barcodes, $b );
  75             }
  76         }
  77
  78         foreach my $item (@items) {
  79             my $ci_id = ModCourseItem(
  80                 itemnumber    => $item->id,
  81                 itype         => $itype,
  82                 ccode         => $ccode,
  83                 holdingbranch => $holdingbranch,
  84                 location      => $location,
  85             );
  86
  87             my $cr_id = ModCourseReserve(
  88                 course_id   => $course_id,
  89                 ci_id       => $ci_id,
  90                 staff_note  => $staff_note,
  91                 public_note => $public_note,
  92             );
  93         }
  94
  95         $template->param(
  96             action           => 'display_results',
  97             items_added      => \@items,
  98             invalid_barcodes => \@invalid_barcodes,
  99             course_id        => $course_id,
 100         );
 101     }
 102 } else {
 103     $template->param( action => 'invalid_course' );
 104 }
 105
 106 output_html_with_http_headers $cgi, $cookie, $template->output;