members/two_factor_auth.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use CGI qw(-utf8);
  21
  22 use C4::Auth qw( get_template_and_user );
  23 use C4::Output qw( output_and_exit output_html_with_http_headers );
  24
  25 use Koha::Patrons;
  26 use Koha::Auth::TwoFactorAuth;
  27 use Koha::Token;
  28
  29 my $cgi = CGI->new;
  30
  31 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  32     {
  33         template_name => 'members/two_factor_auth.tt',
  34         query         => $cgi,
  35         type          => 'intranet',
  36         flagsrequired => { editcatalogue => '*' },
  37     }
  38 );
  39
  40 unless ( C4::Context->preference('TwoFactorAuthentication') ) {
  41     print $cgi->redirect("/cgi-bin/koha/errors/404.pl");
  42     exit;
  43 }
  44
  45 my $logged_in_user = Koha::Patrons->find($loggedinuser);
  46
  47 my $op = $cgi->param('op') // '';
  48 my $csrf_pars = {
  49     session_id => scalar $cgi->cookie('CGISESSID'),
  50     token  => scalar $cgi->param('csrf_token'),
  51 };
  52
  53 if ( $op eq 'register-2FA' ) {
  54     output_and_exit( $cgi, $cookie, $template, 'wrong_csrf_token' )
  55         unless Koha::Token->new->check_csrf($csrf_pars);
  56
  57     my $pin_code = $cgi->param('pin_code');
  58     my $secret32 = $cgi->param('secret32');
  59     my $auth     = Koha::Auth::TwoFactorAuth->new(
  60         { patron => $logged_in_user, secret32 => $secret32 } );
  61
  62     my $verified = $auth->verify(
  63         $pin_code,
  64         1,    # range
  65         $secret32,
  66         undef,    # timestamp (defaults to now)
  67         30,       # interval (default 30)
  68     );
  69
  70     if ($verified) {
  71         $logged_in_user->secret($secret32);
  72         $op = 'registered';
  73
  74         # FIXME Generate a (new?) secret
  75         $logged_in_user->auth_method('two-factor')->store;
  76     }
  77     else {
  78         $template->param( invalid_pin => 1, );
  79         $op = 'enable-2FA';
  80     }
  81 }
  82
  83 if ( $op eq 'enable-2FA' ) {
  84
  85     my $secret = Koha::AuthUtils::generate_salt( 'weak', 16 );
  86     my $auth = Koha::Auth::TwoFactorAuth->new(
  87         { patron => $logged_in_user, secret => $secret } );
  88
  89     $template->param(
  90         issuer      => $auth->issuer,
  91         key_id      => $auth->key_id,
  92         qr_code  => $auth->qr_code,
  93         secret32    => $auth->secret32,
  94             # IMPORTANT: get secret32 after qr_code call !
  95     );
  96     $auth->clear;
  97     $op = 'register';
  98 }
  99 elsif ( $op eq 'disable-2FA' ) {
 100     output_and_exit( $cgi, $cookie, $template, 'wrong_csrf_token' )
 101         unless Koha::Token->new->check_csrf($csrf_pars);
 102     $logged_in_user->auth_method('password')->store;
 103 }
 104
 105 $template->param(
 106     csrf_token => Koha::Token->new->generate_csrf(
 107         { session_id => scalar $cgi->cookie('CGISESSID') }
 108     ),
 109     patron => $logged_in_user,
 110     op     => $op,
 111 );
 112
 113 output_html_with_http_headers $cgi, $cookie, $template->output;