misc/cronjobs/edi_cron.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2013,2014,2015 PTFS Europe Ltd
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use warnings;
  21 use strict;
  22 use utf8;
  23
  24 # Handles all the edi processing for a site
  25 # loops through the vendor_edifact records and uploads and downloads
  26 # edifact files if the appropriate type is enabled
  27 # downloaded quotes, invoices and responses are processed here
  28 # if orders are enabled and present they are generated and sent
  29 # can be run as frequently as required
  30 # log messages are appended to logdir/editrace.log
  31
  32 use Koha::Script -cron;
  33 use C4::Context;
  34 use Log::Log4perl qw(:easy);
  35 use Koha::Database;
  36 use Koha::EDI qw( process_quote process_invoice process_ordrsp);
  37 use Koha::Edifact::Transport;
  38 use Fcntl qw( :DEFAULT :flock :seek );
  39
  40 my $logdir = C4::Context->config('logdir');
  41
  42 # logging set to trace as this may be what you
  43 # want on implementation
  44 Log::Log4perl->easy_init(
  45     {
  46         level => $TRACE,
  47         file  => ">>$logdir/editrace.log",
  48     }
  49 );
  50
  51 # we dont have a lock dir in context so use the logdir
  52 my $pidfile = "$logdir/edicron.pid";
  53
  54 my $pid_handle = check_pidfile();
  55
  56 my $schema = Koha::Database->new()->schema();
  57
  58 my @edi_accts = $schema->resultset('VendorEdiAccount')->all();
  59
  60 my $logger = Log::Log4perl->get_logger();
  61
  62 for my $acct (@edi_accts) {
  63     if ( $acct->quotes_enabled ) {
  64         my $downloader = Koha::Edifact::Transport->new( $acct->id );
  65         $downloader->download_messages('QUOTE');
  66
  67     }
  68
  69     if ( $acct->invoices_enabled ) {
  70         my $downloader;
  71
  72         if ( $acct->plugin ) {
  73             $downloader = Koha::Plugins::Handler->run(
  74                 {
  75                     class  => $acct->plugin,
  76                     method => 'edifact_transport',
  77                     params => {
  78                         vendor_edi_account_id => $acct->id,
  79                     }
  80                 }
  81             );
  82         }
  83
  84         $downloader ||= Koha::Edifact::Transport->new( $acct->id );
  85
  86         $downloader->download_messages('INVOICE');
  87
  88     }
  89     if ( $acct->orders_enabled ) {
  90
  91         # select pending messages
  92         my @pending_orders = $schema->resultset('EdifactMessage')->search(
  93             {
  94                 message_type => 'ORDERS',
  95                 vendor_id    => $acct->vendor_id,
  96                 status       => 'Pending',
  97             }
  98         );
  99         my $uploader = Koha::Edifact::Transport->new( $acct->id );
 100         $uploader->upload_messages(@pending_orders);
 101     }
 102     if ( $acct->responses_enabled ) {
 103         my $downloader = Koha::Edifact::Transport->new( $acct->id );
 104         $downloader->download_messages('ORDRSP');
 105     }
 106 }
 107
 108 # process any downloaded quotes
 109
 110 my @downloaded_quotes = $schema->resultset('EdifactMessage')->search(
 111     {
 112         message_type => 'QUOTE',
 113         status       => 'new',
 114     }
 115 )->all;
 116
 117 foreach my $quote_file (@downloaded_quotes) {
 118     my $filename = $quote_file->filename;
 119     $logger->trace("Processing quote $filename");
 120     process_quote($quote_file);
 121 }
 122
 123 # process any downloaded invoices
 124 if ( C4::Context->preference('EdifactInvoiceImport') eq 'automatic' ) {
 125     my @downloaded_invoices = $schema->resultset('EdifactMessage')->search(
 126         {
 127             message_type => 'INVOICE',
 128             status       => 'new',
 129         }
 130     )->all;
 131
 132     foreach my $invoice (@downloaded_invoices) {
 133         my $filename = $invoice->filename();
 134         $logger->trace("Processing invoice $filename");
 135         process_invoice($invoice);
 136     }
 137 }
 138
 139 my @downloaded_responses = $schema->resultset('EdifactMessage')->search(
 140     {
 141         message_type => 'ORDRSP',
 142         status       => 'new',
 143     }
 144 )->all;
 145
 146 foreach my $response (@downloaded_responses) {
 147     my $filename = $response->filename();
 148     $logger->trace("Processing order response $filename");
 149     process_ordrsp($response);
 150 }
 151
 152 if ( close $pid_handle ) {
 153     unlink $pidfile;
 154     exit 0;
 155 }
 156 else {
 157     $logger->error("Error on pidfile close: $!");
 158     exit 1;
 159 }
 160
 161 sub check_pidfile {
 162
 163     # sysopen my $fh, $pidfile, O_EXCL | O_RDWR or log_exit "$0 already running"
 164     sysopen my $fh, $pidfile, O_RDWR | O_CREAT
 165       or log_exit("$0: open $pidfile: $!");
 166     flock $fh => LOCK_EX or log_exit("$0: flock $pidfile: $!");
 167
 168     sysseek $fh, 0, SEEK_SET or log_exit("$0: sysseek $pidfile: $!");
 169     truncate $fh, 0 or log_exit("$0: truncate $pidfile: $!");
 170     print $fh "$$\n" or log_exit("$0: print $pidfile: $!");
 171
 172     return $fh;
 173 }
 174
 175 sub log_exit {
 176     my $error = shift;
 177     $logger->error($error);
 178
 179     exit 1;
 180 }