members/member-flags.pl

   1 #!/usr/bin/perl
   2
   3 # script to edit a member's flags
   4 # Written by Steve Tonnesen
   5 # July 26, 2002 (my birthday!)
   6
   7 use Modern::Perl;
   8
   9 use CGI qw ( -utf8 );
  10 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  11 use C4::Auth qw( get_template_and_user get_all_subpermissions get_user_subpermissions );
  12 use C4::Context;
  13
  14 use Koha::Patron::Categories;
  15 use Koha::Patrons;
  16
  17 use C4::Output qw( output_and_exit_if_error output_and_exit output_html_with_http_headers );
  18 use Koha::Token;
  19
  20 my $input = CGI->new;
  21
  22 my $flagsrequired = { permissions => 1 };
  23 my $member=$input->param('member');
  24 my $patron = Koha::Patrons->find( $member );
  25 unless ( $patron ) {
  26     print $input->redirect("/cgi-bin/koha/circ/circulation.pl?borrowernumber=$member");
  27     exit;
  28 }
  29
  30 my $category_type = $patron->category->category_type;
  31 my $bor = $patron->unblessed;
  32 if( $category_type eq 'S' )  { # FIXME Is this really needed?
  33     $flagsrequired->{'staffaccess'} = 1;
  34 }
  35 my ($template, $loggedinuser, $cookie) = get_template_and_user({
  36         template_name   => "members/member-flags.tt",
  37         query           => $input,
  38         type            => "intranet",
  39         flagsrequired   => $flagsrequired,
  40 });
  41
  42 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  43 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  44
  45 my %member2;
  46 $member2{'borrowernumber'}=$member;
  47
  48 if ($input->param('newflags')) {
  49
  50     output_and_exit( $input, $cookie, $template,  'wrong_csrf_token' )
  51         unless Koha::Token->new->check_csrf({
  52             session_id => scalar $input->cookie('CGISESSID'),
  53             token  => scalar $input->param('csrf_token'),
  54         });
  55
  56
  57     my $dbh=C4::Context->dbh();
  58
  59     my @perms = $input->multi_param('flag');
  60     my %all_module_perms = ();
  61     my %sub_perms = ();
  62     foreach my $perm (@perms) {
  63         if ($perm !~ /:/) {
  64             $all_module_perms{$perm} = 1;
  65         } else {
  66             my ($module, $sub_perm) = split /:/, $perm, 2;
  67             push @{ $sub_perms{$module} }, $sub_perm;
  68         }
  69     }
  70
  71     # construct flags
  72     my $module_flags = 0;
  73     my $sth=$dbh->prepare("SELECT bit,flag FROM userflags ORDER BY bit");
  74     $sth->execute();
  75     while (my ($bit, $flag) = $sth->fetchrow_array) {
  76         if (exists $all_module_perms{$flag}) {
  77             $module_flags += 2**$bit;
  78         }
  79     }
  80
  81     $sth = $dbh->prepare("UPDATE borrowers SET flags=? WHERE borrowernumber=?");
  82     my $old_flags = $patron->flags // 0;
  83     if( ( $old_flags == 1 || $module_flags == 1 ) &&
  84       $old_flags != $module_flags ) {
  85         die "Non-superlibrarian is changing superlibrarian privileges" if !C4::Context->IsSuperLibrarian && C4::Context->preference('ProtectSuperlibrarianPrivileges'); # Interface should not allow this, so we can just die here
  86     }
  87     $sth->execute($module_flags, $member);
  88
  89     # deal with subpermissions
  90     $sth = $dbh->prepare("DELETE FROM user_permissions WHERE borrowernumber = ?");
  91     $sth->execute($member);
  92     $sth = $dbh->prepare("INSERT INTO user_permissions (borrowernumber, module_bit, code)
  93                         SELECT ?, bit, ?
  94                         FROM userflags
  95                         WHERE flag = ?");
  96     foreach my $module (keys %sub_perms) {
  97         next if exists $all_module_perms{$module};
  98         foreach my $sub_perm (@{ $sub_perms{$module} }) {
  99             $sth->execute($member, $sub_perm, $module);
 100         }
 101     }
 102
 103     print $input->redirect("/cgi-bin/koha/members/moremember.pl?borrowernumber=$member");
 104 } else {
 105
 106     my $accessflags;
 107     my $dbh = C4::Context->dbh();
 108     # FIXME This needs to be improved to avoid doing the same query
 109     my $sth = $dbh->prepare("select bit,flag from userflags");
 110     $sth->execute;
 111     while ( my ( $bit, $flag ) = $sth->fetchrow ) {
 112         if ( $bor->{flags} && $bor->{flags} & 2**$bit ) {
 113             $accessflags->{$flag} = 1;
 114         }
 115     }
 116
 117     my $all_perms  = get_all_subpermissions();
 118     my $user_perms = get_user_subpermissions($bor->{'userid'});
 119     $sth = $dbh->prepare("SELECT bit, flag FROM userflags ORDER BY bit");
 120     $sth->execute;
 121     my @loop;
 122
 123     while (my ($bit, $flag) = $sth->fetchrow) {
 124         my $checked='';
 125         if ($accessflags->{$flag}) {
 126             $checked= 1;
 127         }
 128
 129         my %row = ( bit => $bit,
 130             flag => $flag,
 131             checked => $checked,
 132         );
 133
 134         my @sub_perm_loop = ();
 135         my $expand_parent = 0;
 136         if ($checked) {
 137             if (exists $all_perms->{$flag}) {
 138                 $expand_parent = 1;
 139                 foreach my $sub_perm (sort keys %{ $all_perms->{$flag} }) {
 140                     push @sub_perm_loop, {
 141                         id => "${flag}_$sub_perm",
 142                         perm => "$flag:$sub_perm",
 143                         code => $sub_perm,
 144                         checked => 1
 145                     };
 146                 }
 147             }
 148         } else {
 149             if (exists $user_perms->{$flag}) {
 150                 $expand_parent = 1;
 151                 # put selected ones first
 152                 foreach my $sub_perm (sort keys %{ $user_perms->{$flag} }) {
 153                     push @sub_perm_loop, {
 154                         id => "${flag}_$sub_perm",
 155                         perm => "$flag:$sub_perm",
 156                         code => $sub_perm,
 157                         checked => 1
 158                     };
 159                 }
 160             }
 161             # then ones not selected
 162             if (exists $all_perms->{$flag}) {
 163                 foreach my $sub_perm (sort keys %{ $all_perms->{$flag} }) {
 164                     push @sub_perm_loop, {
 165                         id => "${flag}_$sub_perm",
 166                         perm => "$flag:$sub_perm",
 167                         code => $sub_perm,
 168                         checked => 0
 169                     } unless exists $user_perms->{$flag} and exists $user_perms->{$flag}->{$sub_perm};
 170                 }
 171             }
 172         }
 173         $row{expand} = $expand_parent;
 174         if ($#sub_perm_loop > -1) {
 175             $row{sub_perm_loop} = \@sub_perm_loop;
 176         }
 177         next if ( ( $row{flag} eq 'cash_management' ) && !C4::Context->preference('UseCashRegisters') );
 178         push @loop, \%row;
 179     }
 180
 181 $template->param(
 182     patron         => $patron,
 183     loop           => \@loop,
 184     csrf_token =>
 185         Koha::Token->new->generate_csrf( { session_id => scalar $input->cookie('CGISESSID'), } ),
 186     disable_superlibrarian_privs => C4::Context->preference('ProtectSuperlibrarianPrivileges') ? !C4::Context->IsSuperLibrarian : 0,
 187 );
 188
 189     output_html_with_http_headers $input, $cookie, $template->output;
 190
 191 }