koha-tmpl/intranet-tmpl/prog/en/xslt/UNIMARCslim2intranetResults.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2
   3 <!DOCTYPE stylesheet>
   4
   5 <!-- $Id: MARC21slim2DC.xsl,v 1.1 2003/01/06 08:20:27 adam Exp $ -->
   6 <xsl:stylesheet version="1.0"
   7   xmlns:marc="http://www.loc.gov/MARC21/slim"
   8   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9   xmlns:str="http://exslt.org/strings"
  10   exclude-result-prefixes="marc str">
  11
  12 <xsl:import href="UNIMARCslimUtils.xsl"/>
  13 <xsl:output method = "html" indent="yes" omit-xml-declaration = "yes" encoding="UTF-8"/>
  14
  15 <xsl:template match="/">
  16   <xsl:apply-templates/>
  17 </xsl:template>
  18
  19 <xsl:template match="marc:record">
  20   <xsl:variable name="IntranetBiblioDefaultView" select="marc:sysprefs/marc:syspref[@name='IntranetBiblioDefaultView']"/>
  21   <xsl:variable name="leader" select="marc:leader"/>
  22   <xsl:variable name="leader6" select="substring($leader,7,1)"/>
  23   <xsl:variable name="leader7" select="substring($leader,8,1)"/>
  24   <xsl:variable name="biblionumber" select="marc:controlfield[@tag=001]"/>
  25   <xsl:variable name="isbn" select="marc:datafield[@tag=010]/marc:subfield[@code='a']"/>
  26
  27   <xsl:if test="marc:datafield[@tag=200]">
  28     <xsl:for-each select="marc:datafield[@tag=200]">
  29       <a>
  30         <xsl:attribute name="href">
  31           <xsl:call-template name="buildBiblioDefaultViewURL">
  32             <xsl:with-param name="IntranetBiblioDefaultView">
  33               <xsl:value-of select="$IntranetBiblioDefaultView"/>
  34             </xsl:with-param>
  35           </xsl:call-template>
  36           <xsl:value-of select="str:encode-uri($biblionumber, true())"/>
  37         </xsl:attribute>
  38         <xsl:attribute name="class">title</xsl:attribute>
  39
  40         <xsl:variable name="title" select="marc:subfield[@code='a']"/>
  41         <xsl:variable name="ntitle"
  42             select="translate($title, '&#x0098;&#x009C;&#xC29C;&#xC29B;&#xC298;&#xC288;&#xC289;','')"/>
  43         <xsl:value-of select="$ntitle" />
  44       </a>
  45       <xsl:if test="marc:subfield[@code='e']">
  46         <xsl:text> : </xsl:text>
  47         <xsl:value-of select="marc:subfield[@code='e']"/>
  48       </xsl:if>
  49       <xsl:if test="marc:subfield[@code='b']">
  50         <xsl:text> [</xsl:text>
  51         <xsl:value-of select="marc:subfield[@code='b']"/>
  52         <xsl:text>]</xsl:text>
  53       </xsl:if>
  54       <xsl:if test="marc:subfield[@code='h']">
  55         <xsl:text> : </xsl:text>
  56         <xsl:value-of select="marc:subfield[@code='h']"/>
  57       </xsl:if>
  58       <xsl:if test="marc:subfield[@code='i']">
  59         <xsl:text> : </xsl:text>
  60         <xsl:value-of select="marc:subfield[@code='i']"/>
  61       </xsl:if>
  62       <xsl:if test="marc:subfield[@code='f']">
  63         <xsl:text> / </xsl:text>
  64         <xsl:value-of select="marc:subfield[@code='f']"/>
  65       </xsl:if>
  66       <xsl:if test="marc:subfield[@code='g']">
  67         <xsl:text> ; </xsl:text>
  68         <xsl:value-of select="marc:subfield[@code='g']"/>
  69       </xsl:if>
  70       <xsl:text> </xsl:text>
  71     </xsl:for-each>
  72   </xsl:if>
  73
  74   <xsl:call-template name="tag_4xx" />
  75
  76   <xsl:call-template name="tag_210" />
  77
  78   <xsl:call-template name="tag_215" />
  79
  80 </xsl:template>
  81 </xsl:stylesheet>