misc/cronjobs/fines.pl

   1 #!/usr/bin/perl
   2
   3 #  This script loops through each overdue item, determines the fine,
   4 #  and updates the total amount of fines due by each user.  It relies on
   5 #  the existence of /tmp/fines, which is created by ???
   6 # Doesnt really rely on it, it relys on being able to write to /tmp/
   7 # It creates the fines file
   8 #
   9 #  This script is meant to be run nightly out of cron.
  10
  11 # Copyright 2000-2002 Katipo Communications
  12 # Copyright 2011 PTFS-Europe Ltd
  13 #
  14 # This file is part of Koha.
  15 #
  16 # Koha is free software; you can redistribute it and/or modify it under the
  17 # terms of the GNU General Public License as published by the Free Software
  18 # Foundation; either version 2 of the License, or (at your option) any later
  19 # version.
  20 #
  21 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  22 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  23 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  24 #
  25 # You should have received a copy of the GNU General Public License along
  26 # with Koha; if not, write to the Free Software Foundation, Inc.,
  27 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  28
  29 use strict;
  30 use warnings;
  31 use 5.010;
  32
  33 use C4::Context;
  34 use C4::Overdues;
  35 use Getopt::Long;
  36 use Carp;
  37 use File::Spec;
  38
  39 use Koha::Calendar;
  40 use Koha::DateUtils;
  41
  42 my $help;
  43 my $verbose;
  44 my $output_dir;
  45 my $log;
  46
  47 GetOptions(
  48     'h|help'    => \$help,
  49     'v|verbose' => \$verbose,
  50     'l|log'     => \$log,
  51     'o|out:s'   => \$output_dir,
  52 );
  53 my $usage = << 'ENDUSAGE';
  54
  55 This script calculates and charges overdue fines
  56 to patron accounts.  If the Koha System Preference
  57 'finesMode' is set to 'production', the fines are charged
  58 to the patron accounts.  If set to 'test', the fines are
  59 calculated but not applied.
  60
  61 This script has the following parameters :
  62     -h --help: this message
  63     -l --log: log the output to a file
  64     -o --out:  ouput directory for logs (defaults to env or /tmp if !exist)
  65     -v --verbose
  66
  67 ENDUSAGE
  68
  69 if ($help) {
  70     print $usage;
  71     exit;
  72 }
  73
  74 my @borrower_fields =
  75   qw(cardnumber categorycode surname firstname email phone address citystate);
  76 my @item_fields  = qw(itemnumber barcode date_due);
  77 my @other_fields = qw(type days_overdue fine);
  78 my $libname      = C4::Context->preference('LibraryName');
  79 my $control      = C4::Context->preference('CircControl');
  80 my $mode         = C4::Context->preference('finesMode');
  81 my $delim = "\t";    # ?  C4::Context->preference('delimiter') || "\t";
  82
  83 my %is_holiday;
  84 my $today = DateTime->now( time_zone => C4::Context->tz() );
  85 my $filename = get_filename($output_dir);
  86
  87 my $fh;
  88 if ($log) {
  89     open $fh, '>>', $filename or croak "Cannot write file $filename: $!";
  90     print {$fh} join $delim, ( @borrower_fields, @item_fields, @other_fields );
  91     print {$fh} "\n";
  92 }
  93 my $counted = 0;
  94 my $overdues = Getoverdues();
  95 for my $overdue ( @{$overdues} ) {
  96     if ( !defined $overdue->{borrowernumber} ) {
  97         carp
  98 "ERROR in Getoverdues : issues.borrowernumber IS NULL.  Repair 'issues' table now!  Skipping record.\n";
  99         next;
 100     }
 101     my $borrower = BorType( $overdue->{borrowernumber} );
 102     my $branchcode =
 103         ( $control eq 'ItemHomeLibrary' ) ? $overdue->{homebranch}
 104       : ( $control eq 'PatronLibrary' )   ? $borrower->{branchcode}
 105       :                                     $overdue->{branchcode};
 106
 107 # In final case, CircControl must be PickupLibrary. (branchcode comes from issues table here).
 108     if ( !exists $is_holiday{$branchcode} ) {
 109         $is_holiday{$branchcode} = set_holiday( $branchcode, $today );
 110     }
 111
 112     my $datedue = dt_from_string( $overdue->{date_due} );
 113     if ( DateTime->compare( $datedue, $today ) == 1 ) {
 114         next;    # not overdue
 115     }
 116     ++$counted;
 117
 118     my ( $amount, $type, $unitcounttotal ) =
 119       CalcFine( $overdue, $borrower->{categorycode},
 120         $branchcode, $datedue, $today );
 121     $type ||= q{};
 122
 123     # Don't update the fine if today is a holiday.
 124     # This ensures that dropbox mode will remove the correct amount of fine.
 125     if ( $mode eq 'production' && !$is_holiday{$branchcode} ) {
 126         if ( $amount > 0 ) {
 127             UpdateFine(
 128                 $overdue->{itemnumber},
 129                 $overdue->{borrowernumber},
 130                 $amount, $type, output_pref($datedue)
 131             );
 132         }
 133     }
 134     if ($log) {
 135         my @cells;
 136         push @cells,
 137           map { defined $borrower->{$_} ? $borrower->{$_} : q{} }
 138           @borrower_fields;
 139         push @cells, map { $overdue->{$_} } @item_fields;
 140         push @cells, $type, $unitcounttotal, $amount;
 141         say {$fh} join $delim, @cells;
 142     }
 143 }
 144 if ($log){
 145     close $fh;
 146 }
 147
 148 if ($verbose) {
 149     my $overdue_items = @{$overdues};
 150     print <<"EOM";
 151 Fines assessment -- $today
 152 EOM
 153     if ($log) {
 154         say "Saved to $filename";
 155     }
 156     print <<"EOM";
 157 Number of Overdue Items:
 158      counted $overdue_items
 159     reported $counted
 160
 161 EOM
 162 }
 163
 164 sub set_holiday {
 165     my ( $branch, $dt ) = @_;
 166
 167     my $calendar = Koha::Calendar->new( branchcode => $branch );
 168     return $calendar->is_holiday($dt);
 169 }
 170
 171 sub get_filename {
 172     my $directory = shift;
 173     if ( !$directory ) {
 174         $directory = File::Spec->tmpdir();
 175     }
 176     if ( !-d $directory ) {
 177         carp "Could not write to $directory ... does not exist!";
 178     }
 179     my $name = C4::Context->config('database');
 180     $name =~ s/\W//;
 181     $name .= join q{}, q{_}, $today->ymd(), '.log';
 182     $name = File::Spec->catfile( $directory, $name );
 183     if ($verbose && $log) {
 184         say "writing to $name";
 185     }
 186     return $name;
 187 }