misc/cronjobs/holds/holds_reminder.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Getopt::Long qw( GetOptions );
  21 use Pod::Usage qw( pod2usage );
  22 use DateTime;
  23 use DateTime::Duration;
  24
  25 use C4::Context;
  26 use C4::Letters;
  27 use C4::Log qw( cronlogaction );
  28 use Koha::DateUtils qw( dt_from_string );
  29 use Koha::Calendar;
  30 use Koha::Libraries;
  31 use Koha::Notice::Templates;
  32 use Koha::Patrons;
  33 use Koha::Script -cron;
  34
  35 =head1 NAME
  36
  37 holds_reminder.pl - prepare reminder messages to be sent to patrons with waiting holds
  38
  39 =head1 SYNOPSIS
  40
  41 holds_reminder.pl
  42   -lettercode <notice to send>
  43   [ -c ][ -v ][ -library <branchcode> ][ -library <branchcode> ... ]
  44   [ -days <number of days> ][ -mtt <transport type> ... ][ -holidays ]
  45   [ -date <YYYY-MM-DD> ]
  46
  47  Options:
  48    -help                          brief help message
  49    -man                           full documentation
  50    -v                             verbose
  51    -c --confirm                   confirm, if not set no email will be sent
  52    -days          <days>          days waiting to deal with
  53    -t --triggered                 include only holds <days> days waiting, and not longer
  54    -lettercode   <lettercode>     predefined notice to use, default is HOLD_REMINDER
  55    -library      <branchname>     only deal with holds from this library (repeatable : several libraries can be given)
  56    -holidays                      use the calendar to not count holidays as waiting days
  57    -mtt          <message_transport_type> type of messages to send, default is to use patrons messaging preferences for Hold reminder
  58                                   populating this will force send even if patron has not chosen to receive hold notices
  59                                   email and sms will fallback to print if borrower does not have an address/phone
  60    -date                          Send notices as would have been sent on a specific date
  61
  62 =head1 OPTIONS
  63
  64 =over 8
  65
  66 =item B<-help>
  67
  68 Print a brief help message and exits.
  69
  70 =item B<-man>
  71
  72 Prints the manual page and exits.
  73
  74 =item B<-v>
  75
  76 Verbose. Without this flag set, only fatal errors are reported.
  77
  78 =item B<--confirm | -c>
  79
  80 Confirm. Unless set this script does not send any email (test-mode).
  81 If verbose and not confirm a list of notices that would have been sent to
  82 the patrons are printed to standard out.
  83
  84 =item B<-days>
  85
  86 Optional parameter, number of days an items has been 'waiting' on hold
  87 to send a message for. If not included a notice will be sent to all
  88 patrons with waiting holds.
  89
  90 =item B<-triggered>
  91
  92 Optional parameter, only send notices for holds exactly <days> waiting.
  93 If not included a notice will be sent to all patrons with waiting holds
  94 equal to OR greater than <days>. This option is useful if the cron is
  95 being run daily to avoid spamming the patrons.
  96
  97 =item B<-lettercode>
  98
  99 Optional parameter, choose a notice to use. Default is 'HOLD_REMINDER'.
 100
 101 =item B<-library>
 102
 103 select notices for one specific library. Use the value in the
 104 branches.branchcode table. This option can be repeated in order
 105 to select notices for a group of libraries.
 106
 107 =item B<-holidays>
 108
 109 This option determines whether library holidays are used when calculating how
 110 long an item has been waiting. If enabled the count will skip closed days.
 111
 112 =item B<-date>
 113
 114 use it in order to send notices on a specific date and not Now. Format: YYYY-MM-DD.
 115
 116 =item B<-mtt>
 117
 118 send a notices via a specific transport, this can be repeated to send various notices.
 119 If omitted the patron's messaging preferences for Hold notices will be used.
 120 If supplied the notice types will be force sent even if patron has not selected hold notices
 121 Email and SMS will fall back to print if there is no valid info in the patron's account
 122
 123
 124 =back
 125
 126 =head1 DESCRIPTION
 127
 128 This script is designed to alert patrons of waiting
 129 holds.
 130
 131 =head2 Configuration
 132
 133 This script sends reminders to patrons with waiting holds using a notice
 134 defined in the Tools->Notices & slips module within Koha. The lettercode
 135 is passed into this script and, along with other options, determine the content
 136 of the notices sent to patrons.
 137
 138
 139 =head1 USAGE EXAMPLES
 140
 141 C<holds_reminder.pl> - With no arguments the simple help is printed
 142
 143 C<holds_reminder.pl > In this most basic usage all
 144 libraries are processed individually, and notices are prepared for
 145 all patrons with waiting holds for whom we have email addresses.
 146 Messages for those patrons for whom we have no email
 147 address are sent in a single attachment to the library administrator's
 148 email address, or to the address in the KohaAdminEmailAddress system
 149 preference.
 150
 151 C<holds_reminder.pl -n -csv /tmp/holds_reminder.csv> - sends no email and
 152 populates F</tmp/holds_reminder.csv> with information about all waiting holds
 153 items.
 154
 155 C<holds_reminder.pl -library MAIN -days 14> - prepare notices of
 156 holds waiting for 2 weeks for the MAIN library.
 157
 158 C<holds_reminder.pl -lettercode LATE_HOLDS -library MAIN -days 14> - prepare notices of
 159 holds waiting for 2 weeks for the MAIN library. Use lettercode 'LATE_HOLDS'
 160
 161 =cut
 162
 163 # These variables are set by command line options.
 164 # They are initially set to default values.
 165 my $dbh = C4::Context->dbh();
 166 my $help    = 0;
 167 my $man     = 0;
 168 my $verbose = 0;
 169 my $confirm  = 0;
 170 my $days    ;
 171 my $triggered  = 0;
 172 my $lettercode;
 173 my @branchcodes; # Branch(es) passed as parameter
 174 my $use_calendar = 0;
 175 my $date_input;
 176 my $opt_out = 0;
 177 my @mtts;
 178
 179 GetOptions(
 180     'help|?'         => \$help,
 181     'man'            => \$man,
 182     'v'              => \$verbose,
 183     'c|confirm'      => \$confirm,
 184     'days=s'         => \$days,
 185     'triggered'      => \$triggered,
 186     'lettercode=s'   => \$lettercode,
 187     'library=s'      => \@branchcodes,
 188     'date=s'         => \$date_input,
 189     'holidays'       => \$use_calendar,
 190     'mtt=s'          => \@mtts
 191 );
 192 pod2usage(1) if $help;
 193 pod2usage( -verbose => 2 ) if $man;
 194
 195 $lettercode ||= 'HOLD_REMINDER';
 196
 197 cronlogaction();
 198
 199 # Unless a delay is specified by the user we target all waiting holds
 200 unless (defined $days) {
 201     $days=0;
 202 }
 203
 204 # Unless one ore more branchcodes are passed we use all the branches
 205 if (scalar @branchcodes > 0) {
 206     my $branchcodes_word = scalar @branchcodes > 1 ? 'branches' : 'branch';
 207     $verbose and warn "$branchcodes_word @branchcodes passed on parameter\n";
 208 }
 209 else {
 210     @branchcodes = Koha::Libraries->search()->get_column('branchcode');
 211 }
 212
 213 # If provided we run the report as if it had run on a specified date
 214 my $date_to_run;
 215 if ( $date_input ){
 216     eval {
 217         $date_to_run = dt_from_string( $date_input, 'iso' );
 218     };
 219     die "$date_input is not a valid date, aborting! Use a date in format YYYY-MM-DD."
 220         if $@ or not $date_to_run;
 221 }
 222 else {
 223     $date_to_run = dt_from_string();
 224 }
 225
 226 # Loop through each branch
 227 foreach my $branchcode (@branchcodes) { #BEGIN BRANCH LOOP
 228     # Check that this branch has the letter code specified or skip this branch
 229
 230     # FIXME What if we don't want to default if the translated template does not exist?
 231     my $template_exists = Koha::Notice::Templates->find_effective_template(
 232         {
 233             module     => 'reserves',
 234             code       => $lettercode,
 235             branchcode => $branchcode,
 236             lang       => 'default',
 237         }
 238     );
 239     unless ($template_exists) {
 240         $verbose and print qq|Message '$lettercode' content not found for $branchcode\n|;
 241         next;
 242     }
 243
 244     # If respecting calendar get the correct waiting since date
 245     my $waiting_date;
 246     if( $use_calendar ){
 247         my $calendar = Koha::Calendar->new( branchcode => $branchcode, days_mode => 'Calendar' );
 248         my $duration = DateTime::Duration->new( days => -$days );
 249         $waiting_date = $calendar->addDays($date_to_run,$duration); #Add negative of days
 250     } else {
 251         $waiting_date = $date_to_run->subtract( days => $days );
 252     }
 253
 254     # Find all the holds waiting since this date for the current branch
 255     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 256     my $waiting_since = $dtf->format_date( $waiting_date );
 257     my $comparator = $triggered ? '=' : '<=';
 258     my $reserves = Koha::Holds->search({
 259         waitingdate => {$comparator => $waiting_since },
 260         'me.branchcode'  => $branchcode,
 261     },{ prefetch => 'patron' });
 262
 263     $verbose and warn "No reserves found for $branchcode\n" unless $reserves->count;
 264     next unless $reserves->count;
 265     $verbose and warn $reserves->count . " reserves waiting since $waiting_since for $branchcode\n";
 266
 267     # We only want to send one notice per patron per branch - this variable will hold the completed borrowers
 268     my %done;
 269
 270     # If passed message transports we force use those, otherwise we will use the patrons preferences
 271     # for the 'Hold_Reminder' notice
 272     my $sending_params = @mtts ? { message_transports => \@mtts } : { message_name => "Hold_Reminder" };
 273
 274
 275     my %patrons;
 276     while ( my $reserve = $reserves->next ) {
 277         $patrons{$reserve->borrowernumber}->{patron} = $reserve->patron unless exists $patrons{$reserve->borrowernumber};
 278         push @{$patrons{$reserve->borrowernumber}->{reserves}}, $reserve->reserve_id;
 279     }
 280
 281     foreach my $borrowernumber (keys %patrons){
 282
 283         my $patron = $patrons{$borrowernumber}->{patron};
 284         $verbose and print "  borrower " . $patron->surname . ", " . $patron->firstname . " has " . scalar @{$patrons{$borrowernumber}->{reserves}}  . " holds triggering notice.\n";
 285
 286         # Setup the notice information
 287         my $letter_params = {
 288             module          => 'reserves',
 289             letter_code     => $lettercode,
 290             borrowernumber  => $patron->borrowernumber,
 291             branchcode      => $branchcode,
 292             tables          => {
 293                  borrowers  => $patron->borrowernumber,
 294                  branches   => $branchcode,
 295             },
 296             loops           => {
 297                 reserves    => $patrons{$borrowernumber}->{reserves}
 298             },
 299         };
 300         $sending_params->{letter_params} = $letter_params;
 301         $sending_params->{test_mode} = !$confirm;
 302         my $result_text = $confirm ? "was sent" : "would have been sent";
 303         # queue_notice queues the notices, falling back to print for email or SMS, and ignores phone (they are handled by Itiva)
 304         my $result = $patron->queue_notice( $sending_params );
 305         $verbose and print "   borrower " . $patron->surname . ", " . $patron->firstname . " $result_text notices via: @{$result->{sent}}\n" if defined $result->{sent};
 306         $verbose and print "   borrower " . $patron->surname . ", " . $patron->firstname . " $result_text print fallback for: @{$result->{fallback}}\n" if defined $result->{fallback};
 307         # Mark this borrower as completed
 308         $done{$patron->borrowernumber} = 1;
 309     }
 310
 311
 312 } #END BRANCH LOOP