debian/list-deps

   1 #!/usr/bin/perl
   2 #
   3 # Write dependency list from Koha PerlDependencies.pm, in Debian format.
   4 #
   5 # Copyright 2010  Catalyst IT, Ltd
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 use Modern::Perl;
  21
  22 use C4::Installer::PerlDependencies;
  23
  24 # These are packages that may not be in the apt archive in a way that
  25 # apt-file can find, e.g. in the Koha repo rather than the regular
  26 # debian one.
  27 my %overrides = (
  28     'LWP::Protocol::https' => 'liblwp-protocol-https-perl | libwww-perl (<<6.02), libio-socket-ssl-perl',
  29     'HTTP::OAI'            => 'libhttp-oai-perl (>= 3.2) | libhttp-oai-3.27-perl, libhttp-oai-perl (<< 4.0) | libhttp-oai-3.27-perl',
  30     'IO::Socket::IP'       => 'perl-modules (>= 5.20.0) | libio-socket-ip-perl',
  31     'Swagger2'             => 'libswagger2-perl (>= 0.59)',
  32     'Mojolicious'          => 'libmojolicious-perl (>= 6.0)',
  33     'CPAN::Meta'           => 'libcpan-meta-perl (>= 2.150010) | perl-modules-5.28 | perl-modules-5.30 | perl-modules (>= 5.20.2)',
  34     'Locale::Language'     => 'liblocale-codes-perl'
  35 );
  36
  37 # These are packages we're going to ignore
  38 my %ignore = (
  39     'Data::Pagination'       => 1,
  40     'CHI'                    => 1,
  41     'CHI::Driver::Memcached' => 1,
  42 );
  43
  44 my $deps = $C4::Installer::PerlDependencies::PERL_DEPS;
  45
  46 my $prefix = "^/usr/((lib|share)/perl5|(lib|share)/perl/[0-9.]+|(lib|share)/.*-linux-gnu.*/perl/[0-9.]+|(lib|share)/.*-linux-gnu.*/perl5/[0-9.]+)";
  47
  48 foreach my $module ( keys %$deps ) {
  49     next if $ignore{$module};
  50     my $ver     = $deps->{$module}->{'min_ver'};
  51     my $subpath = $module;
  52     $subpath =~ s,::,/,g;
  53     my $output = qx(apt-file -l -x search "$prefix/$subpath.pm\$");
  54     my @temp   = split( /\n/, $output );
  55     my @lines  = ();
  56
  57     # Remove packages that are required/essential and always installed on
  58     # a Debian system. Debian packages should not have unversioned
  59     # dependencies on such packages.
  60
  61     # skip perl-base and problematic version specific libperl* and
  62     # perl-module* packages (they get installed as deps. anyway)
  63     foreach my $line (@temp) {
  64         if ( $line ne "perl-base" and $line !~ /^libperl5\./ and $line !~ /^perl-modules-5\./ ) {
  65             @lines = ( @lines, $line );
  66         }
  67     }
  68     if ( exists $overrides{$module} ) {
  69         print "$overrides{$module}\n";
  70     }
  71     elsif ( scalar(@lines) == 1 && $lines[0] ne "" ) {
  72         my $pkg = $lines[0];
  73         print "$pkg\n";
  74     }
  75     elsif ( scalar(@lines) > 1 ) {
  76         foreach my $pkg (@lines) {
  77             print " | " if ( $pkg ne $lines[0] );
  78             print "$pkg";
  79         }
  80         print "\n";
  81     }
  82     elsif ( scalar(@temp) != 0 ) {
  83
  84         # I'm an Essential and I'm OK,
  85         # I install all night, and work all day.
  86         # I chomp up strings. I eat my bugs.
  87         # I go to the base install.
  88         # On Fridays I go drinking,
  89         # and have buttered commits for git.
  90         # (Beer O'Clock is more than two hours
  91         # away. I don't even drink beer. There
  92         # is no reason to be suspicious of this
  93         # commit.)
  94         # RM note: suspicious?  me?  always!
  95     }
  96     elsif ( ! $deps->{$module}->{'required'} ) {
  97         # Ignore because we don't have it and we don't care.
  98     }
  99     else {
 100         print "EEEK: unknown package for $module\n";
 101     }
 102 }