members/moremember.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 moremember.pl
  24
  25  script to do a borrower enquiry/bring up borrower details etc
  26  Displays all the details about a borrower
  27  written 20/12/99 by chris@katipo.co.nz
  28  last modified 21/1/2000 by chris@katipo.co.nz
  29  modified 31/1/2001 by chris@katipo.co.nz
  30    to not allow items on request to be renewed
  31
  32  needs html removed and to use the C4::Output more, but its tricky
  33
  34 =cut
  35
  36 use strict;
  37 #use warnings; FIXME - Bug 2505
  38 use CGI qw ( -utf8 );
  39 use C4::Context;
  40 use C4::Auth;
  41 use C4::Output;
  42 use C4::Members;
  43 use C4::Members::Attributes;
  44 use C4::Members::AttributeTypes;
  45 use C4::Dates;
  46 use C4::Reserves;
  47 use C4::Circulation;
  48 use C4::Koha;
  49 use C4::Letters;
  50 use C4::Biblio;
  51 use C4::Branch; # GetBranchName
  52 use C4::Form::MessagingPreferences;
  53 use List::MoreUtils qw/uniq/;
  54 use C4::Members::Attributes qw(GetBorrowerAttributes);
  55 use Koha::Borrower::Debarments qw(GetDebarments IsDebarred);
  56 use Module::Load;
  57 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
  58     load Koha::NorwegianPatronDB, qw( NLGetSyncDataFromBorrowernumber );
  59 }
  60 #use Smart::Comments;
  61 #use Data::Dumper;
  62 use DateTime;
  63 use Koha::DateUtils;
  64 use Koha::Database;
  65
  66 use vars qw($debug);
  67
  68 BEGIN {
  69         $debug = $ENV{DEBUG} || 0;
  70 }
  71
  72 my $dbh = C4::Context->dbh;
  73
  74 my $input = CGI->new;
  75 $debug or $debug = $input->param('debug') || 0;
  76 my $print = $input->param('print');
  77
  78 my $template_name;
  79 my $quickslip = 0;
  80
  81 my $flagsrequired;
  82 if (defined $print and $print eq "page") {
  83     $template_name = "members/moremember-print.tt";
  84     # circ staff who process checkouts but can't edit
  85     # patrons still need to be able to access print view
  86     $flagsrequired = { circulate => "circulate_remaining_permissions" };
  87 } elsif (defined $print and $print eq "slip") {
  88     $template_name = "members/moremember-receipt.tt";
  89     # circ staff who process checkouts but can't edit
  90     # patrons still need to be able to print receipts
  91     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  92 } elsif (defined $print and $print eq "qslip") {
  93     $template_name = "members/moremember-receipt.tt";
  94     $quickslip = 1;
  95     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  96 } elsif (defined $print and $print eq "brief") {
  97     $template_name = "members/moremember-brief.tt";
  98     $flagsrequired = { borrowers => 1 };
  99 } else {
 100     $template_name = "members/moremember.tt";
 101     $flagsrequired = { borrowers => 1 };
 102 }
 103
 104 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 105     {
 106         template_name   => $template_name,
 107         query           => $input,
 108         type            => "intranet",
 109         authnotrequired => 0,
 110         flagsrequired   => $flagsrequired,
 111         debug           => 1,
 112     }
 113 );
 114 my $borrowernumber = $input->param('borrowernumber');
 115 my $error = $input->param('error');
 116 $template->param( error => $error ) if ( $error );
 117
 118 my ( $od, $issue, $fines ) = GetMemberIssuesAndFines($borrowernumber);
 119 $template->param( issuecount => $issue );
 120
 121 my $data = GetMember( 'borrowernumber' => $borrowernumber );
 122
 123 if ( not defined $data ) {
 124     $template->param (unknowuser => 1);
 125         output_html_with_http_headers $input, $cookie, $template->output;
 126     exit;
 127 }
 128
 129 my $category_type = $data->{'category_type'};
 130
 131 $debug and printf STDERR "dates (enrolled,expiry,birthdate) raw: (%s, %s, %s)\n", map {$data->{$_}} qw(dateenrolled dateexpiry dateofbirth);
 132 foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 133                 my $userdate = $data->{$_};
 134                 unless ($userdate) {
 135                         $debug and warn sprintf "Empty \$data{%12s}", $_;
 136                         $data->{$_} = '';
 137                         next;
 138                 }
 139                 $userdate = C4::Dates->new($userdate,'iso')->output('syspref');
 140                 $data->{$_} = $userdate || '';
 141                 $template->param( $_ => $userdate );
 142 }
 143 $data->{'IS_ADULT'} = ( $data->{'categorycode'} ne 'I' );
 144
 145 for (qw(gonenoaddress lost borrowernotes)) {
 146          $data->{$_} and $template->param(flagged => 1) and last;
 147 }
 148
 149 if ( IsDebarred($borrowernumber) ) {
 150     $template->param( 'userdebarred' => 1, 'flagged' => 1 );
 151     my $debar = $data->{'debarred'};
 152     if ( $debar ne "9999-12-31" ) {
 153         $template->param( 'userdebarreddate' => C4::Dates::format_date($debar) );
 154         $template->param( 'debarredcomment'  => $data->{debarredcomment} );
 155     }
 156 }
 157
 158 $data->{ "sex_".$data->{'sex'}."_p" } = 1 if defined $data->{sex};
 159
 160 my $catcode;
 161 if ( $category_type eq 'C') {
 162    my  ( $catcodes, $labels ) =  GetborCatFromCatType( 'A', 'WHERE category_type = ?' );
 163    my $cnt = scalar(@$catcodes);
 164
 165    $template->param( 'CATCODE_MULTI' => 1) if $cnt > 1;
 166    $template->param( 'catcode' =>    $catcodes->[0])  if $cnt == 1;
 167 }
 168
 169 my ( $count, $guarantees ) = GetGuarantees( $data->{'borrowernumber'} );
 170 if ( $count ) {
 171     $template->param( isguarantee => 1 );
 172
 173     # FIXME
 174     # It looks like the $i is only being returned to handle walking through
 175     # the array, which is probably better done as a foreach loop.
 176     #
 177     my @guaranteedata;
 178     for ( my $i = 0 ; $i < $count ; $i++ ) {
 179         push(@guaranteedata,
 180             {
 181                 borrowernumber => $guarantees->[$i]->{'borrowernumber'},
 182                 cardnumber     => $guarantees->[$i]->{'cardnumber'},
 183                 name           => $guarantees->[$i]->{'firstname'} . " "
 184                                 . $guarantees->[$i]->{'surname'}
 185             }
 186         );
 187     }
 188     $template->param( guaranteeloop => \@guaranteedata );
 189 }
 190 else {
 191     if ($data->{'guarantorid'}){
 192             my ($guarantor) = GetMember( 'borrowernumber' =>$data->{'guarantorid'});
 193                 $template->param(guarantor => 1);
 194                 foreach (qw(borrowernumber cardnumber firstname surname)) {
 195                           $template->param("guarantor$_" => $guarantor->{$_});
 196         }
 197     }
 198         if ($category_type eq 'C'){
 199                 $template->param('C' => 1);
 200         }
 201 }
 202
 203 $template->param( adultborrower => 1 ) if ( $category_type eq 'A' || $category_type eq 'I' );
 204
 205 my %bor;
 206 $bor{'borrowernumber'} = $borrowernumber;
 207
 208 # Converts the branchcode to the branch name
 209 my $samebranch;
 210 if ( C4::Context->preference("IndependentBranches") ) {
 211     my $userenv = C4::Context->userenv;
 212     if ( C4::Context->IsSuperLibrarian() ) {
 213         $samebranch = 1;
 214     }
 215     else {
 216         $samebranch = ( $data->{'branchcode'} eq $userenv->{branch} );
 217     }
 218 }
 219 else {
 220     $samebranch = 1;
 221 }
 222 my $branchdetail = GetBranchDetail( $data->{'branchcode'});
 223 @{$data}{keys %$branchdetail} = values %$branchdetail; # merge in all branch columns
 224
 225 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 226 my $lib1 = &GetSortDetails( "Bsort1", $data->{'sort1'} );
 227 my $lib2 = &GetSortDetails( "Bsort2", $data->{'sort2'} );
 228 $template->param( lib1 => $lib1 ) if ($lib1);
 229 $template->param( lib2 => $lib2 ) if ($lib2);
 230
 231 # If printing a page, send the account informations to the template
 232 if ($print eq "page") {
 233     foreach my $accountline (@$accts) {
 234         $accountline->{amount} = sprintf '%.2f', $accountline->{amount};
 235         $accountline->{amountoutstanding} = sprintf '%.2f', $accountline->{amountoutstanding};
 236
 237         if ($accountline->{accounttype} ne 'F' && $accountline->{accounttype} ne 'FU'){
 238             $accountline->{printtitle} = 1;
 239         }
 240     }
 241     $template->param( accounts => $accts );
 242 }
 243
 244 # Show OPAC privacy preference is system preference is set
 245 if ( C4::Context->preference('OPACPrivacy') ) {
 246     $template->param( OPACPrivacy => 1);
 247     $template->param( "privacy".$data->{'privacy'} => 1);
 248 }
 249
 250 my @relatives = GetMemberRelatives($borrowernumber);
 251 my $relatives_issues_count =
 252   Koha::Database->new()->schema()->resultset('Issue')
 253   ->count( { borrowernumber => \@relatives } );
 254
 255 my $roadtype = C4::Koha::GetAuthorisedValueByCode( 'ROADTYPE', $data->{streettype} );
 256 my $today       = DateTime->now( time_zone => C4::Context->tz);
 257 $today->truncate(to => 'day');
 258 my @borrowers_with_issues;
 259 my $overdues_exist = 0;
 260 my $totalprice = 0;
 261
 262 ### ###############################################################################
 263 # BUILD HTML
 264 # show all reserves of this borrower, and the position of the reservation ....
 265 if ($borrowernumber) {
 266     $template->param(
 267         holds_count => Koha::Database->new()->schema()->resultset('Reserve')
 268           ->count( { borrowernumber => $borrowernumber } ) );
 269 }
 270
 271 # current alert subscriptions
 272 my $alerts = getalert($borrowernumber);
 273 foreach (@$alerts) {
 274     $_->{ $_->{type} } = 1;
 275     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 276 }
 277
 278 # Add sync data to the user data
 279 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
 280     my $sync = NLGetSyncDataFromBorrowernumber( $borrowernumber );
 281     if ( $sync ) {
 282         $data->{'sync'}       = $sync->sync;
 283         $data->{'syncstatus'} = $sync->syncstatus;
 284         $data->{'lastsync'}   = $sync->lastsync;
 285     }
 286 }
 287
 288 # check to see if patron's image exists in the database
 289 # basically this gives us a template var to condition the display of
 290 # patronimage related interface on
 291 my ($picture, $dberror) = GetPatronImage($data->{'borrowernumber'});
 292 $template->param( picture => 1 ) if $picture;
 293
 294 my $branch=C4::Context->userenv->{'branch'};
 295
 296 $template->param(%$data);
 297
 298 if (C4::Context->preference('ExtendedPatronAttributes')) {
 299     my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
 300     my @classes = uniq( map {$_->{class}} @$attributes );
 301     @classes = sort @classes;
 302
 303     my @attributes_loop;
 304     for my $class (@classes) {
 305         my @items;
 306         for my $attr (@$attributes) {
 307             push @items, $attr if $attr->{class} eq $class
 308         }
 309         my $lib = GetAuthorisedValueByCode( 'PA_CLASS', $class ) || $class;
 310         push @attributes_loop, {
 311             class => $class,
 312             items => \@items,
 313             lib   => $lib,
 314         };
 315     }
 316
 317     $template->param(
 318         ExtendedPatronAttributes => 1,
 319         attributes_loop => \@attributes_loop
 320     );
 321
 322     my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 323     if (scalar(@types) == 0) {
 324         $template->param(no_patron_attribute_types => 1);
 325     }
 326 }
 327
 328 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 329     C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 330     $template->param(messaging_form_inactive => 1);
 331     $template->param(SMSSendDriver => C4::Context->preference("SMSSendDriver"));
 332     $template->param(SMSnumber     => defined $data->{'smsalertnumber'} ? $data->{'smsalertnumber'} : $data->{'mobile'});
 333     $template->param(TalkingTechItivaPhone => C4::Context->preference("TalkingTechItivaPhoneNotification"));
 334 }
 335
 336 # in template <TMPL_IF name="I"> => instutitional (A for Adult, C for children)
 337 $template->param( $data->{'categorycode'} => 1 );
 338 $template->param(
 339     detailview => 1,
 340     AllowRenewalLimitOverride => C4::Context->preference("AllowRenewalLimitOverride"),
 341     roadtype        => $roadtype,
 342     borrowernumber  => $borrowernumber,
 343     othernames      => $data->{'othernames'},
 344     categoryname    => $data->{'description'},
 345     was_renewed     => $input->param('was_renewed') ? 1 : 0,
 346     branch          => $branch,
 347     todaysdate      => C4::Dates->today(),
 348     totalprice      => sprintf("%.2f", $totalprice),
 349     totaldue        => sprintf("%.2f", $total),
 350     totaldue_raw    => $total,
 351     overdues_exist  => $overdues_exist,
 352     StaffMember     => ($category_type eq 'S'),
 353     is_child        => ($category_type eq 'C'),
 354     samebranch      => $samebranch,
 355     quickslip       => $quickslip,
 356     activeBorrowerRelationship => (C4::Context->preference('borrowerRelationship') ne ''),
 357     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 358     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 359     RoutingSerials => C4::Context->preference('RoutingSerials'),
 360     debarments => GetDebarments({ borrowernumber => $borrowernumber }),
 361     PatronsPerPage => C4::Context->preference("PatronsPerPage") || 20,
 362     relatives_issues_count => $relatives_issues_count,
 363     relatives_borrowernumbers => \@relatives,
 364 );
 365
 366 output_html_with_http_headers $input, $cookie, $template->output;