misc/commit_file.pl

   1 #!/usr/bin/perl
   2
   3 use Modern::Perl;
   4
   5 BEGIN {
   6     # find Koha's Perl modules
   7     # test carefully before changing this
   8     use FindBin ();
   9     eval { require "$FindBin::Bin/kohalib.pl" };
  10 }
  11
  12 use Koha::Script;
  13 use C4::Context;
  14 use C4::ImportBatch qw( GetAllImportBatches GetImportBatch BatchCommitRecords BatchRevertRecords );
  15 use Getopt::Long qw( GetOptions );
  16
  17 $| = 1;
  18
  19 # command-line parameters
  20 my $batch_number = "";
  21 my $list_batches = 0;
  22 my $revert = 0;
  23 my $want_help = 0;
  24 my $framework = '';
  25
  26 my $result = GetOptions(
  27     'batch-number:s' => \$batch_number,
  28     'list-batches'   => \$list_batches,
  29     'framework:s'    => \$framework,
  30     'revert'         => \$revert,
  31     'h|help'         => \$want_help
  32 );
  33
  34 if ($want_help or (not $batch_number and not $list_batches)) {
  35     print_usage();
  36     exit 0;
  37 }
  38
  39 if ($list_batches) {
  40     list_batches();
  41     exit 0;
  42 }
  43
  44 # FIXME dummy user so that logging won't fail
  45 # in future, probably should tie to a real user account
  46 C4::Context->set_userenv(0, 'batch', 0, 'batch', 'batch', 'batch', 'batch');
  47
  48 if ($batch_number =~ /^\d+$/ and $batch_number > 0) {
  49     my $batch = GetImportBatch($batch_number);
  50     die "$0: import batch $batch_number does not exist in database\n" unless defined $batch;
  51     if ($revert) {
  52         die "$0: import batch $batch_number status is '" . $batch->{'import_status'} . "', and therefore cannot be imported\n"
  53             unless $batch->{'import_status'} eq "imported";
  54         revert_batch($batch_number);
  55     } else {
  56         die "$0: import batch $batch_number status is '" . $batch->{'import_status'} . "', and therefore cannot be imported\n"
  57             unless $batch->{'import_status'} eq "staged" or $batch->{'import_status'} eq "reverted";
  58         process_batch($batch_number);
  59     }
  60 } else {
  61     die "$0: please specify a numeric batch ID\n";
  62 }
  63
  64 exit 0;
  65
  66 sub list_batches {
  67     my $results = GetAllImportBatches();
  68     print sprintf("%5.5s %-25.25s %-25.25s %-10.10s\n", "#", "File name", "Batch comments", "Status");
  69     print '-' x 5, ' ' , '-' x 25, ' ', '-' x 25, ' ', '-' x 10, "\n" ;
  70     foreach my $batch (@{ $results}) {
  71         if ($batch->{'import_status'} eq "staged" or $batch->{'import_status'} eq "reverted") {
  72             print sprintf("%5.5s %-25.25s %-25.25s %-10.10s\n",
  73                           $batch->{'import_batch_id'},
  74                           $batch->{'file_name'},
  75                           $batch->{'comments'},
  76                           $batch->{'import_status'});
  77         }
  78     }
  79 }
  80
  81 sub process_batch {
  82     my ($import_batch_id) = @_;
  83
  84     print "... importing MARC records -- please wait\n";
  85     my ($num_added, $num_updated, $num_items_added, $num_items_replaced, $num_items_errored, $num_ignored) =
  86         BatchCommitRecords($import_batch_id, $framework, 100, \&print_progress);
  87     print "... finished importing MARC records\n";
  88
  89     print <<_SUMMARY_;
  90
  91 MARC record import report
  92 ----------------------------------------
  93 Batch number:                    $import_batch_id
  94 Number of new records added:     $num_added
  95 Number of records replaced:      $num_updated
  96 Number of records ignored:       $num_ignored
  97 Number of items added:           $num_items_added
  98 Number of items replaced:        $num_items_replaced
  99 Number of items ignored:         $num_items_errored
 100
 101 Note: an item is ignored if its barcode is a
 102 duplicate of one already in the database.
 103 _SUMMARY_
 104 }
 105
 106 sub revert_batch {
 107     my ($import_batch_id) = @_;
 108
 109     print "... reverting batch -- please wait\n";
 110     my ($num_deleted, $num_errors, $num_reverted, $num_items_deleted, $num_ignored) =
 111         BatchRevertRecords( $import_batch_id );
 112     print "... finished reverting batch\n";
 113
 114     print <<_SUMMARY_;
 115
 116 MARC record import report
 117 ----------------------------------------
 118 Batch number:                    $import_batch_id
 119 Number of records deleted:       $num_deleted
 120 Number of errors:                $num_errors
 121 Number of records reverted:      $num_reverted
 122 Number of records ignored:       $num_ignored
 123 Number of items deleted:         $num_items_deleted
 124
 125 _SUMMARY_
 126 }
 127
 128
 129 sub print_progress {
 130     my ( $recs ) = @_;
 131     print "... processed $recs records\n";
 132 }
 133
 134 sub print_usage {
 135     print <<_USAGE_;
 136 $0: import a batch of staged MARC records into database.
 137
 138 Use this batch job to complete the import of a batch of
 139 MARC records that was staged either by the batch job
 140 stage_file.pl or by the Koha Tools option
 141 "Stage MARC Records for Import".
 142
 143 Parameters:
 144     --batch-number <#>   number of the record batch
 145                          to import
 146     --framework <code>   add new records using this framework.  If
 147                          omitted, the default framework is used.
 148     --list-batches       print a list of record batches
 149                          available to commit
 150     --revert             revert a batch instead of importing it
 151     --help or -h         show this message.
 152 _USAGE_
 153 }