misc/background_jobs_worker.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use JSON qw( decode_json );
  20 use Try::Tiny qw( catch try );
  21
  22 use Koha::BackgroundJobs;
  23
  24 my $conn;
  25 try {
  26     $conn = Koha::BackgroundJob->connect;
  27 } catch {
  28     warn sprintf "Cannot connect to the message broker, the jobs will be processed anyway (%s)", $_;
  29 };
  30
  31 my @job_types = qw(
  32     batch_biblio_record_modification
  33     batch_authority_record_modification
  34     batch_item_record_modification
  35     batch_biblio_record_deletion
  36     batch_authority_record_deletion
  37     batch_item_record_deletion
  38     batch_hold_cancel
  39 );
  40
  41 if ( $conn ) {
  42     # FIXME cf note in Koha::BackgroundJob about $namespace
  43     my $namespace = C4::Context->config('memcached_namespace');
  44     for my $job_type ( @job_types ) {
  45         $conn->subscribe({ destination => sprintf("/queue/%s-%s", $namespace, $job_type), ack => 'client' });
  46     }
  47 }
  48 while (1) {
  49     if ( $conn ) {
  50         my $frame = $conn->receive_frame;
  51         if ( !defined $frame ) {
  52             # maybe log connection problems
  53             next;    # will reconnect automatically
  54         }
  55
  56         my $body = $frame->body;
  57         my $args = decode_json($body);
  58
  59         # FIXME This means we need to have create the DB entry before
  60         # It could work in a first step, but then we will want to handle job that will be created from the message received
  61         my $job = Koha::BackgroundJobs->find($args->{job_id});
  62
  63         process_job( $job, $args );
  64         $conn->ack( { frame => $frame } ); # FIXME depending on success?
  65
  66     } else {
  67         my $jobs = Koha::BackgroundJobs->search({ status => 'new' });
  68         while ( my $job = $jobs->next ) {
  69             my $args = decode_json($job->data);
  70             process_job( $job, { job_id => $job->id, %$args } );
  71         }
  72         sleep 10;
  73     }
  74 }
  75 $conn->disconnect;
  76
  77 sub process_job {
  78     my ( $job, $args ) = @_;
  79
  80     my $pid;
  81     if ( $pid = fork ) {
  82         wait;
  83         return;
  84     }
  85
  86     die "fork failed!" unless defined $pid;
  87
  88     $job->process( $args );
  89     exit;
  90 }