koha-tmpl/intranet-tmpl/prog/en/xslt/NORMARCslim2intranetDetail.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <!-- $Id: MARC21slim2DC.xsl,v 1.1 2003/01/06 08:20:27 adam Exp $ -->
   3
   4 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   5
   6 <xsl:stylesheet version="1.0"
   7   xmlns:marc="http://www.loc.gov/MARC21/slim"
   8   xmlns:items="http://www.koha-community.org/items"
   9   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  10   exclude-result-prefixes="marc items">
  11     <xsl:import href="NORMARCslimUtils.xsl"/>
  12     <xsl:output method = "html" indent="yes" omit-xml-declaration = "yes" encoding="UTF-8"/>
  13     <xsl:template match="/">
  14             <xsl:apply-templates/>
  15     </xsl:template>
  16
  17     <xsl:template match="marc:record">
  18
  19         <!-- Sysprefs -->
  20         <xsl:variable name="UseControlNumber" select="marc:sysprefs/marc:syspref[@name='UseControlNumber']"/>
  21         <xsl:variable name="OPACBaseURL" select="marc:sysprefs/marc:syspref[@name='OPACBaseURL']"/>
  22         <xsl:variable name="SubjectModifier"><xsl:if test="marc:sysprefs/marc:syspref[@name='TraceCompleteSubfields']='1'">,complete-subfield</xsl:if></xsl:variable>
  23         <xsl:variable name="TraceSubjectSubdivisions" select="marc:sysprefs/marc:syspref[@name='TraceSubjectSubdivisions']"/>
  24         <xsl:variable name="OpacSuppression" select="marc:sysprefs/marc:syspref[@name='OpacSuppression']"/>
  25         <xsl:variable name="TracingQuotesLeft">
  26           <xsl:choose>
  27             <xsl:when test="marc:sysprefs/marc:syspref[@name='UseICU']='1'">{</xsl:when>
  28             <xsl:otherwise>"</xsl:otherwise>
  29           </xsl:choose>
  30         </xsl:variable>
  31         <xsl:variable name="TracingQuotesRight">
  32           <xsl:choose>
  33             <xsl:when test="marc:sysprefs/marc:syspref[@name='UseICU']='1'">}</xsl:when>
  34             <xsl:otherwise>"</xsl:otherwise>
  35           </xsl:choose>
  36         </xsl:variable>
  37         <xsl:variable name="DisplayOPACiconsXSLT" select="marc:sysprefs/marc:syspref[@name='DisplayOPACiconsXSLT']"/>
  38
  39         <xsl:variable name="leader" select="marc:leader"/>
  40         <xsl:variable name="leader6" select="substring($leader,7,1)"/>
  41         <xsl:variable name="leader7" select="substring($leader,8,1)"/>
  42         <xsl:variable name="controlField008" select="marc:controlfield[@tag=008]"/>
  43         <xsl:variable name="field019b" select="marc:datafield[@tag=019]/marc:subfield[@code='b']"/>
  44         <xsl:variable name="biblionumber" select="marc:datafield[@tag=999]/marc:subfield[@code='c']"/>
  45         <xsl:variable name="typeOf008">
  46             <!-- The logic here should be exactly the same for NORMARCslim2intranetDetail.xsl, NORMARCslim2intranetResults.xsl, NORMARCslim2OPACDetail.xsl and NORMARCslim2OPACResults.xsl -->
  47             <xsl:choose>
  48                 <xsl:when test="$field019b='b' or $field019b='k' or $field019b='l' or $leader6='b'">Mon</xsl:when>
  49                 <xsl:when test="$field019b='e' or contains($field019b,'ec') or contains($field019b,'ed') or contains($field019b,'ee') or contains($field019b,'ef') or $leader6='g'">FV</xsl:when>
  50                 <xsl:when test="$field019b='c' or $field019b='d' or contains($field019b,'da') or contains($field019b,'db') or contains($field019b,'dc') or contains($field019b,'dd') or contains($field019b,'dg') or contains($field019b,'dh') or contains($field019b,'di') or contains($field019b,'dj') or contains($field019b,'dk') or $leader6='c' or $leader6='d' or $leader6='i' or $leader6='j'">Mus</xsl:when>
  51                 <xsl:when test="$field019b='a' or contains($field019b,'ab') or contains($field019b,'aj') or $leader6='e' or $leader6='f'">Kar</xsl:when>
  52                 <xsl:when test="$field019b='f' or $field019b='i' or contains($field019b,'ib') or contains($field019b,'ic') or contains($field019b,'fd') or contains($field019b,'ff') or contains($field019b,'fi') or $leader6='k'">gra</xsl:when>
  53                 <xsl:when test="$field019b='g' or contains($field019b,'gb') or contains($field019b,'gd') or contains($field019b,'ge') or $leader6='m'">Fil</xsl:when>
  54                 <xsl:when test="$leader6='o'">kom</xsl:when>
  55                 <xsl:when test="$field019b='h' or $leader6='r'">trd</xsl:when>
  56                 <xsl:when test="$field019b='j' or $leader6='a'">
  57                     <xsl:choose>
  58                         <xsl:when test="$leader7='a' or $leader7='c' or $leader7='m' or $leader7='p'">Mon</xsl:when>
  59                         <xsl:when test="$field019b='j' or $leader7='b' or $leader7='s'">Per</xsl:when>
  60                     </xsl:choose>
  61                 </xsl:when>
  62             </xsl:choose>
  63         </xsl:variable>
  64
  65         <!-- Indicate if record is suppressed in OPAC -->
  66         <xsl:if test="$OpacSuppression = 1">
  67             <xsl:if test="marc:datafield[@tag=942][marc:subfield[@code='n'] = '1']">
  68                 <span class="results_summary suppressed_opac">Suppressed in OPAC</span>
  69             </xsl:if>
  70         </xsl:if>
  71
  72         <!-- Tittel og ansvarsopplysninger -->
  73         <xsl:if test="marc:datafield[@tag=245]">
  74         <h1>
  75             <xsl:for-each select="marc:datafield[@tag=245]">
  76                     <xsl:call-template name="subfieldSelect">
  77                         <xsl:with-param name="codes">a</xsl:with-param>
  78                     </xsl:call-template>
  79                     <xsl:if test="marc:subfield[@code='h']">
  80                         <xsl:text> </xsl:text>
  81                         (<xsl:call-template name="subfieldSelect">
  82                             <xsl:with-param name="codes">h</xsl:with-param>
  83                         </xsl:call-template>)
  84                     </xsl:if>
  85                     <xsl:if test="marc:subfield[@code='b']">
  86                         <xsl:text> : </xsl:text>
  87                         <xsl:call-template name="subfieldSelect">
  88                             <xsl:with-param name="codes">b</xsl:with-param>
  89                         </xsl:call-template>
  90                     </xsl:if>
  91                     <xsl:text> </xsl:text>
  92                     <xsl:call-template name="subfieldSelect">
  93                         <xsl:with-param name="codes">np</xsl:with-param>
  94                     </xsl:call-template>
  95             </xsl:for-each>
  96         </h1>
  97         </xsl:if>
  98
  99         <!-- Author Statement -->
 100                 <!-- 245$9 is Koha authority number -->
 101         <xsl:choose>
 102         <xsl:when test="marc:datafield[@tag=100] or marc:datafield[@tag=110] or marc:datafield[@tag=111] or marc:datafield[@tag=700] or marc:datafield[@tag=710] or marc:datafield[@tag=711]">
 103         <h5 class="author">av
 104         <xsl:for-each select="marc:datafield[@tag=100 or @tag=700]">
 105         <a>
 106         <xsl:choose>
 107             <xsl:when test="marc:subfield[@code=9]">
 108                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 109             </xsl:when>
 110             <xsl:otherwise>
 111             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 112             </xsl:otherwise>
 113         </xsl:choose>
 114         <xsl:call-template name="nameABCDQ"/></a>
 115         <xsl:choose>
 116         <xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 117         </xsl:for-each>
 118
 119         <xsl:for-each select="marc:datafield[@tag=110 or @tag=710]">
 120         <a>
 121         <xsl:choose>
 122             <xsl:when test="marc:subfield[@code=9]">
 123                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 124             </xsl:when>
 125             <xsl:otherwise>
 126             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 127             </xsl:otherwise>
 128         </xsl:choose>
 129         <xsl:call-template name="nameABCDN"/></a>
 130         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 131         </xsl:for-each>
 132
 133         <xsl:for-each select="marc:datafield[@tag=111 or @tag=711]">
 134         <a>
 135         <xsl:choose>
 136             <xsl:when test="marc:subfield[@code=9]">
 137                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 138             </xsl:when>
 139             <xsl:otherwise>
 140             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 141             </xsl:otherwise>
 142         </xsl:choose>
 143         <xsl:call-template name="nameACDEQ"/></a>
 144         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 145
 146         </xsl:for-each>
 147         </h5>
 148         </xsl:when>
 149         </xsl:choose>
 150
 151
 152         <xsl:if test="$typeOf008!=''">
 153         <span class="results_summary">
 154             <span class="label">Materialtype: </span>
 155             <xsl:choose>
 156                 <xsl:when test="$typeOf008='Mon'"><img src="/intranet-tmpl/prog/img/famfamfam/BK.png" alt="Bok" title="Bok"/> Bok</xsl:when>
 157                 <xsl:when test="$typeOf008='Per'"><img src="/intranet-tmpl/prog/img/famfamfam/AR.png" alt="Periodika" title="Periodika"/> Periodika</xsl:when>
 158                 <xsl:when test="$typeOf008='Fil'"><img src="/intranet-tmpl/prog/img/famfamfam/CF.png" alt="Fil" title="Fil"/> Fil</xsl:when>
 159                 <xsl:when test="$typeOf008='Kar'"><img src="/intranet-tmpl/prog/img/famfamfam/MP.png" alt="Kart" title="Kart"/> Kart</xsl:when>
 160                 <xsl:when test="$typeOf008='FV'"><img  src="/intranet-tmpl/prog/img/famfamfam/VM.png" alt="Film og video" title="Film og video"/> Film og video</xsl:when>
 161                 <xsl:when test="$typeOf008='Mus'"><img src="/intranet-tmpl/prog/img/famfamfam/PR.png" alt="Musikktrykk og lydopptak" title="Musikktrykk og lydopptak"/> Musikk</xsl:when>
 162                 <xsl:when test="$typeOf008='gra'"><img src="/intranet-tmpl/prog/img/famfamfam/GR.png" alt="Grafisk materiale" title="Grafisk materiale"/> Grafisk materiale</xsl:when>
 163                 <xsl:when test="$typeOf008='kom'"><img src="/intranet-tmpl/prog/img/famfamfam/MX.png" alt="Kombidokumenter" title="Kombidokumenter"/> Kombidokumenter</xsl:when>
 164                 <xsl:when test="$typeOf008='trd'"><img src="/intranet-tmpl/prog/img/famfamfam/TD.png" alt="Tre-dimensjonale gjenstander" title="Tre-dimensjonale gjenstander"/> Tre-dimensjonale gjenstander</xsl:when>
 165             </xsl:choose>
 166         </span>
 167         </xsl:if>
 168
 169         <!--Series -->
 170         <xsl:if test="marc:datafield[@tag=440 or @tag=490]">
 171                 <span class="results_summary"><span class="label">Series: </span>
 172                 <xsl:for-each select="marc:datafield[@tag=440]">
 173                      <a href="/cgi-bin/koha/catalogue/search.pl?q=se:{marc:subfield[@code='a']}">
 174                     <xsl:call-template name="chopPunctuation">
 175                                     <xsl:with-param name="chopString">
 176                                         <xsl:call-template name="subfieldSelect">
 177                                             <xsl:with-param name="codes">av</xsl:with-param>
 178                                         </xsl:call-template>
 179                                     </xsl:with-param>
 180                                 </xsl:call-template>
 181                                 </a>
 182                             <xsl:text> </xsl:text><xsl:call-template name="part"/>
 183                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 184                 </xsl:for-each>
 185
 186                 <xsl:for-each select="marc:datafield[@tag=490][@ind1=0]">
 187                      <a href="/cgi-bin/koha/catalogue/search.pl?q=se:{marc:subfield[@code='a']}">
 188                                 <xsl:call-template name="chopPunctuation">
 189                                     <xsl:with-param name="chopString">
 190                                         <xsl:call-template name="subfieldSelect">
 191                                             <xsl:with-param name="codes">av</xsl:with-param>
 192                                         </xsl:call-template>
 193                                     </xsl:with-param>
 194                                 </xsl:call-template>
 195                     </a>
 196                             <xsl:call-template name="part"/>
 197                 <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 198                 </xsl:for-each>
 199                 </span>
 200         </xsl:if>
 201
 202         <!-- Analytics -->
 203         <xsl:if test="$leader7='s' or $leader7='c'">
 204         <span class="results_summary analytics"><span class="label">Analytics: </span>
 205             <a>
 206             <xsl:choose>
 207             <xsl:when test="$UseControlNumber = '1' and marc:controlfield[@tag=001]">
 208                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=rcn:<xsl:value-of select="marc:controlfield[@tag=001]"/>+and+(bib-level:a+or+bib-level:b)</xsl:attribute>
 209             </xsl:when>
 210             <xsl:otherwise>
 211                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=Host-item:<xsl:value-of select="translate(marc:datafield[@tag=245]/marc:subfield[@code='a'], '/', '')"/></xsl:attribute>
 212             </xsl:otherwise>
 213             </xsl:choose>
 214             <xsl:text>Show analytics</xsl:text>
 215             </a>
 216         </span>
 217         </xsl:if>
 218
 219         <!-- 773 - Links from child to parent -->
 220         <xsl:if test="marc:datafield[@tag=773]">
 221         <xsl:for-each select="marc:datafield[@tag=773]">
 222         <xsl:if test="@ind1=0">
 223         <span class="results_summary in"><span class="label">
 224         <xsl:choose>
 225         <xsl:when test="@ind2=' '">
 226             In:
 227         </xsl:when>
 228         <xsl:when test="@ind2=8">
 229             <xsl:if test="marc:subfield[@code='i']">
 230                 <xsl:value-of select="marc:subfield[@code='i']"/>
 231             </xsl:if>
 232         </xsl:when>
 233         </xsl:choose>
 234         </span>
 235                 <xsl:variable name="f773">
 236                     <xsl:call-template name="chopPunctuation"><xsl:with-param name="chopString"><xsl:call-template name="subfieldSelect">
 237                         <xsl:with-param name="codes">a_t</xsl:with-param>
 238                     </xsl:call-template></xsl:with-param></xsl:call-template>
 239                 </xsl:variable>
 240             <xsl:choose>
 241                 <xsl:when test="$UseControlNumber = '1' and marc:subfield[@code='w']">
 242                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=Control-number:<xsl:call-template name="extractControlNumber"><xsl:with-param name="subfieldW" select="marc:subfield[@code='w']"/></xsl:call-template></xsl:attribute>
 243                         <xsl:value-of select="translate($f773, '()', '')"/>
 244                     </a>
 245                     <xsl:if test="marc:subfield[@code='g']"><xsl:text> </xsl:text><xsl:value-of select="marc:subfield[@code='g']"/></xsl:if>
 246                 </xsl:when>
 247                 <xsl:when test="marc:subfield[@code='0']">
 248                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/detail.pl?biblionumber=<xsl:value-of select="marc:subfield[@code='0']"/></xsl:attribute>
 249                         <xsl:value-of select="$f773"/>
 250                     </a>
 251                 </xsl:when>
 252                 <xsl:otherwise>
 253                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=ti,phr:<xsl:value-of select="translate($f773, '()', '')"/></xsl:attribute>
 254                         <xsl:value-of select="$f773"/>
 255                     </a>
 256                     <xsl:if test="marc:subfield[@code='g']"><xsl:text> </xsl:text><xsl:value-of select="marc:subfield[@code='g']"/></xsl:if>
 257                 </xsl:otherwise>
 258             </xsl:choose>
 259         </span>
 260         <xsl:if test="marc:subfield[@code='n']">
 261             <span class="results_summary"><xsl:value-of select="marc:subfield[@code='n']"/></span>
 262         </xsl:if>
 263         </xsl:if>
 264         </xsl:for-each>
 265         </xsl:if>
 266
 267         <!-- Publisher Statement -->
 268
 269         <xsl:if test="marc:datafield[@tag=260]">
 270         <span class="results_summary"><span class="label">Utgiver: </span>
 271             <xsl:for-each select="marc:datafield[@tag=260]">
 272                 <xsl:call-template name="chopPunctuation">
 273                   <xsl:with-param name="chopString">
 274                     <xsl:call-template name="subfieldSelect">
 275                         <xsl:with-param name="codes">bcg</xsl:with-param>
 276                     </xsl:call-template>
 277                    </xsl:with-param>
 278                </xsl:call-template>
 279                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 280             </xsl:for-each>
 281         </span>
 282         </xsl:if>
 283
 284         <!-- Edition Statement -->
 285
 286         <xsl:if test="marc:datafield[@tag=250]">
 287         <span class="results_summary"><span class="label">Utgave: </span>
 288             <xsl:for-each select="marc:datafield[@tag=250]">
 289                 <xsl:call-template name="chopPunctuation">
 290                   <xsl:with-param name="chopString">
 291                     <xsl:call-template name="subfieldSelect">
 292                         <xsl:with-param name="codes">ab</xsl:with-param>
 293                     </xsl:call-template>
 294                    </xsl:with-param>
 295                </xsl:call-template>
 296                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 297             </xsl:for-each>
 298         </span>
 299         </xsl:if>
 300
 301         <!-- Description -->
 302
 303         <xsl:if test="marc:datafield[@tag=300]">
 304         <span class="results_summary"><span class="label">Beskrivelse: </span>
 305             <xsl:for-each select="marc:datafield[@tag=300]">
 306                 <xsl:call-template name="chopPunctuation">
 307                   <xsl:with-param name="chopString">
 308                     <xsl:call-template name="subfieldSelect">
 309                         <xsl:with-param name="codes">abceg</xsl:with-param>
 310                     </xsl:call-template>
 311                    </xsl:with-param>
 312                </xsl:call-template>
 313                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 314             </xsl:for-each>
 315         </span>
 316        </xsl:if>
 317
 318        <abbr class="unapi-id" title="koha:biblionumber:{marc:datafield[@tag=999]/marc:subfield[@code='c']}" ><!-- unAPI --></abbr>
 319
 320         <!-- Build ISBN -->
 321         <xsl:if test="marc:datafield[@tag=020]/marc:subfield[@code='a']">
 322           <span class="results_summary isbn"><span class="label">ISBN: </span>
 323             <xsl:for-each select="marc:datafield[@tag=020]/marc:subfield[@code='a']">
 324               <span property="isbn">
 325                 <xsl:value-of select="."/>
 326                 <xsl:choose>
 327                   <xsl:when test="position()=last()">
 328                     <xsl:text>.</xsl:text>
 329                   </xsl:when>
 330                   <xsl:otherwise>
 331                     <xsl:text>; </xsl:text>
 332                   </xsl:otherwise>
 333                 </xsl:choose>
 334               </span>
 335             </xsl:for-each>
 336           </span>
 337         </xsl:if>
 338
 339         <!-- Build ISSN -->
 340         <xsl:if test="marc:datafield[@tag=022]/marc:subfield[@code='a']">
 341           <span class="results_summary issn"><span class="label">ISSN: </span>
 342             <xsl:for-each select="marc:datafield[@tag=022]/marc:subfield[@code='a']">
 343               <span property="issn">
 344                 <xsl:value-of select="."/>
 345                 <xsl:choose>
 346                   <xsl:when test="position()=last()">
 347                     <xsl:text>.</xsl:text>
 348                   </xsl:when>
 349                   <xsl:otherwise>
 350                     <xsl:text>; </xsl:text>
 351                   </xsl:otherwise>
 352                 </xsl:choose>
 353               </span>
 354             </xsl:for-each>
 355           </span>
 356         </xsl:if>
 357
 358         <!-- Other Title  Statement -->
 359
 360         <xsl:if test="marc:datafield[@tag=246]">
 361         <span class="results_summary"><span class="label">Parallelltittel: </span>
 362             <xsl:for-each select="marc:datafield[@tag=246]">
 363                 <xsl:call-template name="chopPunctuation">
 364                   <xsl:with-param name="chopString">
 365                     <xsl:call-template name="subfieldSelect">
 366                         <xsl:with-param name="codes">abhfgnp</xsl:with-param>
 367                     </xsl:call-template>
 368                    </xsl:with-param>
 369                </xsl:call-template>
 370                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 371             </xsl:for-each>
 372         </span>
 373        </xsl:if>
 374
 375         <!-- Uniform Title  Statement -->
 376
 377         <xsl:if test="marc:datafield[@tag=130]|marc:datafield[@tag=240]|marc:datafield[@tag=730][@ind2!=2]">
 378         <span class="results_summary"><span class="label">Standardtittel: </span>
 379         <xsl:for-each select="marc:datafield[@tag=130]|marc:datafield[@tag=240]|marc:datafield[@tag=730][@ind2!=2]">
 380             <xsl:variable name="str">
 381                 <xsl:for-each select="marc:subfield">
 382                     <xsl:if test="(contains('adfklmor',@code) and (not(../marc:subfield[@code='n' or @code='p']) or (following-sibling::marc:subfield[@code='n' or @code='p'])))">
 383                         <xsl:value-of select="text()"/>
 384                         <xsl:text> </xsl:text>
 385                      </xsl:if>
 386                 </xsl:for-each>
 387             </xsl:variable>
 388             <xsl:call-template name="chopPunctuation">
 389                 <xsl:with-param name="chopString">
 390                     <xsl:value-of select="substring($str,1,string-length($str)-1)"/>
 391
 392                 </xsl:with-param>
 393             </xsl:call-template>
 394             <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 395         </xsl:for-each>
 396         </span>
 397         </xsl:if>
 398
 399         <!-- Subjects -->
 400
 401         <xsl:if test="marc:datafield[substring(@tag, 1, 1) = '6']">
 402             <span class="results_summary subjects"><span class="label">Emne(r): </span>
 403             <xsl:for-each select="marc:datafield[substring(@tag, 1, 1) = '6']">
 404             <a>
 405             <xsl:choose>
 406             <!-- Will implement this later
 407                 <xsl:when test="marc:subfield[@code=9] and $UseAuthoritiesForTracings='1'">
 408                     <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 409                 </xsl:when>
 410             -->
 411             <xsl:when test="$TraceSubjectSubdivisions='1'">
 412                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:call-template name="subfieldSelect">
 413                         <xsl:with-param name="codes">abcdvxyz</xsl:with-param>
 414                         <xsl:with-param name="delimeter"> AND </xsl:with-param>
 415                         <xsl:with-param name="prefix">(su<xsl:value-of select="$SubjectModifier"/>:<xsl:value-of select="$TracingQuotesLeft"/></xsl:with-param>
 416                         <xsl:with-param name="suffix"><xsl:value-of select="$TracingQuotesRight"/>)</xsl:with-param>
 417                     </xsl:call-template>
 418                 </xsl:attribute>
 419             </xsl:when>
 420             <xsl:otherwise>
 421                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=su<xsl:value-of select="$SubjectModifier"/>:<xsl:value-of select="$TracingQuotesLeft"/><xsl:value-of select="marc:subfield[@code='a']"/><xsl:value-of select="$TracingQuotesRight"/></xsl:attribute>
 422             </xsl:otherwise>
 423             </xsl:choose>
 424             <xsl:call-template name="chopPunctuation">
 425                 <xsl:with-param name="chopString">
 426                     <xsl:call-template name="subfieldSelect">
 427                         <xsl:with-param name="codes">abcdvxyz</xsl:with-param>
 428                         <xsl:with-param name="subdivCodes">vxyz</xsl:with-param>
 429                         <xsl:with-param name="subdivDelimiter">-- </xsl:with-param>
 430                     </xsl:call-template>
 431                 </xsl:with-param>
 432             </xsl:call-template>
 433             </a>
 434             <xsl:choose>
 435             <xsl:when test="position()=last()"></xsl:when>
 436             <xsl:otherwise> | </xsl:otherwise>
 437             </xsl:choose>
 438
 439             </xsl:for-each>
 440             </span>
 441         </xsl:if>
 442
 443         <xsl:if test="marc:datafield[@tag=856]">
 444         <span class="results_summary"><span class="label">Nettbasert ressurs: </span>
 445         <xsl:for-each select="marc:datafield[@tag=856]">
 446             <a><xsl:attribute name="href"><xsl:value-of select="marc:subfield[@code='u']"/></xsl:attribute>
 447         <xsl:choose>
 448             <xsl:when test="marc:subfield[@code='y' or @code='3' or @code='z']">
 449                     <xsl:call-template name="subfieldSelect">
 450                         <xsl:with-param name="codes">y3z</xsl:with-param>
 451                     </xsl:call-template>
 452             </xsl:when>
 453         <xsl:when test="not(marc:subfield[@code='y']) and not(marc:subfield[@code='3']) and not(marc:subfield[@code='z'])">
 454         Klikk her for tilgang
 455         </xsl:when>
 456         </xsl:choose>
 457         </a>
 458             <xsl:choose>
 459             <xsl:when test="position()=last()"></xsl:when>
 460             <xsl:otherwise> | </xsl:otherwise>
 461             </xsl:choose>
 462         </xsl:for-each>
 463         </span>
 464         </xsl:if>
 465
 466         <!-- NORMARC does not define indicators for 505
 467         <xsl:if test="marc:datafield[@tag=505]">
 468         <xsl:for-each select="marc:datafield[@tag=505]">
 469         <span class="results_summary"><span class="label">
 470         <xsl:choose>
 471         <xsl:when test="@ind1=0">
 472             Contents:
 473         </xsl:when>
 474         <xsl:when test="@ind1=1">
 475             Incomplete contents:
 476         </xsl:when>
 477         <xsl:when test="@ind1=1">
 478             Partial contents:
 479         </xsl:when>
 480         </xsl:choose>
 481         </span>
 482         <xsl:choose>
 483         <xsl:when test="@ind2=0">
 484             <xsl:for-each select="marc:subfield[@code='t']">
 485                 <xsl:value-of select="marc:subfield[@code=t]"/> <xsl:value-of select="marc:subfield[@code=r]"/>
 486             </xsl:for-each>
 487         </xsl:when>
 488         <xsl:otherwise>
 489             <xsl:call-template name="subfieldSelect">
 490                 <xsl:with-param name="codes">au</xsl:with-param>
 491             </xsl:call-template>
 492         </xsl:otherwise>
 493         </xsl:choose>
 494         </span>
 495         </xsl:for-each>
 496         </xsl:if>
 497         -->
 498         <xsl:if test="marc:datafield[@tag=505]">
 499                 <xsl:call-template name="subfieldSelect">
 500                 <xsl:with-param name="codes">a</xsl:with-param>
 501             </xsl:call-template>
 502                 </xsl:if>
 503
 504         <!-- 780 -->
 505         <xsl:if test="marc:datafield[@tag=780]">
 506         <xsl:for-each select="marc:datafield[@tag=780]">
 507         <span class="results_summary"><span class="label">
 508         <xsl:choose>
 509                 <xsl:when test="@ind2=0">
 510                     Fortsettelse av:
 511                 </xsl:when>
 512                 <xsl:when test="@ind2=1">
 513                     Delvis fortsettelse av:
 514                 </xsl:when>
 515                 <xsl:when test="@ind2=2">
 516                     Avløser:
 517                 </xsl:when>
 518                 <xsl:when test="@ind2=3">
 519                     Avløser delvis:
 520                 </xsl:when>
 521                 <xsl:when test="@ind2=4">
 522                     Sammenslåing av: ... ; og ...
 523                 </xsl:when>
 524                 <xsl:when test="@ind2=5">
 525                     Har tatt opp:
 526                 </xsl:when>
 527                 <xsl:when test="@ind2=6">
 528                     Har delvis tatt opp:
 529                 </xsl:when>
 530                 <xsl:when test="@ind2=7">
 531                     Utskilt fra:
 532                 </xsl:when>
 533         </xsl:choose>
 534         </span>
 535                 <xsl:variable name="f780">
 536                     <xsl:call-template name="subfieldSelect">
 537                         <xsl:with-param name="codes">a_t</xsl:with-param>
 538                     </xsl:call-template>
 539                 </xsl:variable>
 540              <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:value-of select="translate($f780, '()', '')"/></xsl:attribute>
 541                 <xsl:value-of select="translate($f780, '()', '')"/>
 542             </a>
 543         </span>
 544
 545         <xsl:choose>
 546         <xsl:when test="@ind1=0">
 547             <span class="results_summary"><xsl:value-of select="marc:subfield[@code='n']"/></span>
 548         </xsl:when>
 549         </xsl:choose>
 550
 551         </xsl:for-each>
 552         </xsl:if>
 553
 554         <!-- 785 -->
 555         <xsl:if test="marc:datafield[@tag=785]">
 556         <xsl:for-each select="marc:datafield[@tag=785]">
 557         <span class="results_summary"><span class="label">
 558         <xsl:choose>
 559                 <xsl:when test="@ind2=0">
 560                     Fortsettelse i:
 561                 </xsl:when>
 562                 <xsl:when test="@ind2=1">
 563                     Fortsettes delvis i:
 564                 </xsl:when>
 565                 <xsl:when test="@ind2=2">
 566                     Avløst av:
 567                 </xsl:when>
 568                 <xsl:when test="@ind2=3">
 569                     Delvis avløst av:
 570                 </xsl:when>
 571                 <xsl:when test="@ind2=4">
 572                     Gått inn i:
 573                 </xsl:when>
 574                 <xsl:when test="@ind2=5">
 575                     Delvis gått inn i:
 576                 </xsl:when>
 577                 <xsl:when test="@ind2=6">
 578                     Fortsettes av: ...; og ...
 579                 </xsl:when>
 580                 <xsl:when test="@ind2=7">
 581                         Slått sammen med: .., til: ...
 582                 </xsl:when>
 583         </xsl:choose>
 584         </span>
 585                    <xsl:variable name="f785">
 586                     <xsl:call-template name="subfieldSelect">
 587                         <xsl:with-param name="codes">a_t</xsl:with-param>
 588                     </xsl:call-template>
 589                 </xsl:variable>
 590
 591                 <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:value-of select="translate($f785, '()', '')"/></xsl:attribute>
 592                 <xsl:value-of select="translate($f785, '()', '')"/>
 593             </a>
 594
 595         </span>
 596         </xsl:for-each>
 597         </xsl:if>
 598
 599         <!-- This will only work if the OPACBaseURL syspref is set. -->
 600         <xsl:if test="string-length($OPACBaseURL) > 0">
 601         <p>OPAC View: <a>
 602                       <xsl:attribute name="href"><xsl:value-of select="$OPACBaseURL"/>/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of select="$biblionumber"/></xsl:attribute>
 603                       <xsl:attribute name="target">_blank</xsl:attribute>
 604                       Open in new window
 605                       </a></p>
 606          </xsl:if>
 607
 608     </xsl:template>
 609
 610     <xsl:template name="part">
 611         <xsl:variable name="partNumber">
 612             <xsl:call-template name="specialSubfieldSelect">
 613                 <xsl:with-param name="axis">n</xsl:with-param>
 614                 <xsl:with-param name="anyCodes">n</xsl:with-param>
 615                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 616             </xsl:call-template>
 617         </xsl:variable>
 618         <xsl:variable name="partName">
 619             <xsl:call-template name="specialSubfieldSelect">
 620                 <xsl:with-param name="axis">p</xsl:with-param>
 621                 <xsl:with-param name="anyCodes">p</xsl:with-param>
 622                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 623             </xsl:call-template>
 624         </xsl:variable>
 625         <xsl:if test="string-length(normalize-space($partNumber))">
 626                 <xsl:call-template name="chopPunctuation">
 627                     <xsl:with-param name="chopString" select="$partNumber"/>
 628                 </xsl:call-template>
 629         </xsl:if>
 630         <xsl:if test="string-length(normalize-space($partName))">
 631                 <xsl:call-template name="chopPunctuation">
 632                     <xsl:with-param name="chopString" select="$partName"/>
 633                 </xsl:call-template>
 634         </xsl:if>
 635     </xsl:template>
 636
 637     <xsl:template name="specialSubfieldSelect">
 638         <xsl:param name="anyCodes"/>
 639         <xsl:param name="axis"/>
 640         <xsl:param name="beforeCodes"/>
 641         <xsl:param name="afterCodes"/>
 642         <xsl:variable name="str">
 643             <xsl:for-each select="marc:subfield">
 644                 <xsl:if test="contains($anyCodes, @code)      or (contains($beforeCodes,@code) and following-sibling::marc:subfield[@code=$axis])      or (contains($afterCodes,@code) and preceding-sibling::marc:subfield[@code=$axis])">
 645                     <xsl:value-of select="text()"/>
 646                     <xsl:text> </xsl:text>
 647                 </xsl:if>
 648             </xsl:for-each>
 649         </xsl:variable>
 650         <xsl:value-of select="substring($str,1,string-length($str)-1)"/>
 651     </xsl:template>
 652 </xsl:stylesheet>