misc/cronjobs/fines.pl

   1 #!/usr/bin/perl
   2
   3 #  This script loops through each overdue item, determines the fine,
   4 #  and updates the total amount of fines due by each user.  It relies on
   5 #  the existence of /tmp/fines, which is created by ???
   6 # Doesn't really rely on it, it relys on being able to write to /tmp/
   7 # It creates the fines file
   8 #
   9 #  This script is meant to be run nightly out of cron.
  10
  11 # Copyright 2000-2002 Katipo Communications
  12 # Copyright 2011 PTFS-Europe Ltd
  13 #
  14 # This file is part of Koha.
  15 #
  16 # Koha is free software; you can redistribute it and/or modify it
  17 # under the terms of the GNU General Public License as published by
  18 # the Free Software Foundation; either version 3 of the License, or
  19 # (at your option) any later version.
  20 #
  21 # Koha is distributed in the hope that it will be useful, but
  22 # WITHOUT ANY WARRANTY; without even the implied warranty of
  23 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  24 # GNU General Public License for more details.
  25 #
  26 # You should have received a copy of the GNU General Public License
  27 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  28
  29 use strict;
  30 use warnings;
  31 use 5.010;
  32
  33 use Koha::Script -cron;
  34 use C4::Context;
  35 use C4::Overdues;
  36 use Getopt::Long;
  37 use Carp;
  38 use File::Spec;
  39 use Try::Tiny;
  40
  41 use Koha::Calendar;
  42 use Koha::DateUtils;
  43 use Koha::Patrons;
  44 use C4::Log;
  45
  46 my $help;
  47 my $verbose;
  48 my $output_dir;
  49 my $log;
  50 my $maxdays;
  51
  52 GetOptions(
  53     'h|help'    => \$help,
  54     'v|verbose' => \$verbose,
  55     'l|log'     => \$log,
  56     'o|out:s'   => \$output_dir,
  57     'm|maxdays:i' => \$maxdays,
  58 );
  59 my $usage = << 'ENDUSAGE';
  60
  61 This script calculates and charges overdue fines
  62 to patron accounts.  The Koha system preference 'finesMode' controls
  63 whether the fines are calculated and charged to the patron accounts ("Calculate and charge");
  64 or not calculated ("Don't calculate").
  65
  66 This script has the following parameters :
  67     -h --help: this message
  68     -l --log: log the output to a file (optional if the -o parameter is given)
  69     -o --out:  ouput directory for logs (defaults to env or /tmp if !exist)
  70     -v --verbose
  71     -m --maxdays: how many days back of overdues to process
  72
  73 ENDUSAGE
  74
  75 if ($help) {
  76     print $usage;
  77     exit;
  78 }
  79
  80 my $script_handler = Koha::Script->new({ script => $0 });
  81
  82 try {
  83     $script_handler->lock_exec;
  84 }
  85 catch {
  86     my $message = "Skipping execution of $0 ($_)";
  87     print STDERR "$message\n"
  88         if $verbose;
  89     cronlogaction( $message );
  90     exit;
  91 };
  92
  93 cronlogaction();
  94
  95 my @borrower_fields =
  96   qw(cardnumber categorycode surname firstname email phone address citystate);
  97 my @item_fields  = qw(itemnumber barcode date_due);
  98 my @other_fields = qw(days_overdue fine);
  99 my $libname      = C4::Context->preference('LibraryName');
 100 my $control      = C4::Context->preference('CircControl');
 101 my $mode         = C4::Context->preference('finesMode');
 102 my $delim = "\t";    # ?  C4::Context->preference('delimiter') || "\t";
 103
 104 my %is_holiday;
 105 my $today = dt_from_string();
 106 my $filename;
 107 if ($log or $output_dir) {
 108     $filename = get_filename($output_dir);
 109 }
 110
 111 my $fh;
 112 if ($filename) {
 113     open $fh, '>>', $filename or croak "Cannot write file $filename: $!";
 114     print {$fh} join $delim, ( @borrower_fields, @item_fields, @other_fields );
 115     print {$fh} "\n";
 116 }
 117 my $counted = 0;
 118 my $params;
 119 $params->{maximumdays} = $maxdays if $maxdays;
 120 my $overdues = Getoverdues($params);
 121 for my $overdue ( @{$overdues} ) {
 122     next if $overdue->{itemlost};
 123
 124     if ( !defined $overdue->{borrowernumber} ) {
 125         carp
 126 "ERROR in Getoverdues : issues.borrowernumber IS NULL.  Repair 'issues' table now!  Skipping record.\n";
 127         next;
 128     }
 129     my $patron = Koha::Patrons->find( $overdue->{borrowernumber} );
 130     my $branchcode =
 131         ( $control eq 'ItemHomeLibrary' ) ? $overdue->{homebranch}
 132       : ( $control eq 'PatronLibrary' )   ? $patron->branchcode
 133       :                                     $overdue->{branchcode};
 134     # In final case, CircControl must be PickupLibrary. (branchcode comes from issues table here).
 135
 136     my $datedue = dt_from_string( $overdue->{date_due} );
 137     if ( DateTime->compare( $datedue, $today ) == 1 ) {
 138         next;    # not overdue
 139     }
 140     ++$counted;
 141
 142     my ( $amount, $unitcounttotal, $unitcount ) =
 143       CalcFine( $overdue, $patron->categorycode,
 144         $branchcode, $datedue, $today );
 145
 146     if ( $mode eq 'production' ) {
 147         if ( $amount && $amount > 0 ) {
 148             UpdateFine(
 149                 {
 150                     issue_id       => $overdue->{issue_id},
 151                     itemnumber     => $overdue->{itemnumber},
 152                     borrowernumber => $overdue->{borrowernumber},
 153                     amount         => $amount,
 154                     due            => output_pref($datedue),
 155                 }
 156             );
 157         }
 158     }
 159     my $borrower = $patron->unblessed;
 160     if ($filename) {
 161         my @cells;
 162         push @cells,
 163           map { defined $borrower->{$_} ? $borrower->{$_} : q{} }
 164           @borrower_fields;
 165         push @cells, map { $overdue->{$_} } @item_fields;
 166         push @cells, $unitcounttotal, $amount;
 167         say {$fh} join $delim, @cells;
 168     }
 169 }
 170 if ($filename){
 171     close $fh;
 172 }
 173
 174 if ($verbose) {
 175     my $overdue_items = @{$overdues};
 176     print <<"EOM";
 177 Fines assessment -- $today
 178 EOM
 179     if ($filename) {
 180         say "Saved to $filename";
 181     }
 182     print <<"EOM";
 183 Number of Overdue Items:
 184      counted $overdue_items
 185     reported $counted
 186
 187 EOM
 188 }
 189
 190 sub get_filename {
 191     my $directory = shift;
 192     if ( !$directory ) {
 193         $directory = C4::Context::temporary_directory;
 194     }
 195     if ( !-d $directory ) {
 196         carp "Could not write to $directory ... does not exist!";
 197     }
 198     my $name = C4::Context->config('database');
 199     $name =~ s/\W//;
 200     $name .= join q{}, q{_}, $today->ymd(), '.log';
 201     $name = File::Spec->catfile( $directory, $name );
 202     if ($verbose && $log) {
 203         say "writing to $name";
 204     }
 205     return $name;
 206 }