misc/cronjobs/membership_expiry.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) 2015 Amit Gupta (amitddng135@gmail.com)
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 NAME
  21
  22 membership_expiry.pl - cron script to put membership expiry reminders into the message queue
  23
  24 =head1 SYNOPSIS
  25
  26 ./membership_expiry.pl -c
  27
  28 or, in crontab:
  29
  30 0 1 * * * membership_expiry.pl -c
  31
  32 =head1 DESCRIPTION
  33
  34 This script sends membership expiry reminder notices to patrons.
  35 It queues them in the message queue, which is processed by
  36 the process_message_queue.pl cronjob.
  37
  38 =head1 OPTIONS
  39
  40 =over 8
  41
  42 =item B<--help>
  43
  44 Print a brief help message and exits.
  45
  46 =item B<--man>
  47
  48 Prints the manual page and exits.
  49
  50 =item B<-v>
  51
  52 Verbose. Without this flag set, only fatal errors are reported.
  53
  54 =item B<-n>
  55
  56 Do not send any email. Membership expire notices that would have been sent to
  57 the patrons are printed to standard out.
  58
  59 =item B<-c>
  60
  61 Confirm flag: Add this option. The script will only print a usage
  62 statement otherwise.
  63
  64 =item B<-branch>
  65
  66 Optional branchcode to restrict the cronjob to that branch.
  67
  68 =item B<-before>
  69
  70 Optional parameter to extend the selection with a number of days BEFORE
  71 the date set by the preference.
  72
  73 =item B<-after>
  74
  75 Optional parameter to extend the selection with a number of days AFTER
  76 the date set by the preference.
  77
  78 =item B<-letter>
  79
  80 Optional parameter to use another notice than the default one.
  81
  82 =back
  83
  84 =head1 CONFIGURATION
  85
  86 The content of the messages is configured in Tools -> Notices and slips. Use the MEMBERSHIP_EXPIRY notice.
  87
  88 Typically, messages are prepared for each patron when the memberships are going to expire.
  89
  90 These emails are staged in the outgoing message queue, as are messages
  91 produced by other features of Koha. This message queue must be
  92 processed regularly by the
  93 F<misc/cronjobs/process_message_queue.pl> program.
  94
  95 In the event that the C<-n> flag is passed to this program, no emails
  96 are sent. Instead, messages are sent on standard output from this
  97 program.
  98
  99 Notices can contain variables enclosed in double angle brackets like
 100 E<lt>E<lt>thisE<gt>E<gt>. Those variables will be replaced with values
 101 specific to the soon expiring members.
 102 Available variables are:
 103
 104 =over
 105
 106 =item E<lt>E<lt>borrowers.*E<gt>E<gt>
 107
 108 any field from the borrowers table
 109
 110 =item E<lt>E<lt>branches.*E<gt>E<gt>
 111
 112 any field from the branches table
 113
 114 =back
 115
 116 =cut
 117
 118 use Modern::Perl;
 119 use Getopt::Long qw( GetOptions );
 120 use Pod::Usage qw( pod2usage );
 121 BEGIN {
 122     # find Koha's Perl modules
 123     # test carefully before changing this
 124     use FindBin ();
 125     eval { require "$FindBin::Bin/../kohalib.pl" };
 126 }
 127
 128 use Koha::Script -cron;
 129 use C4::Context;
 130 use C4::Letters;
 131 use C4::Log qw( cronlogaction );
 132
 133 use Koha::Patrons;
 134
 135 # These are defaults for command line options.
 136 my $confirm;                              # -c: Confirm that the user has read and configured this script.
 137 my $nomail;                               # -n: No mail. Will not send any emails.
 138 my $verbose = 0;                           # -v: verbose
 139 my $help    = 0;
 140 my $man     = 0;
 141 my $before  = 0;
 142 my $after   = 0;
 143 my ( $branch, $letter_type );
 144
 145 GetOptions(
 146     'help|?'         => \$help,
 147     'man'            => \$man,
 148     'c'              => \$confirm,
 149     'n'              => \$nomail,
 150     'v'              => \$verbose,
 151     'branch:s'       => \$branch,
 152     'before:i'       => \$before,
 153     'after:i'        => \$after,
 154     'letter:s'       => \$letter_type,
 155 ) or pod2usage(2);
 156
 157 pod2usage( -verbose => 2 ) if $man;
 158 pod2usage(1) if $help || !$confirm;
 159
 160 cronlogaction();
 161
 162 my $expdays = C4::Context->preference('MembershipExpiryDaysNotice');
 163 if( !$expdays ) {
 164     #If the pref is not set, we will exit
 165     warn 'Exiting membership_expiry.pl: MembershipExpiryDaysNotice not set'
 166         if $verbose;
 167     exit;
 168 }
 169
 170 warn 'getting upcoming membership expires' if $verbose;
 171 my $upcoming_mem_expires = Koha::Patrons->search_upcoming_membership_expires(
 172     {
 173         ( $branch ? ( 'me.branchcode' => $branch ) : () ),
 174         before => $before,
 175         after  => $after,
 176     }
 177 );
 178 warn 'found ' . $upcoming_mem_expires->count . ' soon expiring members'
 179     if $verbose;
 180
 181 # main loop
 182 $letter_type = 'MEMBERSHIP_EXPIRY' if !$letter_type;
 183 while ( my $recent = $upcoming_mem_expires->next ) {
 184     my $from_address = $recent->library->from_email_address;
 185     my $letter =  C4::Letters::GetPreparedLetter(
 186         module      => 'members',
 187         letter_code => $letter_type,
 188         branchcode  => $recent->branchcode,
 189         lang        => $recent->lang,
 190         tables      => {
 191             borrowers => $recent->borrowernumber,
 192             branches  => $recent->branchcode,
 193         },
 194     );
 195     last if !$letter; # Letters.pm already warned, just exit
 196     if( $nomail ) {
 197         print $letter->{'content'}."\n";
 198     } else {
 199         C4::Letters::EnqueueLetter({
 200             letter                 => $letter,
 201             borrowernumber         =>  $recent->borrowernumber,
 202             from_address           => $from_address,
 203             message_transport_type => 'email',
 204         });
 205     }
 206 }